Не вызывается процедура Печать() из внешней обработки

Форум Программирование Библиотека стандартных подсистем (БСП)

Управляемые формы

1. AndrewKop 04.06.18 11:18 Сейчас в теме

Сразу, я - нуб.
Пытаюсь сделать внешнюю обработку из типовой ТОРГ13. Хочу формировать её на основе закупочных цен.
Делаю все вроде по многочисленным гайдам. В модуле внешней обработки прописал следующее:

Функция СведенияОВнешнейОбработке() Экспорт 
	Назначения = Новый Массив ; 
	Назначения.Добавить("Документ.ПеремещениеТоваров");
	ПараметрыРегистрации = Новый Структура;
	ПараметрыРегистрации.Вставить("Вид","ПечатнаяФорма");
	ПараметрыРегистрации.Вставить("Назначение",Назначения);
	ПараметрыРегистрации.Вставить("Наименование","Торг13 (Закупочные цены)");
	ПараметрыРегистрации.Вставить("Версия","1.0");
	ПараметрыРегистрации.Вставить("Информация","В отличие от стандартной формы печатает закупочные цены");
	ПараметрыРегистрации.Вставить("БезопасныйРежим",Истина);
	Команды = ПолучитьТаблицуКоманд();
	ДобавитьКоманду(Команды, "Торг13 (Закупочные цены)","Торг13ПоЗакупочным","ВызовКлиентскогоМетода",Ложь,);
	ПараметрыРегистрации.Вставить("Команды",Команды);
	Возврат ПараметрыРегистрации;
КонецФункции

Функция ПолучитьТаблицуКоманд()
	Команды = Новый ТаблицаЗначений;
	Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
	Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
	Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
	Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
	Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
	Возврат Команды;
КонецФункции	

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "") 
	НоваяКоманда = ТаблицаКоманд.Добавить(); 
	НоваяКоманда.Представление = Представление;
	НоваяКоманда.Идентификатор = Идентификатор;
	НоваяКоманда.Использование = Использование;
	НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
	НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры

Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт 
	УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(
					КоллекцияПечатныхФорм, "Торг13ПоЗакупочным", 
					"Торг13 (Закупочные цены)", 
					СформироватьПечатнуюФорму(МассивОбъектов[0], ОбъектыПечати)); 
КонецПроцедуры

Показать

Форму загрузил в конфигурацию. Все прикрепилось в меню печати отобразилось. Но при вызове команды получаю ошибку:

{ОбщийМодуль.ДополнительныеОтчетыИОбработкиКлиент.Модуль(412)}: Метод объекта не обнаружен (Печать)
ФормаОбработки.Печать(ВыполняемаяКоманда.Идентификатор, ОбъектыНазначения);

в этом куске кода

ИначеЕсли ВыполняемаяКоманда.Вид = ПредопределенноеЗначение("Перечисление.ВидыДополнительныхОтчетовИОбработок.ПечатнаяФорма") Тогда
		
		ФормаОбработки.Печать(ВыполняемаяКоманда.Идентификатор, ОбъектыНазначения);

В отладчике ФормаОбработки - Управляемая форма. ФормаОбработки.ИмяФормы - "ВнешняяОбработка.Торг13ПоЗакупочным.Форма" Строка
Почему не отрабатывает?
Есть подозрение, что раз ФормаОбработки - УФ, то процедура Печать() должна быть в модуле формы, но во всех инет гайдах её помещают в модуль самой обработки.

По теме из базы знаний

Найденные решения

2. Jestery 04.06.18 11:25 Сейчас в теме

Попробуйте поменять "Вызов клиентского метода" на "Вызов серверного метода" в описании команды, тогда должна вызываться процедура модуля вн.обработки.

Остальные ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. Jestery 04.06.18 11:25 Сейчас в теме

3. AndrewKop 04.06.18 11:35 Сейчас в теме

(2) Да все верно. Именно оно и было. Спасибо!

Оставьте свое сообщение

E-mail: