hsИнтегратор 3. Онлайновый обмен и удаленное исполнение функций по HTTP протоколу

03.09.19

Интеграция - Обмен между базами 1C

–

Кроссплатформенный онлайновый обмен данными и удаленное исполнение функций по протоколу HTTP. Новая функциональность - обмен элементами плана видов расчета и данными расчетных регистров. Увеличение производительности и упрощение пользовательского API. Тестирование обменов выполнялось с демонстрационными базами: "Бухгалтерия предприятия, редакция 3.0 3.0.72.66" и "Зарплата и Управление Персоналом, редакция 3 3.1.10.135"

Скачать исходный код

	Наименование	Файл	Версия	Размер
	Выгрузка демобазы клиента, расширение hsИнтегратор, файл hsИнтегратор.odt с описанием технологии и настройки. Материалы для всех версий hИнтегратор (1,2,3). .zip 8,30Mb 57	.zip		8,30Mb	57	Скачать

hsИнтегратор 3

Новая функциональность

Реализована поддержка обмена для объектов плана видов расчета и расчетных регистров. Полный перечень поддерживаемых в настоящее время объектов обмена

Справочники
Документы
Перечисления
Планы видов характеристик
Планы счетов
Планы видов расчета
Регистры сведений (независимые и подчиненные регистратору)
Регистры накопления
Регистры бухгалтерии
Регистры расчета

Технология hsИнтегратор позволяет производить "фэйковую" загрузку данных: например, запросить данные регистров у источника за определенный период, получить их на клиенте и, по ссылкам, загрузить отсутствующие на клиенте объекты или те, у которых версия данных отличается от версии данных на сервере. А данные регистров не записывать. Более того, регистры сервера, данные которых запрашивались, могут вообще отсутствовать и не иметь аналогов на клиенте. Клиент может запросить данные бухгалтерского регистра сервера и не иметь бухгалтерских регистров в своей конфигурации. Фактически часть запрашиваемых объектов обмена может использоваться не для записи, а для получения обновленных или новых объектов по ссылкам из запрошенных объектов.

Оптимизация

Реализовано кэширование типов объектов метаданных и ссылок на объекты. Время обмена сократилось от 2-х до 3-х раз (сокращение тем больше, чем больше объем передаваемой информации).

Упрощение пользовательского API

Сокращено количество параметров функций, вызываемых на клиенте. Большая часть параметров получает значения «по умолчанию» при инициализации, но может быть изменена после инициализации.

Теперь пример для загрузки данных регистров и всех объектов на клиенте сервиса выглядит так:

&НаСервере
Процедура ТестОбмена_3_1НаСервере(Знач ИмяФункцииНаСервере)
	
		ИмяМодуля             = ИмяМодуля();
		ИмяНастройки          = ИмяНастройки();
		КонтекстПроцесса = Неопределено;
		Справочники.hsИнтегратор.ИнициализироватьКонтекстПроцесса(КонтекстПроцесса, ИмяНастройки(), , РазрешимыеСсылки());
		
		Парам = Новый Структура("КоличествоЗаписей", КоличествоЗаписей);
		
		КоличествоДней = 0;
		ОбъектыДляЗаписи = Новый Соответствие;
		
		// Запросим обновления для зарегистрированных на клиенте версий объекта сервера 
    	Справочники.hsИнтегратор.ЗапроситьОбновленияКлиент(КонтекстПроцесса, ОбъектыДляЗаписи,  КоличествоДней);
		
		// запросим с сервера записи двух регистров
		Результат = Справочники.hsИнтегратор.ЗапроситьСервер(КонтекстПроцесса,  ИмяФункцииНаСервере, Парам);
		Если Справочники.hsИнтегратор.ОшибкаВРезультате(Результат) Тогда
			Возврат;
		КонецЕсли;	
		
		ТабБух = Результат.Ответ.РегистрБухгалтерии;  
		ТабСв  = Результат.Ответ.РегистрСведений;  
		
		БитыеСсылки = Новый Соответствие;
		
		// Несколько регистров (наборов записей) с объектами
		// в соответствии БитыеСсылки накапливаются общие битые ссылки по двум полученным таблицам
		Справочники.hsИнтегратор.hsТаблицаВТаблицу(КонтекстПроцесса, ТабБух, БитыеСсылки);
		Справочники.hsИнтегратор.hsТаблицаВТаблицу(КонтекстПроцесса, ТабСв , БитыеСсылки);
		// запросим с сервера объекты по всем битым ссылкам
		Справочники.hsИнтегратор.ЗапроситьБитыеСсылкиКлиент(КонтекстПроцесса, БитыеСсылки, ,ОбъектыДляЗаписи);
		
		// построим коллекции для записи в единой транзакции
		КоллекцииДляЗаписи = Новый Структура;
		КоллекцииДляЗаписи.Вставить("Объекты", ОбъектыДляЗаписи);
		// Если закомментировать следующую пару строк, данные регистров не будут записаны. Только объекты по ссылкам (фэйковая загрузка регистров)
		КоллекцииДляЗаписи.Вставить("РегБухгалтерии", Новый Структура("Таблица, ИмяРегистра",ТабБух, "РегистрыБухгалтерии.Хозрасчетный1" ));
		КоллекцииДляЗаписи.Вставить("РегСведений"   , Новый Структура("Таблица, ИмяРегистра",ТабСв , "РегистрыСведений.СчетаУчетаРасчетовСКонтрагентами1" ));
		
		// запишем коллекции
		ТекстОшибки = Справочники.hsИнтегратор.ЗаписатьКоллекции(КоллекцииДляЗаписи);
		Если ТекстОшибки <> "" Тогда
			Сообщить(ТекстОшибки);
		КонецЕсли;
	
КонецПроцедуры

Подготовлен пример макетной базы данных для обмена с демонстрационными базами данных 1С:Бухгалтерия предприятия, редакция 3.0 (БУХ), 1С:Зарплата и управление персоналом , редакция 3.1. (ЗУП)

