Параметры интерфейса

Процедура НастройкаИнтерфейсаПоПараметрамОбслуживающейОрганизацииПриОбновлении(Параметры) Экспорт
	
	Параметры.ОбработкаЗавершена = Истина;
	
	Если Не ВозможнаНастройкаИнтефейсаПоПараметрамОбслуживающейОрганизац­ии() Тогда
		Возврат;
	КонецЕсли;
	
	ПолучитьПараметрыОбслуживающейОрганизацииИНастроитьИнтерфейс­();
	
КонецПроцедуры

Процедура ПолучитьПараметрыОбслуживающейОрганизацииИНастроитьИнтерфейс()
	
	ДоступнаОплата = Ложь;
	УпрощенныйРежимПодключенияК1СОтчетности = Ложь;
	
	УстановитьПривилегированныйРежим(Истина);
	ВнутреннийАдресМенеджераСервиса = РаботаВМоделиСервиса.ВнутреннийАдресМенеджераСервиса();
	ИмяСлужебногоПользователя = РаботаВМоделиСервиса.ИмяСлужебногоПользователяМенеджераСервиса();
	ПарольСлужебногоПользователя = РаботаВМоделиСервиса.ПарольСлужебногоПользователяМенеджераСервиса();
	НомерОбласти = Формат(ОбщегоНазначения.ЗначениеРазделителяСеанса(), "ЧН=0; ЧГ=0");
	УстановитьПривилегированныйРежим(Ложь);
	
	URL = ВнутреннийАдресМенеджераСервиса + "/hs/ui/zone/" + НомерОбласти;
	СтруктураURI = ОбщегоНазначенияКлиентСервер.СтруктураURI(URL);
	ЗащищенноеСоединение = ?(ВРег(СтруктураURI.Схема) = "HTTPS", Новый ЗащищенноеСоединениеOpenSSL, Неопределено);
	
	Попытка
		
		HTTPСоединение = Новый HTTPСоединение(СтруктураURI.Хост,
			СтруктураURI.Порт,
			ИмяСлужебногоПользователя,
			ПарольСлужебногоПользователя,,
			10,
			ЗащищенноеСоединение);
		Ответ = HTTPСоединение.Получить(Новый HTTPЗапрос(СтруктураURI.ПутьНаСервере));
		СтрокаОтвета = Ответ.ПолучитьТелоКакСтроку();
		
		Если Ответ.КодСостояния <> 200 Тогда
			ВызватьИсключение НСтр("ru='Код ответа '") + Ответ.КодСостояния + ":" + Символы.ПС + СтрокаОтвета;
		КонецЕсли;
		
		ЧтениеJSON = Новый ЧтениеJSON;
		ЧтениеJSON.УстановитьСтроку(СтрокаОтвета);
		Данные = ПрочитатьJSON(ЧтениеJSON);
		ЧтениеJSON.Закрыть();
		
		Если Данные.Свойство("invoicingEnabled") Тогда
			ДоступнаОплата = Данные.invoicingEnabled;
		КонецЕсли;
		
		Если Данные.Свойство("simpleConnectionModeTo1CReportingEnabled") Тогда
			УпрощенныйРежимПодключенияК1СОтчетности = Данные.simpleConnectionModeTo1CReportingEnabled;
		КонецЕсли;
		
	Исключение
		ЗаписьЖурналаРегистрации(НСтр("ru='Получение параметров обслуживающей организации'"),
			УровеньЖурналаРегистрации.Ошибка,,, ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
	КонецПопытки;
	
	Обработки.ОплатаСервиса.НастроитьИнтерфейсОплатыСервиса(ДоступнаОплата);
	Константы.ОбслуживающаяОрганизацияИспользуетУпрощенныйРежимПодключения­К1СОтчетности.Установить(УпрощенныйРежимПодключенияК1СОтчетности);
	
КонецПроцедуры