Не распределилось по партиям.

Процедура глСписаниеПартийТМЦ(Конт,ТаблНоменклатуры,СписокПараметров,ВремПартии,ТаблСписПартий="",ТаблСписПартийКом="") Экспорт
	
	Перем ТаблИтогов; // ТЗ, в которую выгружаем итоги       
	Перем ОстПогКоличество, ОстПогСумма, ОстПогСуммаПродУпр, ОстПогСуммаПродРуб, ОстПогСуммаНДС, ОстПогСуммаНП;
	
	ТаблСписПартий=СоздатьОбъект("ТаблицаЗначений");
	ТаблСписПартий.НоваяКолонка("Фирма");
	ТаблСписПартий.НоваяКолонка("МОЛ");
	ТаблСписПартий.НоваяКолонка("Номенклатура");
	ТаблСписПартий.НоваяКолонка("СтатусПартии");
	ТаблСписПартий.НоваяКолонка("Партия");
	ТаблСписПартий.НоваяКолонка("ДатаПартии");
	ТаблСписПартий.НоваяКолонка("ЦенаПрод");
	ТаблСписПартий.НоваяКолонка("Количество");
	ТаблСписПартий.НоваяКолонка("СуммаУпр");
	ТаблСписПартий.НоваяКолонка("СуммаРуб");
	ТаблСписПартий.НоваяКолонка("СуммаБезНДС");
	ТаблСписПартий.НоваяКолонка("СтавкаНДС");
	ТаблСписПартий.НоваяКолонка("СтавкаНП");
	ТаблСписПартий.НоваяКолонка("СуммаПрод");
	ТаблСписПартий.НоваяКолонка("СуммаПродРуб");
	ТаблСписПартий.НоваяКолонка("СуммаПродУпр");
	ТаблСписПартий.НоваяКолонка("СуммаДокРуб");
	ТаблСписПартий.НоваяКолонка("НДСПрод");
	ТаблСписПартий.НоваяКолонка("НППрод");
	ТаблСписПартий.НоваяКолонка("ДоговорКомитента");
	ТаблСписПартий.НоваяКолонка("НомерСтрокиДокумента");
	ТаблСписПартий.НоваяКолонка("СкидкаРуб");
	
	ТаблСписПартийКом=СоздатьОбъект("ТаблицаЗначений");
	ТаблСписПартийКом.Загрузить(ТаблСписПартий); // копируем структуру
	
	РегистрУчета = ВремПартии.Вид();      
	
	Если РегистрУчета="ПартииНаличие" Тогда
		РегПартии	= Конт.Регистр.ПартииНаличие;
	Иначе    
		РегПартии	= Конт.Регистр.ПартииОтданные;
	КонецЕсли;
	
	Фирма		    = СписокПараметров.Получить("Фирма");
	Склад			= СписокПараметров.Получить("Склад");
	Договор			= СписокПараметров.Получить("Договор");
	КодОперации		= СписокПараметров.Получить("КодОперации"); 
	
	Если РегистрУчета="ПартииНаличие" Тогда
		МОЛ			= Склад.МОЛ;
	КонецЕсли;
		      
	МетодРасчетаСебестоимости = Фирма.ЮрЛицо.МетодРасчетаСебестоимости.Получить(Конт.ДатаДок);
	Если ПустоеЗначение(МетодРасчетаСебестоимости)=1 Тогда
		глНеПроводить(Конт,"Не определен метод расчета себестоимости для юр. лица """+Фирма.ЮрЛицо.Наименование+"""");
		Возврат;
	КонецЕсли;
	
	Если МетодРасчетаСебестоимости = Перечисление.МетодыРасчетаСебестоимости.FIFO Тогда
		ЗнакСортировки="+";
	Иначе     
		ЗнакСортировки="-";
	КонецЕсли;
	
	ТаблНоменклатуры.ВыбратьСтроки();
	Пока ТаблНоменклатуры.ПолучитьСтроку()=1 Цикл
		              
		Номенклатура=ТаблНоменклатуры.Номенклатура;
		Если Номенклатура.ВидНоменклатуры = Перечисление.ВидыНоменклатуры.Услуга Тогда
			Продолжить;
		КонецЕсли;
		
		ОстПогКоличество	= ТаблНоменклатуры.Количество;
		ОстПогСуммаПрод		= ТаблНоменклатуры.Сумма;
		ОстПогСуммаПродУпр	= ТаблНоменклатуры.СуммаУпр;
		ОстПогСуммаПродРуб	= ТаблНоменклатуры.ПродСтоимость;   
		ОстПогСуммаДокРуб	= ТаблНоменклатуры.СуммаРуб;
		ОстПогСкидкаРуб		= ТаблНоменклатуры.СкидкаРуб;   
		ОстПогНДСПрод		= ТаблНоменклатуры.СуммаНДС;
		ОстПогНППрод		= ТаблНоменклатуры.СуммаНП;
		
		ВремПартии.УстановитьЗначениеФильтра("Номенклатура",Номенклатура,1);
		Если ТаблНоменклатуры.Партия.Выбран()=1 Тогда
			// выбрана конкретная партия
			ВремПартии.УстановитьЗначениеФильтра("Партия",ТаблНоменклатуры.Партия,1);
		Иначе // снимем фильтр по партии
			ВремПартии.УстановитьЗначениеФильтра("Партия",,0);
		КонецЕсли;                  

		Если РегистрУчета = "ПартииНаличие" Тогда
		    Цена = ТаблНоменклатуры.ЦенаПрод;
			ВремПартии.УстановитьЗначениеФильтра("ЦенаПрод", Цена);
		КонецЕсли;     
		
		ВремПартии.ВыгрузитьИтоги(ТаблИтогов,1,1);     
		
		ТаблИтогов.НоваяКолонка("ДокПартии", "Документ");
		ТаблИтогов.ВыбратьСтроки();
		Пока ТаблИтогов.ПолучитьСтроку() = 1  Цикл
		    ТаблИтогов.ДокПартии = ТаблИтогов.Партия.ПриходныйДокумент;
		КонецЦикла;
		
		// Подготовим таблицу итогов взависимости от настройки контроля остатков
		ПодготовитьТаблИтогов(ТаблИтогов, Фирма);
		
		Если РегистрУчета="ПартииНаличие" Тогда
			ТаблИтогов.Сортировать("-Фирма,"+ЗнакСортировки+"ДатаПартии,"+ЗнакСортировки+"ДокПартии",1);
		КонецЕсли;
		
		ТаблИтогов.ВыбратьСтроки();
		Пока (ТаблИтогов.ПолучитьСтроку()=1) и (ОстПогКоличество>0) Цикл
			
			Если ТаблИтогов.Количество<=0 Тогда
				Продолжить;
			КонецЕсли;                                    
			
			Если КодОперации = глКО.ВозвратКомитенту Тогда

				// возвращаем товары комитенту - только его товары!
				Если ТаблИтогов.Партия.ДоговорПоставщика<>Договор Тогда
					Продолжить;
				КонецЕсли;

			КонецЕсли;              
			
			Если ТаблИтогов.Количество>=ОстПогКоличество Тогда 

				// остаток партии больше, чем нам надо списать
				КоэффСписания=ОстПогКоличество/ТаблИтогов.Количество;

			Иначе
				КоэффСписания=1;
			КонецЕсли;
			
			//измерения
			РегПартии.Фирма				= Фирма;
			
			РегПартии.Номенклатура		= ТаблИтогов.Номенклатура;
			РегПартии.СтатусПартии		= ТаблИтогов.СтатусПартии;
			РегПартии.Партия			= ТаблИтогов.Партия;
			Если РегистрУчета="ПартииНаличие" Тогда
				РегПартии.ДатаПартии		= ТаблИтогов.ДатаПартии;
				РегПартии.МОЛ				= ТаблИтогов.МОЛ;       
				РегПартии.ЦенаПрод			= ТаблИтогов.ЦенаПрод;
			Иначе
				РегПартии.Договор			= ТаблИтогов.Договор;
				РегПартии.ДокументПередачи	= ТаблИтогов.ДокументПередачи;
			КонецЕсли;     
			
			//ресурсы
			РегПартии.Количество		= Окр(ТаблИтогов.Количество	*КоэффСписания,5,1);
			РегПартии.СуммаУпр			= Окр(ТаблИтогов.СуммаУпр	*КоэффСписания,2,1);
			РегПартии.СуммаРуб			= Окр(ТаблИтогов.СуммаРуб	*КоэффСписания,2,1);
			РегПартии.СуммаБезНДС		= Окр(ТаблИтогов.СуммаБезНДС*КоэффСписания,2,1);
			Если РегистрУчета="ПартииОтданные" Тогда 
				РегПартии.ПродСтоимость	= Окр(ТаблИтогов.ПродСтоимость*КоэффСписания,2,1);    
			КонецЕсли;
			
			//реквизиты
			РегПартии.КодОперации 		= КодОперации;
			                                                       
			КоэффПогашения = РегПартии.Количество/ОстПогКоличество;
			
			// корректировка остатка продажной стоимости к списанию
			ОстПогКоличество=ОстПогКоличество-РегПартии.Количество;
			
			СписСуммаПрод	= Окр(ОстПогСуммаПрод	*КоэффПогашения,2,1);
			СписСуммаПродУпр= Окр(ОстПогСуммаПродУпр*КоэффПогашения,2,1);
			СписСуммаПродРуб= Окр(ОстПогСуммаПродРуб*КоэффПогашения,2,1);
			СписСуммаДокРуб	= Окр(ОстПогСуммаДокРуб*КоэффПогашения,2,1);
			СписСкидкаРуб	= Окр(ОстПогСкидкаРуб 	*КоэффПогашения,2,1);
			СписНДСПрод		= Окр(ОстПогНДСПрод		*КоэффПогашения,2,1);
			СписНППрод	 	= Окр(ОстПогНППрод		*КоэффПогашения,2,1);
			
			ОстПогСуммаПрод		= ОстПогСуммаПрод	- СписСуммаПрод;
			ОстПогСуммаПродУпр 	= ОстПогСуммаПродУпр- СписСуммаПродУпр;
			ОстПогСуммаПродРуб 	= ОстПогСуммаПродРуб- СписСуммаПродРуб;
			ОстПогСуммаДокРуб 	= ОстПогСуммаДокРуб	- СписСуммаДокРуб;
			ОстПогСкидкаРуб 	= ОстПогСкидкаРуб	- СписСкидкаРуб;
			ОстПогНДСПрод		= ОстПогНДСПрод 	- СписНДСПрод;
			ОстПогНППрод		= ОстПогНППрод	 	- СписНППрод;
		    
			СтавкаНДС		= ТаблНоменклатуры.СтавкаНДС;
			СтавкаНП		= ТаблНоменклатуры.СтавкаНП;
			                                               
			Если РегистрУчета = "ПартииНаличие" Тогда   
				РегПартии.ПродСтоимость	= СписСуммаПродРуб;    
			КонецЕсли;
			
			Если (КодОперации <> глКО.Перемещение) и (КодОперации <> глКО.ПередачаВРозницу) и (КодОперации <> глКО.ВозвратИзРозницы)
			   и (КодОперации <> глКО.ВозвратПоставщикуИзРозницы) Тогда
				РегПартии.Выручка	= Окр(РегПартии.ПродСтоимость - СписНДСПрод - СписНППрод, 2, 1);
			
			ИначеЕсли КодОперации = глКО.ВозвратПоставщикуИзРозницы Тогда
				РегПартии.Выручка	= Окр(СписСуммаДокРуб - СписНДСПрод - СписНППрод, 2, 1);
				
			Иначе
				РегПартии.Выручка	= 0;
			КонецЕсли;

			ЗапомнитьСписаннуюПартию(РегПартии,ТаблСписПартий,СписСуммаПрод,СписСуммаПродУпр,СписСуммаПродРуб,СписНДСПрод,СписНППрод,СтавкаНДС,СтавкаНП, ТаблНоменклатуры.НомерСтрокиДокумента, СписСкидкаРуб, СписСуммаДокРуб);
			Если РегПартии.СтатусПартии=глСП.Т_Принятый Тогда
				ЗапомнитьСписаннуюПартию(РегПартии,ТаблСписПартийКом,СписСуммаПрод,СписСуммаПродУпр,СписСуммаПродРуб,СписНДСПрод,СписНППрод,СтавкаНДС,СтавкаНП, ТаблНоменклатуры.НомерСтрокиДокумента, СписСкидкаРуб, СписСуммаДокРуб);
			КонецЕсли;
			
			РегПартии.ПривязыватьСтроку(ТаблНоменклатуры.НомерСтрокиДокумента);
			
			РегПартии.ДвижениеРасходВыполнить();
		КонецЦикла; // по строкам ТаблИтогов
		    
		
		Если ОстПогКоличество>0 Тогда
			// значит мы расходуем Номенклатуру
			// а Партии, которые надо погашать исчерпаны,
			// значит надо выдать сообщение об этом инциденте
			// и записать текущий документ как Партию с отриц. знаком
			Если ПустоеЗначение(ТаблНоменклатуры.Партия)=1 Тогда
				глСообщениеПроведения ("При проведении партий ТМЦ по "+Конт.ТекущийДокумент()+" от "+Конт.ДатаДок+" по ТМЦ "
				+СокрЛП(Номенклатура)+" не распределилось по партиям "+ОстПогКоличество+" "+Номенклатура.БазоваяЕдиница, Конт.ТекущийДокумент(),,,1);
			Иначе 
				глСообщениеПроведения("По указанной к списанию партии ТМЦ """ + ТаблНоменклатуры.Партия.ПриходныйДокумент +
				""" по ТМЦ " +СокрЛП(Номенклатура) + 
				?(ПустоеЗначение(ТаблНоменклатуры.Партия.Свойство) = 1,"", 
				  ", (" +  
				  СокрЛП(ТаблНоменклатуры.Партия.Свойство.Владелец) +  ": "  +
				  СокрЛП(ТаблНоменклатуры.Партия.Свойство) +")"
				  ) +  
				" не распределилось  "+ОстПогКоличество+" "+Номенклатура.БазоваяЕдиница, Конт.ТекущийДокумент(),,,1);
			КонецЕсли;
			
            //измерения
			РегПартии.Фирма				= Фирма;
			РегПартии.Номенклатура		= Номенклатура;
			РегПартии.СтатусПартии		= глПолучитьСтатусПартииПрихода(Перечисление.ВидыТМЦ.Товар,Номенклатура,КодОперации, Склад);
			РегПартии.Партия			= ПолучитьПустоеЗначение("Справочник.Партии");
			Если РегистрУчета="ПартииНаличие" Тогда
				РегПартии.ДатаПартии	= "";
				РегПартии.МОЛ			= МОЛ;                    
				РегПартии.ЦенаПрод	= ТаблНоменклатуры.ЦенаПрод;
			Иначе
				РегПартии.Договор		= Договор;
				РегПартии.ДокументПередачи = "";
			КонецЕсли;
			
			//ресурсы
			РегПартии.Количество		= ОстПогКоличество;
			РегПартии.СуммаУпр			= 0;
			РегПартии.СуммаРуб			= 0;
			РегПартии.СуммаБезНДС		= 0;
			Если РегистрУчета="ПартииОтданные" Тогда
				РегПартии.ПродСтоимость	= 0;
			КонецЕсли;
			
			//реквизиты   
			РегПартии.КодОперации 		= КодОперации;
			
			СтавкаНДС		= ТаблНоменклатуры.СтавкаНДС;
			СтавкаНП		= ТаблНоменклатуры.СтавкаНП;
			
			ЗапомнитьСписаннуюПартию       (РегПартии,ТаблСписПартий,ОстПогСуммаПрод,ОстПогСуммаПродУпр,ОстПогСуммаПродРуб,ОстПогНДСПрод,ОстПогНППрод,СтавкаНДС,СтавкаНП, ТаблНоменклатуры.НомерСтрокиДокумента, ОстПогСкидкаРуб, ОстПогСуммаДокРуб);
			Если РегПартии.СтатусПартии=глСП.Т_Принятый Тогда
				ЗапомнитьСписаннуюПартию(РегПартии,ТаблСписПартийКом,ОстПогСуммаПрод,ОстПогСуммаПродУпр,ОстПогСуммаПродРуб,ОстПогНДСПрод,ОстПогНППрод,СтавкаНДС,СтавкаНП, ТаблНоменклатуры.НомерСтрокиДокумента, ОстПогСкидкаРуб, ОстПогСуммаДокРуб);
			КонецЕсли;          
			
			// все, погасили всю строку документа
			ОстПогКоличество= 0;
			ОстПогСуммаПрод	= 0;         
			ОстПогСуммаПродУпр	= 0;         
			ОстПогСуммаПродРуб	= 0;         
			ОстПогСкидкаРуб	= 0;         
			ОстПогНДСПрод	= 0;
			ОстПогНППрод	= 0;
			
			РегПартии.ПривязыватьСтроку(ТаблНоменклатуры.НомерСтрокиДокумента);
			
			РегПартии.ДвижениеРасходВыполнить();
		КонецЕсли;
	
	КонецЦикла; // по строкам ТаблНоменклатуры
	
КонецПроцедуры // глСписаниеПартийТМЦ()                                                     
//////////////////