Тесты обмена в макетной базе:

Загрузка из БУХ справочника «Контрагенты» в справочник «Контрагенты1», загрузка из ЗУП справочника «Сотрудники» в справочник «Контрагенты1»
Загрузка из БУХ документов «РеализацияТоваровУслуг» в «РеализацияТоваровУслуг1»
Загрузка данных регистра бухгалтерии «Хозрасчетный» из БУХ в «Хозрасчетный1»
Загрузка данных регистров «Начисления» и «Удержания» из ЗУП в одноименные регистры макетной конфигурации.

При загрузке любых данных автоматически рекурсивно загружаются все объекты по ссылкам. Например, загрузка записей регистра бухгалтерии приводит к загрузке документов, элементов плана счетов, контрагентов и т. д., которые необходимы для «разрешения» ссылок.
Также при загрузке выполняется сравнение версий данных объектов на клиенте сервиса и на сервере и клиенту передаются только отсутствующие на объекты или объекты, версии данных которых различны на сервере и клиенте. Поэтому, например, повторная загрузка выполняется в 10 раз быстрее — в базе данных клиента сервера все объекты уже есть и версии данных совпадают.

Архивный файл hs.zip содержит папки с материалами всех версий (hsИнтегратор, hsИнтегратор2, hsИнтегратор3)

Описание истории разработки и предыдущих версий под спойлером (развернуть плюс):

hsИнтегратор 2
Развитие и расширение технологии, опубликованной ранее //infostart.ru/public/852394/

Организация онлайнового обмена данными и удаленного исполнения функций между базами данных на платформе 1С:Предприятие, начиная с версии платформы 8.3.9. Обмен выполняется по протоколу HTTP между любыми конфигурациями, в том числе развернутыми на мобильной платформе.
Организация и настройка обмена выполняется без изменения существующих конфигураций, с использованием расширения конфигурации hsИнтегратор (в мобильной платформе расширения не поддерживаются, необходимо внедрение объектов метаданных hsИнтегратор) в мобильную конфигурацию.
После внедрения и настройки расширения hsИнтегратор одна и та же база может одновременно обеспечивать сервис для подключения клиентов hsИнтегратор и, в качестве клиента, подключаться к любому количеству сервисов hsИнтегратор. Возможна организация произвольной топологии сети для онлайновых обменов.
Обмен данными и удаленное исполнение функций использует простую парадигму: Y = F(X), где F – имя функции в модуле удаленного исполнения, X – параметр функции. Всё, что описано ниже для параметра, также применимо и к результату функции (Y), который возвращается клиенту сервиса hsИнтегратор.

В качестве параметра можно использовать примитивные типы данных, коллекции (в том числе содержащие другие коллекции) — структуры, соответствия, массивы, таблицы значений. Колонки таблиц значений также могут быть коллекциями. Для передачи объектов базы данных используется результат запроса, преобразованный в таблицу значений, которая содержит только примитивные типы данных. Ссылки преобразуются в специальный строчный формат, например СПР.Контрагенты.<GUID> - это предствление ссылки, созданное сервисом для базы приемника.

При получении данных второй стороной обмена таблица значений преобразуется в массив объектов, которые могут быть созданы фабрикой приемника. Функции преобразования могут вызывать определенные в модуле обмена функции замен, которые позволяют сформировать представление данных для клиента в тех случаях, когда типы и организация данных на клиенте и сервере отличаются (преобразование одного объекта в два, два в один, изменение типа данных и др.).
Для передачи всех данных объектов с совпадающей структурой можно формировать данные для передачи с помощью запроса «по звездочке». Объем передаваемых данных можно значительно сократить, если в запросе указывать только нужные реквизиты и табличные части. Если имена реквизитов на премнике данных отличаются, в запросе можно определить имена для приемника с помощью оператора «КАК». Если отличаются имена табличных частей, для табличной части также используется оператор «КАК». Реквизиты, полученные в данных и отсутствующие в объектах приемника, не копируются. Поэтому если в источнике изменится структура данных (добавлен реквизит), а данные получены запросом «через звездочку», приемник будет успешно получать данные. Если же впоследствии в конфигурации приемника добавить реквизит с таким же именем, при следующих обменах приемник начнет получать данные нового реквизита.
При получении объектов приемником возможно автоматически рекурсивно запрашивать объекты по ссылкам на сервере. Причем запись всех данных полученных данных производится на приемнике в единой транзакции. Возможны следующие варианты:
1) не запрашивать объекты по ссылкам
2) запрашивать объекты по ссылкам всегда, если ссылка отсутствует на приемнике.
3) запрашивать объекты по ссылкам, если ссылка отсутствует на приемнике ИЛИ версии данных объекта на приемнике и источнике отличаются.
Вторая версия hsИнтегратор поддерживает передачу следующих типов объектов:
- элементы справочников, документов, планов видов характеристик, планов счетов (в том числе предопределенные)
- значения перечислений (также с помощью функций замен можно преобразовать к существующим на приемнике).
- данные регистров сведений (независимых и подчиненных регистатору), накопления, бухгалтерии. Если регистратор отсутствует и не был определен для приемника, запись на приемнике создана не будет.
При передаче между источником и приемником (и обратно) данные могут быть сериализованы в строку JSON (при обмене с мобильной платформой возможен только этот вариант), Base64 или передаваться в бинарном виде — это самый экономный вариант.
Передаваемые данные автоматически разбиваются на пакеты заданного размера, чтобы не превышать ограничения Web-сервера. Размер пакетов может быть задан отдельно для сервера и для клиента.
Функции удаленного исполнения могут исполняться сервисом:

