Остатки товаров на дату в ЗАКУПОЧНЫХ ЦЕНАХ

Форум Учет и отчетность Складской учет и логистика (WMS)

1С:Управление торговлей 10 Платформа 1С v8.3

1. SergiusK 10.05.15 19:06 Сейчас в теме

Всем привет! Люди подскажите как в конфе УТ 10.3 (10.3.32.1) сделать отчет по остаткам товаров в закупочных ценах???

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. jobkostya1c_ERP 101 10.05.15 19:17 Сейчас в теме

(1) SergiusK, если по конкретному товару то анализ партионных движений
1. Главное меню УТ 10.3 Отчеты -> Запасы(склад) -> ведомость по товарам на складах
2. В отчете по партиям можно увидеть цену поступления
Вот есть решение Остатки складов по последним закупочным ценам для УТ 10

3. jobkostya1c_ERP 101 10.05.15 19:19 Сейчас в теме

Еще можно смотреть регистр закупки

4. jobkostya1c_ERP 101 10.05.15 19:25 Сейчас в теме

Можно перебирать регистраторы документов поступления товаров и услуг для определения величины закупочной цены по последнему поступлению или усреднять (была задача по корректировке расхождений партионного учета по складам и по организациям:

ВЫБРАТЬ
    ПоступлениеТоваровУслугТовары.Номенклатура КАК Номенклатура,
    ПоступлениеТоваровУслугТовары.СерияНоменклатуры,
    ПоступлениеТоваровУслугТовары.ХарактеристикаНоменклатуры,
    МАКСИМУМ(ПоступлениеТоваровУслугТовары.Ссылка.Дата) КАК Дата
ПОМЕСТИТЬ ВТПериоды
ИЗ
    Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
ГДЕ
    ПоступлениеТоваровУслугТовары.Ссылка.Дата <= &Дата1
    И ПоступлениеТоваровУслугТовары.Ссылка.Проведен
    И НЕ ПоступлениеТоваровУслугТовары.Ссылка.ПометкаУдаления

СГРУППИРОВАТЬ ПО
    ПоступлениеТоваровУслугТовары.Номенклатура,
    ПоступлениеТоваровУслугТовары.СерияНоменклатуры,
    ПоступлениеТоваровУслугТовары.ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТПериоды.Номенклатура КАК Номенклатура,
    ВТПериоды.СерияНоменклатуры КАК СерияНоменклатуры,
    ВТПериоды.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
    ПоступлениеТоваровУслугТовары.Цена
ПОМЕСТИТЬ ВТПоследняяЦена
ИЗ
    ВТПериоды КАК ВТПериоды
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
        ПО ВТПериоды.Номенклатура = ПоступлениеТоваровУслугТовары.Номенклатура
            И ВТПериоды.Дата = ПоступлениеТоваровУслугТовары.Ссылка.Дата
            И ВТПериоды.СерияНоменклатуры = ПоступлениеТоваровУслугТовары.СерияНоменклатуры
            И ВТПериоды.ХарактеристикаНоменклатуры = ПоступлениеТоваровУслугТовары.ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ТоварыНаСкладахОстатки.Номенклатура КАК Номенклатура,
    ТоварыНаСкладахОстатки.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
    ТоварыНаСкладахОстатки.СерияНоменклатуры,
    ТоварыНаСкладахОстатки.Склад КАК Склад,
    ТоварыНаСкладахОстатки.Номенклатура.ЕдиницаХраненияОстатков КАК ЕдиницаИзмерения,
    ТоварыНаСкладахОстатки.Номенклатура.ЕдиницаХраненияОстатков.Коэффициент КАК Коэффициент,
    ТоварыНаСкладахОстатки.Качество,
    ВТПоследняяЦена.Цена КАК Цена,
    ТоварыНаСкладахОстатки.КоличествоОстаток КАК Количество,
    ТоварыНаСкладахОстатки.КоличествоОстаток * ВТПоследняяЦена.Цена КАК Сумма,
    ПОДСТРОКА(ТоварыНаСкладахОстатки.Номенклатура.Код, 3, 10) КАК НоменклатураКод,
    ТоварыНаСкладахОстатки.КоличествоОстаток * ВТПоследняяЦена.Цена КАК СуммаРегл,
    ТоварыНаСкладахОстатки.Номенклатура.Код КАК Код,
    ТоварыНаСкладахОстатки.Номенклатура.Наименование КАК Наименование
ИЗ
    РегистрНакопления.ТоварыНаСкладах.Остатки(&Граница1, Склад = &парСклад) КАК ТоварыНаСкладахОстатки
        ЛЕВОЕ СОЕДИНЕНИЕ ВТПоследняяЦена КАК ВТПоследняяЦена
        ПО ТоварыНаСкладахОстатки.Номенклатура = ВТПоследняяЦена.Номенклатура
            И ТоварыНаСкладахОстатки.ХарактеристикаНоменклатуры = ВТПоследняяЦена.ХарактеристикаНоменклатуры
            И ТоварыНаСкладахОстатки.СерияНоменклатуры = ВТПоследняяЦена.СерияНоменклатуры

ДЛЯ ИЗМЕНЕНИЯ
    РегистрНакопления.ТоварыНаСкладах.Остатки

УПОРЯДОЧИТЬ ПО
    Склад,
    Номенклатура,
    ХарактеристикаНоменклатуры

Показать

5. jobkostya1c_ERP 101 10.05.15 19:31 Сейчас в теме

Главное, определиться с методикой как считать закупочную цену. Тип цены то может задаваться как "Закупочная" и в прайсе ее можно посмотреть, но вот Вам нужно связать с остатками...
Или еще вариант использовать отчет по стоимостной оценке склада в ценах номенклатуры, но тут свои особенности. Материалы по данной теме
Появляются уже проблемы отклонений плановой и фактической себестоимости, которые нужно постоянно отслеживать и корректировать. Подобное делал для БП 3.0

6. SergiusK 10.05.15 19:51 Сейчас в теме

(5) kostyaomsk, у нас две цены: закупочная и розничная, один склад - розничный (АТТ - автом.торг.точка), соответственно: приход по закупоч.ценам, далее переоценка на определенный процент, получается розничная цена, потом продажи ...
очень хочется узнать остаток товара на дату по закупоч.ценам после продаж ...

9. reazek 20.05.15 13:28 Сейчас в теме

(6)Вам скорее всего нужно смотреть не остаток в закупке, а себестоимость склада.

7. jobkostya1c_ERP 101 10.05.15 20:06 Сейчас в теме

Тогда может быть попробовать для начала в отчете стоимостная оценка склада в ценах номенклатуры установить тип цен закупочная, а дальше посмотреть на контрольных примерах расхождения.
Если нет множества перемещений (некоторые виды документов из этого отчета в сложных случаях исключают, то можно получить верные результаты).
Отчет опирается на остатки товаров на складах

8. jobkostya1c_ERP 101 10.05.15 20:09 Сейчас в теме

Запрос выдергивает цены из регистра "цены номенклатуры" указанного типа. Дальше уже игра с курасами валют и коэффициентами единицы измерения.

ВЫРАЗИТЬ(ВЫБОР
КОГДА ЦеныНоменклатуры.Цена ЕСТЬ NULL
ТОГДА ЦеныНоменклатурыБезХарактеристик.Цена * ТаблицаРегистра.Номенклатура.ЕдиницаХраненияОстатков.Коэффициент / ЦеныНоменклатурыБезХарактеристик.ЕдиницаИзмерения.Коэффициент * (КурсыВалютСрезПоследнихБезХарактеристик.Курс / КурсыВалютСрезПоследнихБезХарактеристик.Кратность) / (УпрВалюты.Курс / УпрВалюты.Кратность) * &КоэффициентБазовогоТипаЦен
ИНАЧЕ ЦеныНоменклатуры.Цена * ТаблицаРегистра.Номенклатура.ЕдиницаХраненияОстатков.Коэффициент / ЦеныНоменклатуры.ЕдиницаИзмерения.Коэффициент * (КурсыВалютСрезПоследних.Курс / КурсыВалютСрезПоследних.Кратность) / (УпрВалюты.Курс / УпрВалюты.Кратность) * &КоэффициентБазовогоТипаЦен
КОНЕЦ КАК ЧИСЛО(15, 2))

Причем, в виртуальной таблице "ЦеныНоменклатуры" закупочная цена выбирается на последнюю дату (вернее последняя установленная цена).

10. sancho86 1 31.08.16 14:31 Сейчас в теме

Где-нибудь кроме как в инвентаризации можно увидеть остатки товаров на розничном складе в приходных ценах?
Стоимостная оценка склада - не предлагать, партионный учет не ведется, перепроводить все документы нет желания.

11. sancho86 1 06.09.16 10:31 Сейчас в теме

все еще актуально

12. tatoshka0403 120 06.09.16 16:12 Сейчас в теме

(11) sancho86, включи партионку и сделай перепроведение партий, она начнет себестоимость считать. По другому никак. Либо ищи самописку или инвентаризация.

13. Dmitriy_8911 37 19.09.16 15:51 Сейчас в теме

ВЫБРАТЬ
                       |    ТоварыНаСкладахОстатки.Склад КАК Склад,
                       |    ТоварыНаСкладахОстатки.Номенклатура.Ссылка КАК сНоменклатура,
                       |    МестаХраненияНоменклатуры.МестоХранения.Родитель КАК Секция,
                       |    ВлЗ.Регистратор КАК ПоследнееПоступление,
                       |    ВЫБОР
                       |        КОГДА ВлЗ.ЦенаПоступления ЕСТЬ NULL 
                       |            ТОГДА ЕСТЬNULL(ЦеныНоменклатуры.Цена, 0)
                       |        ИНАЧЕ ВлЗ.ЦенаПоступления
                       |    КОНЕЦ КАК Цена,
                       |    ЕСТЬNULL(ТоварыНаСкладахОстатки.КоличествоОстаток, 0) КАК КоличествоОстаток,
                       |    ВЫБОР
                       |        КОГДА ВлЗ.ЦенаПоступления ЕСТЬ NULL 
                       |            ТОГДА ЕСТЬNULL(ЦеныНоменклатуры.Цена, 0)
                       |        ИНАЧЕ ВлЗ.ЦенаПоступления
                       |    КОНЕЦ * ЕСТЬNULL(ТоварыНаСкладахОстатки.КоличествоОстаток, 0) КАК Сумма
                       |{ВЫБРАТЬ
                       |    Склад.* КАК Склад,
                       |    ТоварыНаСкладахОстатки.Номенклатура.* КАК Номенклатура,
                       |    МестаХраненияНоменклатуры.МестоХранения.Родитель КАК Секция,
                       |    МестаХраненияНоменклатуры.МестоХранения КАК Ячейка,
                       |    ВлЗ.Регистратор.* КАК ПоследнееПоступление,
                       |    Цена КАК Цена,
                       |    КоличествоОстаток КАК КоличествоОстаток,
                       |    Сумма КАК Сумма,
                       |    Секция.*}
                       |ИЗ
                       |    РегистрНакопления.ТоварыНаСкладах.Остатки(&ДатаКонца, {(Склад).* КАК Склад}) КАК ТоварыНаСкладахОстатки
                       |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.МестаХраненияНоменклатуры КАК МестаХраненияНоменклатуры
                       |        ПО (МестаХраненияНоменклатуры.Номенклатура = ТоварыНаСкладахОстатки.Номенклатура)
                       |            И ТоварыНаСкладахОстатки.Склад = МестаХраненияНоменклатуры.Склад
                       |        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
                       |            ВложенныйЗапрос.Номенклатура КАК Номенклатура,
                       |            ВложенныйЗапрос.Регистратор КАК Регистратор,
                       |            ВЫБОР
                       |                КОГДА СУММА(Закупки.Количество) = 0
                       |                    ТОГДА 0
                       |                ИНАЧЕ СУММА(Закупки.Стоимость) / СУММА(Закупки.Количество)
                       |            КОНЕЦ КАК ЦенаПоступления
                       |        ИЗ
                       |            (ВЫБРАТЬ
                       |                ВложенныйЗапрос.Номенклатура КАК Номенклатура,
                       |                МАКСИМУМ(Закупки.Регистратор) КАК Регистратор
                       |            ИЗ
                       |                (ВЫБРАТЬ
                       |                    Закупки.Номенклатура КАК Номенклатура,
                       |                    МАКСИМУМ(Закупки.Период) КАК Период
                       |                ИЗ
                       |                    РегистрНакопления.Закупки КАК Закупки
                       |                ГДЕ
                       |                    Закупки.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг
                       |                    И НЕ Закупки.Контрагент В (&КонтрагентыИсключения)
                       |                
                       |                СГРУППИРОВАТЬ ПО
                       |                    Закупки.Номенклатура) КАК ВложенныйЗапрос
                       |                    ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.Закупки КАК Закупки
                       |                    ПО ВложенныйЗапрос.Номенклатура = Закупки.Номенклатура
                       |                        И ВложенныйЗапрос.Период = Закупки.Период
                       |            ГДЕ
                       |                Закупки.ДокументЗакупки ССЫЛКА Документ.ПоступлениеТоваровУслуг
                       |                И НЕ Закупки.Контрагент В (&КонтрагентыИсключения)
                       |            
                       |            СГРУППИРОВАТЬ ПО
                       |                ВложенныйЗапрос.Номенклатура) КАК ВложенныйЗапрос
                       |                ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрНакопления.Закупки КАК Закупки
                       |                ПО ВложенныйЗапрос.Номенклатура = Закупки.Номенклатура
                       |                    И ВложенныйЗапрос.Регистратор = Закупки.Регистратор
                       |        ГДЕ
                       |            Закупки.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг
                       |        
                       |        СГРУППИРОВАТЬ ПО
                       |            ВложенныйЗапрос.Номенклатура,
                       |            ВложенныйЗапрос.Регистратор) КАК ВлЗ
                       |        ПО (ВлЗ.Номенклатура = ТоварыНаСкладахОстатки.Номенклатура)
                       |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаКонца, ТипЦЕн = &ТипЦен) КАК ЦеныНоменклатуры
                       |        ПО (ЦеныНоменклатуры.Номенклатура = ТоварыНаСкладахОстатки.Номенклатура)
                       |{ГДЕ
                       |    ТоварыНаСкладахОстатки.Номенклатура.* КАК Номенклатура,
                       |    МестаХраненияНоменклатуры.МестоХранения.Родитель КАК Секция,
                       |    МестаХраненияНоменклатуры.МестоХранения КАК Ячейка,
                       |    ВлЗ.Регистратор.* КАК ПоследнееПоступление,
                       |    ЦеныНоменклатуры.Цена КАК Цена,
                       |    ТоварыНаСкладахОстатки.КоличествоОстаток КАК Остаток,
                       |    МестаХраненияНоменклатуры.МестоХранения.Родитель.*,
                       |    МестаХраненияНоменклатуры.МестоХранения.*}
                       |{УПОРЯДОЧИТЬ ПО
                       |    Склад.* КАК Склад,
                       |    ТоварыНаСкладахОстатки.Номенклатура.* КАК Номенклатура,
                       |    МестаХраненияНоменклатуры.МестоХранения.Родитель.Наименование КАК Секция,
                       |    МестаХраненияНоменклатуры.МестоХранения КАК Ячейка,
                       |    ВлЗ.Регистратор.* КАК ПоследнееПоступление,
                       |    Секция.*}
                       |ИТОГИ
                       |    СРЕДНЕЕ(Цена),
                       |    СУММА(КоличествоОстаток),
                       |    СУММА(Сумма)
                       |ПО
                       |    ОБЩИЕ
                       |{ИТОГИ ПО
                       |    Склад.* КАК Склад,
                       |    ТоварыНаСкладахОстатки.Номенклатура.* КАК Номенклатура,
                       |    МестаХраненияНоменклатуры.МестоХранения.Родитель КАК Секция,
                       |    МестаХраненияНоменклатуры.МестоХранения КАК Ячейка,
                       |    ВлЗ.Регистратор.* КАК ПоследнееПоступление,
                       |    Секция.*}
                       |АВТОУПОРЯДОЧИВАНИЕ

Показать

14. Berserk_02 22.06.21 18:04 Сейчас в теме

(13)Спасибо! оч помогли

Оставьте свое сообщение

E-mail: