Принятие к учету ОС. Нулевая стоимость НУ

Question

Провожу документ Принятие к учету ОС. При отражении проводок в регл. учете есть только сумма БУ, а суммы НУ нет, она нулевая. Залез в код, понял, что данные берутся из РН "Стоимость ОС". Смотрю движения по этому регистру. В ресурсе Стоимость (НУ) ноль. Посмотрел как формируются набор движений в этот регистр. Ниже сам запрос (важные фрагменты выделены //).

ТекстЗапросаТаблицаСтоимостьОС

Процедура ТекстЗапросаТаблицаСтоимостьОС(Запрос, ТекстыЗапроса, Регистры)

    ИмяРегистра = "СтоимостьОС";
    
    Если Не ПроведениеСерверУТ.ТребуетсяТаблицаДляДвижений(ИмяРегистра, Регистры) Тогда
        Возврат;
    КонецЕсли;
    
    ///////////////////////////////////////////////////////////////////////////////////////////////
    ВнеоборотныеАктивыСлужебный.ТекстЗапросаПустаяТаблицаСтоимости(ТекстыЗапроса, Запрос);
    ///////////////////////////////////////////////////////////////////////////////////////////////
    
    ///////////////////////////////////////////////////////////////////////////////////////////////
    ТекстЗапроса = ПринятиеКУчетуОСЛокализация.ТекстЗапросаТаблицаСтоимостьОС(ТекстыЗапроса);
    ///////////////////////////////////////////////////////////////////////////////////////////////
    
    Если ТекстЗапроса = Неопределено Тогда
        
        ТекстЗапроса =
        "ВЫБРАТЬ
        |    ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)       КАК ВидДвижения,
        |    &Период                                      КАК Период,
        |    &Организация                                 КАК Организация,
        |    &Местонахождение                             КАК Подразделение,
        |    &ГруппаФинансовогоУчета                      КАК ГруппаФинансовогоУчета,
        |    &НаправлениеДеятельности                     КАК НаправлениеДеятельности,
        |    ВЫБОР 
        |        КОГДА &ПорядокУчетаУУ = ЗНАЧЕНИЕ(Перечисление.ПорядокУчетаСтоимостиВнеоборотныхАктивов.АмортизацияНачислена)
        |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПринятиеКУчетуСамортизированногоОС)
        |        ИНАЧЕ &ХозяйственнаяОперация 
        |    КОНЕЦ                                        КАК ХозяйственнаяОперация,
        |    &ОтражатьВРеглУчете                          КАК ОтражатьВРеглУчете,
        |    &ОтражатьВУпрУчете                           КАК ОтражатьВУпрУчете,
        |    &ВидАналитикиКапитализацииРасходов           КАК ВидАналитикиКапитализацииРасходов,
        |    ТаблицаОС.ОсновноеСредство                   КАК ОсновноеСредство,
        |    ВЫБОР 
        |        КОГДА &ВидАналитикиКапитализацииРасходов = ЗНАЧЕНИЕ(Перечисление.ВидыАналитикиКапитализацииРасходов.ОбъектСтроительства) 
        |            ТОГДА &ОбъектСтроительства 
        |        ИНАЧЕ ТаблицаОС.ОсновноеСредство 
        |    КОНЕЦ                                        КАК АналитикаКапитализацииРасходов,
        |
        |    ЕСТЬNULL(РасчетСтоимости.КорПодразделение, НЕОПРЕДЕЛЕНО)                КАК КорПодразделение,
        |    ЕСТЬNULL(РасчетСтоимости.КорНаправлениеДеятельности, НЕОПРЕДЕЛЕНО)      КАК КорНаправлениеДеятельности,
        |    ЕСТЬNULL(РасчетСтоимости.КорСтатьяРасходов, НЕОПРЕДЕЛЕНО)               КАК КорСтатьяРасходов,
        |    ЕСТЬNULL(РасчетСтоимости.КорАналитикаРасходов, НЕОПРЕДЕЛЕНО)            КАК КорАналитикаРасходов,
        |    НЕ РасчетСтоимости.ОбъектУчета ЕСТЬ NULL                                КАК РасчетСтоимости,
        |
        |    ЕСТЬNULL(РасчетСтоимости.Стоимость, ТаблицаОС.СтоимостьУУ) КАК Стоимость,
        |    ЕСТЬNULL(РасчетСтоимости.СтоимостьРегл, ТаблицаОС.СтоимостьБУ) КАК СтоимостьРегл,
        |    ЕСТЬNULL(РасчетСтоимости.СтоимостьНУ, 0) КАК СтоимостьНУ,
        |    ЕСТЬNULL(РасчетСтоимости.СтоимостьПР, 0) КАК СтоимостьПР,
        |    ЕСТЬNULL(РасчетСтоимости.СтоимостьВР, 0) КАК СтоимостьВР,
        |    ЕСТЬNULL(РасчетСтоимости.СтоимостьЦФ, 0) КАК СтоимостьЦФ,
        |    ЕСТЬNULL(РасчетСтоимости.СтоимостьНУЦФ, 0) КАК СтоимостьНУЦФ,
        |    ЕСТЬNULL(РасчетСтоимости.СтоимостьПРЦФ, 0) КАК СтоимостьПРЦФ,
        |    ЕСТЬNULL(РасчетСтоимости.СтоимостьВРЦФ, 0) КАК СтоимостьВРЦФ,
        |
        |    0 КАК ПредварительнаяСтоимость,
        |    0 КАК ПредварительнаяСтоимостьРегл
        |ИЗ
        |    Документ.ПринятиеКУчетуОС2_4.ОС КАК ТаблицаОС
        |        ЛЕВОЕ СОЕДИНЕНИЕ ВтРасчетСтоимости КАК РасчетСтоимости
        |        ПО РасчетСтоимости.ОбъектУчета = ТаблицаОС.ОсновноеСредство
        |ГДЕ
        |    ТаблицаОС.Ссылка = &Ссылка
        |
        |ОБЪЕДИНИТЬ ВСЕ
        |
        // Нужно отдельно записать предварительную стоимость для расчета амортизации
        |ВЫБРАТЬ
        |    ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)       КАК ВидДвижения,
        |    &Период                                      КАК Период,
        |    &Организация                                 КАК Организация,
        |    &Местонахождение                             КАК Подразделение,
        |    &ГруппаФинансовогоУчета                      КАК ГруппаФинансовогоУчета,
        |    &НаправлениеДеятельности                     КАК НаправлениеДеятельности,
        |    ВЫБОР 
        |        КОГДА &ПорядокУчетаУУ = ЗНАЧЕНИЕ(Перечисление.ПорядокУчетаСтоимостиВнеоборотныхАктивов.АмортизацияНачислена)
        |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПринятиеКУчетуСамортизированногоОС)
        |        ИНАЧЕ &ХозяйственнаяОперация 
        |    КОНЕЦ                                        КАК ХозяйственнаяОперация,
        |    &ОтражатьВРеглУчете                          КАК ОтражатьВРеглУчете,
        |    &ОтражатьВУпрУчете                           КАК ОтражатьВУпрУчете,
        |    &ВидАналитикиКапитализацииРасходов           КАК ВидАналитикиКапитализацииРасходов,
        |    ТаблицаОС.ОсновноеСредство                   КАК ОсновноеСредство,
        |    ВЫБОР 
        |        КОГДА &ВидАналитикиКапитализацииРасходов = ЗНАЧЕНИЕ(Перечисление.ВидыАналитикиКапитализацииРасходов.ОбъектСтроительства) 
        |            ТОГДА &ОбъектСтроительства 
        |        ИНАЧЕ ТаблицаОС.ОсновноеСредство 
        |    КОНЕЦ                                        КАК АналитикаКапитализацииРасходов,
        |
        |    НЕОПРЕДЕЛЕНО                                 КАК КорПодразделение,
        |    НЕОПРЕДЕЛЕНО                                 КАК КорНаправлениеДеятельности,
        |    НЕОПРЕДЕЛЕНО                                 КАК КорСтатьяРасходов,
        |    НЕОПРЕДЕЛЕНО                                 КАК КорАналитикаРасходов,
        |    ЛОЖЬ                                         КАК РасчетСтоимости,
        |
        |    0                                            КАК Стоимость,
        |    0                                            КАК СтоимостьРегл,
        |    0                                            КАК СтоимостьНУ,
        |    0                                            КАК СтоимостьПР,
        |    0                                            КАК СтоимостьВР,
        |    0                                            КАК СтоимостьЦФ,
        |    0                                            КАК СтоимостьНУЦФ,
        |    0                                            КАК СтоимостьПРЦФ,
        |    0                                            КАК СтоимостьВРЦФ,
        |
        |    ТаблицаОС.СтоимостьУУ                        КАК ПредварительнаяСтоимость,
        |
        |    ВЫБОР
        |        КОГДА НЕ &ВедетсяРегламентированныйУчетВНА
        |            ТОГДА ТаблицаОС.СтоимостьБУ
        |        ИНАЧЕ 0
        |    КОНЕЦ                                        КАК ПредварительнаяСтоимостьРегл
        |ИЗ
        |    Документ.ПринятиеКУчетуОС2_4.ОС КАК ТаблицаОС
        |ГДЕ
        |    ТаблицаОС.Ссылка = &Ссылка
        |    И (ТаблицаОС.СтоимостьБУ <> 0 И НЕ &ВедетсяРегламентированныйУчетВНА
        |        ИЛИ ТаблицаОС.СтоимостьУУ <> 0)";
        
    КонецЕсли;
    
    ТекстыЗапроса.Добавить(ТекстЗапроса, ИмяРегистра, Истина);
    
