Ускорение перепроведения документов

31.03.15

База данных - HighLoad оптимизация

Описание незначительной доработки типовой конфигурации, которая привела к ускорению перепроведения документов на 40%.
Дорабатывалась УПП 1.3, но это должно без каких-либо изменений работать и в других конфигурациях с подобным подходом к проведению документов (КА, УТ 10)

Необходимость в такой доработке возникла после того, как такая регулярная операция, как перепроведение месяца, перестала укладываться в ночь. Начальник IT сказал, что полгода назад всё было ОК, а значит, надо откатить все изменения, сделанные предыдущим программистом (я тогда только-только устроился на эту работу) за последние полгода, благо бэкап есть.
Идея интересная, чтобы не сказать больше, но я решил пойти другим путём: запустил замер производительности, перепровёл день и посмотрел, кто вылез в топ. Одним из рекордсменов оказалась процедура ОбщегоНазначения.УдалитьЗаписанныеДвиженияДокумента, которая вызывалась перед проведением каждого документа. Процедура записывает пустые наборы записей в каждый регистр, в котором проводимый документ является регистратором, что не есть хорошо, потому что обычно в большинстве этих регистров данный документ и так не делал движений.

Список регистров для очистки процедура получала от функции ПроведениеДокументов.МассивРегистровНужноОчистить, поэтому оставалось сделать так, чтобы эта процедура возвращала только те регистры, в которых есть движения.

Для этого в конфигурацию я добавил:

  • регистр сведений ГМ_НепустыеДвижения (по старой традиции этой конфигурации, истоков которой никто не помнит, все нетиповые объекты должны содержать префикс "ГМ_") с измерениями Документ (ведущее, основной отбор) типа ДокументСсылка и НомерРегистра (основной отбор) типа Число(3,0,Неотрицательное).
  • параметр сеанса ГМ_РегистрыПоНомеру типа ФиксированныйМассив
  • параметр сеанса ГМ_НомераРегистровПоИмени типа ФиксированноеСоответствие
  • справочник ГМ_НомераРегистров с кодом типа Число длиной 3 (должно совпадать с длиной измерения НомерРегистра)

Затем подправил процедуру ПроведениеДокументов.МассивРегистровНужноОчистить:


Функция МассивРегистровНужноОчистить(ДокументОбъект) Экспорт
	
	МассивРегистров = Новый Массив();
	//Коровин 09.09.2014
	лствИмена=ПараметрыСеанса.ГМ_РегистрыПоНомеру;
	лНабор=РегистрыСведений.ГМ_НепустыеДвижения.СоздатьНаборЗаписей();
	лНабор.Отбор.Документ.Установить(ДокументОбъект.Ссылка);
	лНабор.Прочитать();
	Для каждого ТекЗапись Из лНабор Цикл
		МассивРегистров.Добавить("РегистрНакопления."+лствИмена[ТекЗапись.НомерРегистра-1]);
	КонецЦикла;
	лфлНетИнформацииОДвижениях=МассивРегистров.Количество()=0;//Мы, вероятно, в том периоде, где регистр ГМ_НепустыеДвижения пуст
	//Коровин 09.09.2014 - конец
	
	Для Каждого Движение ИЗ ДокументОбъект.Метаданные().Движения Цикл
		//Коровин 09.09.2014
		//МассивРегистров.Добавить(Движение.ПолноеИмя());
		Если лфлНетИнформацииОДвижениях ИЛИ Найти(Движение.ПолноеИмя(),"РегистрНакопления.")=0 Тогда
			МассивРегистров.Добавить(Движение.ПолноеИмя());
		КонецЕсли;
		//Коровин 09.09.2014 - конец
	КонецЦикла; 
	
	Возврат МассивРегистров;
	
КонецФункции

И добавил в привилегированный модуль процедуру, которую потом вызвал в начале процедуры ПередНачаломРаботыСистемы модуля обычного приложения:

