БСП Как вставить в новый документ отчет по движениям документа?

Форум Программирование Библиотека стандартных подсистем (БСП)
1С:Предприятие 8
1. HAMMER_59 256 06.06.18 08:55 Сейчас в теме
На текущий момент сделал так (рабочий вариант): 

ОткрытьФорму("Отчет.ДвиженияДокумента.Форма", 
		Новый Структура("Документ", Объект.Ссылка),
			ЭтаФорма,
			УникальныйИдентификатор,
			ЭтаФорма.Окно);


Пробовал добавлять кнопку с вызовом команды "Отчет.ДвиженияДокумента.Команда.ДвиженияДокумента", в качестве параметра указал объект, в таком случае ничего не отображается.

Также пробовал подключить отчет через БСП, сначала вставил код для подсистемы "Подключаемые команды".
Затем вставил: 
Процедура ПередДобавлениемКомандОтчетов(КомандыОтчетов, Параметры, СтандартнаяОбработка) Экспорт
    ДокументыСОтчетомОДвижениях = Новый Массив;
    ДокументыСОтчетомОДвижениях.Добавить(Метаданные.Документы._ДемоНачислениеЗарплаты);
    ДокументыСОтчетомОДвижениях.Добавить(Метаданные.Документы._ДемоПоступлениеТоваров);
    ДокументыСОтчетомОДвижениях.Добавить(Метаданные.Документы._ДемоРеализацияТоваров);
    Отчеты.ДвиженияДокумента.ДобавитьКомандуОтчетОДвиженияхДокумента(КомандыОтчетов, Параметры,     ДокументыСОтчетомОДвижениях);
КонецПроцедуры


При запуске получил сообщение об ошибке: отсутствует экспортная процедура ДобавитьКомандуОтчетОДвиженияхДокумента.
Манипуляции проводил на Конфигурации УТ 11.4.1.261.
payta; +1 – Ответить
По теме из базы знаний
Ответы
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
12. nicknick267-1 30.01.24 17:02 Сейчас в теме
Интересно, Получилось ли
+ – Ответить
2. Serg_tvr 2 30.11.18 14:26 Сейчас в теме
В ЗУП делал так:

В ПриСозданииНаСервере добавил 
// СтандартныеПодсистемы.ПодключаемыеКоманды
   ПодключаемыеКоманды.ПриСозданииНаСервере(ЭтотОбъект); 
   // Конец СтандартныеПодсистемы.ПодключаемыеКоманды


В модуль формы добавил процедуры 

// СтандартныеПодсистемы.ПодключаемыеКоманды
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
	ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, Объект);
КонецПроцедуры

&НаСервере
Процедура Подключаемый_ВыполнитьКомандуНаСервере(Контекст, Результат)
	ПодключаемыеКоманды.ВыполнитьКоманду(ЭтотОбъект, Контекст, Объект, Результат);
КонецПроцедуры

&НаКлиенте
Процедура Подключаемый_ОбновитьКоманды()
	ПодключаемыеКомандыКлиентСервер.ОбновитьКоманды(ЭтотОбъект, Объект);
КонецПроцедуры
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
Показать


!!!Самое главное (убил полдня, пока врубился)
В регистре сведений ПараметрыРаботыПрограммы надо прибить строку с именем параметра СтандартныеПодсистемы.ПодключаемыеКоманды
furlizon; ramze1C; annak2906; nat_stav; greenlist; GAS.tlt; Lapitskiy; Andy_NTG; TH000; ab_initio; Derek777; Diego_Iv; Bnwk; Natalia; payta; Восьмой; +16 – Ответить
3. Восьмой 99 06.12.18 17:09 Сейчас в теме
(2)
В регистре сведений ПараметрыРаботыПрограммы надо прибить строку с именем параметра СтандартныеПодсистемы.ПодключаемыеКоманды



Дай бог тебе здоровье!
От себя добавлю что в ЗУПЕ достаточно выполнить ПодключаемыеКоманды.ОперативноеОбновлениеОбщихДанныхКонфигурации();

Для своих документов в модуле формы "ПриСозданииНаСервере" в самое начало вставляю вот такой код: 


	ПараметрыПодключенияКСтандартнымПодсистемам = СтандартныеПодсистемыСервер.ПараметрРаботыПрограммы("СтандартныеПодсистемы.ПодключаемыеКоманды");
	СинонимОбъектаМетаданных = Объект.Ссылка.Метаданные().Синоним;
	ТребуетсяОперативноеОбновление = Истина;
	Для Каждого ПодключенныйОбъект из ПараметрыПодключенияКСтандартнымПодсистемам.ПодключенныеОбъекты Цикл
		Если ПодключенныйОбъект.Ключ.Синоним = СинонимОбъектаМетаданных Тогда
			ТребуетсяОперативноеОбновление = Ложь;
			Прервать;
		КонецЕсли;
	КонецЦикла;
	Если ТребуетсяОперативноеОбновление = Истина Тогда
		ПодключаемыеКоманды.ОперативноеОбновлениеОбщихДанныхКонфигурации();
	КонецЕсли;
