Форум Программирование Библиотека стандартных подсистем (БСП)

Серверный вызов не всегда выполняется

Платформа 1С v8.3 Программист Внешняя обработка (ert,epf) Бесплатно (free) Инструменты и обработки

1. FVK 25.10.19 14:32 Сейчас в теме

Добрый день, коллеги!
Столкнулись с проблемой - созданная внешняя обработка иногда работает правильно, а в большинстве случаев выполняется, но при этом процедура ВыполнитьКоманду () в модуле не вызывается, при этом ошибок не происходит.

Платформа: 1С:Предприятие 8.3 (8.3.15.1565)
Конфигурация: Розница, редакция 2.2 (2.2.11.29)
Режим: Файловый (без сжатия)
Приложение: Тонкий клиент
Локализация: Информационная база: русский (Россия), Сеанс: русский (Россия)
Вариант интерфейса: Такси
Пробовали и на других конфигурациях (Бухгалтерия, Торговля), результат - тот же.

Обработка примитивная. Формы нет, только модуль. Вот он:

Функция СведенияОВнешнейОбработке() Экспорт
	
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке();
	
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();	
	ПараметрыРегистрации.Назначение.Добавить("Документ.ПоступлениеТоваров");
	ПараметрыРегистрации.Версия = "2.0";
	ПараметрыРегистрации.БезопасныйРежим = ЛОЖЬ;
	ПараметрыРегистрации.Информация = "(с) ООО ""ИНФОТЕХ"", 2019";
	
			
	ТаблицаКоманд = ПолучитьТаблицуКоманд();
    ДобавитьКоманду(ТаблицаКоманд,
				    "Автоматическая загрузка поступлений товаров...",
				    "АвтозагрузкаПоступленийТоваров",
				    ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода(),
				    ЛОЖЬ,
					"");
    ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
			
	Возврат ПараметрыРегистрации;
	
КонецФункции

Функция ПолучитьТаблицуКоманд()
	
    //    Тип данных - таблица значений.
    //    Таблица содержит 5 колонок:
    //    1) Представление. Наименование команды в пользовательском интерфейсе;
    //    2) Идентификатор. Для печатных форм список макетов, для остальных обработок любая строка, уникальная для данной обработки.
    //    3) Использование. Строка, одно из значений - 
    //        - ОткрытиеФормы. Открывает форму обработки.
    //        - ВызовКлиентскогоМетода. Вызов клиентского экспортного метода модуля формы
    //        - ВызовСерверногоМетода. Вызов экспортного серверного метода модуля объекта.
    //        Для внешних печатных форм нужно указывать последнее значение.
    //    4) ПоказыватьОповещение. Булево, нужно ли показывать оповещение при начале и окончании действия.
    //    5) Модификатор. Для внешних печатных форм должно содержаться значение "ПечатьMXL".
    Команды = Новый ТаблицаЗначений;
    Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
    Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
    Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
    Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
    Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
    Возврат Команды;
КонецФункции


Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
    НоваяКоманда = ТаблицаКоманд.Добавить();
    НоваяКоманда.Представление = Представление;
    НоваяКоманда.Идентификатор = Идентификатор;
    НоваяКоманда.Использование = Использование;
    НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
    НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры

Процедура ВыполнитьКоманду(ИдентификаторКоманды, ПараметрыВыполнения = Неопределено ) Экспорт
	
		Сообщить ("Выполняется " + ИдентификаторКоманды + " " + ТекущаяДата());
		ПутьКФайлам = "C:\Test";
		МассивФайлов = НайтиФайлы(ПутьКФайлам, "*.txt");
		Для Каждого Стр из МассивФайлов Цикл
			Сообщить("Обработка: " + Стр.Имя);
			ЗаписьЖурналаРегистрации ("Обработан файл: " + Стр.Имя + " " +ТекущаяДата());
		КонецЦикла;	

        ЗаписьЖурналаРегистрации ("Выполнена "+ИдентификаторКоманды + " " +ТекущаяДата());
					
КонецПроцедуры

Показать

Кто нибудь сталкивался? В чем может быть проблема?

Прикрепленные файлы:

АвтоЗагрузкаФайлов.epf

По теме из базы знаний

Вознаграждение за ответ

Сумма: 0 $m

Добавили:
FVK (1.00 $m)

Получили:

Lord_Michael (0.5 $m), Igor_K_ (0.5 $m)

Показать полностью

Найденные решения

