Я предполагаю, что одним из способов, позволяющих получить большую простоту и прозрачность, могло бы стать последовательное применение принципа, в чем-то схожего с одним из основных принципов функционального программирования. Смысл в том, что результат проведения документа должен зависеть только от самого документа, т.е. от тех данных, что содержатся в документе. Но не от данных из других документов и не от данных из регистров. Другими словами, результат проведения документа не должен зависеть от окружения.
В настоящий момент в платформе 1С регистры реализованы таким образом, что применение данного принципа несколько затруднительно, но вполне возможно. В идеале было бы конечно получить то, о чем здесь говорится, на уровне платформы. Будем надеяться, что когда-нибудь такая реализация появится. Пока же я опишу несколько идей возможного расширения регистров и продемонстрирую рабочую модель, в которой расширенные регистры реализованы на том, что уже есть в платформе.
Первое расширение регистров, которое я хочу предложить, назовем регистром с неотрицательным остатком. Этот регистр работает точно так же, как обычный регистр накопления, за исключением одного момента. При формировании виртуальной таблицы остатков, сначала вычисляются наиболее подробные остатки, т.е остатки по всем измерениям. К этим остаткам применяется операция max(,0). И только после этого выполняется агрегация.
Прежде чем переходить к реализации данного расширения, опишу одну из практических задач, которая может быть решена данным способом.
У нас есть связка документов Заказ покупателя - Отгрузка. Отгрузка вводится на основании Заказа. При этом возможна связь один-ко-многим. Т.е. на основании одного Заказа может вводиться несколько Отгрузок.
Мы хотим организовать регистр накопления, в котором будут храниться резервы товаров по заказам.
Запись в этот регистр из документа Заказ очевидна
Процедура ОбработкаПроведения(Отказ, РежимПроведения)
//Регистр Резервирование - это регистр с неотрицательным остатком
//для получения остатков по этому регистру следует обращаться к функции ОстаткиПлюс()
//общего модуля РасширениеРегистров
Движения.Резервирование.Записывать=истина;
для каждого стр из Товары цикл
дв=Движения.Резервирование.Добавить();
дв.ВидДвижения=ВидДвиженияНакопления.Приход;
дв.Период=Дата;
дв.Заказ=Ссылка;
дв.Товар=стр.Товар;
дв.Количество=стр.Количество;
конеццикла;
КонецПроцедуры
Документ Заказ резервирует товар, а документ Отгрузка должен товар с резерва снимать. Но как это сделать? Если просто регистрировать снятие с резерва в количестве, которое указано в Отгрузке, то можно получить отрицательный остаток.
Процедура ОбработкаПроведения(Отказ, РежимПроведения)
//Регистр Резервирование - это регистр с неотрицательным остатком
//для получения остатков по этому регистру следует обращаться к функции ОстаткиПлюс()
//общего модуля РасширениеРегистров
если не Основание.Пустая() тогда
Движения.Резервирование.Записывать=истина;
для каждого стр из Товары цикл
дв=Движения.Резервирование.Добавить();
дв.ВидДвижения=ВидДвиженияНакопления.Расход;
дв.Период=Дата;
дв.Заказ=Основание;
дв.Товар=стр.Товар;
дв.Количество=стр.Количество;
конеццикла;
конецесли;
КонецПроцедуры
В нашем случае мы получим по Товар1 остаток -14. С тех пор, как разработчики платформы 1С убрали обязательное ежемесячное хранение в регистрах накопления, отрицательные остатки, как таковые, перестали быть проблемой. Также нет проблемы с тем, чтобы правильно интерпретировать отрицательный остаток. Можно принимать любые значения <=0 за отсутствие резерва. Но все же мы не можем оставить отрицательные остатки в регистре Резервирование, потому что данные агрегируются.
У нас может быть еще один заказ
И тогда обращение к виртуальной таблице остатков даст нам резерв 15-14=1, что будет неприемлемо.
В общем модуле определим следующую функцию
Функция ОстаткиПлюс(ИмяРегистра,МоментВремени=неопределено,Отбор=неопределено,Детализация="") экспорт
тз=РегистрыНакопления[ИмяРегистра].Остатки(МоментВремени,Отбор);
для каждого стр из тз цикл
для каждого рес из метаданные.РегистрыНакопления[ИмяРегистра].Ресурсы цикл
стр[рес.имя]=макс(стр[рес.имя],0);
конеццикла;
конеццикла;
если не ЗначениеЗаполнено(Детализация) тогда
для каждого рес из метаданные.РегистрыНакопления[ИмяРегистра].Измерения цикл
Детализация=Детализация+рес.имя+",";
конеццикла;
Детализация=лев(Детализация,стрдлина(Детализация)-1);
конецесли;
ресурсы="";
для каждого рес из метаданные.РегистрыНакопления[ИмяРегистра].Ресурсы цикл
ресурсы=ресурсы+рес.имя+",";
конеццикла;
ресурсы=лев(ресурсы,стрдлина(ресурсы)-1);
тз.свернуть(Детализация,ресурсы);
возврат тз;
КонецФункции
Здесь мы получаем остатки по всем измерениям. Приводим их к неотрицательному виду. И только потом применяем операцию агрегирования. Легко убедиться, что теперь мы получим правильное значение остатка, при том, что проведение документа Отгрузка остается простым и не зависит от окружения.
В приложении демонстрационная выгрузка базы. Пример тестировался на версии платформы 8.3.19.1467.