Показать
Alex17; nporrep; TH000; user1251410; Natalia; payta; +6 – Ответить
4. Stepka1206 20.07.19 13:53 Сейчас в теме
(3) Что-бы не втыкать ПодключаемыеКоманды.ОперативноеОбновлениеОбщихДанныхКонфигурации();
В установленном шаблоне конфигурации БСП есть папка с вспомогательными обработками. нужно воспользоваться обработкой "ОбновлениеВспомогательныхДанных" обновить варианты отчетов.
bprogs; +1 – Ответить
5. MikeI 74 26.02.20 01:10 Сейчас в теме
Блин , ну почему они(разрабы 1С) все делают через 04K0?
unknown181538; user1027191; Derek777; +3 –1 Ответить
6. пользователь 01.04.21 23:58
Сообщение было скрыто модератором.
...
7. Progart 08.08.22 15:19 Сейчас в теме
Можно в код не лезть и поступить проще. Спасибо Курсам по 1С РФ. Вот здесь https://xn----1-bedvffifm4g.xn--p1ai/%D0%B1%D0%B5%D1%81%D0%BF%D0%BB%D0%B0%D1%82%D0%BD%D0%BE%­D0%B5/2020-03-03-how-to-display-links-to-document-movements/
+ –1 Ответить
8. dmpolik 17.08.22 06:27 Сейчас в теме
Функционал БСП. На форме 

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
     ПодключаемыеКоманды.ПриСозданииНаСервере(ЭтотОбъект);
КонецПроцедуры

&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
     ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, Объект);
КонецПроцедуры
Показать
+ – Ответить
13. Mr_174 17.07.25 19:30 Сейчас в теме
(8)
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
ПодключаемыеКомандыКлиент.ВыполнитьКоманду(ЭтотОбъект, Команда, Объект);
КонецПроцедуры

Просто лучший!!!
+ – Ответить
9. sergling 34 18.08.22 15:19 Сейчас в теме
просто почитайте доку про внедрение подсистем БСП на its.ru - там все целиком, о чем здесь разными эпизодами отписались коллеги.
SagittariusA; +1 – Ответить
10. SagittariusA 31.08.22 12:49 Сейчас в теме
(9) Думаю ещё полезней будет оставить тут ссылку на документацию
user689379_di_ang; DoctorRoot; native-api; Hogyoku; +4 – Ответить
11. CaSH_2004 375 10.12.23 20:49 Сейчас в теме
Я сделал так: открыл демо конфигурацию БСП и в ней в формах документа и списка документов увидел одинаковый механизм подключения: 

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	// СтандартныеПодсистемы.ПодключаемыеКоманды
	ПодключаемыеКоманды.ПриСозданииНаСервере(ЭтотОбъект);
	// Конец СтандартныеПодсистемы.ПодключаемыеКоманды
КонецПроцедуры

#Область СлужебныеПроцедурыИФункции

// СтандартныеПодсистемы.ПодключаемыеКоманды
&НаКлиенте
Процедура Подключаемый_ВыполнитьКоманду(Команда)
	ПодключаемыеКомандыКлиент.НачатьВыполнениеКоманды(ЭтотОбъект, Команда, Объект);
КонецПроцедуры

&НаКлиенте
Процедура Подключаемый_ПродолжитьВыполнениеКомандыНаСервере(ПараметрыВыполнения, ДополнительныеПараметры) Экспорт
	ВыполнитьКомандуНаСервере(ПараметрыВыполнения);
КонецПроцедуры

&НаСервере
Процедура ВыполнитьКомандуНаСервере(ПараметрыВыполнения)
	ПодключаемыеКоманды.ВыполнитьКоманду(ЭтотОбъект, ПараметрыВыполнения, Объект);
КонецПроцедуры

&НаКлиенте
Процедура Подключаемый_ОбновитьКоманды()
	ПодключаемыеКомандыКлиентСервер.ОбновитьКоманды(ЭтотОбъект, Объект);
КонецПроцедуры
// Конец СтандартныеПодсистемы.ПодключаемыеКоманды

#КонецОбласти
Показать


и все тут же заработало
Designer1C; maikl007; +2 – Ответить
Для отправки сообщения требуется регистрация/авторизация

Для получения уведомлений об ответах подключите телеграм бот:
Инфостарт бот