После обновления с 11.3.3 на 11.4.3 не работает внешняя обработка заполнения табличной части

Question

После обновления с 11.3.3 на 11.4.3 не работает внешняя обработка заполнения табличной части, то есть она просто исчезла из кнопки "Заполнить" в соответствующем документе. Переподключать пробовал, не помогает. Ошибок никаких не выдает, даже в журнале.

Подключаю так:
[1C-CODE]
Функция СведенияОВнешнейОбработке() Экспорт
    ПараметрыРегистрации = Новый Структура;
    МассивНазначений = Новый Массив;
    МассивНазначений.Добавить("Документ.ВозвратТоваровОтКлиента");

    ПараметрыРегистрации.Вставить("Вид", "ЗаполнениеОбъекта");
    ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);
    ПараметрыРегистрации.Вставить("Наименование", "Автоподбор реализаций в возврат");
    ПараметрыРегистрации.Вставить("Версия", "1.0");
    ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);
    ПараметрыРегистрации.Вставить("Информация", "Дополнительная обработка табличной части к документу ""Возврат товаров от клиента""");

    ТаблицаКоманд = ПолучитьТаблицуКоманд();

    ДобавитьКоманду(ТаблицаКоманд,
    "Автоподбор реализаций (по контрагенту)",
    "АвтоподборРеализацийПоКонтрагенту",
    "ВызовКлиентскогоМетода",
    Истина);

	//ДобавитьКоманду(ТаблицаКоманд,
	//"Автоподбор реализаций (по партнеру)",
	//"АвтоподборРеализацийПоПартнеру",
	//"ВызовКлиентскогоМетода",
	//Истина);

    ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);

    Возврат ПараметрыРегистрации;
КонецФункции

Функция ПолучитьТаблицуКоманд()
  Команды = Новый ТаблицаЗначений;
  Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
  Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
  Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
  Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
  Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
  Возврат Команды;
КонецФункции

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
  НоваяКоманда = ТаблицаКоманд.Добавить();
  НоваяКоманда.Представление = Представление;
  НоваяКоманда.Идентификатор = Идентификатор;
  НоваяКоманда.Использование = Использование;
  НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
  НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры
[/1C-CODE]

Подскажите, кто знает, как лечить?

Accepted Answer

Вот пример с ИТС по БСП 3.0.1.
[CODE]Функция СведенияОВнешнейОбработке() Экспорт
    ПараметрыРегистрации =ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.2.2.1");
    ПараметрыРегистрации.Вид =ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиЗаполнениеОбъекта();
    ПараметрыРегистрации.Версия = "1.2";
    ПараметрыРегистрации.Назначение.Добавить("Документ.ВозвратТоваровОтКлиента");
     НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
    НоваяКоманда.Представление = НСтр("ru = 'Автоподбор реализаций (по контрагенту)'");
    НоваяКоманда.Идентификатор = "АвтоподборРеализацийПоКонтрагенту";
    НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыЗаполнениеФормы();
    Возврат ПараметрыРегистрации;
 КонецФункции[/CODE]