Подключение внешних обработок

Форум Учет и отчетность Бухгалтерский учет и налоги (БУ)

1С:Управление нашей фирмой 1.6 Платформа 1С v8.3

1. galexo 17.11.11 13:19 Сейчас в теме

УНФ, редакция 1.3 (1.3.2.5)
Не могу подключить внешнюю обработку:
Настройка и администрирование -> Доп. отчеты и обработки (на панели навигации) -> Создать. Подключаю обработку «ЗагрузкаДанныхИзТабличногоДокумента.epf», или «Поиск и замена значений» (стандартные, с диска ИТС).
Получаю сообщение об ошибке: Возможно, обработка устарела или не является дополнительной:Метод объекта не обнаружен (СведенияОВнешнейОбработке).
М.б. существует особый порядок подключения обработок, или они не подходят для УНФ?

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. anig99 2843 17.11.11 14:09 Сейчас в теме

Получаю сообщение об ошибке: Возможно, обработка устарела или не является дополнительной:Метод объекта не обнаружен (СведенияОВнешнейОбработке).

В обработку нужно создать экспортную функцию СведенияОВнешнейОбработке. Можно наверное, пустую.

3. hastar 17.11.11 15:01 Сейчас в теме

Для УНФ нужны обработки для управляемой формы, просто сконвертированные не пойдут.

4. panam 58 17.11.11 15:23 Сейчас в теме

Как пример можно посмотреть тут
http://infostart.ru/public/82855/
или тут
http://infostart.ru/public/90112/
Это варианты для подключения отчета к самой конфигурации.
Есть еще одна возможность через открыть в верхнем левом углу следующий после логотипа кружок и открыть.
Но повторюсь отчет нужен только для управляемых форм.

5. galexo 17.11.11 15:24 Сейчас в теме

Т.е. весь арсенал универсальных обработок с ИТС для 8.2 для УНФ не годится? Создавать свои?

9. Настройщик 26.11.11 20:41 Сейчас в теме

(5) сон,
Обработками с диска ИТС можно пользоваться через Файл - Открыть если УНФ запускать в режиме "толстый клиент - обычное приложение"

13. lux17 03.11.12 21:25 Сейчас в теме

(9), (12),
спасибо, помогло

6. galexo 17.11.11 16:03 Сейчас в теме

Спасибо за ссылки - буду разбираться "что к чему".

7. Sergant119 17.11.11 16:17 Сейчас в теме

скачал на этом форуме обработку по Исправление себестоимости! кто пользовался ей? что то никак не пойму как она работает? выдает сообщение с датой сегоднешней и все?

8. panam 58 18.11.11 13:45 Сейчас в теме

Смотрел обработку, там ситуация такая. Обработка исправляет даты в документах согласно структуры подчиненности. Для работы обработки надо отключать контроль остатков.

10. Bacemo 26.10.12 23:09 Сейчас в теме

Так нашлась ли хоть один внешний отчет или обработка для УНФ , чтобы подключить через внешние обработки?

11. Bacemo 28.10.12 19:52 Сейчас в теме

ссори, разобрался ит подключил, как рекомендовали на форуме после обновления конфигурации

12. ИрискаЯ 22 30.10.12 08:09 Сейчас в теме

Мне в УНФ-ке понадобилось поработать с "Групповой обработкой справочников и документов".
В УНФ-ке такой не нашла. Выдернула из Бухгалтерии, зашла в режиме "толстый клиент - обычное приложение" (через конфигуратор), открыла обработку, сделала, что нужно было, вернулась в конфигуратор, вернула назад настройки запуска (Сервис - Параметры - Запуск 1С: Предприятия).

15. slava.poison 05.12.12 23:05 Сейчас в теме

(12) ИрискаЯ, в последнем обновлении к конфигурации эта обработка включена.

16. MrWonder 642 30.12.12 10:26 Сейчас в теме

(12) ИрискаЯ, спасибо, как раз то что мне было нужно!

14. panam 58 08.11.12 15:37 Сейчас в теме

Поиском не пробовали пользоваться? и таких обработок не одна.

Универсальные подбор и обработка объектов с установкой реквизитов табличных частей (управляемое и обычное приложение)

http://infostart.ru/public/122215/

17. DarkDaemon 15.03.14 23:31 Сейчас в теме

Открыть обработку в конфигураторе и поместить в Модуль Объекта следующий код:

