В документе Модернизация ОС поле в т.ч. хозспособом (БУ) не заполняется

Процедура РассчитатьСтоимостьНажатие(Элемент)

	Если Ссылка.Проведен Тогда
		Предупреждение("Заполнение возможно только в непроведенном документе." , 60,);
		Возврат;
	КонецЕсли;

	СтруктураСтоимости = УправлениеВнеоборотнымиАктивами.РассчитатьСтоимостьОбъектаСтроительства(ОтражатьВУправленческомУчете,
	                                                             ОтражатьВБухгалтерскомУчете,
	                                                             ОтражатьВНалоговомУчете,
	                                                             СчетУчетаБУВнеоборотногоАктива,
	                                                             СчетУчетаНУВнеоборотногоАктива,
	                                                             ОбъектСтроительства,
	                                                             Организация,
	                                                             КонецДня(Дата));
	
	ЭлементыФормы.Стоимость.Значение      = СтруктураСтоимости.СтоимостьУУ;
	ЭлементыФормы.СтоимостьБУ.Значение    = СтруктураСтоимости.СтоимостьБУ;
	ЭлементыФормы.СтоимостьБУХоз.Значение = СтруктураСтоимости.СтоимостьБУХоз;
	ЭлементыФормы.СтоимостьНУ.Значение    = СтруктураСтоимости.СтоимостьНУ;
	ЭлементыФормы.СтоимостьНУХоз.Значение = СтруктураСтоимости.СтоимостьНУХоз;
	ЭлементыФормы.СтоимостьПР.Значение    = СтруктураСтоимости.СтоимостьПР;
	ЭлементыФормы.СтоимостьПРХоз.Значение = СтруктураСтоимости.СтоимостьПРХоз;
	ЭлементыФормы.СтоимостьВР.Значение    = СтруктураСтоимости.СтоимостьВР;
	ЭлементыФормы.СтоимостьВРХоз.Значение = СтруктураСтоимости.СтоимостьВРХоз;
	ЭлементыФормы.СтоимостьУСН.Значение   = СтруктураСтоимости.СтоимостьБУ;

КонецПроцедуры // РассчитатьСтоимостьНажатие()

