WinHttpRequest/ServerXMLHTTP - а теперь, как отправить zip?

Question

И снова все доброго дня!
[B]Преамбула:[/B]
Долгое время для интернет-магазина использовали битрикс, на своем сервере. И свою самописную обработку для обмена 1с 7.7 (опять же кастомная конфа) для обмена с ним. Написана она была с использованием v7plus. Битрикс, из-за старенькой ОС (CentOS 6.5) уже не мог обновляться, а перенести магазин на новый через архив - не получилось, из-за разработчиков конкретно нашего магазина, как то так криво адаптировавших выбранный шаблон под наши хотелки, что новом движке битрикса у него вылетало все что только можно с руганью о устаревших и неподдерживаемых операторах.
Но вот так случилось что сервер с битриксом скоропостижно скончался, и прежде чем его восстанавливать, решила я оглядеться - а что за эти годы (около 10) изменилось? Может появилось что-то поинтереснее и полегче битрикса?
Ну вот обратила внимание на InSales - и выглядит симпатично, и легкая, и обмен с 1с по тому же протоколу, что и у битрикса. Но вот беда - у InSales обмен возможен только по протоколу https, который v7plus не поддерживает.
Делать нечего, засучила рукава, стала переделывать на использование системных компонент, на выбор - либо WinHttpRequest, - либо ServerXMLHTTP.
[B]Теперь собтвенно проблема:[/B]
С приёмом данных от вебсервера справилась. С передачей xml тоже. [B]Засада появилась при попытке передать zip файл.
[/B]
В v7plus все проблемы по формированию заголовков и правильной обертке данных для передачи берет на себя сама компонента. Пишешь просто
[1C-CODE]Соединение.ОтправитьДляОбработки(Ресурс + "?type=sale&mode=file&filename=" + ФайлЗаказов, ПутьКЗаказам, 1, Ответ, 2)[/1C-CODE]
в ФайлЗаказов - имя файла
в ПутьКЗаказам - полный путь к файлу
И не важно что там в файле, xml или zip - 1с файл отправит, вебсервер его примет
А вот с компонентами всё на так просто :(
Ладно, как я уже говорила, с текстом (xml) я справилась:
[1C-CODE]Функция ОтправитьДляОбработки(Соединение, Ресурс, Знач Источник, ТипДанных, Ответ, ТипОтвета)  
	
	//ТипДанных = 1 - Путь к файлу, 2 - Строка, 3 - поток
	//ТипЩтвета = 1 - Путь к файлу, 2 - Строка, 3 - поток
	
	Если флДвижок = 1 Тогда
		Соединение.Open("POST", Ресурс, 0, ПараметрыСоединения.ИмяПользователя, ПараметрыСоединения.ПарольПользователя);
	Иначе
		Соединение.Open("POST", Ресурс, 0);
		Соединение.SetCredentials(ПараметрыСоединения.ИмяПользователя, ПараметрыСоединения.ПарольПользователя, 0);
	КонецЕсли;
		
	Если ПустоеЗначение(ПараметрыСоединения.Печенька) = 0 Тогда
		Соединение.SetRequestHeader("Cookie", ПараметрыСоединения.Печенька);
	КонецЕсли;

	
	Если ТипДанных = 1 Тогда
		
		Если Прав(Источник, 3) = "xml" Тогда
			
			ДанныеДляОтправки = СоздатьОбъект("MSXML2.DOMDocument.6.0");
			ДанныеДляОтправки.load(Источник);
			
			Соединение.Send(ДанныеДляОтправки.xml)
			
		Иначе
			
		КонецЕсли;
									
	Иначе
		
		Соединение.Send(Источник);
		
	КонецЕсли;
			
	Если Соединение.Status <> 200 Тогда
		Предупреждение(Ресурс + РазделительСтрок + Соединение.Status + " " + Соединение.statusText);
		Возврат 0;
	КонецЕсли;
	
	Если ТипОтвета = 1 Тогда
		
	ИначеЕсли ТипОтвета = 2 Тогда
		
		Ответ = СтрЗаменить(Соединение.ResponseText, Симв(13), "");
		Ответ = СтрЗаменить(Ответ, Симв(10), РазделительСтрок);

	Иначе

		Ответ = Соединение.ResponseStream;
		
	КонецЕсли;	
	
	Возврат 1;

КонецФункции
[/1C-CODE]

А вот с zip - возникли проблемы.
Попыталась использовать 1cpp BinaryData:
[1C-CODE]ДвоичныеДанные = СоздатьОбъект("BinaryData");
ДвоичныеДанные.ЗагрузитьИзФайла(Источник);
			
РазмерФайла = ДвоичныеДанные.Размер();
ДвоичныеДанные.Перейти(0, 0);

ДанныеДляОтправки = 0;
ДвоичныеДанные.ПрочитатьСтроку(ДанныеДляОтправки, РазмерФайла);
Соединение.Send(ДанныеДляОтправки);[/1C-CODE]
Ошибка "Недопустимая длина."


Пробовала ADODB.Stream - тоже не получается:
[1C-CODE]Поток = СоздатьОбъект("adodb.stream");
Поток.Mode = 1;
Поток.Open();
Поток.LoadFromFile(Источник);
Соединение.Send(Поток.Read(Поток.Size));[/1C-CODE]
1c ругается -  мол Read() возвращает неподдерживаемый тип

И я опять в тупике - как же отправить то файл?

Accepted Answer

Все оказалось до тривиального просто

[CODE]Поток = СоздатьОбъект("adodb.stream");
Поток.Type = 1;
Поток.Open();
Поток.LoadFromFile(Источник);
		
Если Найти(Источник, ".jpg") > 0 Тогда
	Соединение.setRequestHeader("Content-Type", "image/jpeg");
ИначеЕсли Найти(Источник, ".zip") > 0 Тогда
	Соединение.setRequestHeader("Content-Type", "application/zip");
ИначеЕсли Найти(Источник, ".xml") > 0 Тогда
	Соединение.setRequestHeader("Content-Type", "application/xml;charset=utf-8");
КонецЕсли;
	
Соединение.Send(Поток);
Поток.Close();
[/CODE]