Функция СведенияОВнешнейОбработке() Экспорт
РегистрационныеДанные = Новый Структура;
РегистрационныеДанные.Вставить("Наименование", "Пример использование внешних обработок 8.2.");
РегистрационныеДанные.Вставить("БезопасныйРежим", Истина);
РегистрационныеДанные.Вставить("Версия", "1.0");
//ДополнительнаяОбработка
//ДополнительныйОтчет
//ЗаполнениеОбъекта
//Отчет
//ПечатанаяФорма
//СозданиеСвязанныхОбъектов
РегистрационныеДанные.Вставить("Вид", "ДополнительнаяОбработка");
РегистрационныеДанные.Вставить("Информация", "Обработка сделано по новому стандарту подключения внешних обработок 8.2. Пример обработки ""Hello Word"" ");
///////////// команды /////////////////////////
тзКоманд = Новый ТаблицаЗначений;
тзКоманд.Колонки.Добавить("Идентификатор");
тзКоманд.Колонки.Добавить("Представление");
тзКоманд.Колонки.Добавить("Модификатор");
тзКоманд.Колонки.Добавить("ПоказыватьОповещение");
тзКоманд.Колонки.Добавить("Использование");
строкаКоманды = тзКоманд.Добавить();
строкаКоманды.Идентификатор = "1";
строкаКоманды.Представление = "команда ""Hello Word"" (ОткрытиеФормы)";
строкаКоманды.ПоказыватьОповещение = Истина;
строкаКоманды.Использование = "ОткрытиеФормы";
строкаКоманды = тзКоманд.Добавить();
строкаКоманды.Идентификатор = "2";
строкаКоманды.Представление = "команда ""Hello Word"" (ВызовКлиентскогоМетода)";
строкаКоманды.ПоказыватьОповещение = Истина;
строкаКоманды.Использование = "ВызовКлиентскогоМетода";
строкаКоманды = тзКоманд.Добавить();
строкаКоманды.Идентификатор = "3";
строкаКоманды.Представление = "команда ""Hello Word"" (ВызовСерверногоМетода)";
строкаКоманды.ПоказыватьОповещение = Истина;
строкаКоманды.Использование = "ВызовСерверногоМетода";
РегистрационныеДанные.Вставить("Команды", тзКоманд);
////////////// назначение (в каких объектах используется) /////////////////////////
//для печ.форм, заполнения, ввода свазанных объектов
//МассивНазначений = Новый Массив;
//МассивНазначений.Добавить("Документ.*"); // все документы назначаются
//МассивНазначений.Добавить("Документ.АвансовыйОтчет");
//МассивНазначений.Добавить("Документ.ЗаказПокупателя");
//РегистрационныеДанные.Вставить("Назначение", МассивНазначений);
Возврат РегистрационныеДанные;
КонецФункции

Показать

Ответить

25. natarezn 14.11.15 10:13 Сейчас в теме

(17) DarkDaemon, ой спасибо Вам большое !

18. vajlerik 05.06.15 08:52 Сейчас в теме

Функция СведенияОВнешнейОбработке() Экспорт 
    ПараметрыРегистрации = Новый Структура;
    МассивНазначений = Новый Массив;
    МассивНазначений.Добавить("Документ.РеализацияТоваровУслуг");
    ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма");  
    ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);
    ПараметрыРегистрации.Вставить("Наименование", "Расходная");
    ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);
    ПараметрыРегистрации.Вставить("Версия", "1.0"); 
    ПараметрыРегистрации.Вставить("Информация","Расходная"); 
    ТаблицаКоманд = ПолучитьТаблицуКоманд();
    ДобавитьКоманду(ТаблицаКоманд, "Расходная","","ВызовСерверногоМетода", 
    Истина, "Расходная");
    ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);    
   Возврат ПараметрыРегистрации; 
	

КонецФункции
 
Функция ПолучитьТаблицуКоманд()
    Команды = Новый ТаблицаЗначений;
    Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
    Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка")); 
    Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка")); 
    Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
    Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
    Возврат Команды;
КонецФункции
 
Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
    НоваяКоманда = ТаблицаКоманд.Добавить();
    НоваяКоманда.Представление = Представление; 
    НоваяКоманда.Идентификатор = Идентификатор;
    НоваяКоманда.Использование = Использование;
    НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
    НоваяКоманда.Модификатор = Модификатор; 
КонецПроцедуры

Показать