Функция РассчитатьСтоимостьОбъектаСтроительства(ОтражатьВУправленческомУчете,
	                                           ОтражатьВБухгалтерскомУчете,
	                                           ОтражатьВНалоговомУчете,
	                                           СчетУчетаБУВнеоборотногоАктива,
	                                           СчетУчетаНУВнеоборотногоАктива,
	                                           ОбъектСтроительства,
	                                           Организация,
	                                           Период = Неопределено) Экспорт

	СтруктураСтоимостьОбъектаСтроительства = Новый Структура;
	СтруктураСтоимостьОбъектаСтроительства.Вставить("СтоимостьУУ",0);
	СтруктураСтоимостьОбъектаСтроительства.Вставить("СтоимостьБУ",0);
	СтруктураСтоимостьОбъектаСтроительства.Вставить("СтоимостьБУХоз",0);
	СтруктураСтоимостьОбъектаСтроительства.Вставить("СтоимостьНУ",0);
	СтруктураСтоимостьОбъектаСтроительства.Вставить("СтоимостьНУХоз",0);
	СтруктураСтоимостьОбъектаСтроительства.Вставить("СтоимостьПР",0);
	СтруктураСтоимостьОбъектаСтроительства.Вставить("СтоимостьПРХоз",0);
	СтруктураСтоимостьОбъектаСтроительства.Вставить("СтоимостьВР",0);
	СтруктураСтоимостьОбъектаСтроительства.Вставить("СтоимостьВРХоз",0);

	Если НЕ ЗначениеЗаполнено(ОбъектСтроительства) Тогда
		Предупреждение("Не выбран объект строительства", 60);
		Возврат СтруктураСтоимостьОбъектаСтроительства;
	КонецЕсли;

	Если (ОтражатьВБухгалтерскомУчете ИЛИ ОтражатьВНалоговомУчете) И (НЕ ЗначениеЗаполнено(Организация)) Тогда
		Предупреждение("Не выбрана организация", 60);
		Возврат СтруктураСтоимостьОбъектаСтроительства;
	КонецЕсли;

	Если (ОтражатьВБухгалтерскомУчете) И (НЕ ЗначениеЗаполнено(СчетУчетаБУВнеоборотногоАктива)) Тогда
		Предупреждение("Не выбран счет бухгалтерского учета объекта строительства", 60);
		Возврат СтруктураСтоимостьОбъектаСтроительства;
	КонецЕсли;

	Если (ОтражатьВНалоговомУчете) И (НЕ ЗначениеЗаполнено(СчетУчетаНУВнеоборотногоАктива)) Тогда
		Предупреждение("Не выбран счет налогового учета объекта строительства", 60);
		Возврат СтруктураСтоимостьОбъектаСтроительства;
	КонецЕсли;

	Если ОтражатьВУправленческомУчете Тогда
		
		Запрос = Новый Запрос;
		Запрос.УстановитьПараметр("Период"             , Период);
		Запрос.УстановитьПараметр("ОбъектСтроительства", ОбъектСтроительства);
		Запрос.Текст =
		"ВЫБРАТЬ
		|	СтроительствоОбъектовОсновныхСредствОстатки.СуммаОстаток КАК Стоимость
		|ИЗ
		|	РегистрНакопления.СтроительствоОбъектовОсновныхСредств.Остатки(&Период, ОбъектСтроительства = &ОбъектСтроительства) КАК СтроительствоОбъектовОсновныхСредствОстатки
		|";
		РезультатЗапроса = Запрос.Выполнить();
		Если НЕ РезультатЗапроса.Пустой() Тогда
			СтруктураСтоимостьОбъектаСтроительства.СтоимостьУУ = РезультатЗапроса.Выгрузить()[0].Стоимость;
		КонецЕсли;
		
	КонецЕсли;

	Если ОтражатьВБухгалтерскомУчете ИЛИ ОтражатьВНалоговомУчете Тогда

		ПорядокСубконто = Новый Массив();
		ПорядокСубконто.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.ОбъектыСтроительства);
		ПорядокСубконто.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.СпособыСтроительства);
		
		Запрос = Новый Запрос;
		Запрос.УстановитьПараметр("Период",               Период);
		Запрос.УстановитьПараметр("Организация",          Организация);
		Запрос.УстановитьПараметр("ОбъектСтроительства",  ОбъектСтроительства);
		Запрос.УстановитьПараметр("СчетУчетаБУ",          СчетУчетаБУВнеоборотногоАктива);
		Запрос.УстановитьПараметр("СчетУчетаНУ",          СчетУчетаНУВнеоборотногоАктива);
		Запрос.УстановитьПараметр("ПорядокСубконто",      ПорядокСубконто);
		Запрос.УстановитьПараметр("ОбъектыСтроительства", ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.ОбъектыСтроительства);
		Запрос.УстановитьПараметр("Хозспособ",            Перечисления.СпособыСтроительства.Хозспособ);
		
		ТекстЗапроса = "";
		
		Если ОтражатьВБухгалтерскомУчете Тогда
			
			ТекстЗапроса = ТекстЗапроса +
			"ВЫБРАТЬ
			|	""БУ"" КАК ВидУчета,
			|	ХозрасчетныйОстатки.СуммаОстатокДт КАК Стоимость,
			|	ХозрасчетныйОстаткиХозспособ.СуммаОстатокДт КАК СтоимостьХозспособ
			|ИЗ
			|	РегистрБухгалтерии.Хозрасчетный.Остатки(&Период, Счет = &СчетУчетаБУ, &ОбъектыСтроительства, Субконто1 = &ОбъектСтроительства И Организация = &Организация) КАК ХозрасчетныйОстатки	
			|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.Остатки(&Период, Счет = &СчетУчетаБУ, &ПорядокСубконто, Субконто1 = &ОбъектСтроительства И Субконто2 = &Хозспособ И Организация = &Организация) КАК ХозрасчетныйОстаткиХозспособ
			|		ПО ХозрасчетныйОстатки.Субконто1 = ХозрасчетныйОстаткиХозспособ.Субконто1
			|";
			
		КонецЕсли;
		
		Если ОтражатьВНалоговомУчете Тогда
			
			Если НЕ ПустаяСтрока(ТекстЗапроса) Тогда
				ТекстЗапроса = ТекстЗапроса +
				"ОБЪЕДИНИТЬ ВСЕ
				|";
			КонецЕсли;
			
			ТекстЗапроса = ТекстЗапроса +
			"ВЫБРАТЬ
			|	НалоговыйОстатки.ВидУчета,
			|	НалоговыйОстатки.СуммаОстатокДт,
			|	НалоговыйОстаткиХозспособ.СуммаОстатокДт
			|ИЗ
			|	РегистрБухгалтерии.Налоговый.Остатки(&Период, Счет = &СчетУчетаНУ, &ОбъектыСтроительства, Субконто1 = &ОбъектСтроительства И Организация = &Организация) КАК НалоговыйОстатки
			|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Налоговый.Остатки(&Период, Счет = &СчетУчетаНУ, &ПорядокСубконто, Субконто1 = &ОбъектСтроительства И Субконто2 = &Хозспособ И Организация = &Организация) КАК НалоговыйОстаткиХозспособ
			|		ПО НалоговыйОстатки.Субконто1 = НалоговыйОстаткиХозспособ.Субконто1
			|		 И НалоговыйОстатки.ВидУчета  = НалоговыйОстаткиХозспособ.ВидУчета
			|";
			
		КонецЕсли;
		
		Запрос.Текст = ТекстЗапроса;
		
		Выборка = Запрос.Выполнить().Выбрать();

		Пока Выборка.Следующий() Цикл
			
			Если Выборка.ВидУчета = "БУ" Тогда
				СтруктураСтоимостьОбъектаСтроительства.СтоимостьБУ    = Выборка.Стоимость;
				СтруктураСтоимостьОбъектаСтроительства.СтоимостьБУХоз = Выборка.СтоимостьХозспособ;
			ИначеЕсли Выборка.ВидУчета = Перечисления.ВидыУчетаПоПБУ18.НУ Тогда
				СтруктураСтоимостьОбъектаСтроительства.СтоимостьНУ    = Выборка.Стоимость;
				СтруктураСтоимостьОбъектаСтроительства.СтоимостьНУХоз = Выборка.СтоимостьХозспособ;
			ИначеЕсли Выборка.ВидУчета = Перечисления.ВидыУчетаПоПБУ18.ПР Тогда
				СтруктураСтоимостьОбъектаСтроительства.СтоимостьПР    = Выборка.Стоимость;
				СтруктураСтоимостьОбъектаСтроительства.СтоимостьПРХоз = Выборка.СтоимостьХозспособ;
			ИначеЕсли Выборка.ВидУчета = Перечисления.ВидыУчетаПоПБУ18.ВР Тогда
				СтруктураСтоимостьОбъектаСтроительства.СтоимостьВР    = Выборка.Стоимость;
				СтруктураСтоимостьОбъектаСтроительства.СтоимостьВРХоз = Выборка.СтоимостьХозспособ;
			КонецЕсли;
				
		КонецЦикла;

	КонецЕсли;

	Возврат СтруктураСтоимостьОбъектаСтроительства;

КонецФункции // РассчитатьСтоимостьОбъектаСтроительства()