Процедура ПодготовитьНомераРегистров() Экспорт
	лмИменаРегистров=Новый Массив;
	лствНомераПоИмени=Новый Соответствие;
	лЗапрос=Новый Запрос("ВЫБРАТЬ Код, Наименование ИЗ Справочник.ГМ_НомераРегистров УПОРЯДОЧИТЬ ПО Код");
	лВыборка=лЗапрос.Выполнить().Выбрать();
	лТекКод=0;
	Пока лВыборка.Следующий() Цикл
		лТекКод=лТекКод+1;
		Пока лВыборка.Код>лТекКод Цикл //На случай, которого не должно быть - когда коды идут не подряд
			лмИменаРегистров.Добавить();
			лТекКод=лТекКод+1;
		КонецЦикла;
		лмИменаРегистров.Добавить(лВыборка.Наименование);
		лствНомераПоИмени.Вставить(лВыборка.Наименование,лТекКод);
	КонецЦикла;
	Для каждого ТекРегистр Из Метаданные.РегистрыНакопления Цикл
		Если лствНомераПоИмени[ТекРегистр.Имя]=Неопределено Тогда //Новый регистр
			лЭлемент=Справочники.ГМ_НомераРегистров.СоздатьЭлемент();
			лЭлемент.Наименование=ТекРегистр.Имя;
			Если лЭлемент.Наименование<>ТекРегистр.Имя Тогда
				ВызватьИсключение "Наименование регистра "+ТекРегистр.Имя+" слишком длинное ("+СтрДлина(ТекРегистр.Имя)+" символов) и не влезает в справочник ГМ_НомераРегистров";
			КонецЕсли;
			лЭлемент.Записать();
			
			лмИменаРегистров.Добавить(ТекРегистр.Имя);
			лствНомераПоИмени.Вставить(ТекРегистр.Имя,лЭлемент.Код);
		КонецЕсли;
	КонецЦикла;
	ПараметрыСеанса.ГМ_РегистрыПоНомеру=Новый ФиксированныйМассив(лмИменаРегистров);
	ПараметрыСеанса.ГМ_НомераРегистровПоИмени=Новый ФиксированноеСоответствие(лствНомераПоИмени);
КонецПроцедуры

 И, наконец, добавил подписку на событие ПриЗаписи всех регистров накопления:

Процедура ПриЗаписиРегистраНакопления(Источник,Отказ,Замещение) Экспорт
	Если НЕ Отказ Тогда
		лНабор=РегистрыСведений.ГМ_НепустыеДвижения.СоздатьНаборЗаписей();
		лНабор.Отбор.Документ.Установить(Источник.Отбор.Регистратор.Значение);
		лНабор.Отбор.НомерРегистра.Установить(ПараметрыСеанса.ГМ_НомераРегистровПоИмени[Источник.Метаданные().Имя]);
		Если Источник.Количество() Тогда
			лЗапись=лНабор.Добавить();
			лЗапись.Документ=лНабор.Отбор.Документ.Значение;
			лЗапись.НомерРегистра=лНабор.Отбор.НомерРегистра.Значение;
			лНабор.Записать();
		ИначеЕсли Замещение Тогда
			//Как минимум РасчетСебестоимостиВыпуска в регистр НезавершенноеПроизводство пишет движения порциями,
			//так что без учёта флага Замещение есть риск сбросить признак, если последний дописанный набор был пустым
			лНабор.Записать();
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры


В общем, работает всё так: при запуске 1С процедура ПодготовитьНомераРегистров заполняет параметры сеанса именами и номерами регистров накопления, создавая при необходимости нужные элементы в справочнике ГМ_НомераРегистров. При каждой записи непустого набора в какой-либо регистр накопления подписка на событие ПриЗаписи добавляет для этого регистра и регистратора набора запись в регистр ГМ_НепустыеДвижения. При записи пустого набора с установленным флагом Замещение такая запись, наоборот, удаляется.