Почему пишет печатная форма недоступна? Всё же верно прописано.(УТ11)

19. Поручик 4674 05.06.15 10:11 Сейчас в теме

(18) Потому что, неправильно. Не указан указан модификатор MXL и похоже саму процедуру печати сделал неправильно. Надёргай внешних печатных форм и сделай по образцу. Но сначала курить мануалы.

20. vajlerik 05.06.15 10:46 Сейчас в теме

(19) Поручик,

&НаСервере
Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати,ПараметрыВвода) Экспорт
    ИмяФормы =  "Расходная";
	СинонимФормы = "Расходная";
	
	УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(
	КоллекцияПечатныхФорм,
	ИмяФормы,
	СинонимФормы,
	ПечатьВнешняя(МассивОБъектов, ОбъектыПечати,ИмяФормы));
	


КонецПроцедуры
&НаСервере
Функция ПечатьВнешняя(МассивОбъектов, ОбъектыПечати, ИмяМакета) // МассивОбъектов - ссылка на данные
	ИмяФормы =  "Расходная";
	СинонимФормы = "Расходная";
	
	ТабличныйДокумент = Новый ТабличныйДокумент;
	ТабличныйДокумент.КлючПараметровПечати = "ПараметрыПечати_" + ИмяФормы;
	
	//ТабличныйДокумент = ПечатьРасходная(МассивОбъектов, ОбъектыПечати,ПараметрыПечати,КомплектыПечати);
	ТабличныйДокумент.АвтоМасштаб = Истина;
	//ТабличныйДокумент = новый ТабличныйДокумент;
	
	Возврат ТабличныйДокумент;
	
КонецФункции // ПечатнаяФорма()

Показать

я все по примерам итак делал.

21. Поручик 4674 05.06.15 12:10 Сейчас в теме

(20) Неправильно сделал. Поиск - разработка внешних печатных форм для конфигураций на БСП

22. natarezn 14.11.15 10:03 Сейчас в теме

Функция СведенияОВнешнейОбработке() Экспорт
ПараметрыРегистрации = Новый Структура;
ПараметрыРегистрации.Вставить("Вид", "ЗаполнениеОбъекта");
ОбъектыНазначения = Новый Массив;
ОбъектыНазначения.Добавить("Документ.РасходнаяНакладная");
ПараметрыРегистрации.Вставить("Назначение", ОбъектыНазначения);
ПараметрыРегистрации.Вставить("Наименование", "Продажи внутри");
ПараметрыРегистрации.Вставить("Версия", "1.0");
ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);
ПараметрыРегистрации.Вставить("Информация", "Продажи внутри");
ПараметрыРегистрации.Вставить("ВерсияБСП", "1.2.1.4");
ТаблицаКоманд = ПолучитьТаблицуКоманд();
ДобавитьКоманду(ТаблицаКоманд,
"Продажи внутри",
"ЗаполнитьТЧ",
"ВызовКлиентскогоМетода");
ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
Возврат ПараметрыРегистрации;
КонецФункции

23. natarezn 14.11.15 10:03 Сейчас в теме

Функция ПолучитьТаблицуКоманд()
Команды = Новый ТаблицаЗначений;
Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
Возврат Команды;
КонецФункции

24. natarezn 14.11.15 10:04 Сейчас в теме

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
НоваяКоманда = ТаблицаКоманд.Добавить();
НоваяКоманда.Представление = Представление;
НоваяКоманда.Идентификатор = Идентификатор;
НоваяКоманда.Использование = Использование;
НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры

26. natarezn 14.11.15 10:14 Сейчас в теме

подключила ! работает - подключила через справочник внешние отчеты и обработки.

27. ivanchai 05.04.22 13:24 Сейчас в теме

Еще бывает такое что в модуле внешней обработки есть Функция СведенияОВнешнейОбработке() Экспорт
а при добавлении в 1с выкатывает Метод объекта не обнаружен (СведенияОВнешнейОбработке)
Идем в общий модуль ДополнительныеОтчетыИОбработки и смотрим
Процедура ПриПолученииРегистрационныхДанных(Объект, РегистрационныеДанные, ПараметрыРегистрации, РезультатРегистрации)

находим там строку СведенияОВнешнейОбработке = ВнешнийОбъект.СведенияОВнешнейОбработке();
и копируем оттуда текст названия СведенияОВнешнейОбработке в название своей процедуры в модуле

Оставьте свое сообщение

E-mail: