Вариант реализации работы с сервисом Dadata применительно к конфигурации УТ 11.4 и подобным

08.09.20

–

В статье описывается реализация получения данных с сервиса DaData при работе с формами справочников в конфигурации УТ 11 для дополнения информации по ФИО, ИНН, Адресу.

Вводные

В конфигурации УТ 11 присутствует функционал заполнения адресов и конрагентов через сервис ИТС, автодополнения ФИО нет.

Заполнение контрагентов работает при подписке ПРОФ или наличии 1С:Контрагент, адреса работают при активной подписке ИТС.

Данная реализация позволяет получить схожий функционал бесплатно с порогом 10к обращений в день, что для средних фирм более чем хватает.

Документация.

Получение ключа https://dadata.ru/suggestions/usage/

Работа с API https://dadata.ru/api/suggest/

Реализация

Реализовывал через расширение, настройки храню в выделенном справочнике.

dd_ОбщийМодульПовторноеИспользование

Функция ПолучитьНастройкиПодсистемы() Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	
	СтруктураНастроек = Новый Структура;
	СтруктураНастроек.Вставить("ИспользованиеСервиса", Ложь);
	СтруктураНастроек.Вставить("КлючДоступа", "");
	
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ ПЕРВЫЕ 1
	|	dd_НастройкиПодсистемы.ИспользованиеСервиса КАК ИспользованиеСервиса,
	|	dd_НастройкиПодсистемы.КлючДоступа КАК КлючДоступа
	|ИЗ
	|	Справочник.dd_НастройкиПодсистемы КАК dd_НастройкиПодсистемы
	|ГДЕ
	|	НЕ dd_НастройкиПодсистемы.ПометкаУдаления";
	
	РезультатЗапроса = Запрос.Выполнить();
	
	Если Не РезультатЗапроса.Пустой() Тогда
		Выборка = РезультатЗапроса.Выбрать();
		Выборка.Следующий();
		
		СтруктураНастроек.ИспользованиеСервиса = Выборка.ИспользованиеСервиса;
		СтруктураНастроек.КлючДоступа = Выборка.КлючДоступа;
		
	КонецЕсли;
	
	Возврат СтруктураНастроек;
	
КонецФункции

Обращения к сервису

Обращения к сервису вынес в общий модуль, реализовывал на клиентской части, возможно имеет смысл переносить на сервер, чтобы все обращения были с него.

Запросы к сервису

Функция ПолучитьСоответствиеПодсказок(Текст, ВидПодсказки) Экспорт
	
	НастройкиПодсистемы = dd_ОбщийМодульПовторноеИспользование.ПолучитьНастройкиПодсистемы();
	
	СоответствиеОтвет = Новый Соответствие;
	
	Если НЕ НастройкиПодсистемы.ИспользованиеСервиса Тогда
		Возврат СоответствиеОтвет;
	КонецЕсли;
	
	СоответствиеДанные = Новый Соответствие;
	СоответствиеДанные.Вставить("query", Текст);
	СтрокаДанные = В_JSON(СоответствиеДанные);
	
	АдресРесурса = "/suggestions/api/4_1/rs";
	
	Если ВидПодсказки = "Адрес" Тогда
		АдресРесурса = АдресРесурса + "/suggest/address";
		
	ИначеЕсли ВидПодсказки = "ФИО" Тогда
		АдресРесурса = АдресРесурса + "/suggest/fio";
		
	ИначеЕсли ВидПодсказки = "ОрганизацияНаименование" Тогда
		АдресРесурса = АдресРесурса + "/suggest/party";
		
	ИначеЕсли ВидПодсказки = "ОрганизацияИНН" Тогда
		АдресРесурса = АдресРесурса + "/findById/party";
		
	Иначе
		Возврат СоответствиеОтвет;
	КонецЕсли;
	
	ДанныеОтвет = POST(АдресРесурса, СтрокаДанные);
	
	Если ДанныеОтвет.КодСостояния = 200 Тогда
		
		СтрокаДанныеОтвет = ДанныеОтвет.ПолучитьТелоКакСтроку();
		СоответствиеОтвет = ИЗ_JSON(СтрокаДанныеОтвет);
		
	КонецЕсли;
	
	Возврат СоответствиеОтвет;
	
КонецФункции

Обвязку HTTP запроса не выкладываю, каждый пишет на свой вкус.