28. Lord_Michael 28.10.19 14:10 Сейчас в теме +0.5 $m

ну, во-первых, не знаю как в Рознице 2.2, но сейчас в БСП функция ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке() уже возвращает таблицу команд. так что отдельные процедуры на это писать не надо. достаточно добавить строчку и заполнить значения. это я пишу к тому, что возможно проблема с типами данных в описании. сейчас корректно делать описание так:

Функция СведенияОВнешнейОбработке() Экспорт
	ВерсияБСП = СтандартныеПодсистемыСервер.ВерсияБиблиотеки();
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке(ВерсияБСП);
	ПараметрыРегистрации.Информация = НСтр("ru = '(с) ООО ""ИНФОТЕХ"", 2019'");
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();
	ПараметрыРегистрации.Версия = "2.0";
	ПараметрыРегистрации.Назначение.Добавить("Документ.ПоступлениеТоваров");
	ПараметрыРегистрации.БезопасныйРежим = Ложь;
	
	Команда = ПараметрыРегистрации.Команды.Добавить();
	Команда.Представление = НСтр("ru = 'Автоматическая загрузка поступлений товаров...'");
	Команда.Идентификатор = "АвтозагрузкаПоступленийТоваров";
	Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
	Команда.ПоказыватьОповещение = Ложь;
	Команда.Модификатор = "";
	
	Возврат ПараметрыРегистрации;
КонецФункции

Показать

далее, вы хотя бы в начале процедуры сделайте запись в ЖР, что вы туда пришли и начали выполнение. это уже будет показатель.
также можно ваш код обернуть попыткой и в случае исключения писать в ЖР описание ошибки. это на случай проблем работы с файловой системой, так как это чаще всего основная ошибка с фоновыми заданиями и безопасным режимом.
ну и разберитесь с параметрами записи в ЖР. писать комментарий в событие то еще извращение.

37. Igor_K_ 28.10.19 15:12 Сейчас в теме +0.5 $m

(34) На вашем скриншоте в первом сообщении форма из БСП, а не стандартная.

Прикрепленные файлы:

Остальные ответы

В избранное Подписаться на ответы

Свернуть все

5. alex-l19041 8 25.10.19 16:01 Сейчас в теме

(1) если есть возможность протестируйте на другой версии платформы

6. FVK 25.10.19 17:24 Сейчас в теме

(5) Попробовали на 8.3.15.1489. Результат тот же. Выполнилась 1 раз, потом не выполняется.

29. RocKeR_13 1266 28.10.19 14:21 Сейчас в теме

(1) Хм, настроил расписание раз в 30 секунд - все запускает.

Процедура ВыполнитьКоманду(ИдентификаторКоманды, ПараметрыВыполнения = Неопределено ) Экспорт
	
	ЗаписьЖурналаРегистрации ("Запуск "+ИдентификаторКоманды);
	ПутьКФайлам = "C:\Test";
	МассивФайлов = НайтиФайлы(ПутьКФайлам, "*.txt");
	Для Каждого Стр из МассивФайлов Цикл
		Сообщить("Обработка: " + Стр.Имя);
		ЗаписьЖурналаРегистрации ("Обработан файл: " + Стр.Имя + " " +ТекущаяДата());
	КонецЦикла;	
	
	ЗаписьЖурналаРегистрации ("Выполнена "+ИдентификаторКоманды + " " +ТекущаяДата());
					
КонецПроцедуры

Показать

Прикрепленные файлы:

30. FVK 28.10.19 14:29 Сейчас в теме

(29) У меня то же самое. Запускать - запускает, но делать - ничего не делает. В ЖР должны появляться записи о произведенных действиях:

ЗаписьЖурналаРегистрации ("Обработан файл: " + Стр.Имя + " " +ТекущаяДата());

31. RocKeR_13 1266 28.10.19 14:32 Сейчас в теме

(30) ну раз делает запись ЖР, то вызов команды осуществляется. Если отладки на сервере нет, то добавьте записи ЖР перед обходом массива найденных файлов: может быть он пустой?

33. RocKeR_13 1266 28.10.19 14:39 Сейчас в теме

(30) накидал файлов - все опять-таки нормально

Прикрепленные файлы:

40. FVK 28.10.19 16:23 Сейчас в теме

(33) Подскажите, какая у Вас конфигурация была использована?

41. RocKeR_13 1266 28.10.19 16:24 Сейчас в теме