При очистке движений документа изменённая процедура ПроведениеДокументов.МассивРегистровНужноОчистить читает из регистра ГМ_НепустыеДвижения все записи по этому документу и возвращает массив регистров, для которых записи есть. Если нет ни одной записи, то работает старый алгоритм - на тот случай, если перепроводимый документ был проведён до того, как в конфигурацию были внесены эти изменения. Это также означает, что из регистра ГМ_НепустыеДвижения можно смело вычищать записи по документам из закрытых периодов, которые трогать не предполагается, так как в случае необходимости перепроведение этих документов пройдёт нормально без всяких дополнительных действий.

Upd

В комментариях мне указали на то, что переименование регистра приведёт к проблемам. Тут я вижу три способа с этим разобраться:

1. Непосредственно перед сохранением изменений конфигурации, включающих в себя переименование регистра, переименовать этот регистр в справочнике ГМ_НомераРегистров. Самый простой и быстрый способ, который, однако, требует помнить о такой необходимости, потому что если сохранить изменения в конфигурацию базы данных, воспользоваться этим способом уже не выйдет.

2. Очистить регистр ГМ_НепустыеДвижения. Способ на случай, когда не воспользовались первым. Справочник ГМ_НомераРегистров тоже можно очистить (я бы очистил), но необязательно.

3. Доработать алгоритм так, чтобы в справочнике ГМ_НомераРегистров также хранилось имя таблицы базы данных соответствующего регистра. При переименовании регистра имя таблицы не поменяется и это можно будет использовать в процедуре ПодготовитьНомераРегистров.

Я эту проблему решать не стал, потому что не помню, чтобы хоть раз менял имя регистра (разве что с ИмяРегистра на УдалитьИмяРегистра, но к этому моменту в регистре, как правило, всё равно не было записей), но эта проблема на самом деле не единственная, есть и более вероятная и неприятная: некоторые обновления релиза включают в себя какую-нибудь обработку записей регистров. При этом могут быть перезаписаны наборы записей в том периоде, для которого в регистре ГМ_НепустыеДвижения нет записей и тогда при перепроведении тех документов этого периода, которые делали движения по перезаписанному регистру, движения по всем остальным регистрам задвоятся. Неприятность этой второй проблемы в том, что вы не узнаете о ней по матюкам программы, как непременно узнаете о первой. Зато если вы про неё в курсе, решить её можно способом №2 из решений первой проблемы.

В качестве профилактической меры можно после каждого обновления релиза запускать обработку, которая бы удаляла записи из регистра ГМ_НепустыеДвижения до определённой даты. Такую обработку по-любому стоит иметь для того, чтобы удалять заведомо старые записи, ибо маленькие регистры быстрее работают.

УПП оптимизация перепроведение

См. также

Анализируем SQL сервер глазами 1С-ника

HighLoad оптимизация Инструменты администратора БД Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Обработка для простого и удобного анализа настроек, нагрузки и проблем с SQL сервером с упором на использование оного для 1С. Анализ текущих зааросов на sql, ожиданий, конвертация запроса в 1с и рекомендации где может тормозить

1 стартмани

15.02.2024    7636    158    ZAOSTG    68    

96

Начните уже использовать хранилище запросов

HighLoad оптимизация Запросы

Очень немногие из тех, кто занимается поддержкой MS SQL, работают с хранилищем запросов. А ведь хранилище запросов – это очень удобный, мощный и, главное, бесплатный инструмент, позволяющий быстро найти и локализовать проблему производительности и потребления ресурсов запросами. В статье расскажем о том, как использовать хранилище запросов в MS SQL и какие плюсы и минусы у него есть.

11.10.2023    16184    skovpin_sa    14    

98

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8820    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2071    21    progmaster    7    

3

MS SQL Server: изучаем планы запросов

Запросы HighLoad оптимизация Запросы Бесплатно (free)