Для работы с адресами нужно преобразовать формат Dadata в формат адресов 1С.

Преобразование формата адреса

Функция СформироватьКИФормата1С(СоответствиеАдресДаДата) Экспорт
	
	СтруктураДанных = Новый Структура;
	СтруктураДанных.Вставить("Комментарий", "");
	СтруктураДанных.Вставить("КонтактнаяИнформация", "");
	СтруктураДанных.Вставить("Корректный", Неопределено);
	СтруктураДанных.Вставить("Представление", "");
	
	СтруктураДанных.Представление = СоответствиеАдресДаДата.Получить("unrestricted_value");
	
	АдресДаДатаДанные = СоответствиеАдресДаДата.Получить("data");
	
	
	Результат = РаботаСАдресамиКлиентСервер.ОписаниеНовойКонтактнойИнформации(ПредопределенноеЗначение("Перечисление.ТипыКонтактнойИнформации.Адрес"));
	
	Результат.Вставить("Country", "Россия");
	Результат.Вставить("CountryCode", "643");
	Результат.Вставить("Value", СоответствиеАдресДаДата.Получить("unrestricted_value"));
	
	Результат.AddressType = РаботаСАдресамиКлиентСервер.АдминистративноТерриториальныйАдрес();
	
	Результат.ZIPCode = Строка(АдресДаДатаДанные.Получить("postal_code"));
	Результат.OKTMO = Строка(АдресДаДатаДанные.Получить("oktmo"));
	Результат.OKATO = Строка(АдресДаДатаДанные.Получить("okato"));
	
	Результат.Area     = Строка(АдресДаДатаДанные.Получить("region"));
	Результат.AreaType = Строка(АдресДаДатаДанные.Получить("region_type"));
	
	Результат.District     = Строка(АдресДаДатаДанные.Получить("area"));
	Результат.DistrictType = Строка(АдресДаДатаДанные.Получить("area_type"));
	
	Результат.City     = Строка(АдресДаДатаДанные.Получить("city"));
	Результат.CityType = Строка(АдресДаДатаДанные.Получить("city_type"));
	
	Если Результат.City = "Москва" Тогда
		Результат.City = "";
		Результат.CityType = "";
	КонецЕсли;
	
	Результат.Locality     = Строка(АдресДаДатаДанные.Получить("settlement"));
	Результат.LocalityType = Строка(АдресДаДатаДанные.Получить("settlement_type"));
	
	Результат.Street     = Строка(АдресДаДатаДанные.Получить("street"));
	Результат.StreetType = Строка(АдресДаДатаДанные.Получить("street_type"));
	
	Результат.CityDistrict     = Строка(АдресДаДатаДанные.Получить("city_district"));
	Результат.CityDistrictType = Строка(АдресДаДатаДанные.Получить("city_district_type"));
	
	Если Не ПустаяСтрока(АдресДаДатаДанные.Получить("house")) Тогда
		
		house_type = АдресДаДатаДанные.Получить("house_type");
		
		Если house_type = "д" Тогда
			
			Результат.HouseType = "Дом";
			Результат.HouseNumber = АдресДаДатаДанные.Получить("house");
			
		ИначеЕсли house_type = "влд" Тогда
			
			Результат.HouseType = "Владение";
			Результат.HouseNumber = АдресДаДатаДанные.Получить("house");
			
		ИначеЕсли house_type = "двлд" Тогда			
			
			Результат.HouseType = "Домовладение";
			Результат.HouseNumber = АдресДаДатаДанные.Получить("house");
			
		ИначеЕсли house_type = "к" Тогда
			Результат.Buildings.Добавить(УправлениеКонтактнойИнформациейКлиентСервер.ЗначениеСтроенияИлиПомещения("Корпус", АдресДаДатаДанные.Получить("house")));
		КонецЕсли;
		
	КонецЕсли;
	
	Если Не ПустаяСтрока(АдресДаДатаДанные.Получить("block")) Тогда
		
		block_type = АдресДаДатаДанные.Получить("block_type");
		
		Если block_type = "стр" Тогда
			Тип = "Строение";
		ИначеЕсли block_type = "к" Тогда
			Тип = "Корпус";
		ИначеЕсли block_type = "сооружение" Тогда
			Тип = "Сооружение";	
		ИначеЕсли block_type = "литер" Тогда
			Тип = "Литер";
		Иначе
			Тип = "";
		КонецЕсли;
		
		Результат.Buildings.Добавить(УправлениеКонтактнойИнформациейКлиентСервер.ЗначениеСтроенияИлиПомещения(Тип, АдресДаДатаДанные.Получить("block")));
		
	КонецЕсли;
	
	Если Не ПустаяСтрока(АдресДаДатаДанные.Получить("flat")) Тогда
		
		flat_type = АдресДаДатаДанные.Получить("flat_type");
		
		Если block_type = "оф" Тогда
			Тип = "Офис";
		ИначеЕсли block_type = "кв" Тогда
			Тип = "Квартира";
		ИначеЕсли block_type = "эт" Тогда
			Тип = "Этаж";	
		ИначеЕсли block_type = "пом" Тогда
			Тип = "Помещение";
		Иначе
			Тип = "";
		КонецЕсли;
		
		Результат.Apartments.Добавить(УправлениеКонтактнойИнформациейКлиентСервер.ЗначениеСтроенияИлиПомещения(Тип, АдресДаДатаДанные.Получить("flat")));
		
	КонецЕсли;
	
	СтруктураДанных.КонтактнаяИнформация = dd_ЗапросыКСервису.В_JSON(Результат);
	
	Возврат СтруктураДанных;
	