(40) Розница 2.3.1.30 + платформа 8.3.15.1656

44. FVK 28.10.19 16:28 Сейчас в теме

(41) Значит, у Вас уже исправленная форма ЖР, это видно по скриншоту. А у нас в конфе Розница (2.2.11.29) - глючная. Мы это увидели, как только воспользовались стандартной формой (Через меню ВсеФункции). Все равно спасибо за участие!

2. VmvLer 25.10.19 14:40 Сейчас в теме

иногда нет файлов для обработки
почему?

3. FVK 25.10.19 14:43 Сейчас в теме

(2) Файлы всегда есть. Процедура не всегда вызывается. Работает правильно примерно один раз из двадцати.

4. FVK 25.10.19 14:49 Сейчас в теме

Ставлю в отладчике точку останова на общем модуле, она в большинстве случаев не срабатывает. Когда срабатывает, все идет нормально.

Прикрепленные файлы:

7. Xershi 1433 25.10.19 18:32 Сейчас в теме

(4) значит у тебя косяк в коде.
Рисуй форму и эмулируй окружение.

8. FVK 25.10.19 18:41 Сейчас в теме

(7) Где у меня косяк, можно конкретнее?
Зачем нужна форма, если планируется ее использовать как регламентное задание по расписанию?
Что значит "эмулируй окружение" ?
Моя обработка - в прикрепленных файлах, если хотите помочь - скачайте и проверьте у себя.

9. Xershi 1433 25.10.19 18:45 Сейчас в теме

(8) просканируй конфигурацию на все галки и поставь точку останова при ошибке.
Эмулировать написать код, который позволит отлаживать внешнюю обработку.

10. FVK 25.10.19 19:24 Сейчас в теме

(9) Это уже все было сделано, ошибок нет, точки стоят. Эта обработка и так сама по себе эмулятор, она ничего не делает, кроме чтения списка пустых файлов в каталоге. Предполагается, что в дальнейшем она в автоматическом режиме будет их читать и заполнять табличные части документов информацией из них.
Главный вопрос: ПОЧЕМУ СИСТЕМА ВЕДЕТ СЕБЯ ТАК, ЧТО В НЕКОТОРЫХ СЛУЧАЯХ ОБРАБОТКА РАБОТАЕТ НОРМАЛЬНО, А В НЕКОТОРЫХ НИЧЕГО НЕ ВЫПОЛНЯЕТ И ОШИБОК НЕ ВЫДАЕТ?

Может, кто-то скачает мою обработку к себе и протестирует ее?

12. Xershi 1433 25.10.19 19:50 Сейчас в теме

(10) обработка ошибок и не будет выдавать. Потому что она как дополнительная. А ошибка есть.
Эмулируй вызов и найдешь свои косяки.

14. Igor_K_ 25.10.19 21:09 Сейчас в теме

(4) Обычно в большинстве случаев ваша обработка запускается в фоновом задании. Включите отладку фоновых заданий, чтобы точка останова сработала.

Прикрепленные файлы:

15. o4karek 25.10.19 21:55 Сейчас в теме

(4) ДополнительныеОтчетыИОбработки - у этого общего модуля не установлено повторное использование возвращаемых значений?

11. Anion86 25.10.19 19:33 Сейчас в теме

Скажу так , в обработке есть два экспортных куска кода , в какую из них ломиться в модуле обработки при нажатии на кнопку на клиенте ? где инфа в команде что она должна выполнять?

24. FVK 28.10.19 13:24 Сейчас в теме

(11) должна вызываться процедура ВыполнитьКоманду () , по определению.

13. Igor_K_ 25.10.19 20:39 Сейчас в теме

Собственно, а с чего вы вообще взяли, что «при этом процедура ВыполнитьКоманду () в модуле не вызывается»?

По отсутствию сообщений? Ну, так обработка выполняется в фоновом задании в другом сеансе. Сообщения из другого сеанса не передаются в ваш сеанс.
Иногда при запуске обработки очередь фоновых заданий бывает уже занята чем-то другим, потому обработка запускается не в фоне, а в вашем сеансе. В этом случае вы видите вывод сообщений.

Для эксперимента можете включить РежимОтладки БСП (см. вложение) — тогда обработка будет запускаться в вашем сеансе всегда (без фоновых заданий).

Ещё, например, можете запустить Process Monitor и проверить: происходит ли чтение вашей папки при запуске обработки или нет.

