Помогите понять строчку кода

Процедура ОбработатьТаблицуШтрихкодов(ТаблицаШтрихкодов, ФормаКлиент)

    Перем Номенклатура;
    Перем ХарактеристикаНоменклатуры;
    Перем СерияНоменклатуры;
    Перем Качество;
    Перем ЕдиницаИзмерения;

    ТаблицаШтрихкодов.Свернуть("Штрихкод", "Количество");

    Для Каждого СтрокаТЧ Из ТаблицаШтрихкодов Цикл
        ШК = СтрокаТЧ.Штрихкод;
        Количество = СтрокаТЧ.Количество;

        Если РаботаСТорговымОборудованием.ТипШтрихкодаEAN8ТО(ШК) Тогда
            ТипШК = мEAN8;
        ИначеЕсли РаботаСТорговымОборудованием.ТипШтрихкодаEAN13ТО(ШК) Тогда
            ТипШК = мEAN13;
        Иначе
            ТипШК = мCODE39;
        КонецЕсли;

        НоменклатураНайдена = Ложь;

        Если ЗначениеЗаполнено(мПрефиксВесовогоТовара)
           И ЗначениеЗаполнено(мДлинаКодаВесовогоТовара)
           И ТипШК = мEAN13
           И Лев(ШК, 2) = "2" + мПрефиксВесовогоТовара Тогда
            КодТовара        = Сред(ШК, 3, мДлинаКодаВесовогоТовара);
            КоличествоТовара = Сред(ШК, 3 + мДлинаКодаВесовогоТовара, 10 - мДлинаКодаВесовогоТовара);

            Запрос = Новый Запрос("
            |ВЫБРАТЬ ПЕРВЫЕ 1
            |    РегКВТ.Номенклатура                         КАК Номенклатура,
            |    РегКВТ.Номенклатура.ЕдиницаХраненияОстатков КАК ЕдиницаИзмерения,
            |    РегКВТ.ХарактеристикаНоменклатуры           КАК ХарактеристикаНоменклатуры,
            |    " + КоличествоТовара + " / 1000             КАК Количество,
            |    РегКВТ.СерияНоменклатуры                    КАК СерияНоменклатуры,
            |    ВЫБОР
            |        КОГДА РегКВТ.Качество = &КачествоПустаяСсылка ТОГДА
            |            &КачествоНовый
            |        ИНАЧЕ
            |            РегКВТ.Качество
            |    КОНЕЦ                                       КАК Качество
            |ИЗ
            |    РегистрСведений.КодыВесовогоТовара          КАК РегКВТ
            |ГДЕ
            |    РегКВТ.Код = &Код
            |");

            Запрос.УстановитьПараметр("КачествоПустаяСсылка", мКачествоПустаяСсылка);
            Запрос.УстановитьПараметр("КачествоНовый",        мКачествоНовый);
            Запрос.УстановитьПараметр("Код",                  Число(КодТовара));

            РезультатЗапроса = Запрос.Выполнить();
            Если Не РезультатЗапроса.Пустой() Тогда
                РезультатЗапроса = РезультатЗапроса.Выбрать();
                РезультатЗапроса.Следующий();

                Номенклатура               = РезультатЗапроса.Номенклатура;
                ХарактеристикаНоменклатуры = РезультатЗапроса.ХарактеристикаНоменклатуры;
                СерияНоменклатуры          = РезультатЗапроса.СерияНоменклатуры;
                Качество                   = РезультатЗапроса.Качество;
                ЕдиницаИзмерения           = РезультатЗапроса.ЕдиницаИзмерения;
                Количество                 = Количество * РезультатЗапроса.Количество;

                НоменклатураНайдена = Истина;
            КонецЕсли;
        КонецЕсли;

        Если Не НоменклатураНайдена Тогда
            Запрос = Новый Запрос("
            |ВЫБРАТЬ ПЕРВЫЕ 1
            |    РегШК.Владелец                   КАК Владелец,
            |    РегШК.ЕдиницаИзмерения           КАК ЕдиницаИзмерения,
            |    РегШК.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
            |    РегШК.СерияНоменклатуры          КАК СерияНоменклатуры,
            |    РегШК.Качество                   КАК Качество
            |ИЗ
            |    РегистрСведений.Штрихкоды        КАК РегШК
            |ГДЕ
            |    РегШК.Штрихкод = &Штрихкод
            |");

            Запрос.УстановитьПараметр("Штрихкод", ШК);
            РезультатЗапроса = Запрос.Выполнить();
            Если Не РезультатЗапроса.Пустой() Тогда
                РезультатЗапроса = РезультатЗапроса.Выбрать();
                РезультатЗапроса.Следующий();
                Если ТипЗнч(РезультатЗапроса.Владелец) = Тип("СправочникСсылка.Номенклатура") Тогда
                    Номенклатура               = РезультатЗапроса.Владелец;
                    ХарактеристикаНоменклатуры = РезультатЗапроса.ХарактеристикаНоменклатуры;
                    СерияНоменклатуры          = РезультатЗапроса.СерияНоменклатуры;
                    Качество                   = РезультатЗапроса.Качество;
                    ЕдиницаИзмерения           = РезультатЗапроса.ЕдиницаИзмерения;

                    НоменклатураНайдена = Истина;
                КонецЕсли;
            КонецЕсли;
        КонецЕсли;

        Если НоменклатураНайдена Тогда
            ФормаКлиент.СШКНоменклатура(Номенклатура, ХарактеристикаНоменклатуры,
               СерияНоменклатуры, Качество, ЕдиницаИзмерения, Количество, Неопределено);
        Иначе
            Текст = ПолучитьТекстОшибкиСШКТО(мОшибкаНеизвестныйШтрихкод, ШК, ТипШК);
            Сообщить(Текст);
        КонецЕсли;
    КонецЦикла;

КонецПроцедуры // ОбработатьТаблицуШтрихкодов()