- в синхронном режиме. В том случае, если функция исполняется на сервере быстро и загрузка сервера небольшая (несколько десятков запросов в секунду), целесообразно использовать данный режим, поскольку он обеспечивает минимальное время отклика сервиса.
- в асинхронном режиме, а сеансах Web-сервера (большое количество длительных запросов).
- в асинхронном режиме, в фоновых процессах сервера 1С. Количество фоновых процессов задаётся для каждого пользователя, под именем которого исполняется функция удаленного исполнения. Это самый масштабируемый вариант, поскольку позволяет снизить нагрузку на Web-сервер и перенести вычисления на кластер серверов 1С.

Пример кода для загрузки данных независимого регистра сведений и регистра бухгалтерии на стороне клиента и сервера. Это самый сложный пример, загружаются
данные регистров сведений и рекурсивно объекты по ссылкам в регистрах. Причем объекты запрашиваются на сервере только при отсутствии на клиенте или если различаются версии данных объектов.
Сторона клиента:

&НаСервере
Процедура ТестОбмена_3_1НаСервере(Знач ИмяФункцииНаСервере, JSONУпаковка, Асинхронно, КоличествоДокументов)
	
	#Если Не МобильноеПриложениеСервер И Не ТолстыйКлиентУправляемоеПриложение И Не ТолстыйКлиентОбычноеПриложение Тогда
		
		ИмяМодуля             = ИмяМодуля();
		ИмяНастройки          = ИмяНастройки();
		ИменаФункцийЗамен     = "ЗаменыПараметров/ЗаменыОтвета";
		ИменаЗаменБитыхСсылок = "БитыеСсылкиЗаменаПараметров/ЗаменыОтвета"; 
		ИмяФункцииНаСервере   = ИмяФункцииНаСервере + "/" + ИменаФункцийЗамен;
		
		Парам = Новый Структура("КоличествоЗаписей", КоличествоЗаписей);
		
		КоличествоДней = 0;
		ОбъектыДляЗаписи = Новый Соответствие;
		
		// Запросим обновления для зарегистрированных на клиенте версий объекта сервера 
    	Справочники.hsИнтегратор.ЗапроситьОбновленияКлиент(ИмяНастройки, ИмяМодуля,	ОбъектыДляЗаписи, РазрешимыеСсылки(), JSONУпаковка, Асинхронно, ИменаЗаменБитыхСсылок, БинарныйОбмен,КоличествоДней);
		
		// запросим с сервера записи двух регистров
		Результат = Справочники.hsИнтегратор.ЗапроситьСервер(ИмяНастройки, ИмяМодуля, ИмяФункцииНаСервере, Парам, Асинхронно, JSONУпаковка, БинарныйОбмен);
		Если Справочники.hsИнтегратор.ОшибкаВРезультате(Результат) Тогда
			Возврат;
		КонецЕсли;	
		
		ТабБух = Результат.Ответ.РегистрБухгалтерии;  
		ТабСв  = Результат.Ответ.РегистрСведений;  
		
		БитыеСсылки = Новый Соответствие;
		
		//ПолучатьНовыеВерсииОбъектов = Истина;  // запрашивать объекты по ссылкам, даже если они уже есть на клиенте
		ПолучатьНовыеВерсииОбъектов = Ложь;      // запрашивать без рекурсивных запросов битых ссылок (они уже приехали с обновлениями)
		
		// Несколько регистров (наборов записей) с объектами
		
		// в соответствии БитыеСсылки накапливаются общие битые ссылки по двум полученным таблицам
		Справочники.hsИнтегратор.hsТаблицаВТаблицу(ТабБух, БитыеСсылки, ПолучатьНовыеВерсииОбъектов);
		Справочники.hsИнтегратор.hsТаблицаВТаблицу(ТабСв , БитыеСсылки, ПолучатьНовыеВерсииОбъектов);
		// запросим с сервера объекты по всем битым ссылкам
		Справочники.hsИнтегратор.ЗапроситьБитыеСсылкиКлиент(ИмяНастройки,БитыеСсылки,ИмяМодуля,,ОбъектыДляЗаписи, РазрешимыеСсылки() , ПолучатьНовыеВерсииОбъектов, JSONУпаковка, Асинхронно, ИменаЗаменБитыхСсылок, БинарныйОбмен);
		
		// построим коллекции для записи в единой транзакции
		КоллекцииДляЗаписи = Новый Структура;
		КоллекцииДляЗаписи.Вставить("Объекты", ОбъектыДляЗаписи);
		КоллекцииДляЗаписи.Вставить("РегБухгалтерии", Новый Структура("Таблица, ИмяРегистра",ТабБух, "РегистрыБухгалтерии.Хозрасчетный1" ));
		КоллекцииДляЗаписи.Вставить("РегСведений"   , Новый Структура("Таблица, ИмяРегистра",ТабСв , "РегистрыСведений.СчетаУчетаРасчетовСКонтрагентами1" ));
		
		// запишем коллекции
		ТекстОшибки = Справочники.hsИнтегратор.ЗаписатьКоллекции(КоллекцииДляЗаписи);
		
		
		Если ТекстОшибки <> "" Тогда
			Сообщить(ТекстОшибки);
		КонецЕсли;
		
	#КонецЕсли
	
КонецПроцедуры

Сторона сервера (модуль содержит все прикладные функции для трех тестов):

#Область СлужебныеПроцедуры
// Нужна при копировании текста модуля в модуль объекта подключаемой обработки
// (в этом случае функции удаленного исполнения переопределяются в модуле обработке
// в общем модуле не используется
Функция СведенияОВнешнейОбработке() Экспорт
	
	РегистрационныеДанные = Новый Структура;
	РегистрационныеДанные.Вставить("Наименование", "Это просто хранилище экспортных функций в модуле объекта");
	РегистрационныеДанные.Вставить("БезопасныйРежим", Истина);
	РегистрационныеДанные.Вставить("Версия", "1.00");
	
	РегистрационныеДанные.Вставить("Вид", "ДополнительнаяОбработка");
	РегистрационныеДанные.Вставить("Информация", "Хранилище экспортных функций для сервиса hsИнтегратор");
	
	Назначение = Новый Массив;
	РегистрационныеДанные.Вставить("Назначение", Назначение);	
	
	///////////// команды /////////////////////////
	тзКоманд = Новый ТаблицаЗначений;
	тзКоманд.Колонки.Добавить("Идентификатор");
	тзКоманд.Колонки.Добавить("Представление");
	тзКоманд.Колонки.Добавить("Модификатор");
	тзКоманд.Колонки.Добавить("ПоказыватьОповещение");
	тзКоманд.Колонки.Добавить("Использование");
	
	РегистрационныеДанные.Вставить("Команды", тзКоманд);
	Возврат РегистрационныеДанные;
	