Прикрепленные файлы:

25. FVK 28.10.19 13:51 Сейчас в теме

(13) Стоило мне по Вашему совету установить параметр запуска РежимОтладки, как моя обработка по кнопке Выполнить в справочнике доп.отчетов и обработок стала стабильно вызываться и отрабатывать код. Стоило мне его очистить, как опять все проблемы те же вернулись.
Однако в фоновом режиме она по-прежнему не отрабатывает код, запускается по времени, но впустую.

Мне по-прежнему непонятна причина: Вы пишете, что обработка может выполняться в фоне в другом сеансе, и сообщения мне не видны. Да, но в таком случае отсутствуют и записи в журнале регистрации, которые по-любому должны быть видны. Здесь что-то не так.

26. Igor_K_ 28.10.19 14:04 Сейчас в теме

(25)

Да, но в таком случае отсутствуют и записи в журнале регистрации, которые по-любому должны быть видны.

Судя по скриншоту вы пользуетесь формой журанала регистрации из БСП. Похоже, в ней есть проблемы при отображении новых событий из фоновых заданий записанных после открытия этой формы. Подробно в причине такого поведения не разбирался. Попробуйте закрыть/открыть форму журнала и поискать записи ещё раз. Или попробуйте использовать стандартную форму журнала.

Прикрепленные файлы:

34. FVK 28.10.19 15:01 Сейчас в теме

(26)Пользуюсь стандартной формой журнала

37. Igor_K_ 28.10.19 15:12 Сейчас в теме +0.5 $m

(34) На вашем скриншоте в первом сообщении форма из БСП, а не стандартная.

Прикрепленные файлы:

38. FVK 28.10.19 15:34 Сейчас в теме

(37) Простите, Вы правы. Использовали меню Администрирование - Обслуживание - Журнал регистрации, а там, оказывается, форма из БСП.
В стандартной форме выводятся все сообщения, в БСП-шной - не все. Сообщения из моей ВО туда не попадают. Спасибо Вам!

16. DrAku1a 1609 26.10.19 17:55 Сейчас в теме

ПараметрыРегистрации.Назначение.Добавить("Документ.ПоступлениеТоваров"); - Если не ошибаюсь, для Вашей обработки это лишнее.

Проверьте и исключите административную проблему - права доступа к файлам пользователя, под которым запущен сервер.

21. FVK 28.10.19 13:19 Сейчас в теме

(16) Спасибо, но уже пробовали. Этот параметр в данном случае ни на что не влияет. Права доступа к файлам есть. Проблема в чем-то другом.

17. 2C_prog 8 27.10.19 23:26 Сейчас в теме

Добрый вечер. Попробуйте точку остановы в команде "Выполнить" на общей форме дополнительных обработок. Ваша обработка работает верно, но её где-то срезает проверка безопасности. Есть риск, что часть коды вы не предоставили, какое-нибудь com соединение не закрывается или еще что-то похожее. Политика фирмы 1С по борьбе с внешними обработками на лицо =)

18. Alex_E 2344 28.10.19 04:02 Сейчас в теме

Я так понял, что Вас терзают смутные сомнения, выполняется код или не выполняется... Причина тех сомнений- то видим сообщения, то не видим - избавьтесь от этого - пишите лог в файл(ы)...

22. FVK 28.10.19 13:21 Сейчас в теме

(18) Пишем лог в ЖР. Но он то пишется, то нет.

32. Alex_E 2344 28.10.19 14:33 Сейчас в теме

(22) я не говорил про ЖР, я предложил писать на диск в файл, или просто создавать файлы, как признак того, что задание выполняется...

42. FVK 28.10.19 16:24 Сейчас в теме

(32) Спасибо, сделали это

19. AlexPC 28.10.19 08:11 Сейчас в теме

Если база клиент-серверная, то фоновые задания выполняются на сервере. Может быть там нет каталога "C:\Test".

23. FVK 28.10.19 13:22 Сейчас в теме

(19) Каталог точно есть. Ведь иногда обработка запускается и отрабатывает код правильно. А иногда - нет. А в чем причина такого ее поведения - пока непонятно.

27. Xershi 1433 28.10.19 14:09 Сейчас в теме

(23) база файловая, так может тут и загвоздка? Неизвестно кто и как запускает фоновое задание!
Может антивирус блочит?))

35. FVK 28.10.19 15:02 Сейчас в теме

(27)Антивирус не блочит