Многие знают, что для ускорения работы запроса нужно «изучить план». При этом сам план обычно обескураживает: куча разноцветных иконок и стрелочек; ничего не понятно, но очень интересно! Аналитик производительности Александр Денисов на конференции Infostart Event 2021 Moscow Premiere рассказал, как выполняется план запроса и что нужно сделать, чтобы с его помощью находить проблемы производительности.

20.06.2023    16006    Филин    37    

113

Пример многопоточной обработки (БСП)

HighLoad оптимизация БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Обработка-шаблон, на основе которой можно делать свои многопоточные обработки данных для конфигураций на БСП.

13.02.2023    9324    6    echo77    8    

93
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. cargobird 306 31.03.15 07:28 Сейчас в теме
Интересная идея, попробую...
2. tormozit 7136 31.03.15 07:47 Сейчас в теме
Рекомендую автору предупредить читателей о том, что в его реализации не предусмотрено переименование регистров. Последствия такого шага будут плачевными.
charushkin; Diversus; +2 Ответить
3. cargobird 306 31.03.15 08:23 Сейчас в теме
(2) tormozit, на своей практике переименование регистров не встречал ни разу (у вас, видимо, опыта побольше). Копипастом по конфигурации размножаются самые причудливые названия, и чтобы принципиально потребовалось переименование - такого не было...
5. tormozit 7136 31.03.15 09:24 Сейчас в теме
(3) cargobird, конечно, у меня опыта побольше =) Думаете мало добавляют свои регистры и потом меняют им наименование, когда поймут, что промахнулись с именем? Тем более в 8.3.6 сейчас переименование стало заметно менее затратным из-за нового помощника.
4. Vladimir-R 167 31.03.15 09:00 Сейчас в теме
где статистика на сколько увеличилась производительность в результате описанных изменений?
8. vasyak319 150 31.03.15 10:42 Сейчас в теме
(4) Балабас, (7) deadman66, в первой же фразе анонса. Понятно, что это не ровно 40.00000%, но точные цифры тут не имеют смысла - даже на одном и том же сервере, выделенном специально для тестирования и замера (а иначе как вообще было оценить прирост) время заметно плавает от перепроведения к перепроведению, а приводить его одно и то же состояние перед каждым тестом (делаем образ диска - перезагружаем - тестируем - восстанавливаем образ диска - перезагружаем - тестируем...) мне нафиг не упёрлось. А даже если бы упёрлось, это не помогло бы статье, так как это были бы цифры для моей базы и моего тестового сервера.
На рабочем сервере теперь возможно за ночь перепровести два месяца вместо одного - по мне так вполне достаточная характеристика доработки.
6. AlX0id 31.03.15 10:14 Сейчас в теме
Чота закрадываются сомнения насчет того, что подобный подход не ведет к постоянным блокировкам на регистре ГМ_НепустыеДвижения.. Каждый документ при записи каждого регистра в него лезет писать свои сочинения.. Или я чот недопонял?
9. vasyak319 150 31.03.15 10:51 Сейчас в теме
(6) AlX0id, (7) deadman66, были такие опасения и думал, что придётся накладывать управляемые блокировки (тут-то всё будет хорошо на 100%, ибо диапазоны разных документов не пересекаются), но то ли 1С сама их хорошо накладывает, то ли одно из двух (не было времени выяснять, отчего же всё хорошо), но проблем не возникло.
11. AlX0id 31.03.15 12:08 Сейчас в теме
(9)
Внимательно посмотрел структуру регистра - понял, что недопонял )
Думал, что в регистре привязка идет к типу документа, а не к конкретной ссылке. Тогда да - диапазоны не пересекаются, 1С и так наложит блокировку по измерениям, если для регистра применяется управляемый режим.
7. deadman66 31.03.15 10:24 Сейчас в теме
Статистика замеров где? И, да, с блокировками не возникает проблем?
10. Fox-trot 156 31.03.15 12:08 Сейчас в теме
так речь про файловый вариант?
15. vasyak319 150 31.03.15 14:34 Сейчас в теме
(10) Fox-trot, нет, но мне интересно, из чего вы сделали такой вывод.
17. Fox-trot 156 31.03.15 16:05 Сейчас в теме
(15) всю жись с 1с работал тока с трехзвенкой и когда-то сделал вывод, что количество информации = размер базы не влияет на скорость выполнения проги. такие дела
19. vasyak319 150 31.03.15 16:18 Сейчас в теме
(17) Fox-trot, ну, во-первых, конечно, влияет (другое дело, что вы могли этого не заметить), а во-вторых, всё равно непонятно - в статье про количество данных ни слова.
12. CrazyCD 31.03.15 13:46 Сейчас в теме
После проведения года попробую вкрячить на КОРП подобное.
А так ловите плюсик авансом =)))
13. Йожкин Кот 1006 31.03.15 13:55 Сейчас в теме
Еще можно сделать проведение док-та на сервере, чтобы не гонять наборы записей, результаты запросов к шапке и ТЧ туда-сюда. Тоже очень хорошо скажется на производительности.
14. vasyak319 150 31.03.15 14:33 Сейчас в теме
(13) Йожкин Кот, а я долгое время думал, ОбработкаПроведения всегда на сервере выполняется. Пока как-то утром не пришел и не увидел, что проведение (Операции - Проведение документов...) встало и ждёт, что я в окне предупреждения ОК нажму. Так я узнал две вещи: что один из тех парней, что дорабатывали эту конфигу, идиот (в ОбработкуПроведения Предупреждение воткнул!) и что перепроведение выполняется на клиенте, потому что иначе тот документ вылетел бы с ошибкой компиляции модуля.
Какое-то время попереписывался с Хотлайном на тему "Когда такое стало возможно", но получился, как это часто бывает, разговор с глухим.
25. Йожкин Кот 1006 01.04.15 12:32 Сейчас в теме
(14) Проведение, которое инициировано из формы или формы списка док-та для толстого клиента всегда выполняется на клиенте. Для тонкого клиента - всегда на сервере, в не зависимости от точки вызова.
26. tormozit 7136 01.04.15 12:40 Сейчас в теме
(25) Йожкин Кот, не совсем верно. Проведение стандартными командами вызывается
- для управляемой формы всегда на сервере
- для обычной формы всегда на клиенте
31. vasyak319 150 01.04.15 17:28 Сейчас в теме
(25) Йожкин Кот, теперь-то я в курсе, но ещё в 8.1 всё проводилось на сервере и такой мрачный прикол с Предупреждением в ОбработкеПроведения даже не компилировался. Там даже Сообщить сначала не компилировалось, это потом сделали очередь сообщений, которую сервер отдаёт клиенту вместе с возвратом управления.
16. Evg-Lylyk 4559 31.03.15 15:52 Сейчас в теме
Не понял зачем так
Я переписал функцию МассивРегистровНужноОчистить

