Интеграция с web сервисом ГИИС ДМДК

&НаКлиенте
Функция ПодписатьДанные(Сертификат,Данные,Откреп = Ложь)
	
	///Получим внешнюю компоненту из общих макетов (КомпонентаXMLDSig)
	ВнешняяКомпонента = КомпонентаПодписи();
	
	Если ВнешняяКомпонента = Неопределено Тогда
		возврат Неопределено;
	КонецЕсли;
	
	///Получим отфарматированный сертификат (Двоичные данные, преобразованные в base64)
	СертификатКриптографииBase64 = ПолучитьСертификатBase64Строку(Сертификат);
	
	Если СертификатКриптографииBase64 = Неопределено Тогда
		возврат Неопределено;
	КонецЕсли;
	
	Попытка
		АтрибутSignatureValue = ВнешняяКомпонента.CMSSign(Данные,   ///Подписываемые данные
				СертификатКриптографииBase64,     ///Сертификат в Base64
				"",  	 	///Параоль сертификата
				0,    		//тип подписи "CAdES-BES"
				Откреп,  	//открепленная
				17);        //РежимВключенияСертификатовКриптографии.ВключатьПолнуюЦепочку 
	Исключение
		ВызватьИсключение НСтр("ru = 'Ошибка вызова метода CMSSign компоненты XMLDSig.'") + Символы.ПС + ПодробноеПредставлениеОшибки(ИнформацияОбОшибке());
	КонецПопытки;
	
	///Преобразуем подпись в Base64Строку
	Подпись = Base64Строка(АтрибутSignatureValue);
	Подпись = СтрЗаменить(Подпись, Символы.ПС, "");
	Подпись = СтрЗаменить(Подпись, Символы.ВК, "");
	
	Возврат Подпись;	    ///Подписанные данные
	
КонецФункции

&НаКлиенте
Функция КомпонентаПодписи()
	
	КомпонентаДвоичныеДанные = ПолучитьКомпонентуПодписи();
	АдресМакета = ПоместитьВоВременноеХранилище(КомпонентаДвоичныеДанные);
	
	Если ПодключитьВнешнююКомпоненту(АдресМакета, "XMLDSignAddInSymbolicName", ТипВнешнейКомпоненты.Native) Тогда
		ВнешняяКомпонента = Новый("AddIn.XMLDSignAddInSymbolicName.XMLDSignAddIn");
	Иначе
		УстановитьВнешнююКомпоненту(АдресМакета);
		Если ПодключитьВнешнююКомпоненту(АдресМакета, "XMLDSignAddInSymbolicName", ТипВнешнейКомпоненты.Native) Тогда
			ВнешняяКомпонента = Новый("AddIn.XMLDSignAddInSymbolicName.XMLDSignAddIn");
		Иначе
			Сообщить(ОписаниеОшибки());
			ВнешняяКомпонента = Неопределено;
		КонецЕсли;	
	КонецЕсли;	
			
	Возврат	ВнешняяКомпонента;
КонецФункции


&НаСервере
Функция ПолучитьКомпонентуПодписи() Экспорт
	Возврат ПолучитьОбщийМакет("КомпонентаXMLDSig");	
КонецФункции

&НаСервере
Функция ПолучитьСертификатBase64Строку(Ссылка) Экспорт
	
	ДанныеСертификата = Ссылка.ФайлСертификата.Получить(); ///Двоичные данные сертификата (Из справочника Сертификаты ЭЦП)	
	
	СтрокаBase64 = Base64Строка(ДанныеСертификата);
	
	Значение = СтрЗаменить(СтрокаBase64, Символы.ВК, "");
	Значение = СтрЗаменить(Значение, Символы.ПС, "");
	
	Возврат Значение;

КонецФункции

	Функция ПодписатьСертификатомДокумент(ВыбранныйСертификат, СтрокаДляПодписи,Открепл)Экспорт
	Попытка
        comStore = Новый COMОбъект("CAdESCOM.Store");
        comCPSigner = Новый COMОбъект("CAdESCOM.CPSigner"); // Аналог "CAPICOM.Signer".
        comSignedData = Новый COMОбъект("CAdESCOM.CadesSignedData");
    Исключение
        Сообщить("Не установлен КриптоПро!");
        Возврат Неопределено;
    КонецПопытки;
	
	СтрокаВBase64 = Истина;
	
    comStore.Open(
        2, // StoreLocation - CAPICOM_CURRENT_USER_STORE.
        "MY", // StoreName
        0); // OpenMode - CAPICOM_STORE_OPEN_READ_ONLY.
    comCertificates = comStore.Certificates;
    comStore.Close();
    comStore = Неопределено;

	
	comCPSigner.Certificate = ВыбранныйСертификат;
		    // + Что-то из этого может быть нужным.
		//    comCPSigner.TSAAddress = "http://cryptopro.ru/tsp/";
		//    comCPSigner.Options = 0; // CAPICOM_CERTIFICATE_INCLUDE_CHAIN_EXCEPT_ROOT. Ещё есть CAPICOM_CERTIFICATE_INCLUDE_WHOLE_CHAIN и CAPICOM_CERTIFICATE_INCLUDE_END_ENTITY_ONLY.
		    
	Если СтрокаВBase64 Тогда // Очень важно!
		comSignedData.ContentEncoding = 1; // CADESCOM_BASE64_TO_BINARY
		//Иначе // Так и остаётся 0 - CADESCOM_ENCODE_BINARY
	КонецЕсли;
	
	comSignedData.Content = СтрокаДляПодписи;
	ПодписанныеДанные = comSignedData.SignCades(
		        comCPSigner, // Signer
		        1, // CadesType, CADESCOM_CADES_BES.
		        Открепл, // bDetached - "флаг открепленной подписи (исходное сообщение не включается в итоговый CMS-контейнер)".
		        ); // EncodingType - по умолчанию CAPICOM_ENCODE_BASE64.
		    
	comCPSigner = Неопределено;
	comSignedData = Неопределено;
	
	Возврат УбратьСимволы1013(ПодписанныеДанные);
	//Возврат ПодписанныеДанные;
	
КонецФункции