36. karamazoff 94 28.10.19 15:06 Сейчас в теме

(35)попробуйте мой вариант, и как советовали, поставьте свою процедуру через попытку, в фоновых процессах обращение к файлам по не существующим путям вешает процесс, проверено.

45. FVK 28.10.19 16:33 Сейчас в теме

(36) Спасибо, сделали. Но Исключение не вызывается, значит, зависаний нет

20. karamazoff 94 28.10.19 10:48 Сейчас в теме

Ваша обработка по расписанию действительно не срабатывает, прилагаю рабочий проверенный вариант, вставьте туда свой код, все должно взлететь

Прикрепленные файлы:

ВыгрузкаВБазу-test.epf

46. FVK 28.10.19 16:34 Сейчас в теме

(20) Спасибо, не успели )). Уже со своей разобрались.

28. Lord_Michael 28.10.19 14:10 Сейчас в теме +0.5 $m

Функция СведенияОВнешнейОбработке() Экспорт
	ВерсияБСП = СтандартныеПодсистемыСервер.ВерсияБиблиотеки();
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке(ВерсияБСП);
	ПараметрыРегистрации.Информация = НСтр("ru = '(с) ООО ""ИНФОТЕХ"", 2019'");
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();
	ПараметрыРегистрации.Версия = "2.0";
	ПараметрыРегистрации.Назначение.Добавить("Документ.ПоступлениеТоваров");
	ПараметрыРегистрации.БезопасныйРежим = Ложь;
	
	Команда = ПараметрыРегистрации.Команды.Добавить();
	Команда.Представление = НСтр("ru = 'Автоматическая загрузка поступлений товаров...'");
	Команда.Идентификатор = "АвтозагрузкаПоступленийТоваров";
	Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
	Команда.ПоказыватьОповещение = Ложь;
	Команда.Модификатор = "";
	
	Возврат ПараметрыРегистрации;
КонецФункции

Показать

39. FVK 28.10.19 16:17 Сейчас в теме

В общем, что удалось в итоге выяснить:

(28) По Вашему совету оформили СведенияОВнешнейОбработке. В результате она стала запускаться всегда.
В код обработки было добавленно изменение найденных файлов, чтобы понять, происходит ли что-либо при выполнении обработки. Она приобрела такой вид:

Функция СведенияОВнешнейОбработке() Экспорт
	
	ВерсияБСП = СтандартныеПодсистемыСервер.ВерсияБиблиотеки();
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке(ВерсияБСП);

	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка();	
	ПараметрыРегистрации.Назначение.Добавить("Документ.ПоступлениеТоваров");
	ПараметрыРегистрации.Версия = "2.1";
	ПараметрыРегистрации.БезопасныйРежим = ЛОЖЬ;
	ПараметрыРегистрации.Информация = "(с) ООО ""ИНФОТЕХ"", 2019";
	
	Команда = ПараметрыРегистрации.Команды.Добавить();
	Команда.Представление = НСтр("ru = 'Автоматическая загрузка поступлений товаров...'");
	Команда.Идентификатор = "АвтозагрузкаПоступленийТоваров";
	Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
	Команда.ПоказыватьОповещение = Ложь;
	Команда.Модификатор = "";
	 			
	Возврат ПараметрыРегистрации;
	
	
КонецФункции


Процедура ВыполнитьКоманду(ИдентификаторКоманды, ПараметрыВыполнения = Неопределено ) Экспорт
	
		Сообщить ("Выполняется " + ИдентификаторКоманды + " " + ТекущаяДата());
		ПутьКФайлам = "C:\Test";
		Попытка
			МассивФайлов = НайтиФайлы(ПутьКФайлам, "*.txt");
		Исключение
			Инфо = ИнформацияОбОшибке();
			ЗаписьЖурналаРегистрации("Описание='" + Инфо.Описание + 
			 						"'"+"ИмяМодуля='" + Инфо.ИмяМодуля + 
			 						"'" + "НомерСтроки=" + Инфо.НомерСтроки + 
			 						" ИсходнаяСтрока='" + Инфо.ИсходнаяСтрока + "'",
			 						УровеньЖурналаРегистрации.Ошибка);
			Возврат;
		КонецПопытки;	
		Для Каждого Стр из МассивФайлов Цикл
			Сообщить("Обработка: " + Стр.Имя);
			ТекФайл = Стр.ПолноеИмя;
			ВыбФайл = Новый Файл(ТекФайл);
			ДатаИзмененияФайла = ВыбФайл.ПолучитьУниверсальноеВремяИзменения();		
			ТекДок = Новый ТекстовыйДокумент;
			ТекДок.Прочитать(ТекФайл, КодировкаТекста.ANSI);
			НовТекст = ТекДок.ПолучитьТекст()+Символы.ПС+ "Изменен:" +ДатаИзмененияФайла;
			ТекДок.УстановитьТекст(НовТекст);
			ТекДок.Записать(ТекФайл, КодировкаТекста.ANSI);

			ЗаписьЖурналаРегистрации ("Обработан файл: " + Стр.Имя + " " +ТекущаяДата(), УровеньЖурналаРегистрации.Информация );
		КонецЦикла;	

        ЗаписьЖурналаРегистрации ("Выполнена "+ИдентификаторКоманды + " " +ТекущаяДата(), УровеньЖурналаРегистрации.Информация);
					