Функция МассивРегистровНужноОчистить(ДокументОбъект) Экспорт

МассивРегистров = Новый Массив();
Запрос = Новый Запрос;

ДвиженияДокумента = ДокументОбъект.Метаданные().Движения;
Для Каждого Движение ИЗ ДвиженияДокумента Цикл

ИмяРегистра = Движение.ПолноеИмя();

Если ЗначениеЗаполнено(Запрос.Текст) Тогда
Запрос.Текст = Запрос.Текст + " ОБЪЕДИНИТЬ ВСЕ ";
КонецЕсли;
Запрос.Текст = Запрос.Текст + "ВЫБРАТЬ ПЕРВЫЕ 1""" + ИмяРегистра + """ ИЗ " + ИмяРегистра + " ГДЕ " + ИмяРегистра + ".Регистратор = &Регистратор";
КонецЦикла;

Запрос.УстановитьПараметр("Регистратор", ДокументОбъект.Ссылка);
Результат = Запрос.Выполнить();

Возврат Результат.Выгрузить().ВыгрузитьКолонку("Поле1");

КонецФункции

вроде все теперь очищает только те регистры в которых были записи...
проверял на документе ПлатежкаИсх (5 раз проводил) ускорилось очень значительно
теперь проверяю и думаю на что это может повлиять эта доработка
Mkonst; kauksi; vasyak319; AlkB; +4 Ответить
18. vasyak319 150 31.03.15 16:16 Сейчас в теме
(16) Evg-Lylyk, у меня запрос к одной маленькой таблице (вся эта заморочка с нумерацией регистров как раз для того, чтобы она была настолько маленькой, насколько возможно), а у вас к множеству очень больших. Это тоже должно ускорить перепроведение (что вы и ощутили), так как все СУБД оптимизируют на чтение, а не на запись, но тут вопрос, чего вам нужно больше - написать покороче и постабильнее (у вашего способа нет проблем моего) или выжать из возможности максимум.
Хотя я допускаю, что ответ вопрос "какой метод быстрее" не такой однозначный и зависит от обстоятельств (мозги сервера, размер базы, характер заполненности регистров и т.п.).

Думаю, будет здорово, если вы оформите свой камент в виде статьи.
20. Evg-Lylyk 4559 31.03.15 16:29 Сейчас в теме
(18) Понятно. Думаю вашей статьи достаточно.
21. ZOMI 444 31.03.15 23:44 Сейчас в теме
Ниже привожу листинг процедуры( УПП 1.3.51, которая так возбудила возмутила автора

// Процедура очистки записанных движений документа
//
// Параметры:
//	ДокументОбъект 				- документ, движения которого удаляются
//	Отказ 						- булево, признак отказа
//	ВыборочноОчищатьРегистры 	- булево, признак выборочной очистки наборов записей 
//								Если Истина - часть наборов записей не будут очищены, будут очищены только коллекции движений
//	РежимПроведенияДокумента 	- режим проведения (оперативный / неоперативный), 
//								нужен для составления списка регистров, которые не надо очищать
Процедура УдалитьЗаписанныеДвиженияДокумента(ДокументОбъект, Отказ, ВыборочноОчищатьРегистры, РежимПроведенияДокумента)
	
	// Получим перечень регистров, движения по которым нужно очистить
	МассивРегистров = ПроведениеДокументов.МассивРегистровНужноОчистить(ДокументОбъект);
	
	Если МассивРегистров.Количество() = 0 Тогда
		Возврат;
	КонецЕсли;
	
	// Если очищать регистры надо выборочно, то подготовим список таких регистров, 
	//	которые можно не очищать при перепроведении
	Если ВыборочноОчищатьРегистры Тогда
		РегистрыДляОптимизацииПерезаписиДвижений = ПолучитьРегистрыДляОптимизацииПерезаписиДвижений(РежимПроведенияДокумента);
	КонецЕсли;
	
	// Переменные логики отложенного проведения
	ДокументИспользуетсяВОтложенномПроведении = Ложь;
	ВыполняетсяДопроведение                   = Ложь;
	ПроведениеПоВсемВидамУчета                = Ложь;
	
	СтруктураПараметровПроведения = ОтложенноеПроведениеДокументов.ПолучитьПараметрыПроведенияДокумента(ДокументОбъект);
	ДокументИспользуетсяВОтложенномПроведении = СтруктураПараметровПроведения.ДокументИспользуетсяВОтложенномПроведении;
	
	Если ДокументИспользуетсяВОтложенномПроведении Тогда
		ВыполняетсяДопроведение = СтруктураПараметровПроведения.ВыполняетсяДопроведение;
		ПроведениеПоВсемВидамУчета = СтруктураПараметровПроведения.ПроведениеПоВсемВидамУчета;
		РегистрыОтложенногоПроведения = ОтложенноеПроведениеДокументов.ПолучитьРегистрыОтложенногоПроведения();
	КонецЕсли;
	
	//Обойдем список регистров, по которым существуют движения, и выполним очистку необходимых регистров
	Для Каждого ПолноеИмяРегистра ИЗ МассивРегистров Цикл
		
		// Имя регистра передается как значение, 
		// полученное с помощью функции ПолноеИмя() метаданных регистра
		ПозицияТочки = Найти(ПолноеИмяРегистра, ".");
		ТипРегистра = Лев(ПолноеИмяРегистра, ПозицияТочки - 1);
		ИмяРегистра = СокрП(Сред(ПолноеИмяРегистра, ПозицияТочки + 1));
		
		// Используется для оптимизации перезаписи движений платформой
		//	Если значение Ложь, набор записей не будет очищен
		// По умолчанию все движения надо удалять
		УдалятьДвижения = Истина;
		
		Если ВыборочноОчищатьРегистры И РегистрыДляОптимизацииПерезаписиДвижений.Найти(ИмяРегистра) <> Неопределено Тогда
			УдалятьДвижения = Ложь;
		КонецЕсли;
		
		Если ДокументИспользуетсяВОтложенномПроведении Тогда
			Если ВыполняетсяДопроведение Тогда
				//	Если выполняется допроведение, то удаляются только движения по регистрам, 
				//	которые формируются при отложенном проведении
				Если РегистрыОтложенногоПроведения.Найти(СокрЛП(ПолноеИмяРегистра)) = Неопределено Тогда
					Продолжить;
				КонецЕсли;
			Иначе
				// Документ проводится в режиме отложенного проведения
				
				// Если для документа выключен режим проведения "по всем видам учета", 
				// то всегда удаляются движения по регистрам, которые формируются при допроведении
				//	(независимо от того, входят ли они в список РегистрыДляОптимизацииПерезаписиДвижений)
				Если НЕ УдалятьДвижения
					И НЕ ПроведениеПоВсемВидамУчета 
					И РегистрыОтложенногоПроведения.Найти(СокрЛП(ПолноеИмяРегистра)) <> Неопределено Тогда
					
					УдалятьДвижения = Истина;
				КонецЕсли;
			КонецЕсли; 
		КонецЕсли; 
		
		Если УдалятьДвижения Тогда
			// Удаление движений происходит без контроля доступа - передаем пустую таблицу движений
			ПолныеПрава.ЗаписатьНаборЗаписейНаСервере(ИмяРегистра, ДокументОбъект.Ссылка,, ТипРегистра);
		Иначе
			//Установим признак модифицированности набора записей, чтобы записались все коллекции движений, по которым
			//были записи на момент проведения
			ДокументОбъект.Движения[ИмяРегистра].Очистить();
		КонецЕсли;
	КонецЦикла;	
	
КонецПроцедуры
Показать


Напрашивается вопросик - а выборочное очищение регистров - чем вам не по душе?
Извините, но то что вы нагородили кто-то (через полгодика?) уберет и заюзает механизмы типовой...


anchovy; Fox-trot; +2 Ответить
22. vasyak319 150 01.04.15 09:45 Сейчас в теме
(21) ZOMI, напрашивается встречный вопросик: Вы смотрели, что на самом деле делает эта процедура при взведённом параметре ВыборочноОчищатьРегистры и в каких вообще случаях он взведён, или вы просто увидели, что есть такой параметр и решили, что вот он - золотой ключик?
23. AlX0id 01.04.15 09:49 Сейчас в теме
(21) ZOMI,
а это выборочное очищение где-то отдельно включается или само по себе работает?
24. vasyak319 150 01.04.15 10:23 Сейчас в теме
(23) AlX0id, советую посмотреть, как и откуда вызывается процедура, вызывающая эту процедуру и, до кучи, список регистров, на который влияет упомянутый флажок, хотя последнее, в общем, необязательно.
28. AlX0id 01.04.15 15:21 Сейчас в теме
(24)
Ну вот сильно не хочется по коду лазить, если честно ) Тем более, когда не знаешь, как он должен работать. Я просто интересуюсь, может быть где-то есть описание этого использования механизма на уровне пользователя/программиста/администратора - мало ли удастся облегчить людям жизнь, не утруждая свою ))
30. vasyak319 150 01.04.15 16:49 Сейчас в теме
(28) AlX0id, там немного, потому и предложил взглянуть. Если вкратце, то этот параметр, конечно, никакими настройками не управляется. Где можно (а можно в большинстве реально используемых документов, в частности - ПТиУ и РТиУ) он уже взведён. Влияние оказывает не на все, а где-то на десяток второстепенных регистров.
В общем, что имел в виду ZOMI своей цитатой процедуры (спасибо, что не модуль целиком), а также ссылкой на загадочные "механизмы типовой", по-моему даже он сейчас не в курсе.
27. capitan 2466 01.04.15 13:54 Сейчас в теме
Программисты 1С они такие ... программисты.
А те, кто не прогуливал в институте Основы программирования, знают, что каждую задачу можно (и нужно) описать формально, потом блок-схема, потом код.
Оставив за бортом код мы увидим следующее:
1. Автор подозревает, возможно небезосновательно, что документы в УПП являются регистраторами для регистров, в которых проводки не делают. Тут камень в огород 1С ибо в каждой книге по программированию написано - не добавляйте лишних регистров/регистраторов.
И тут вот хорошо бы увидеть отчет, который пройдет по конфигурации, посчитает и выведет в виде - Документ - Количество регистров где он является регистратором - Количество регистров, где реально есть проводки.
Если автор состряпает такой отчет и выложит его сюда, да еще для любой конфигурации - звезду ему во всю грудь.
Тогда можно уже аргументированно теребить 1С и/или править документ убирая регистры, где он в регистраторах не нужен.
2. Что сделал автор (надеюсь инфостарт не читают его юзеры и начальник) - он ускорил перепроведение документов, замедлив, в зависимости от количества строк табличной части документа конечно, проведение документа. Не говоря уже о взаимных блокировках регистра сведений при проведении, до которых автору конечно дела нет - он то ночью один работает. За что конечно юзеры, говорят простое человеческое спасибо.
По хорошему нужно делать регламентное задание, заполняющее регистр сведений и всю кухню с перепроведением завязывать на принак - массовое перепроведение ли это вообще. А так - оставлять возможно стандартный механизм от 1С.
3. В итоге статья получается о том, как один, даже не выпивший фанты программист, может тормознуть десяток другой пользователей.
Designer1C; Fox-trot; 7o2uYXg; +3 Ответить
29. vasyak319 150 01.04.15 16:42 Сейчас в теме
(27) capitan, бред. Расписал бы подробнее, да вот опровергать буйные фантазии мне ещё лет 10 назад скучно стало.
32. capitan 2466 01.04.15 18:39 Сейчас в теме
(29) а ты посмотри на сколько дольше стал проводиться один документ. И поймешь чему за 10 лет научился.
33. user1310927 20.05.20 13:12 Сейчас в теме
(32) Подскажите почему блокируется Регистр бухгалтерии после очистки движения и параллельная работа не возможна до конца проведения документа
34. user1310927 20.05.20 13:22 Сейчас в теме
..............
Если УдалятьДвижения Тогда
// Удаление движений происходит без контроля доступа - передаем пустую таблицу движений
ПолныеПрава.ЗаписатьНаборЗаписейНаСервере(ИмяРегистра, ДокументОбъект.Ссылка,, ТипРегистра);
Иначе
.............
после 15 итерции где идет очиска Бух регистра (всего 54), не возможно провести любой документ где задействованы корреспонденция счетов в этом документе до конца проведения документа
Оставьте свое сообщение