КонецПроцедуры

Показать

ПринятиеКУчетуОСЛокализация.ТекстЗапросаТаблицаСтоимостьОС

Функция ТекстЗапросаТаблицаСтоимостьОС(ТекстыЗапроса) Экспорт

    ТекстЗапроса = Неопределено;
    
    //++ Локализация
    
    ТекстЗапроса =
    "ВЫБРАТЬ
    |    ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)       КАК ВидДвижения,
    |    &Период                                      КАК Период,
    |    &Организация                                 КАК Организация,
    |    &Местонахождение                             КАК Подразделение,
    |    &ГруппаФинансовогоУчета                      КАК ГруппаФинансовогоУчета,
    |    &НаправлениеДеятельности                     КАК НаправлениеДеятельности,
    |    ВЫБОР 
    |        КОГДА &ПорядокУчетаБУ = ЗНАЧЕНИЕ(Перечисление.ПорядокПогашенияСтоимостиОС.АмортизацияНачислена)
    |                ИЛИ &ПорядокУчетаУУ = ЗНАЧЕНИЕ(Перечисление.ПорядокУчетаСтоимостиВнеоборотныхАктивов.АмортизацияНачислена)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПринятиеКУчетуСамортизированногоОС)
    |        ИНАЧЕ &ХозяйственнаяОперация 
    |    КОНЕЦ                                        КАК ХозяйственнаяОперация,
    |    &ВариантПримененияЦелевогоФинансирования     КАК ВариантПримененияЦелевогоФинансирования,
    |    &ОтражатьВРеглУчете                          КАК ОтражатьВРеглУчете,
    |    &ОтражатьВУпрУчете                           КАК ОтражатьВУпрУчете,
    |    &ВидАналитикиКапитализацииРасходов           КАК ВидАналитикиКапитализацииРасходов,
    |    ТаблицаОС.ОсновноеСредство                   КАК ОсновноеСредство,
    |    &НалогообложениеНДС                          КАК НалогообложениеНДС,
    |    ВЫБОР 
    |        КОГДА &ВидАналитикиКапитализацииРасходов = ЗНАЧЕНИЕ(Перечисление.ВидыАналитикиКапитализацииРасходов.ОбъектСтроительства) 
    |            ТОГДА &ОбъектСтроительства 
    |        ИНАЧЕ ТаблицаОС.ОсновноеСредство 
    |    КОНЕЦ                                        КАК АналитикаКапитализацииРасходов,
    |
    |    ЕСТЬNULL(РасчетСтоимости.КорПодразделение, НЕОПРЕДЕЛЕНО)                КАК КорПодразделение,
    |    ЕСТЬNULL(РасчетСтоимости.КорНаправлениеДеятельности, НЕОПРЕДЕЛЕНО)      КАК КорНаправлениеДеятельности,
    |    ЕСТЬNULL(РасчетСтоимости.КорСтатьяРасходов, НЕОПРЕДЕЛЕНО)               КАК КорСтатьяРасходов,
    |    ЕСТЬNULL(РасчетСтоимости.КорАналитикаРасходов, НЕОПРЕДЕЛЕНО)            КАК КорАналитикаРасходов,
    |    НЕ РасчетСтоимости.ОбъектУчета ЕСТЬ NULL                                КАК РасчетСтоимости,
    |
    |    ЕСТЬNULL(РасчетСтоимости.Стоимость, ТаблицаОС.СтоимостьУУ) КАК Стоимость,
    |    ЕСТЬNULL(РасчетСтоимости.СтоимостьРегл, ТаблицаОС.СтоимостьБУ - ТаблицаОС.СуммаЦелевыхСредств) КАК СтоимостьРегл,
    |
    ///////////////////////////////////////////////////////////////////////////////////////////////
    |    ВЫБОР 
    |        КОГДА &ВключатьВСоставНалоговыхРасходовЛизинговыеПлатежи
    |                И &ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПринятиеКУчетуОСПоДоговоруЛизинга)
    |            ТОГДА ТаблицаОС.СтоимостьНУ 
    |        ИНАЧЕ ЕСТЬNULL(РасчетСтоимости.СтоимостьНУ, ТаблицаОС.СтоимостьНУ)
    |    КОНЕЦ КАК СтоимостьНУ,
    ///////////////////////////////////////////////////////////////////////////////////////////////
    |
    |    ВЫБОР 
    |        КОГДА &ВключатьВСоставНалоговыхРасходовЛизинговыеПлатежи
    |                И &ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПринятиеКУчетуОСПоДоговоруЛизинга)
    |            ТОГДА 0
    |        ИНАЧЕ ЕСТЬNULL(РасчетСтоимости.СтоимостьПР, ТаблицаОС.СтоимостьПР)
    |    КОНЕЦ КАК СтоимостьПР,
    |
    |    ВЫБОР 
    |        КОГДА &ВключатьВСоставНалоговыхРасходовЛизинговыеПлатежи 
    |                И &ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПринятиеКУчетуОСПоДоговоруЛизинга)
    |            ТОГДА ЕСТЬNULL(РасчетСтоимости.СтоимостьРегл, ТаблицаОС.СтоимостьБУ) - ТаблицаОС.СтоимостьНУ
    |        ИНАЧЕ ЕСТЬNULL(РасчетСтоимости.СтоимостьВР, ТаблицаОС.СтоимостьВР) 
    |    КОНЕЦ КАК СтоимостьВР,
    |
    |    ВЫБОР 
    |        КОГДА НЕ РасчетСтоимости.ОбъектУчета ЕСТЬ NULL
    |            ТОГДА РасчетСтоимости.СтоимостьЦФ 
    |        КОГДА &ОтражатьВРеглУчете
    |            ТОГДА ТаблицаОС.СуммаЦелевыхСредств 
    |        ИНАЧЕ 0 
    |    КОНЕЦ КАК СтоимостьЦФ,
    |
    |    ЕСТЬNULL(РасчетСтоимости.СтоимостьНУЦФ, 0) КАК СтоимостьНУЦФ,
    |    ЕСТЬNULL(РасчетСтоимости.СтоимостьПРЦФ, 0) КАК СтоимостьПРЦФ,
    |    ЕСТЬNULL(РасчетСтоимости.СтоимостьВРЦФ, 0) КАК СтоимостьВРЦФ,
    |
    |    ВЫБОР 
    |        КОГДА НЕ &ОтражатьВРеглУчете
    |            ТОГДА 0
    |        КОГДА &ВключатьВСоставНалоговыхРасходовЛизинговыеПлатежи
    |                И &ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПринятиеКУчетуОСПоДоговоруЛизинга)
    |            ТОГДА ТаблицаОС.СтоимостьНУ 
    |        ИНАЧЕ ЕСТЬNULL(РасчетСтоимости.СтоимостьНУ, ТаблицаОС.СтоимостьНУ)
    |    КОНЕЦ * &ПроцентКапитальныхВложенийВключаемыхВРасходыНУ / 100 КАК АмортизационнаяПремия,
    |
    |    0 КАК ПредварительнаяСтоимость,
    |    0 КАК ПредварительнаяСтоимостьРегл,
    |    ЕСТЬNULL(РасчетСтоимости.КорПостояннаяРазница, 0) КАК КорПостояннаяРазница,
    |    ЕСТЬNULL(РасчетСтоимости.КорВременнаяРазница, 0)  КАК КорВременнаяРазница
    |ИЗ
    |    Документ.ПринятиеКУчетуОС2_4.ОС КАК ТаблицаОС
    |        ЛЕВОЕ СОЕДИНЕНИЕ ВтРасчетСтоимости КАК РасчетСтоимости
    |        ПО РасчетСтоимости.ОбъектУчета = ТаблицаОС.ОсновноеСредство
    |ГДЕ
    |    ТаблицаОС.Ссылка = &Ссылка
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    // Нужно отдельно записать предварительную стоимость для расчета амортизации
    |ВЫБРАТЬ
    |    ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)       КАК ВидДвижения,
    |    &Период                                      КАК Период,
    |    &Организация                                 КАК Организация,
    |    &Местонахождение                             КАК Подразделение,
    |    &ГруппаФинансовогоУчета                      КАК ГруппаФинансовогоУчета,
    |    &НаправлениеДеятельности                     КАК НаправлениеДеятельности,
    |    ВЫБОР 
    |        КОГДА &ПорядокУчетаБУ = ЗНАЧЕНИЕ(Перечисление.ПорядокПогашенияСтоимостиОС.АмортизацияНачислена)
    |                ИЛИ &ПорядокУчетаУУ = ЗНАЧЕНИЕ(Перечисление.ПорядокУчетаСтоимостиВнеоборотныхАктивов.АмортизацияНачислена)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПринятиеКУчетуСамортизированногоОС)
    |        ИНАЧЕ &ХозяйственнаяОперация 
    |    КОНЕЦ                                        КАК ХозяйственнаяОперация,
    |    &ВариантПримененияЦелевогоФинансирования     КАК ВариантПримененияЦелевогоФинансирования,
    |    &ОтражатьВРеглУчете                          КАК ОтражатьВРеглУчете,
    |    &ОтражатьВУпрУчете                           КАК ОтражатьВУпрУчете,
    |    &ВидАналитикиКапитализацииРасходов           КАК ВидАналитикиКапитализацииРасходов,
    |    ТаблицаОС.ОсновноеСредство                   КАК ОсновноеСредство,
    |    &НалогообложениеНДС                          КАК НалогообложениеНДС,
    |    ВЫБОР 
    |        КОГДА &ВидАналитикиКапитализацииРасходов = ЗНАЧЕНИЕ(Перечисление.ВидыАналитикиКапитализацииРасходов.ОбъектСтроительства) 
    |            ТОГДА &ОбъектСтроительства 
    |        ИНАЧЕ ТаблицаОС.ОсновноеСредство 
    |    КОНЕЦ                                        КАК АналитикаКапитализацииРасходов,
    |
    |    НЕОПРЕДЕЛЕНО                                 КАК КорПодразделение,
    |    НЕОПРЕДЕЛЕНО                                 КАК КорНаправлениеДеятельности,
    |    НЕОПРЕДЕЛЕНО                                 КАК КорСтатьяРасходов,
    |    НЕОПРЕДЕЛЕНО                                 КАК КорАналитикаРасходов,
    |    ЛОЖЬ                                         КАК РасчетСтоимости,
    |
    |    0                                            КАК Стоимость,
    |    0                                            КАК СтоимостьРегл,
    |    0                                            КАК СтоимостьНУ,
    |    0                                            КАК СтоимостьПР,
    |    0                                            КАК СтоимостьВР,
    |    0                                            КАК СтоимостьЦФ,
    |    0                                            КАК СтоимостьНУЦФ,
    |    0                                            КАК СтоимостьПРЦФ,
    |    0                                            КАК СтоимостьВРЦФ,
    |    0                                            КАК АмортизационнаяПремия,
    |
    |    ТаблицаОС.СтоимостьУУ                        КАК ПредварительнаяСтоимость,
    |
    |    ВЫБОР
    |        КОГДА НЕ &ВедетсяРегламентированныйУчетВНА
    |            ТОГДА ТаблицаОС.СтоимостьБУ
    |        ИНАЧЕ 0
    |    КОНЕЦ                                        КАК ПредварительнаяСтоимостьРегл,
    |    0                                            КАК КорПостояннаяРазница,
    |    0                                            КАК КорВременнаяРазница
    |ИЗ
    |    Документ.ПринятиеКУчетуОС2_4.ОС КАК ТаблицаОС
    |ГДЕ
    |    ТаблицаОС.Ссылка = &Ссылка
    |    И (ТаблицаОС.СтоимостьБУ <> 0 И НЕ &ВедетсяРегламентированныйУчетВНА
    |        ИЛИ ТаблицаОС.СтоимостьУУ <> 0)
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    // Списание на расходы в НУ
    |ВЫБРАТЬ
    |    ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход)       КАК ВидДвижения,
    |    &Период                                      КАК Период,
    |    &Организация                                 КАК Организация,
    |    &Местонахождение                             КАК Подразделение,
    |    &ГруппаФинансовогоУчета                      КАК ГруппаФинансовогоУчета,
    |    &НаправлениеДеятельности                     КАК НаправлениеДеятельности,
    |    ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.СписаниеСтоимостиОС) КАК ХозяйственнаяОперация,
    |    &ВариантПримененияЦелевогоФинансирования     КАК ВариантПримененияЦелевогоФинансирования,
    |    &ОтражатьВРеглУчете                          КАК ОтражатьВРеглУчете,
    |    &ОтражатьВУпрУчете                           КАК ОтражатьВУпрУчете,
    |    &ВидАналитикиКапитализацииРасходов           КАК ВидАналитикиКапитализацииРасходов,
    |    ТаблицаОС.ОсновноеСредство                   КАК ОсновноеСредство,
    |    &НалогообложениеНДС                          КАК НалогообложениеНДС,
    |    ВЫБОР 
    |        КОГДА &ВидАналитикиКапитализацииРасходов = ЗНАЧЕНИЕ(Перечисление.ВидыАналитикиКапитализацииРасходов.ОбъектСтроительства) 
    |            ТОГДА &ОбъектСтроительства 
    |        ИНАЧЕ ТаблицаОС.ОсновноеСредство 
    |    КОНЕЦ                                        КАК АналитикаКапитализацииРасходов,
    |
    |    &Местонахождение                КАК КорПодразделение,
    |    &НаправлениеДеятельности        КАК КорНаправлениеДеятельности,
    |    &СтатьяРасходовБУ               КАК КорСтатьяРасходов,
    |    &АналитикаРасходовБУ            КАК КорАналитикаРасходов,
    |    НЕ РасчетСтоимости.ОбъектУчета ЕСТЬ NULL   КАК РасчетСтоимости,
    |
    |    0      КАК Стоимость,
    |    0      КАК СтоимостьРегл,
    |
    |    ЕСТЬNULL(РасчетСтоимости.СтоимостьНУ, ТаблицаОС.СтоимостьНУ) КАК СтоимостьНУ,
    |    0 КАК СтоимостьПР,
    |    ЕСТЬNULL(-РасчетСтоимости.СтоимостьНУ, -ТаблицаОС.СтоимостьНУ) КАК СтоимостьВР,
    |
    |    0 КАК СтоимостьЦФ,
    |    0 КАК СтоимостьНУЦФ,
    |    0 КАК СтоимостьПРЦФ,
    |    0 КАК СтоимостьВРЦФ,
    |    0 КАК АмортизационнаяПремия,
    |    0 КАК ПредварительнаяСтоимость,
    |    0 КАК ПредварительнаяСтоимостьРегл,
    |    0 КАК КорПостояннаяРазница,
    |    0 КАК КорВременнаяРазница
    |ИЗ
    |    Документ.ПринятиеКУчетуОС2_4.ОС КАК ТаблицаОС
    |        ЛЕВОЕ СОЕДИНЕНИЕ ВтРасчетСтоимости КАК РасчетСтоимости
    |        ПО РасчетСтоимости.ОбъектУчета = ТаблицаОС.ОсновноеСредство
    |        ЛЕВОЕ СОЕДИНЕНИЕ ПланВидовХарактеристик.СтатьиРасходов КАК ПВХСтатьиРасходов
    |            ПО &СтатьяРасходовБУ = ПВХСтатьиРасходов.Ссылка
    |ГДЕ
    |    ТаблицаОС.Ссылка = &Ссылка
    |    И &ПорядокУчетаНУ = ЗНАЧЕНИЕ(Перечисление.ПорядокВключенияСтоимостиОСВСоставРасходовНУ.ВключениеВРасходыПриПринятииКУчету)";
    
    //-- Локализация
    
    Возврат ТекстЗапроса;