КонецФункции

Функция ТестовыйЗапрос(Параметры, СлужебнаяИнформация = Неопределено, ИмяЗаменПараметров = Неопределено, ИмяЗаменОтвета = Неопределено) Экспорт
	
	// Ничего не делает, используется для проверки обмена
	Строка = "Дата клиента: " + СокрЛП(Параметры.ТестоваяСтрока)
	+ Символы.ПС 
	+ "Дата сервера: " + СокрЛП(ТекущаяДата());
	Возврат Новый Структура("ТестоваяСтрока",Строка);
	
КонецФункции	

Функция ИмяМодуля() // имя этого модуля
	
	Возврат "hsМодульТестыОбмена";
	
КонецФункции	

Функция ИмяФункцииЗамен(ИмяФункции)  // возвращает полное имя функции
	
	Возврат ИмяМодуля() + "." + ИмяФункции;
	
КонецФункции	

#КонецОбласти 

#Область ФункцииУдаленногоВызова

//////////////////////////////////////////////////////////////////////
// Модуль содержит функции, вызываемые через HTTP-сервис hsExchange
// Коллекция Параметры передаётся клиентом, функция возвращает 
// коллекцию, передаваемую клиенту. 
// 
// Имя функции, передаваемое клиентом должно совпадать с именем одной
// из функций модуля.

Функция ТестОбмена_1_1(Параметры = Неопределено, СлужебнаяИнформация = Неопределено,ИмяЗаменПараметров = Неопределено,ИмяЗаменОтвета = Неопределено) Экспорт
	
	// Объекты передаются с преобразованием в hsТаблицы
	Запрос = Новый Запрос;
	Количество = Параметры.КоличествоКонтрагентов;
	
	// Поскольку запрос "по звездочке", в результат запроса на сервере 
	// попадут ссылки на ПВХ и характеристики, которые не поддерживаются мобильной платформой
	// Поэтому в мобильном приложении в справочнике контрагентов
	// удалить реквизит ДополнительныеРеквизиты.Свойство (все равно не заполняется)
	// и у реквизита ДополнительныеРеквизиты.Значение
	// заменить тип с Характеристика.ДополнительныеРеквизитыИСведения (характеристика в моб.приложении не поддерживается)
	//              на составной (любая ссылка, примитивные типы)
	// иначе будет "вылет" с ошибкой SDBL
	Запрос.Текст =
	"ВЫБРАТЬ ПЕРВЫЕ 1
	|	*,
	|	Контрагенты.ИНН КАК ИНН
	|ИЗ
	|	Справочник.Контрагенты КАК Контрагенты
	|ГДЕ
	|	Контрагенты.ИНН = ""5260274718""
	|
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ ПЕРВЫЕ <КоличествоКонтрагентов>
	|	*,
	|	Контрагенты.ИНН КАК ИНН
	|ИЗ
	|	Справочник.Контрагенты КАК Контрагенты";
		
	Если Количество = 0 Тогда
		Запрос.Текст = СтрЗаменить(Запрос.Текст, "<КоличествоКонтрагентов>","1");
	Иначе	
		Запрос.Текст = 
		СтрЗаменить(Запрос.Текст, "<КоличествоКонтрагентов>",Формат(Количество,"ЧДЦ=0; ЧГ=0"));
	КонецЕсли;	
	
	Пакет = Запрос.ВыполнитьПакет();
	ДеревоКонтрагенты = Пакет[0].Выгрузить(ОбходРезультатаЗапроса.ПоГруппировкам);
	hsТаблицаКонтрагенты = Справочники.hsИнтегратор.КоллекцияВhsТаблицу(ДеревоКонтрагенты, ИмяФункцииЗамен(ИмяЗаменОтвета));
	
	Ответ = Новый Структура;
	Ответ.Вставить("Контрагенты",hsТаблицаКонтрагенты);
	
	Возврат Ответ;
	
КонецФункции	

//////////////////////////////////////////////////////////////////////
// Модуль содержит функции, вызываемые через HTTP-сервис hsExchange
// Коллекция Параметры передаётся клиентом, функция возвращает 
// коллекцию, передаваемую клиенту. 
// 
// Имя функции, передаваемое клиентом должно совпадать с именем одной
// из функций модуля.

Функция ТестОбмена_2_1(Параметры = Неопределено, СлужебнаяИнформация = Неопределено,ИмяЗаменПараметров = Неопределено,ИмяЗаменОтвета = Неопределено) Экспорт
	
	// Объекты передаются с преобразованием в hsТаблицы
	Запрос = Новый Запрос;
	Количество = Параметры.КоличествоДокументов;
	
	// Поскольку запрос "по звездочке", в результат запроса на сервере 
	// попадут ссылки на ПВХ и характеристики, которые не поддерживаются мобильной платформой
	// Поэтому в мобильном приложении в справочнике контрагентов
	// удалить реквизит ДополнительныеРеквизиты.Свойство (все равно не заполняется)
	// и у реквизита ДополнительныеРеквизиты.Значение
	// заменить тип с Характеристика.ДополнительныеРеквизитыИСведения (характеристика в моб.приложении не поддерживается)
	//              на составной (любая ссылка, примитивные типы)
	// иначе будет "вылет" с ошибкой SDBL
	Запрос.Текст =
	"ВЫБРАТЬ <КоличествоДокументов>
	|	*
	|ИЗ
	|	Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг";
		
	Если Количество = 0 Тогда
		Запрос.Текст = СтрЗаменить(Запрос.Текст, "<КоличествоДокументов>","");
	Иначе	
		Запрос.Текст = 
		СтрЗаменить(Запрос.Текст, "<КоличествоДокументов>"," ПЕРВЫЕ " + XMLСтрока(Количество));
	КонецЕсли;	
	
	Пакет = Запрос.ВыполнитьПакет();
	ДеревоДокументы = Пакет[0].Выгрузить(ОбходРезультатаЗапроса.ПоГруппировкам);
	hsТаблицаДокументы = Справочники.hsИнтегратор.КоллекцияВhsТаблицу(ДеревоДокументы, ИмяФункцииЗамен(ИмяЗаменОтвета));
	
	Ответ = Новый Структура;
	Ответ.Вставить("Документы",hsТаблицаДокументы);
	
	Возврат Ответ;
	