КонецПроцедуры

Показать

После чего стало понятно, что все работает! Расписание установили на "каждые 10 сек". В файлы стали дописываться строчки:

Изменен:28.10.2019 12:01:26
Изменен:28.10.2019 12:02:27
Изменен:28.10.2019 12:03:27
Изменен:28.10.2019 12:06:03
Изменен:28.10.2019 12:06:39
Изменен:28.10.2019 12:06:39
Изменен:28.10.2019 12:06:45
Изменен:28.10.2019 12:07:44
Изменен:28.10.2019 12:07:45
Изменен:28.10.2019 12:07:47
Изменен:28.10.2019 12:08:47
Изменен:28.10.2019 12:09:08
Изменен:28.10.2019 12:10:08
Изменен:28.10.2019 12:11:09
Изменен:28.10.2019 12:12:09
Изменен:28.10.2019 12:13:10
Изменен:28.10.2019 12:14:10
Изменен:28.10.2019 12:15:11
Изменен:28.10.2019 12:16:11
Изменен:28.10.2019 12:17:11
Изменен:28.10.2019 12:18:12
Изменен:28.10.2019 12:19:12
Изменен:28.10.2019 12:20:13
Изменен:28.10.2019 12:21:13
Изменен:28.10.2019 12:22:14
Изменен:28.10.2019 12:23:14
Изменен:28.10.2019 12:23:26
Изменен:28.10.2019 12:23:26
Изменен:28.10.2019 12:23:28
Изменен:28.10.2019 12:24:28
Изменен:28.10.2019 12:25:12
Изменен:28.10.2019 12:25:12
Изменен:28.10.2019 12:25:33

Показать

Далее, по совету (37) открыли стандартную форму ЖР и увидели, что все сообщения в журнал выводятся и отображаются. То есть и здесь все работает, только БСПшная форма журнала, которая открывается в стандартном меню Администрирование их почему-то не отображает.
Далее, по совету (13) использовали параметр РежимОтладки и пришли к выводу, что:
- при установленном параметре процедура Сообщить() выводит сообщение
- при не установленном - не выводит.

В общем, совместными усилиями разобрались. Спасибо всем, кто принял участие в обсуждении и особенно тем, кто помог найти путь решения проблемы.
Приз достается Lord_Michael и Igor_K_

43. Sashares 34 28.10.19 16:27 Сейчас в теме

(39)

Далее, по совету (13) использовали параметр РежимОтладки и пришли к выводу, что:
- при установленном параметре процедура Сообщить() выводит сообщение
- при не установленном - не выводит.

Ну логично, при установленном параметре все выполняется в текущем сеансе, а при не установленном - в фоновом задании.
Если хотите выводить сообщения из фонового задания, это надо отдельно прописывать.

47. FVK 28.10.19 16:35 Сейчас в теме

(43) Да, теперь это стало понятно.

Оставьте свое сообщение

E-mail:

Вакансии

1С-Программист (интегратор Битрикс24)
Санкт-Петербург
зарплата от 150 000 руб. до 250 000 руб.
Полный день

Разработчик 1С
Москва
зарплата от 100 000 руб.
Временный (на проект)

Разработчик 1С
Москва
зарплата от 150 000 руб.
Полный день

Программист
Санкт-Петербург
зарплата от 180 000 руб. до 240 000 руб.
Полный день

Разработчик 1С
Москва
зарплата от 150 000 руб. до 250 000 руб.
Полный день