КонецФункции

Показать

Данные формируются в этой строчке ЕСТЬNULL(РасчетСтоимости.СтоимостьНУ, ТаблицаОС.СтоимостьНУ).

РасчетСтоимости - это временная таблица и она всегда будет пустой. Не знаю, то ли я чего не досмотрел, то ли ошибка в программе. Ниже запрос для этой таблицы:

ВнеоборотныеАктивыСлужебный.ТекстЗапросаПустаяТаблицаСтоимости

Процедура ТекстЗапросаПустаяТаблицаСтоимости(ТекстыЗапроса, Запрос, ИмяТаблицы = Неопределено) Экспорт

    Если ИмяТаблицы = Неопределено Тогда
        ИмяТаблицы = "ВтРасчетСтоимости";
    КонецЕсли; 
    
    Если Запрос.МенеджерВременныхТаблиц.Таблицы.Найти(ИмяТаблицы) <> Неопределено Тогда
        Возврат;
    КонецЕсли;
    
    Если ПроведениеСерверУТ.ЕстьТаблицаЗапроса(ИмяТаблицы, ТекстыЗапроса) Тогда
        Возврат;
    КонецЕсли;
    
    ТекстЗапроса = 
    "ВЫБРАТЬ
    |    NULL   КАК Ссылка,
    |    NULL   КАК ОбъектУчета,
    |    NULL   КАК КорСтатьяРасходов,
    |    NULL   КАК КорАналитикаРасходов,
    |    NULL   КАК КорПодразделение,
    |    NULL   КАК КорНаправлениеДеятельности,
    |    0      КАК Стоимость,
    |    0      КАК Сумма,
    |    0      КАК СтоимостьРегл,
    |    0      КАК СтоимостьНУ,
    |    0      КАК СтоимостьПР,
    |    0      КАК СтоимостьВР,
    |    0      КАК СтоимостьЦФ,
    |    0      КАК СтоимостьНУЦФ,
    |    0      КАК СтоимостьПРЦФ,
    |    0      КАК СтоимостьВРЦФ,
    |    0      КАК АмортизационнаяПремия,
    |    0      КАК РезервПереоценкиСтоимости,
    |    0      КАК РезервПереоценкиСтоимостиРегл,
    |    0      КАК ЗалоговаяСтоимость,
    |    0      КАК ПредварительнаяСтоимость,
    |    0      КАК ПредварительнаяСтоимостьРегл,
    |    0      КАК КорПостояннаяРазница,
    |    0      КАК КорВременнаяРазница
    |ПОМЕСТИТЬ " + ИмяТаблицы + " 
    |ГДЕ
    |    ЛОЖЬ";
    
    ТекстыЗапроса.Добавить(ТекстЗапроса, ИмяТаблицы);
    