КонецФункции	

Функция ТестОбмена_3_1(Параметры = Неопределено, СлужебнаяИнформация = Неопределено,ИмяЗаменПараметров = Неопределено,ИмяЗаменОтвета = Неопределено) Экспорт
	
	// Объекты передаются с преобразованием в hsТаблицы
	Запрос = Новый Запрос;
	КоличествоЗаписей = Параметры.КоличествоЗаписей;
	
	// Поскольку запрос "по звездочке", в результат запроса на сервере 
	// попадут ссылки на ПВХ и характеристики, которые не поддерживаются мобильной платформой
	// Поэтому в мобильном приложении в справочнике контрагентов
	// удалить реквизит ДополнительныеРеквизиты.Свойство (все равно не заполняется)
	// и у реквизита ДополнительныеРеквизиты.Значение
	// заменить тип с Характеристика.ДополнительныеРеквизитыИСведения (характеристика в моб.приложении не поддерживается)
	//              на составной (любая ссылка, примитивные типы)
	// иначе будет "вылет" с ошибкой SDBL
	Запрос.Текст =
	"ВЫБРАТЬ <КоличествоЗаписей>
	|	*
	|ИЗ
	|	РегистрБухгалтерии.Хозрасчетный КАК Хозрасчетный
	|;
	|ВЫБРАТЬ <КоличествоЗаписей>
	|	*
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами КАК СчетаУчетаРасчетовСКонтрагентами";
	
	Если КоличествоЗаписей = 0 Тогда
		Запрос.Текст = СтрЗаменить(Запрос.Текст, "<КоличествоЗаписей>","");
	Иначе	
		Запрос.Текст = 
		СтрЗаменить(Запрос.Текст, "<КоличествоЗаписей>"," ПЕРВЫЕ " + XMLСтрока(КоличествоЗаписей));
	КонецЕсли;	
	
	
	Пакет = Запрос.ВыполнитьПакет();
	БухРегистр = Пакет[0].Выгрузить();
	hsРегистрБухгалтерии = Справочники.hsИнтегратор.КоллекцияВhsТаблицу(БухРегистр, ИмяФункцииЗамен(ИмяЗаменОтвета));
	
	СвРегистр = Пакет[1].Выгрузить();
	hsРегистрСведений = Справочники.hsИнтегратор.КоллекцияВhsТаблицу(СвРегистр, ИмяФункцииЗамен(ИмяЗаменОтвета));
	
	Ответ = Новый Структура;
	Ответ.Вставить("РегистрБухгалтерии",hsРегистрБухгалтерии);
	Ответ.Вставить("РегистрСведений"   ,hsРегистрСведений);
	
	Возврат Ответ;
	
КонецФункции	

Функция СоответствиеТипов() // ключ - имя hsТипа клиента, значение - имя hsТипа сервера
	
	Соответствие = Новый Соответствие;
	//                     тип в базе клиента                       тип в базе сервера
	Соответствие.Вставить("СПР.Номенклатура1"                    , "СПР.Номенклатура");
	Соответствие.Вставить("СПР.Контрагенты1"                     , "СПР.Контрагенты");
	Соответствие.Вставить("СПР.СтраныМира1"                      , "СПР.СтраныМира");
	Соответствие.Вставить("СПР.ЗначенияСвойствОбъектов1"         , "СПР.ЗначенияСвойствОбъектов");
	Соответствие.Вставить("ДОК.РеализацияТоваровУслуг1"          , "ДОК.РеализацияТоваровУслуг");
	Соответствие.Вставить("ПВХ.ДополнительныеРеквизитыИСведения1", "ПВХ.ДополнительныеРеквизитыИСведения");
	Соответствие.Вставить("ПВХ.ВидыСубконтоХозрасчетные1"        , "ПВХ.ВидыСубконтоХозрасчетные");
	Соответствие.Вставить("ПРЧ.ЮрФизЛицо1"                       , "ПРЧ.ЮрФизЛицо");
	Соответствие.Вставить("ПСЧ.Хозрасчетный1"                    , "ПСЧ.Хозрасчетный");
	Соответствие.Вставить("СПР.НоменклатурныеГруппы1"            , "СПР.НоменклатурныеГруппы");
	Соответствие.Вставить("СПР.Субконто1"                        , "СПР.Субконто");
	Соответствие.Вставить("ПРЧ.ВидыРасчетовПоДоговорам1"         , "ПРЧ.ВидыРасчетовПоДоговорам");
	
	Возврат Соответствие;
	
КонецФункции	

Функция ОбратноеСоответствиеТипов() // ключ - имя hsТипа сервера, значение - имя hsТипа клиента
	
	Возврат Справочники.hsИнтегратор.РеверсСоответствия(СоответствиеТипов());
	
КонецФункции	

