Расчет ФСС НС копейки за прошлые месяца

1. Roman_Go 2 29.09.22 14:20 Сейчас в теме
Рассчитываем з.п. за август в релизе Зарплата и управление персоналом КОРП, редакция 3.1 (3.1.23.63) имеем Взносы -********,71

Обновляемся и

Рассчитываем з.п. за август в релизе Зарплата и управление персоналом КОРП, редакция 3.1 (3.1.23.68) имеем Взносы - ********,77

в ексельке нашел эти копейки - это +-1 копейка по 14 сотрудникам по ФСС НС, в итоге взносы изменились на 6 копеек. Все бы ничего, если бы он эти копейки текущим месяцем ставил, он их все прошлыми месяцами сделал. Причем в тех месяцах эта копейка то и не нужна, может накопительно и есть в ней смысл, но какого он их засунул в прошлые периоды.

У кого-нибудь после обновления подобное было? Что с этим делать?
Ответы
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
2. PetrS 30.09.22 08:05 Сейчас в теме
Аналогичная картина после обновления 3.1.23.68, по двум сотрудникам по 1 копейке за февраль в сентябрьской зарплате вылезли. 4-ФСС выдает с ними ошибку контрольных соотношений. Если строки с копейками из начисления зарплаты удалить, то 4-ФСС не ругается.
4. Roman_Go 2 30.09.22 12:55 Сейчас в теме
(2) там как раз контрольные соотношение за прошлые кварталы вылазиет, на эти копейки требуется уточненка
3. PetrS 30.09.22 09:23 Сейчас в теме
Ради интереса сделал начисление ЗП за октябрь, там копейки за период "февраль" вылезли уже у других сотрудников.
5. gucci76 367 05.10.22 16:52 Сейчас в теме
Такая же ситуация. Куча копеек за прошлые месяца.
6. GSokolov 320 05.10.22 19:28 Сейчас в теме
Это старая проблема учёта взносов ФСС_НС в программе. Они хранятся в копейках, но такой разрядности не хватает для ведения неперсонифицированного учёта взносов по отношению к начислениям, почти всегда вылезут ошибки. Поэтому, видимо, 1С изменила алгоритм формирования взносов исходя из общих начислений, а затем погрешности разбрасываются в каком-то порядке по сотрудникам, чтобы получить нужную общую сумму взносов за месяц, квартал и т.п.
7. Roman_Go 2 06.10.22 06:35 Сейчас в теме
(6) да пуская разбрасывают, кто им не дает, пусть эту копейку текущем месяцем отражают, а не прошлым кварталом, чтобы уточненку сдавать
8. Roman_Go 2 06.10.22 07:05 Сейчас в теме
вот, кстати, вставка в модуль "УчетСтраховыхВзносов" (в 63 релизе его нет, а в 68 уже есть), которая генерирует эти копейки прошлыми месяцами

