54-ФЗ: Обработка для фискальных регистраторов АТОЛ, ШТРИХ и других (бесплатная демо обработка)

Функция ЗакрытьЧек(Объект, СуммаНал, СуммаБезнал) Экспорт

	Результат = мНетОшибки;
	
	КодСистемыНалогообложения = ?(Объект.Параметры.КодСистемыНалогообложения = Неопределено,0,Объект.Параметры.КодСистемыНалогообложения);
	ОтправительEmail = ?(Объект.Параметры.ОтправительEmail = Неопределено,0,Объект.Параметры.ОтправительEmail);
	ОтбиватьЧек = ?(Объект.Параметры.ОтбиватьЧек = Неопределено,0,Объект.Параметры.ОтбиватьЧек);
	
	ПокупательEmail = "";
	ПокупательНомер = "";
	
	Если ОтбиватьЧек=1 Тогда
		ВвестиЗначение(ПокупательНомер,"Введите номер телефона покупателя:");
	КонецЕсли;	
	Если ОтбиватьЧек=2 Тогда
		ВвестиЗначение(ПокупательEmail,"Введите Е-mail покупателя:");
	КонецЕсли;	
	Если ОтбиватьЧек=3 Тогда
		ВвестиЗначение(ПокупательНомер,"Введите номер телефона покупателя:");
		ВвестиЗначение(ПокупательEmail,"Введите Е-mail покупателя:");
	КонецЕсли;	

	ПризнакВозврата= Объект.ПризнакВозврата;
	Чек = Объект.Чек;
	
	Электронно  = Ложь;
	НомерЧека = 0;
	НомерСмены  = 0;
	ФискальныйПризнак = "";
	AddressSiteInspections = "";
	
	ДанныеЧека = "";
	ЗаписьXML = Новый ЗаписьXML();
	ЗаписьXML.УстановитьСтроку("UTF-8");
	ЗаписьXML.ЗаписатьОбъявлениеXML();
	ЗаписьXML.ЗаписатьНачалоЭлемента("CheckPackage");
	
	ЗаписьXML.ЗаписатьНачалоЭлемента("Parameters");	
	Если ПризнакВозврата = Неопределено 
		ИЛИ НЕ ПризнакВозврата Тогда
		ЗаписьXML.ЗаписатьАтрибут("PaymentType" , XMLСтрока(ПолучитьКодТипаРасчетаДенежнымиСредствами("ПриходДенежныхСредств")));
	Иначе
		ЗаписьXML.ЗаписатьАтрибут("PaymentType" , XMLСтрока(ПолучитьКодТипаРасчетаДенежнымиСредствами("ВозвратДенежныхСредств")));
	КонецЕсли;	
	Если КодСистемыНалогообложения<>0 Тогда
		ЗаписьXML.ЗаписатьАтрибут("TaxVariant" , XMLСтрока(КодСистемыНалогообложения));
	КонецЕсли;
	
	ЗаписьXML.ЗаписатьАтрибут("SenderEmail", XMLСтрока(СокрЛП(ОтправительEmail)));
	// Email 
	Если СокрЛП(ПокупательEmail)<>"" Тогда
		ЗаписьXML.ЗаписатьАтрибут("CustomerEmail", XMLСтрока(СокрЛП(ПокупательEmail)));
	КонецЕсли;
	// SMS 
	Если СокрЛП(ПокупательНомер)<>"" Тогда
		ЗаписьXML.ЗаписатьАтрибут("CustomerPhone", XMLСтрока(СокрЛП(ПокупательНомер)));
	КонецЕсли;

	ЗаписьXML.ЗаписатьКонецЭлемента();
	
	// Табличная часть
	СуммаЧека = 0;
	Если Чек.Количество()>0 Тогда
		ЗаписьXML.ЗаписатьНачалоЭлемента("Positions");
		Для ИндексМассива = 0 По Чек.Количество() - 1 Цикл
			ТекущаяПозиция = Чек[ИндексМассива];
			Если ТекущаяПозиция.Свойство = "ФискальнаяСтрока" Тогда
				ЗаписьXML.ЗаписатьНачалоЭлемента("FiscalString");
				ЗаписьXML.ЗаписатьАтрибут("Name"      , XMLСтрока(ТекущаяПозиция.Номенклатура));
				ЗаписьXML.ЗаписатьАтрибут("Quantity"  , XMLСтрока(ТекущаяПозиция.Количество));
				ЗаписьXML.ЗаписатьАтрибут("Price"     , XMLСтрока(ТекущаяПозиция.Цена));
				ЗаписьXML.ЗаписатьАтрибут("Amount"    , XMLСтрока(ТекущаяПозиция.Сумма));
				ЗаписьXML.ЗаписатьАтрибут("Tax"       , XMLСтрока(ТекущаяПозиция.СтавкаНДС));
				ЗаписьXML.ЗаписатьКонецЭлемента();
				СуммаЧека = СуммаЧека + ТекущаяПозиция.Сумма;
			ИначеЕсли ТекущаяПозиция.Свойство = "ТекстоваяСтрока" Тогда
				ЗаписьXML.ЗаписатьНачалоЭлемента("TextString");
				ЗаписьXML.ЗаписатьАтрибут("Text", XMLСтрока(ТекущаяПозиция.Текст));
				ЗаписьXML.ЗаписатьКонецЭлемента();
			ИначеЕсли ТекущаяПозиция.Свойство = "ШтрихКод" Тогда
				ЗаписьXML.ЗаписатьНачалоЭлемента("Barcode");
				ЗаписьXML.ЗаписатьАтрибут("BarcodeType", XMLСтрока(ТекущаяПозиция.ТипШтрихкода));
				ЗаписьXML.ЗаписатьАтрибут("Barcode", XMLСтрока(ТекущаяПозиция.ШтрихКод));
				ЗаписьXML.ЗаписатьКонецЭлемента();
			Иначе
				ТекстОшибки = НСтр("ru='Не определен тип позиции чека.'"); 
				Сообщить("ОШИБКА! "+ТекстОшибки);
				Возврат мОшибкаНеизвестно;
			КонецЕсли;
		КонецЦикла;
		ЗаписьXML.ЗаписатьКонецЭлемента();	
	КонецЕсли;
	
	// Таблица оплат
	Если СуммаЧека <> 0 Тогда
		СуммаНаличнойОплаты     = СуммаНал;
		СуммаЭлектроннойОплаты1 = СуммаБезнал;
		СуммаЭлектроннойОплаты2 = 0;
		СуммаЭлектроннойОплаты3 = 0;
		ЗаписьXML.ЗаписатьНачалоЭлемента("Payments");
		ЗаписьXML.ЗаписатьАтрибут("Cash", XMLСтрока(СуммаНаличнойОплаты));
		ЗаписьXML.ЗаписатьАтрибут("CashLessType1", XMLСтрока(СуммаЭлектроннойОплаты1));
		ЗаписьXML.ЗаписатьАтрибут("CashLessType2", XMLСтрока(СуммаЭлектроннойОплаты2));
		ЗаписьXML.ЗаписатьАтрибут("CashLessType3", XMLСтрока(СуммаЭлектроннойОплаты3));
		ЗаписьXML.ЗаписатьКонецЭлемента();
	КонецЕсли;
	
	ЗаписьXML.ЗаписатьКонецЭлемента();
	ДанныеЧека = ЗаписьXML.Закрыть();
	
	Если НЕ Объект.Драйвер.СформироватьЧек(Объект.ИДУстройства,СокрЛП(Кассир),Электронно, ДанныеЧека, НомерЧека, НомерСмены, ФискальныйПризнак, AddressSiteInspections) Тогда
		Результат = мОшибкаНеизвестно;
		Объект.Драйвер.ПолучитьОшибку(Объект.ОписаниеОшибки);
	КонецЕсли;	
	
	//Сообщить("Номер чека: "+СокрЛП(НомерЧека));
	//Сообщить("Номер смены: "+СокрЛП(НомерСмены));
	//Сообщить("Фискальный признак: "+СокрЛП(ФискальныйПризнак));
	//Сообщить("Адрес проверки чека: "+СокрЛП(AddressSiteInspections));

	Возврат Результат;

КонецФункции // ЗакрытьЧек()