Функция ЗаменыОтвета(Имя,                             // Имя в источнике    
	Значение,                        // Значение в источнике
	КонтекстОбъекта = Неопределено,  // строка таблицы значений, поля которой соответствуют реквизитам строки
	КонтекстСтроки = Неопределено) 
	Экспорт
	
	ТипОбъекта = "";  // тип объекта метаданных ("Документ", "Справочник", "Перечисление" и т.д.) в приемнике
	// типы в источнике и приемнике могут отличаться (справочник в документ и др.)
	ИмяОбъекта = "";  // имя объекта метаданных в приемнике 
	ЗначениеРеквизита = Неопределено;  // преобразованное для получения приемником Значение
	
	Если КонтекстОбъекта = Неопределено Тогда  
		// если нет контекста объекта, это запрос имени типа
		ИмяТипаНаКлиенте = ОбратноеСоответствиеТипов().Получить(Имя);
		Возврат ?(ИмяТипаНаКлиенте = Неопределено, Имя, ИмяТипаНаКлиенте);
	Иначе	
		ТипЗн = Справочники.hsИнтегратор.ДанныеРеквизита(Имя, Значение, ТипОбъекта, ИмяОбъекта, ЗначениеРеквизита);
	КонецЕсли;
	
	// пример переопределения имени предопределенного счета для базы клиента
	Если Имя = "ИмяПредопределенныхДанных"
		И КонтекстОбъекта <> Неопределено 
		И Значение = "РасчетыСПокупателямиИЗаказчиками" 
		И Лев(КонтекстОбъекта._hs_Ссылка_Ссылка,4)= "ПСЧ." Тогда
		Значение = "РасчетыСоВсякими";    // такое имя предопределенных данных у счета на клиенте
		Возврат Значение; 
	КонецЕсли;	
	
	Если Не Справочники.hsИнтегратор.ЭтоСсылка(Значение) 
		Тогда
		Возврат Значение;
	КонецЕсли;
	
	
	ИмяТипаНаСервере = ТипОбъекта + "." + ИмяОбъекта;
	ИмяТипаНаКлиенте = ОбратноеСоответствиеТипов().Получить(ИмяТипаНаСервере);
	Если ИмяТипаНаКлиенте <> Неопределено Тогда
		Лексемы = СтрРазделить(ИмяТипаНаКлиенте,"."); 
		ТипОбъекта = Лексемы[0];
		ИмяОбъекта = Лексемы[1];
	КонецЕсли;

	Возврат Справочники.hsИнтегратор.hsСсылка(ТипОбъекта, ИмяОбъекта, ЗначениеРеквизита);
	
КонецФункции	

Функция БитыеСсылкиЗаменаПараметров(БитыеСсылки) Экспорт
	
	Замена = Новый Соответствие;
	Для каждого Эл Из БитыеСсылки Цикл
		Ключ = СоответствиеТипов().Получить(Эл.Ключ);
		Если Ключ <> Неопределено Тогда
			Замена.Вставить(Ключ, Эл.Значение);
		Иначе	
			Замена.Вставить(Эл.Ключ, Эл.Значение);
		КонецЕсли;
	КонецЦикла;
	Возврат Замена;
	
КонецФункции