КонецПроцедуры

Показать

ТаблицаОС - это данные ТЧ ОС самого документа. В документе не возможно установить СтоимостьНУ. Более того, каждый раз перед записью, данные реквизита СтоимостьНУ удаляются, если Видимость = Ложь.

Конфигурация 1С:Комплексная автоматизация 2 (2.4.9.98). Платформа: 1С:Предприятие 8.3 (8.3.14.1854)

Помогите разобраться, как оформить документ Принятие к учету ОС, чтобы формировались данные и по налоговому учету.

Accepted Answer

(1)Разобрался. Проблема была в том что не стояла галочка "Принимается к налоговому учету по налогу на прибыль" в статье расходов при создании документа "Списание на расходы". Потратил много времени, но понял как это работает :) .

В нашем случае, были введены остатки по собственным товарам в декабре 2018 года. В январе 2019 создали документ "Внутренне потребление товаров - списание на расходы". В этом документе в "Статья списания" не стояла галочка "Принимается к налоговому учету по налогу на прибыль". Если не стоит эта галочка, то в РН "Прочие расходы" в ресурс "Сумма ПР" попадает стоимость ОС. А дальше при закрытии месяца не рассчитывается стоимость ОС по налоговому учету. И еще, стоимость по налоговому учету происходит при закрытие месяца, а не при проведении документа "Принятие к учету ОС"