КонецФункции

В преобразовании не переносятся коды ФИАС, в текущей реализации нет необходимости, можно доработать.

Работа с формами, ФИО

На мой взгляд оптимумом является связка АвтоПодбор + ОбработкаВыбора

В расширении формы (например спр. "КонтактныеЛицаПартнеров") к полю наименование добавляем обработчики:

Обработчики на форме работа с ФИО

&НаКлиенте
Процедура dd_НаименованиеОбработкаВыбораВместо(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
	
	dd_ОбщийМодульКлиент.ОбработкаВыбора_СтрокаФИО(Элемент, ВыбранноеЗначение, СтандартнаяОбработка, ЭтаФорма, Объект, Параметры);
	
КонецПроцедуры

&НаКлиенте
Процедура dd_НаименованиеАвтоПодборВместо(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка)
	
	dd_ОбщийМодульКлиент.АвтоПодбор_СтрокаФИО(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка, ЭтаФорма, Объект, Параметры);
	
КонецПроцедуры

Реализация вынес в общий модуль для возможности переиспользования

Обработчики работы с ФИО, общий модуль

Процедура АвтоПодбор_СтрокаФИО(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка, Форма, Объект, Параметры) Экспорт
	
	Если Параметры.НаименованиеИзменено
		ИЛИ 
		СтрДлина(Текст) < 3 
		ИЛИ Прав(Текст, 1) = " " Тогда
		
		Параметры.НаименованиеИзменено = Ложь;
		Возврат;
		
	КонецЕсли;
	
	СтандартнаяОбработка = Ложь;
	
	СоответствиеОтвет = dd_ЗапросыКСервису.ПолучитьСоответствиеПодсказок(Текст, "ФИО");
	
	Если СоответствиеОтвет.Количество() = 0  Тогда
		Возврат;
	КонецЕсли;
	
	СписокЗначений = Новый СписокЗначений;
	
	Для каждого СтрТ Из СоответствиеОтвет.Получить("suggestions") Цикл
		
		СписокЗначений.Добавить(СтрТ.Получить("value"));
		
	КонецЦикла;
	
	ДанныеВыбора = СписокЗначений;
	
КонецПроцедуры

Процедура ОбработкаВыбора_СтрокаФИО(Элемент, ВыбранноеЗначение, СтандартнаяОбработка, Форма, Объект, Параметры) Экспорт
	
	СтандартнаяОбработка = Ложь;
	
	Если ВыбранноеЗначение = Элемент.ТекстРедактирования  Тогда
		Возврат;
	КонецЕсли;
	
	Объект.Наименование = ВыбранноеЗначение;
	Форма.ОбновитьОтображениеДанных(Форма.Элементы.Наименование);
	
	Позиция = СтрДлина(Элемент.ТекстРедактирования) + 1;
	Элемент.УстановитьГраницыВыделения(Позиция, Позиция);
	
	Форма.Модифицированность = Истина;
	
	Параметры.НаименованиеИзменено = Истина;
	
КонецПроцедуры

Работа с формами, Адрес

Поля адресов (контактной информации) на форме выводится кодом и обработчики вынесены в общий модуль. В обработку редактирования адреса не лез, изменил работу заполнения по строке.

УправлениеКонтактнойИнформациейКлиент

&Вместо("АвтоПодборАдреса")
Процедура dd_АвтоПодборАдреса(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка) Экспорт
	
	Если СтрДлина(Текст) < 3 ИЛИ Прав(Текст, 1) = " " Тогда
		Возврат;
	КонецЕсли;
	
	НастройкиПодсистемы = dd_ОбщийМодульПовторноеИспользование.ПолучитьНастройкиПодсистемы();
	
	Если НЕ НастройкиПодсистемы.ИспользованиеСервиса Тогда
		ПродолжитьВызов(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка);
		Возврат;
	КонецЕсли;
	
	СоответствиеОтвет = dd_ЗапросыКСервису.ПолучитьСоответствиеПодсказок(Текст, "Адрес"); 
	
	Если СоответствиеОтвет.Количество() = 0  Тогда
		Возврат;
	КонецЕсли;
	
	СписокЗначений = Новый СписокЗначений;
	
	Для каждого СтрТ Из СоответствиеОтвет.Получить("suggestions") Цикл
		
		СписокЗначений.Добавить(СтрТ, СтрТ.Получить("value"));
		
	КонецЦикла;
	
	ДанныеВыбора = СписокЗначений;
	СтандартнаяОбработка = Ложь;
	
КонецПроцедуры

&Вместо("ОбработкаВыбора")
Процедура dd_ОбработкаВыбора(Знач Форма, Знач ВыбранноеЗначение, Знач ИмяРеквизита, СтандартнаяОбработка = Ложь) Экспорт
	
	НастройкиПодсистемы = dd_ОбщийМодульПовторноеИспользование.ПолучитьНастройкиПодсистемы();
	
	Если НастройкиПодсистемы.ИспользованиеСервиса Тогда
		
		ДанныеАдреса = dd_ЗапросыКСервису.СформироватьКИФормата1С(ВыбранноеЗначение);
		Представление = ВыбранноеЗначение.Получить("Value");
		
		ВыбранноеЗначение = Новый Структура;
		
		ВыбранноеЗначение.Вставить("Адрес", ДанныеАдреса.КонтактнаяИнформация);
		ВыбранноеЗначение.Вставить("Представление", ДанныеАдреса.Представление);
		
	КонецЕсли;
	
	ПродолжитьВызов(Форма, ВыбранноеЗначение, ИмяРеквизита, СтандартнаяОбработка);
	
	Если НастройкиПодсистемы.ИспользованиеСервиса Тогда
		
		Форма.ОбновитьОтображениеДанных(Форма.Элементы[ИмяРеквизита]);
		Позиция = СтрДлина(Форма.Элементы[ИмяРеквизита].ТекстРедактирования) + 1;
		Форма.Элементы[ИмяРеквизита].УстановитьГраницыВыделения(Позиция, Позиция);
		
	КонецЕсли;
	
КонецПроцедуры

Установки курсора как в случае с ФИО нет, для начала такой вариант вполне рабочий.

Работа с формами, ИНН

Работа с ИНН ведется из форм спр. Контрагенты, спр. Партнеры, формы "Помощник ввода нового", для спр. Контрагенты:

Обработчики

//-- в общем модуле
Процедура АвтоПодбор_СтрокаИНН(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка) Экспорт
	
	Если СтрДлина(Текст) < 10 Тогда
		Возврат;
	КонецЕсли;
	
	СтандартнаяОбработка = Ложь;
	
	СоответствиеОтвет = dd_ЗапросыКСервису.ПолучитьСоответствиеПодсказок(Текст, "ОрганизацияИНН");
	
	Если СоответствиеОтвет.Количество() = 0  Тогда
		Возврат;
	КонецЕсли;
	
	СписокЗначений = Новый СписокЗначений;
	
	Для каждого СтрТ Из СоответствиеОтвет.Получить("suggestions") Цикл
		
		СписокЗначений.Добавить(СтрТ.Получить("data"), СтрТ.Получить("value"));
		
	КонецЦикла;
	
	ДанныеВыбора = СписокЗначений;
	
КонецПроцедуры

//-- в форме

&НаКлиенте
Процедура dd_ИННПриИзмененииВместо(Элемент)
	
	Если НЕ Параметры.КонтрагентВыбран Тогда
		ПродолжитьВызов(Элемент);
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура dd_ИННОбработкаВыбораВместо(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	РеквизитыКонтрагента = dd_ОбщийМодульКлиент.ПолучитьРеквизитыКонтрагента(ВыбранноеЗначение);
	
	Объект.ИНН = РеквизитыКонтрагента.ИНН;
	Объект.КПП = РеквизитыКонтрагента.КПП;
	Объект.Наименование = РеквизитыКонтрагента.Наименование;
	Объект.НаименованиеПолное = РеквизитыКонтрагента.НаименованиеПолное;
	
	ВидКонтактнойИнформацииЮрАдрес = ПредопределенноеЗначение("Справочник.ВидыКонтактнойИнформации.ЮрАдресКонтрагента");
	
	ПартнерыИКонтрагентыКлиент.ЗаполнитьЭлементКонтактнойИнформации(
	ЭтотОбъект,
	ВидКонтактнойИнформацииЮрАдрес,
	РеквизитыКонтрагента.ЮридическийАдрес);
	
	//--
	
	Отбор = Новый Структура("Вид", ВидКонтактнойИнформацииЮрАдрес);
	
	НайденныеСтроки = ЭтаФорма.КонтактнаяИнформацияОписаниеДополнительныхРеквизитов.НайтиСтроки(Отбор);
	
	ИмяРеквизита = "";
	ИмяЭлементаДляРазмещения = "";
	ХранитьИсториюИзменений = Истина;
	
	Для каждого СтрокаКонтактнойИнформации Из НайденныеСтроки Цикл
		Если НЕ СтрокаКонтактнойИнформации.ЭтоИсторическаяКонтактнаяИнформация Тогда
			ИмяРеквизита = СтрокаКонтактнойИнформации.ИмяРеквизита;
			ИмяЭлементаДляРазмещения = СтрокаКонтактнойИнформации.ИмяЭлементаДляРазмещения;
			ХранитьИсториюИзменений = СтрокаКонтактнойИнформации.ХранитьИсториюИзменений;
		КонецЕсли;
		ЭтаФорма.КонтактнаяИнформацияОписаниеДополнительныхРеквизитов.Удалить(СтрокаКонтактнойИнформации);
	КонецЦикла;
	
	ДанныеСтроки = ЭтаФорма.КонтактнаяИнформацияОписаниеДополнительныхРеквизитов.Добавить();
	ДанныеСтроки.Вид = ВидКонтактнойИнформацииЮрАдрес;
	ДанныеСтроки.Тип = ПредопределенноеЗначение("Перечисление.ТипыКонтактнойИнформации.Адрес");
	ДанныеСтроки.Значение = РеквизитыКонтрагента.ЮридическийАдрес.КонтактнаяИнформация;
	ДанныеСтроки.Представление = РеквизитыКонтрагента.ЮридическийАдрес.Представление;
	ДанныеСтроки.Комментарий = РеквизитыКонтрагента.ЮридическийАдрес.Комментарий;
	ДанныеСтроки.ИмяЭлементаДляРазмещения = ИмяЭлементаДляРазмещения;
	
	ДанныеСтроки.ДействуетС = Неопределено; //Дата(1970,1,1,1,0,0) + ВыбранноеЗначение.Получить("ogrn_date") / 1000;
	
	ДанныеСтроки.ИмяРеквизита = ИмяРеквизита;
	ДанныеСтроки.ЭтоИсторическаяКонтактнаяИнформация = Ложь;
	ДанныеСтроки.ХранитьИсториюИзменений = Ложь;
	
	//--
	
	Модифицированность = Истина;
	Параметры.КонтрагентВыбран = Истина;
	
КонецПроцедуры

В данным сразу получаю адрес, его преобразую в формат 1С и фиксирую на форме.

В типовой реализации отслеживается обработка выбора с созданием фонового задания её блокирую используя ключевой параметр формы.

Проект на GitHub https://github.com/malikov-pro/dadata_suggestions_ut11

Благодарю за внимание.

Если нужна готовая сборка или есть предложения по доработке - пишите в комментарии.

DaData ИНН Адрес

–

См. также

Интеграция Альфа Авто 5 / Альфа Авто 6 и AUTOCRM / Инфотек

Сайты и интернет-магазины WEB-интеграция Платформа 1С v8.3 Конфигурации 1cv8 1С:Управление торговлей 11 Автомобили, автосервисы Россия Управленческий учет Платные (руб)

Интеграционный модуль обмена между конфигурацией Альфа Авто 5 и Альфа Авто 6 и порталом AUTOCRM. Данный модуль универсален. Позволяет работать с несколькими обменами AUTOCRM разных брендов в одной информационной базе в ручном и автоматическом режиме.

36000 руб.

03.08.2020 15953 13 18

Управление доставками Boxberry, СДЭК, ЭкстраПочта, Почта России, Энергия, DPD, ПЭК, Grastin, Деловые Линии, КСЕ, Dalli

WEB-интеграция Рабочее место Оптовая торговля Розничная торговля Логистика, склад и ТМЦ Платформа 1С v8.3 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Оптовая торговля, дистрибуция, логистика Россия Управленческий учет Платные (руб)

Управление доставками в транспортных компаниях из 1С.

18000 руб.

10.03.2016 56809 289 97

Все службы доставки в Вашей 1С! Без изменения конфигурации! УТ, ERP, КА, УНФ

WEB-интеграция Рабочее место Оптовая торговля Розничная торговля Логистика, склад и ТМЦ Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 Россия Управленческий учет Платные (руб)

40+ служб доставки для 1С в одном модуле! Внешняя обработка, которая НЕ изменяет Вашу конфигурацию! Подписная модель на 1 год.

19200 руб.

22.03.2017 36498 16 47

Интеграция с OpenCart 2.x, 3x

WEB-интеграция Оптовая торговля Розничная торговля Управляемые формы 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 Розничная и сетевая торговля (FMCG) Оптовая торговля, дистрибуция, логистика Управленческий учет Платные (руб)

Внешняя обработка, позволяет обмениваться данными между OpenCart (самая популярная бесплатная cms для интернет-магазинов) и 1С:Предприятие 8.

6800 руб.

17.11.2015 115997 344 137

213

Заполнение по ИНН или наименованию реквизитов контрагента по данным сайта ФНС

Обмен с ГосИС WEB-интеграция Платформа 1С v8.3 Управляемые формы 1С:Комплексная автоматизация 1.х 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Управление производственным предприятием 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия государственного учреждения 1С:Документооборот 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Платные (руб)

Обработка является альтернативой механизму, разработанному фирмой 1С и заполняющему реквизиты контрагента по ИНН или наименованию. Не требуется действующей подписки ИТС. Вызывается как внешняя дополнительная обработка, т.е. используется, непосредственно, из карточки контрагента. Заполнение по ИНН или наименованию реквизитов контрагента по данным сайта ФНС (egrul.nalog.ru) для БП 2.0, БП 3.0, БГУ 1.0, БГУ 2.0, УТ 10.3, УТ 11.x, КА 1.1, КА 2.x, УПП 1.x, ERP 2.x, УНФ 1.5, УНФ 1.6, УНФ 3.0, ДО 2.1

2400 руб.

28.04.2016 89016 163 216

318

[Расширение] БОР-Навигатор.Культура

Зарплата Бюджетный учет WEB-интеграция Обмен с ГосИС Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 Государственные, бюджетные структуры Россия Бюджетный учет Платные (руб)

Расширение конфигурации, включающее в себя объекты, необходимые для подготовки и сдачи отчета "Штатная численность" системы "БОР-Навигатор.Культура" в программе "1С:Зарплата и кадры государственного учреждения", редакция 3.1.

8400 руб.

01.02.2019 25892 9 0

Интеграция с сервисом vetmanager

WEB-интеграция Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Бытовые услуги, сервис Платные (руб)

Внешняя обработка разрабатывалась для загрузки документов из Ветменеджер в 1С: Бухгалтерия 3.0

12000 руб.

02.02.2021 16496 42 49

Merlion Commander Версия 1.3.9.2 - июль 2022 г. (Интеграция с 1С: УT, редакция 11.4, 1С:Розница 2.3,1С:ERP Управление предприятием 2, УТ 10.3, редакция веб-сервиса MERLION API 3.0 от 18.08.2021)

Оптовая торговля Розничная торговля WEB-интеграция Платформа 1С v8.3 1С:Управление торговлей 11 Россия Платные (руб)

Расширении конфигурации "Управление торговлей, редакция 11" для работы с веб-сервисом Мерлион с помощью Merlion API. Расширение и набор подключаемых дополнительных обработок позволяет без изменения конфигурации получить возможность работы с API крупнейшего российского дистрибьютора http://merlion.com. Логика работы максимально приближена к работе веб-сервиса b2b. Вы сможете создать и исправить заказ, зарезервировать товар прямо из 1С, посмотреть актуальные остатки и цены, импортировать штрихкода EAN13 товаров, загружать заказ c автоматическим созданием номенклатуры в 1С и корректности создания. Можно выбирать характеристики по товарным группам и загружать товар с выбранными характеристиками, загружать изображения товара. Не требуется установки дополнительного ПО для работы с веб-сервисом. Кроссплатформенное решение для ОС Windows и Linux. Весь код модулей открыт и доступен для просмотра и внесения изменений.

8280 руб.

02.05.2017 41095 43 64

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. Sergafan10 24.03.20 16:35 Сейчас в теме

функцию (ИЗ)В_JSON зажали :(

2. malikov_pro 1293 24.03.20 17:32 Сейчас в теме

(1)
Функция В_JSON(СоответствиеДанные, Отказ = Ложь) Экспорт

//ПараметрыЗаписиJSON = Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет);
//
//ИмяФайла = ПолучитьИмяВременногоФайла("json");
//ЗаписьJSON = Новый ЗаписьJSON;
//ЗаписьJSON.ОткрытьФайл(ИмяФайла,,, ПараметрыЗаписиJSON);
//ЗаписатьJSON(ЗаписьJSON, СоответствиеДанные);
//ЗаписьJSON.Закрыть();
//
//Сообщение = Новый СообщениеПользователю;
//Сообщение.Текст = "" + ИмяФайла;
//Сообщение.Сообщить();

//--

Попытка

ЗаписьJSON = Новый ЗаписьJSON;
ЗаписьJSON.УстановитьСтроку();

ЗаписатьJSON(ЗаписьJSON, СоответствиеДанные);

СтрокаДанные = ЗаписьJSON.Закрыть();

Возврат СтрокаДанные;

Исключение

Отказ = Истина;
Сообщить(ОписаниеОшибки());

Возврат Неопределено;

КонецПопытки;

КонецФункции

3. fatman78 17 27.04.20 10:00 Сейчас в теме

Здравствуйте.Очень заинтересовала возможность подсказок сервиса dadata при заполнения адреса. Не могли бы вы поделится расширением. Хочу его портировать на КА.

4. malikov_pro 1293 27.04.20 10:56 Сейчас в теме

(3)
Добрый день.
Под КА работает нормально (писалось под нее).
Не выкладывал cfe, т.к. не доработано заполнение полей (коды ФИАС).
Могу дать доступ к git репозиторию (напишите в личку). Буду рад если доведете до кондиции этот блок.

5. fatman78 17 27.04.20 11:16 Сейчас в теме

Ок. Буду рад помочь. Как раз коды ФИАС в первую очередь мне сейчас нужны для выгрузки ГИС ЖКХ.

6. Termokrator 47 08.09.20 20:32 Сейчас в теме

Здравствуйте. Хотелось бы посмотреть на итоговый вариант, если нужна доработка в плане ФИАС, то мог бы помочь

7. malikov_pro 1293 08.09.20 21:17 Сейчас в теме

(6) https://github.com/malikov-pro/dadata_suggestions_ut11

8. naletovam77 2 14.04.22 16:45 Сейчас в теме

Здравствуйте!
Задача - отправить запрос на сервис dadata.ru, обработать ответ.
Запрос по расстоянию от МКАД, для адреса.

Платформа - 8.2 (8.2.19.102), записи JSON нет и у меня не получается ее эмулировать.
Подробности можно обсудить.

9. malikov_pro 1293 14.04.22 17:39 Сейчас в теме

(8) Гуглится по 1C JSON 8.2, один из результатов, внизу статьи ссылка на код, возможно и на этом ресурсе под 8.2 есть
https://1c-programmer-blog.ru/programmirovanie/rabota-s-json-v-1s.html

Сам с 8.2 не работаю, помочь кодом врятли смогу.