Функция ТекстыЗапросовБитыхСсылок()
	
	// если не хотим передавать клиенту лишнюю информацию об объектах,
	// которая всё равно не используется на клиенте, вместо "универсального"
	// запроса объекта по "звездочке", укажем конкретные поля в запросе
	// Все подобные запросы должны включать условие
	// 
	//  |ГДЕ
	//  |	<ИмяТаблицы>.Ссылка В(&Ссылки)";	
	//
	// ... можно вынести эту функцию в модуль повторного использования, но
	//     тогда нельзя будет перегружать модуль из доп.обработки
	//     
	Тексты = Новый Соответствие;
	
	// определение возвращаемых клиенту данных для битых ссылок справочника СтраныМира
	Тексты.Вставить("СПР.СтраныМира",
	"ВЫБРАТЬ
	|	СтраныМира.Ссылка КАК Ссылка,
	|	СтраныМира.Наименование КАК Наименование,
	|	СтраныМира.НаименованиеПолное КАК НаименованиеПолное,
	|	СтраныМира.КодАльфа2 КАК КодАльфа2,
	|	СтраныМира.КодАльфа3 КАК КодАльфа3,
	|	СтраныМира.ПометкаУдаления КАК ПометкаУдаления
	|ИЗ
	|	Справочник.СтраныМира КАК СтраныМира
	|ГДЕ
	|	СтраныМира.Ссылка В(&Ссылки)");
	
	Возврат Тексты;
	
КонецФункции

Функция ЗапросБитыхСсылок(Параметры = Неопределено, 
	СлужебнаяИнформация = Неопределено,
	ИмяФункцииЗаменДляПараметров = Неопределено,
	ИмяФункцииЗаменДляОтвета = Неопределено) Экспорт
	
	// ВАЖНО !
	// "ТекстыЗапросовБитыхСсылок" - зарезервированное имя параметра, используется в функции hsИнтегратор.ЗапросБитыхСсылок()
	
	Параметры.Вставить("ТекстыЗапросовБитыхСсылок", ТекстыЗапросовБитыхСсылок());
	Возврат hsИнтегратор.ЗапросБитыхСсылок(Параметры, СлужебнаяИнформация, ИмяФункцииЗаменДляПараметров, ИмяФункцииЗаменДляОтвета, ИмяМодуля());
	
КонецФункции	

Функция ЗапросОбновленияОбъектов(Параметры = Неопределено, 
	СлужебнаяИнформация = Неопределено,
	ИмяФункцииЗаменДляПараметров = Неопределено,
	ИмяФункцииЗаменДляОтвета = Неопределено) Экспорт
	
	// ВАЖНО !
	// "ТекстыЗапросовБитыхСсылок" - зарезервированное имя параметра, используется в функции hsИнтегратор.ЗапросБитыхСсылок()
	
	Параметры.Вставить("ТекстыЗапросовБитыхСсылок", ТекстыЗапросовБитыхСсылок());
	Возврат hsИнтегратор.ЗапросОбновленияОбъектов(Параметры, СлужебнаяИнформация, ИмяФункцииЗаменДляПараметров, ИмяФункцииЗаменДляОтвета, ИмяМодуля());

КонецФункции	

Функция ПолученоФотоКонтрагента(Параметры = Неопределено, 
	СлужебнаяИнформация = Неопределено,
	ИмяФункцииЗаменДляПараметров = Неопределено,
	ИмяФункцииЗаменДляОтвета = Неопределено) Экспорт

    Ссылка = Справочники.Контрагенты.ПолучитьСсылку(Параметры.GUID);
	Об = Ссылка.ПолучитьОбъект();
	Об.Фото = Новый ХранилищеЗначения(Параметры.ДвДанные);
	Об.Записать();
	
КонецФункции	
#КонецОбласти

Технология обмена hsИнтегратор является универсальной, работает под управлением платформы 1С:Предприятие, начиная с версии 8.3.9 под Windows, Linux, на мобильной платформе.

Однако для мобильной платформы имеются следующие ограничения:

hsИнтегратор работает только в качестве клиента (HTTP-сервисы мобильная платформа не поддерживает).
код расширения hsИнтегратор необходимо непосредственно внедрять в мобильную конфигурацию (мобильная платформа не поддерживает расширения)
в мобильной платформе отсутствует ряд объектов метаданных (планы видов характеристик, планы счетов и др.). Поэтому, при необходимости, данные таких объектов необходимо передавать, например, как элементы справочников.

Обмен HTTP удаленное исполнение интеграция универсальное расширение конфигурации

–

См. также

SALE! 10%

Перенос данных из УПП 1.3 в ERP 2 / УТ 11 / КА 2. Переносятся документы, справочная информация и остатки

Обмен между базами 1C Платформа 1С v8.3 1С:Управление производственным предприятием 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Платные (руб)

Перенос документов, начальных остатков и справочной информации из УПП 1.3 в ERP 2 | из УПП 1.3 в УТ 11 | из УПП в КА 2 | Правила конвертации (КД 2) в продаже с 2015 года, постоянно работаем над их развитием | Более 360 предприятий выполнили переход с использованием этого продукта! | Сэкономьте время - используйте готовое решение для перехода! | Позволяет перенести из УПП 1.3 в ERP / УТ 11 / КА 2 всю возможную информацию | В переносе есть фильтр по организации и множество других опциональных параметров выгрузки | Есть несколько алгоритмов выгрузки остатков на выбор

~~50722~~ 45650 руб.

04.08.2015 160263 368 268

349

SALE! 15%

[ED3] Обмен для ERP 2.5, КА 2.5, УТ 11.5 БП 3.0, Розница, УНФ и других с EnterpriseData (универсальный формат обмена), правила обмена

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Россия Платные (руб)

Правила в универсальном формате обмена для ERP 2.5, КА 2.5, УТ 11.5, БП 3.0, Розница, УНФ, для последних версий конфигураций. Ссылки на другие конфигурации в описании публикации. Правила совместимы со всеми другими версиями конфигураций новыми и старыми, поддерживающими обмен в формате EnterpriseData. Не требуется синхронного обновления правил после обновления другой конфигурации, участвующей в обмене. Типовой обмен через планы обмена кнопкой Синхронизация вручную или автоматически по расписанию, или вручную обработкой.

25080 руб.

12.06.2017 135532 730 291

391

Перенос данных из УПП 1.3 в БП 3.0. Переносятся документы (обороты за период), справочная информация и остатки

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:Управление производственным предприятием 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Управленческий учет Платные (руб)

Перенос данных из 1С:Управление производственным предприятием 1.3 в 1С:Бухгалтерия предприятия 3.0 с помощью правил обмена. Переносятся остатки, документы (обороты за период), справочная информация. Правила проверены на конфигурациях УПП 1.3 (1.3.226.x) и БП 3.0 (3.0.151.x). Правила подходят для версии ПРОФ и КОРП.

28000 руб.

15.12.2021 20603 137 38

SALE! 10%

Перенос данных из ERP 2 / КА 2 / УТ 11 в БП 3.0. Переносятся документы, начальные остатки и справочники

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Платные (руб)

Перенос данных из ERP в БП 3 | из КА 2 в БП 3 | из УТ 11 в БП 3 | из ЕРП в БП 3 | В продаже с 2019г. | Воспользовались более 176 предприятий! | Сэкономьте время - используйте готовое решение для перехода! | Перенос разработан в формате КД 2 (правила конвертации данных) | Переносятся все возможные виды документов, начальных остатков и нормативно-справочная информация| Можно опционально выгружать каждую пару "номенклатура+характеристика" как отдельную номенклатуру | Есть выгрузка настроек счетов учета и зарплатных данных из ERP / КА 2 | Можно проверить на вашем сервере перед покупкой, обращайтесь!

~~38500~~ 34650 руб.

15.04.2019 68820 179 139

111

Перенос данных из УТ 10.3 в УТ 11.5. Переносятся документы (обороты за период), справочная информация и остатки

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 Оперативный учет 1С:Управление торговлей 10 1С:Управление торговлей 11 Россия Управленческий учет Платные (руб)

Перенос данных из 1С:Управление торговлей 10.3 в 1С:Управление торговлей 11.5 с помощью правил обмена. Переносятся остатки, документы (обороты за период), справочная информация. Правила проверены на конфигурациях УТ 10.3 (10.3.87.x) и УТ 11.5 (11.5.16.x).

28000 руб.

23.07.2020 46751 199 64

162

SALE! 10%

Перенос данных из БП 3.0 в УТ 11 / КА 2 / ERP 2. Переносятся начальные остатки, документы и справочники

Обмен между базами 1C Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Платные (руб)

В продаже с 2014г. | Воспользовались более 122 предприятий! | Перенос данных из БП 3.0 в УТ 11 | из БП 3.0 в КА 2 | из БП 3.0 в ERP | Сэкономьте свое время - используйте готовое решение для перехода! | Постоянно работаем над развитием переноса данных | Обновляем на новые релизы 1С | Есть фильтр выгрузки по организациям | Переносятся начальные остатки на выбранную дату, документы за период времени и вся возможная справочная информация | Перенос сделан на технологии КД 2 (правила конвертации данных)

~~50722~~ 45650 руб.

31.10.2014 231878 124 327

296

SALE! 10%

Перенос данных из БП 3.0 в УНФ 3.0 / УНФ 1.6. Переносятся остатки, документы и справочная информация

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия 3.0 1С:Управление нашей фирмой 3.0 Россия Платные (руб)

В продаже с 2018г. | Воспользовались более 41 предприятия! | Правила конвертации (КД 2) для переноса данных из БП 3 в УНФ | Переносятся все виды документов, начальные остатки и вся возможная справочная информация | Есть фильтр по организациям | Оперативно обновляем на новые релизы | Оказываем техподдержку | В комплект файлов входит инструкция, авторская версия обработки "Универсальный обмен...", актуальные правила переноса данных и архив старых версий переноса | Учет в БП 3 должен быть корректным, некорректные данные не переносятся | Можно бесплатно проверить на вашем сервере до покупки!

50722 руб.

10.07.2018 67743 41 123

SALE! 10%

Перенос данных из ERP 2 / КА 2 в ЗУП 3. Переносятся остатки, документы и справочники

Обмен между базами 1C Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Россия Бухгалтерский учет Управленческий учет Платные (руб)

Перенос данных из ERP в ЗУП 3 | из КА 2 в ЗУП | Воспользовались более 79 предприятий! | Предлагаем приобрести готовые правила конвертации данных (КД 2) для переноса остатков, документов с движениями и справочной информации 3 | В продаже с 2020г. | Оперативно обновляем правила до актуальных релизов 1С | Есть перенос начальной задолженности по зарплате и начальной штатной расстановки на выбранную дату | Обороты за прошлые годы (данные для расчета среднего) переносятся свернуто в документ "Перенос данных" | Есть фильтр по организациям | Документы за текущий период переносятся сразу с движениями, поэтому не потребуется делать перерасчеты | Перенос можно проверить перед покупкой, обращайтесь!

~~48278~~ 43450 руб.

03.12.2020 34411 81 58

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. chg 10.12.19 10:13 Сейчас в теме

Добрый день.

Подскажите несколько вопросов по 3 версии, Бух и Зуп как понимаю это серверные части, соответственно клиент клиентская для любой конфы (с небольшими переделками) или нет?
По прежнему нужно публиковать базы на веб сервере?

2. hobi 616 10.12.19 17:06 Сейчас в теме

Добрый день.

Да, Бух и Зуп - это серверные части расширения. Отличаются только тем, что в них уже включены заимствованные объекты прикладных конфигураций (Контрагенты и проч.), к которым выполняется
обращение через сервис. Если использовать расширение без этих объектов, при выполнении
тестов из примера, на клиенте будут отображаться сообщения о недостаточных правах
к этим объектам.
Собственно части Бух и Зуп включены публикацию, чтобы примеры сразу заработали, без дополнительных действий по добавлению таких прикладных объектов в расширение.

Если базы уже были ранее опубликованы, то повторная публикация не обязательна. Потому что сам сервис не изменился, изменилось содержание алгоритмов, которые из него вызываются.

3. chg 11.12.19 03:10 Сейчас в теме

(2)под новые релизы вы расширения не изменяли? к примеру ЗуП 3.1.12
для синхронизации других элементов (справочники, регистры и т.д.) их необходимо заимствовать в расширение или что то нужно ещё в коде прописывать?
клиент под определённую конфигурацию нужно подгонять, так как ругается заимствования?

4. hobi 616 11.12.19 06:48 Сейчас в теме

Нет, расширение не изменял. Для новых релизов (ЗуП, Бух) нужно старые заимствования удалить и создать новые. Само расширение не привязано к каким-либо релизам и конкретной конфигурации, даже БСП не использует. Поэтому должно работать, только все прикладные объекты серверной конфигурации, к которым есть обращения из клиента, нужно заимствовать в расширении на сервере. И на самом клиенте, тоже - расширение "не знает" о прикладных объектах, к которым обращается, пока не выполнено заимствование. Эта операция выполняется чисто формально, выбором из меню. Никаких изменений в заимствованных объектах в расширении делать не обязательно.

5. hazyaka 21.06.20 09:06 Сейчас в теме

Для очереди исходящих сообщений используется регистр Сведений, правильно? Это нагрузка на 1с ку, возможные блокировки регистра сведений, который не отличается скоростью.. а если в качестве очереди использовать например это? https://infostart.ru/public/1250079/.. Service Broker ядра Microsoft SQL Server

6. hazyaka 21.06.20 15:13 Сейчас в теме

(5) но это будет уже другая программа с другой идеей.

7. hobi 616 22.06.20 08:48 Сейчас в теме

(5)
Да, очереди на регистрах сведений. Только вот проблем блокировками нет. Нужно просто "правильно их готовить". Какие могут быть блокировки, если один сеанс работает с регистром ?
Кроме того, составные ключи в регистрах для каждого сообщения не пересекаются.
Что касается "Service Broker ядра Microsoft SQL Server" - это будет работать только под Windows. А как же мобильные приложения, Linux ?
И, кроме того, через данный механизм уже без проблем ведутся интенсивные информационные обмены между двумя десятком баз данных (большие распределительные центры в разных городах + онлайновая синхронизация с аналитическими копиями для каждой базы).

8. hazyaka 22.06.20 09:03 Сейчас в теме

(7)

мобильные приложения

Я просто предложил идею, опцию развития системы.. Ваша система мне очень нравится. Поскольку я систему воспринимаю, как инструмент синхронизации баз, то MSSQL это распространенный стандарт.