// Добавим перерасчет взносов в связи с возможным изменением тарифа в течение расчетного года задним числом.
		Если Месяц(ПериодРегистрации) > 1 Тогда
			
		    Запрос.УстановитьПараметр("КонецПредыдущегоМесяца", НачалоМесяца(ПериодРегистрации) - 1); 
			Запрос.Текст = 
			"ВЫБРАТЬ
			|	РанееИсчисленныеВзносы.ФизическоеЛицо КАК ФизическоеЛицо,
			|	НАЧАЛОПЕРИОДА(РанееИсчисленныеВзносы.ДатаПолученияДохода, МЕСЯЦ) КАК Период,
			|	СУММА(РанееИсчисленныеВзносы.ФССНесчастныеСлучаи) КАК ФССНесчастныеСлучаиОборот
			|ПОМЕСТИТЬ ВТРанееИсчисленныеВзносыПредыдущиеПериоды
			|ИЗ
			|	ВТДанныеУчетаВзносов КАК РанееИсчисленныеВзносы
			|ГДЕ
			|	РанееИсчисленныеВзносы.Период МЕЖДУ &НачалоГода И &ДатаОкончанияРегистрации
			|	И РанееИсчисленныеВзносы.Организация = &Организация
			|
			|СГРУППИРОВАТЬ ПО
			|	РанееИсчисленныеВзносы.ФизическоеЛицо,
			|	НАЧАЛОПЕРИОДА(РанееИсчисленныеВзносы.ДатаПолученияДохода, МЕСЯЦ)
			|;
			|
			|////////////////////////////////////////////////////////////­////////////////////
			|ВЫБРАТЬ
			|	ВзносыПоСтавкам.Период КАК Период,
			|	ВзносыПоСтавкам.ФизическоеЛицо КАК ФизическоеЛицо,
			|	ВзносыПоСтавкам.ФизическоеЛицоНаименование КАК Порядок,
			|	СУММА(ВзносыПоСтавкам.Взносов) КАК Взносов
			|ПОМЕСТИТЬ ВТВзносыФССНесчастныеСлучаиПредыдущиеПериоды
			|ИЗ
			|	(ВЫБРАТЬ
			|		Начислено.ПериодРегистрации КАК Период,
			|		Начислено.ФизическоеЛицо КАК ФизическоеЛицо,
			|		Начислено.ФизическоеЛицоНаименование КАК ФизическоеЛицоНаименование,
			|		Начислено.СтавкаНаНСиПЗ КАК СтавкаНаНСиПЗ,
			|		(ВЫРАЗИТЬ(СУММА(Начислено.БазаФСС_НСПоОсновномуТарифу) * Начислено.СтавкаНаНСиПЗ КАК ЧИСЛО(18, 5))) + (ВЫРАЗИТЬ(СУММА(Начислено.БазаФСС_НСИнвалида) * Начислено.СтавкаНаНСиПЗ * 0.6 КАК ЧИСЛО(18, 5))) КАК Взносов
			|	ИЗ
			|		ВТДоходыЗастрахованныхЛиц КАК Начислено
			|	ГДЕ
			|		Начислено.ПериодРегистрации МЕЖДУ &НачалоГода И &КонецПредыдущегоМесяца
			|		И Начислено.Организация = &Организация
			|	
			|	СГРУППИРОВАТЬ ПО
			|		Начислено.ПериодРегистрации,
			|		Начислено.СтавкаНаНСиПЗ,
			|		Начислено.ФизическоеЛицоНаименование,
			|		Начислено.ФизическоеЛицо) КАК ВзносыПоСтавкам
			|
			|СГРУППИРОВАТЬ ПО
			|	ВзносыПоСтавкам.Период,
			|	ВзносыПоСтавкам.ФизическоеЛицо,
			|	ВзносыПоСтавкам.ФизическоеЛицоНаименование
			|;
			|
			|////////////////////////////////////////////////////////////­////////////////////
			|ВЫБРАТЬ
			|	СУММА(Начислено.Взносов) КАК ВзносовСводно,
			|	Начислено.Период КАК Период
			|ИЗ
			|	(ВЫБРАТЬ
			|		Начислено.Взносов КАК Взносов,
			|		Начислено.Период КАК Период
			|	ИЗ
			|		ВТВзносыФССНесчастныеСлучаиПредыдущиеПериоды КАК Начислено
			|	
			|	ОБЪЕДИНИТЬ ВСЕ
			|	
			|	ВЫБРАТЬ
			|		-РанееИсчисленныеВзносы.ФССНесчастныеСлучаиОборот,
			|		РанееИсчисленныеВзносы.Период
			|	ИЗ
			|		ВТРанееИсчисленныеВзносыПредыдущиеПериоды КАК РанееИсчисленныеВзносы) КАК Начислено
			|
			|СГРУППИРОВАТЬ ПО
			|	Начислено.Период
			|
			|ИМЕЮЩИЕ
			|	СУММА(Начислено.Взносов) > 0.01";

			Результат = Запрос.Выполнить();
			Если Не Результат.Пустой() Тогда
				
				Запрос.Текст =
				"ВЫБРАТЬ
				|	Взносы.ФизическоеЛицо КАК ФизическоеЛицо,
				|	НАЧАЛОПЕРИОДА(КОНЕЦПЕРИОДА(Взносы.Период, МЕСЯЦ), ДЕНЬ) КАК ДатаПолученияДохода,
				|	Взносы.Взносов - ЕСТЬNULL(ИсчисленныеВзносы.ФССНесчастныеСлучаиОборот, 0) КАК ФССНесчастныеСлучаи,
				|	ИсчисленныеВзносы.Период КАК Период
				|ИЗ
				|	ВТВзносыФССНесчастныеСлучаиПредыдущиеПериоды КАК Взносы
				|		ЛЕВОЕ СОЕДИНЕНИЕ ВТРанееИсчисленныеВзносыПредыдущиеПериоды КАК ИсчисленныеВзносы
				|		ПО Взносы.ФизическоеЛицо = ИсчисленныеВзносы.ФизическоеЛицо
				|			И Взносы.Период = ИсчисленныеВзносы.Период
				|ГДЕ
				|	Взносы.Взносов - ЕСТЬNULL(ИсчисленныеВзносы.ФССНесчастныеСлучаиОборот, 0) <> 0
				|
				|УПОРЯДОЧИТЬ ПО
				|	Взносы.Период,
				|	Взносы.Порядок";
				ВременнаяТаблицаФССНесчастныеСлучаи = Запрос.Выполнить().Выгрузить();
				ВременнаяТаблицаФССНесчастныеСлучаи.Индексы.Добавить("Период");
				СтруктураОтбора = Новый Структура("Период");
				
				РезультатПерерасчета = ВременнаяТаблицаФССНесчастныеСлучаи.СкопироватьКолонки();
				Выборка = Результат.Выбрать(); 
				Пока Выборка.Следующий() Цикл
					СтруктураОтбора.Период = Выборка.Период;
					ТаблицаДляОкругления = ВременнаяТаблицаФССНесчастныеСлучаи.Скопировать(ВременнаяТаблицаФССНесчастныеСлучаи.НайтиСтроки(СтруктураОтбора)); 
					ЗарплатаКадры.ОкруглитьСлагаемыеПоСумме(ТаблицаДляОкругления,"ФССНесчастныеСлучаи", Выборка.ВзносовСводно, 2, "ФизическоеЛицо, ДатаПолученияДохода"); 
					ОбщегоНазначенияКлиентСервер.ДополнитьТаблицу(ТаблицаДляОкругления, РезультатПерерасчета);
				КонецЦикла;
				ВременнаяТаблица.Индексы.Добавить("ФизическоеЛицо,ДатаПолученияДохода");
				СтруктураОтбора = Новый Структура("ФизическоеЛицо,ДатаПолученияДохода");
				Для Каждого СтрокаФССНесчастныеСлучаи Из РезультатПерерасчета Цикл
					Если ЗначениеЗаполнено(СтрокаФССНесчастныеСлучаи.ФССНесчастныеСлучаи) Тогда
						ЗаполнитьЗначенияСвойств(СтруктураОтбора, СтрокаФССНесчастныеСлучаи);
						СтрокаПоДатеПолученияДохода = ВременнаяТаблица.НайтиСтроки(СтруктураОтбора); 
						Если СтрокаПоДатеПолученияДохода.Количество() > 0 Тогда
							СтрокаПоДатеПолученияДохода[0].ФССНесчастныеСлучаи = СтрокаФССНесчастныеСлучаи.ФССНесчастныеСлучаи;
						Иначе
							ЗаполнитьЗначенияСвойств(ВременнаяТаблица.Добавить(), СтрокаФССНесчастныеСлучаи);
						КонецЕсли;
					КонецЕсли;
				КонецЦикла;
				
			КонецЕсли;
			
			ТаблицыКУничтожению.Добавить("ВТРанееИсчисленныеВзносыПредыдущиеПериоды");
			ТаблицыКУничтожению.Добавить("ВТВзносыФССНесчастныеСлучаиПредыдущиеПериоды");
		КонецЕсли;
Показать


т.е., если верить их же комментарию из кода, они не с копейками борются, а хотят сделать перерасчет если ставка задним числом налога поменялась, а по факту, головной боли добавили, для тех у кого ставка не менялась
Оставьте свое сообщение

Для получения уведомлений об ответах подключите телеграм бот:
Инфостарт бот