Особенность при добавлении внешних отчетов в УНФ 1.6

23.12.21

Задачи пользователя - Менеджеры внешних отчетов

Добавляем внешний отчет в УНФ 1.6, Устанавливаем "тэги" для внешнего отчета в УНФ 1.6; устанавливаем "изображение образца" для внешнего отчета в УНФ 1.6.

Скачать файлы

Наименование Файл Версия Размер
Особенность при добавлении внешних отчетов в УНФ 1.6:
.erf 36,65Kb
5
.erf 36,65Kb 5 Скачать
Особенность при добавлении внешних отчетов в УНФ 1.6 (1.6.26.124):
.erf 36,66Kb
12
.erf 36,66Kb 12 Скачать

Коллеги, добрый день!

 

Тэги

Кто пользовался УНФ 1.6 наверное видел, что в этой конфигурации расположение внешних отчетов несколько отличается от привычного многим. Команды "Дополнительные отчеты" как например в БП 3.0 или УТ 11 в УНФ 1.6 - нет. Вместо этого (если включена функциональная опция "Использовать дополнительные отчеты и обработки") при входе в подраздел "Отчеты" присутствует кнопка "Внешние" (см. рис.1).

Для того, чтобы добавленный нами в конфигурацию внешний отчет появился в перечне внешних отчетов, у него должен быть установлен соответствующий "Тэг" (см. рис.2).

Немного про "Тэги" отчетов: "Тэги" в отчетах УНФ 1.6 используются как для определения местоположения отчета в разделе программы (есть теги соответствующие наименованиям разделов: "Продажи", "Закупки", "Зарплата" и т.д.), так и для быстрого поиска необходимого отчета (теги: "Запасы", "Заказы" и т.д.) (см. рис.3). Список всех отчетов и установленных для них тегов хранится в регистре сведений "Настройки варианта отчетов УНФ" (см. рис.4), увидеть который можно через "Все функции". И наша задача заключается в том, чтобы при добавлении внешнего отчета в этот регистр сведений записался нужный нам "Тег". Конечно же можно просто вручную указать "Тэг" в этом регистре сведений, но при таком варианте каждый раз при добавлении/обновлении внешнего отчета, нужно не забывать заходить в регистр сведений и указывать "Тэг".

Итак приступим, допустим у нас есть какой-то готовый внешний отчет на СКД, для начала нужно создать реквизит отчета "ЭтоОтчетУНФ" с типом булево (см. рис. 5). Далее заходим в модуль объекта и после обязательной функции "СведенияОВнешнейОбработке" (описывая сведения о внешней обработке/отчете можно по-старинке вручную заполнить "параметры регистрации", а можно с помощью общего модуля "ДополнительныеОтчетыИОбработки", в моём случае с помощью общего модуля), создаём экспортную процедуру "ПриОпределенииНастроекОтчета", в которой указываем "Теги" либо для конкретных вариантов отчета свои, либо для всех вариантов общие.

Пример кода, указываем теги для определённых вариантов отчета:

Процедура ПриОпределенииНастроекОтчета(НастройкиОтчета, НастройкиВариантов) Экспорт

	//Указываем "Теги" для варианта отчета "Основной"
	НастройкиВариантов["Основной"].Теги = НСтр("ru = 'Продажи,CRM'");

	//Указываем "Теги" для варианта отчета "Подробный"
	НастройкиВариантов["Подробный"].Теги = НСтр("ru = 'Продажи,CRM'");
	
КонецПроцедуры

Пример кода, указываем теги для всех вариантов отчета:

Процедура ПриОпределенииНастроекОтчета(НастройкиОтчета, НастройкиВариантов) Экспорт
	
	Для Каждого НастройкиТекВарианта Из НастройкиВариантов Цикл

		//Указываем "Теги" для всех вариантов отчета
		НастройкиТекВарианта.Значение.Теги = НСтр("ru = 'Продажи,CRM'");

	КонецЦикла;
	
КонецПроцедуры

В моём примере два варианта отчета: "Основной" и "Подробный" (см. рис. 6), и нет необходимости указывать разные "тэги", для разных вариантов отчета, поэтому будем использовать второй вариант.

 

Изображение образца отчета

Теперь разберёмся с изображениями образцов для внешних отчетов. Для того, чтобы добавить изображение образца в отчете нужно добавить макет с типом "Двоичные данные" (см. рис. 7). Далее нужно загрузить, заранее подготовленное изображение, в макет "Двоичные данные". Для этого кликаем два раза по макету, в появившемся окне жмём "Загрузить из файла" (см. рис. 8), указываем картинку и жмём "ОК". Изображение должно быть размером 580 x 366 пикселей, формат может быть: PNG или JPG, без разницы.

Далее, чтобы программа поняла, что ваше изображение нужно показывать пользователю в режиме "Предприятие" можно пойти двумя путями:  

1ый - указать имя макета образца следующим образом "Образец" + Имя варианта отчета.

Например, у нас два варианта отчета: "Основной" и "Подробный", и мы хотим для каждого варианта отдельную картинку, поэтому добавляем два макета типа "Двоичные данные", в каждый загружаем своё изображение и называем макеты "ОбразецОсновной" и "ОбразецПодробный" соответственно. Больше никаких "строк кода" не надо, всё уже заранее описано в общих модулях, при загрузке внешнего отчета в базу, у каждого варианта отчета будет своё изображение.

2ой - указать имя макета образца в, ранее описанной, экспортной процедуре "ПриОпределенииНастроекОтчета".

Пример кода, указываем имя макета для определённых вариантов отчета:

Процедура ПриОпределенииНастроекОтчета(НастройкиОтчета, НастройкиВариантов) Экспорт
	
	//Указываем "Изображение образца" для варианта отчета "Основной"
	НастройкиВариантов["Основной"].Вставить("ИмяМакетаОбразца", "ОбразецОсновной");
	
	//Указываем "Изображение образца" для варианта отчета "Подробный"
	НастройкиВариантов["Подробный"].Вставить("ИмяМакетаОбразца", "Подробный");
	
КонецПроцедуры

Пример кода, указываем имя макета для всех вариантов отчета:

Процедура ПриОпределенииНастроекОтчета(НастройкиОтчета, НастройкиВариантов) Экспорт
	
	Для Каждого НастройкиТекВарианта Из НастройкиВариантов Цикл
		
		//Указываем "Изображение образца" для всех вариантов отчета
		НастройкиТекВарианта.Значение.ИмяМакетаОбразца = "ОбразецОсновной";
		
	КонецЦикла;
	
КонецПроцедуры

В прилагаемом отчете, для варианта отчета "Основной" указано имя макета образца "ОбразецОсновной", то есть отработает общий модуль и для этого варианта изображение будет "выводиться само", а для варианта отчета "Подробный" указано имя макета образца "Подробный", поэтому для второго варианта отчета назначаем имя макета в процедуре "ПриОпределенииНастроекОтчета".

 

ЭтоОтчетУНФ

Далее, в тело модуля объекта (в самом конце модуля объекта внешнего отчета после всех процедур и функций) нужно для ранее созданного реквизита "ЭтоОтчетУНФ" установить значение "Истина":

ЭтоОтчетУНФ = Истина;

 

Очень важный момент!

В конфигураторе, в свойствах отчета (Действия - Свойства) не забываем указать "Хранилище вариантов" (см. рис. 9). Иначе, при добавлении отчета, программа будет ругаться, что не заполнено это свойство и отчет не будет виден.

После всего проделанного, когда внешний отчет будет добавлен в базу, в регистре сведений "Настройки варианта отчетов УНФ", для нашего отчета появятся теги: Продажи, CRM. Соответственно наш отчет будет виден в подразделе "Отчеты" в таких разделах как: "Продажи" и "CRM", а также каждый вариант отчета будет иметь собственное изображение (см. рис. 10).


Пример кода из модуля объекта целиком:

Функция СведенияОВнешнейОбработке() Экспорт
	
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке();
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиОтчет();
	ПараметрыРегистрации.Версия = "1.0";
	ПараметрыРегистрации.Наименование = "Анализ состояний заказов покупателей";
	ПараметрыРегистрации.Информация = "Анализ состояний заказов покупателей";
	
	Возврат ПараметрыРегистрации;
	
КонецФункции

Процедура ПриОпределенииНастроекОтчета(НастройкиОтчета, НастройкиВариантов) Экспорт
	
	//Указываем "Теги" для варианта отчета "Основной"
	//НастройкиВариантов["Основной"].Теги = НСтр("ru = 'Продажи,CRM'");
	//не используем, так как добавляем "Тэги" для всех вариантов ниже
	
	//Указываем "Теги" для варианта отчета "Подробный"
	//НастройкиВариантов["Подробный"].Теги = НСтр("ru = 'Продажи,CRM'");
	//не используем, так как добавляем "Тэги" для всех вариантов ниже
	
	
	//Указываем "Изображение образца" для варианта отчета "Основной"
	//НастройкиВариантов["Основной"].Вставить("ИмяМакетаОбразца", "ОбразецОсновной");
	//не используем, так как с указанным именем макета отработает Общий модуль
	
	//Указываем "Изображение образца" для варианта отчета "Подробный"
	НастройкиВариантов["Подробный"].Вставить("ИмяМакетаОбразца", "Подробный");
	
	
	Для Каждого НастройкиТекВарианта Из НастройкиВариантов Цикл
		
		//Указываем "Теги" для всех вариантов отчета
		НастройкиТекВарианта.Значение.Теги = НСтр("ru = 'Продажи,CRM'");
		
		//Указываем "Изображение образца" для всех вариантов отчета
		//НастройкиТекВарианта.Значение.ИмяМакетаОбразца = "ОбразецОсновной";
		//не используем, так как для каждого варианта отчета выводим своё изображение
		
	КонецЦикла;
	
КонецПроцедуры

ЭтоОтчетУНФ = Истина;

 

В качестве примера, прилагаю внешний отчет.

Про отчет: одному из клиентов очень важна корректность установки "Состояний" у заказов покупателей (на продажу), чтобы заказ покупателя был "успешно завершен", только когда полностью оплачен и отгружен. А так как в УНФ никак не контролируются состояния заказов покупателей и вручную можно установить что угодно, был написан этот простенький отчет.

Отчет тестировался на конфигурации УНФ 1.6, версии: 1.6.17.174; 1.6.18.88; 1.6.18.98; 1.6.18.168; 1.6.19.137.

 

Изменения начиная с версии УНФ 1.6.26.124

(возможно и раньше)

Коллеги, с недавних пор, в УНФ произошли небольшие изменения. Теперь "тэги" не влияют на расположение отчета в том или ином разделе. В настоящее время, "тэги" используются только для поиска отчета. Расположение отчета в разделах определяется при добавлении и сохранении отчета в программу. Но чтобы это можно было сделать, необходимо внести небольшие исправления в код экспортной функции "СведенияОВнешнейОбработке()" модуля объекта внешнего отчета. А именно, необходимо в параметрах регистрации указать, что вид дополнительной обработки/отчета теперь "ВидОбработкиДополнительныйОтчет()". Далее, всё остается без изменений.

Приведу сразу пример всего кода из модуля объекта нашего отчета:

Функция СведенияОВнешнейОбработке() Экспорт
	
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке();
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительныйОтчет();
	ПараметрыРегистрации.Версия = "2.0";
	ПараметрыРегистрации.Наименование = "Анализ состояний заказов покупателей";
	ПараметрыРегистрации.Информация = "Анализ состояний заказов покупателей";
	
	Возврат ПараметрыРегистрации;
	
КонецФункции

Процедура ПриОпределенииНастроекОтчета(НастройкиОтчета, НастройкиВариантов) Экспорт
	
	//Указываем "Теги" для варианта отчета "Основной"
	//НастройкиВариантов["Основной"].Теги = НСтр("ru = 'Продажи,CRM'");
	//не используем, так как добавляем "Тэги" для всех вариантов ниже
	
	//Указываем "Теги" для варианта отчета "Подробный"
	//НастройкиВариантов["Подробный"].Теги = НСтр("ru = 'Продажи,CRM'");
	//не используем, так как добавляем "Тэги" для всех вариантов ниже
	
	
	//Указываем "Изображение образца" для варианта отчета "Основной"
	//НастройкиВариантов["Основной"].Вставить("ИмяМакетаОбразца", "ОбразецОсновной");
	//не используем, так как с указанным именем макета отработает Общий модуль
	
	//Указываем "Изображение образца" для варианта отчета "Подробный"
	НастройкиВариантов["Подробный"].Вставить("ИмяМакетаОбразца", "Подробный");
	
	
	Для Каждого НастройкиТекВарианта Из НастройкиВариантов Цикл
		
		//Указываем "Теги" для всех вариантов отчета
		НастройкиТекВарианта.Значение.Теги = НСтр("ru = 'Продажи,CRM'");
		
		//Указываем "Изображение образца" для всех вариантов отчета
		//НастройкиТекВарианта.Значение.ИмяМакетаОбразца = "ОбразецОсновной";
		//не используем, так как для каждого варианта отчета выводим своё изображение
		
	КонецЦикла;
	
КонецПроцедуры

ЭтоОтчетУНФ = Истина;

 

После вышеуказанных изменений, при добавлении дополнительного отчета в базу, необходимо нажать кнопку "Записать" на вкладке "Варианты отчета" (см. рис. 11). Далее для каждого варианта отчета, нужно указать в его расположение в разделах программы (см. рис. 12).

 

В качестве примера прилагаю обновленный вариант отчета.

Отчет тестировался на конфигурации УНФ 1.6, версии: 1.6.26.124; 1.6.26.132.

УНФ внешний отчет СКД

См. также

"Мобильный ТСД" - инвентаризация и сбор штрихкодов для iOS и Android

Сканер штрих-кода Терминал сбора данных Мобильная разработка Монитор заказов Оптовая торговля Розничная торговля Ценообразование, анализ цен Платформа 1С v8.3 Мобильная платформа 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Розничная и сетевая торговля (FMCG) Оптовая торговля, дистрибуция, логистика Управленческий учет Платные (руб)

Простой мобильный терминал сбора данных для смартфонов на iOS и Android, не требующий сложных настроек и установки дополнительных программ. Обмен между Вашей 1С и мобильным приложением осуществляется через облачный сервис и расширение конфигурации. Работает с конфигурациями УТ 11, ERP, КА2, Розница 2, Розница 3, УНФ 1.6, УНФ 3.0. Полнофункциональный демо-доступ для своей конфигурации можно запросить в настройках мобильного приложения - все необходимое придет на почту автоматически.

2000 руб.

22.04.2019    91947    511    186    

293

Состояние обеспечения заказов 2021 для новых УТ 11.5, КА 2.5 и ERP 2.5

Логистика, склад и ТМЦ Рабочее место Монитор заказов Платформа 1С v8.3 Оперативный учет Управляемые формы 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Управленческий учет Платные (руб)

Хит продаж 2023 года! Расширение "Состояние обеспечения заказов 2021" добавляет дизайн и возможности "Состояние обеспечения заказов" из старых УТ 11.4 / КА 2.4 / ERP 2.4 в новые УТ 11.5 / КА 2.5 / ERP 2.5.

4900 руб.

20.09.2022    13418    37    34    

41

CASH DISPLAY 2.0: Дисплей покупателя под Windows, Android, Wi-Fi

Монитор заказов Оптовая торговля Розничная торговля Рабочее место Бытовые услуги, сервис Розничная и сетевая торговля (FMCG) Оптовая торговля, дистрибуция, логистика Ювелирная промышленность и торговля Платные (руб)

Используйте второй монитор или Android планшет в качестве дисплея покупателя на кассе для работы с клиентами и просмотра рекламы. Интеграция с любой версией 1С. Подходит для использования в торговой сети. Обновленная версия.

6000 руб.

20.01.2022    11296    15    21    

22

Статус, состояние заказа, визуальные галки - кружки оплат и отгрузки для журнала Заказов клиентов. УТ 11, КА 2, ERP 2

Монитор заказов Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Управленческий учет Платные (руб)

Вывод визуальных кругов-статусов состоянии для списка документов Заказы клиентов по оплате и отгрузке для конфигурации Управление торговлей 11, Комплексная автоматизация 2, ERP 2 через Расширение, что позволяет не снимать конфигурацию с поддержки и не иметь проблемы с обновлением в последующем.

2880 руб.

26.02.2020    24172    89    28    

59

Закупки, продажи, сколько осталось закупить УТ 11.4, КА 2.4, EPR 2.4,УТ 11.5, КА 2.5, EPR 2.5

Монитор заказов Логистика, склад и ТМЦ Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Управленческий учет Платные (руб)

Внешний отчет предназначен для получения текущей информации по товарным остаткам, закупленным товарам, продажам, резервам, а также заказам поставщику. УТ 11.4, КА 2.4, EPR 2.4,УТ 11.5, КА 2.5, EPR 2.5

3000 руб.

24.12.2021    5025    37    3    

6

Добавление отчета в расширение и вывод в меню отчетов на БСП на примере УТ 11.5

Менеджеры внешних отчетов Платформа 1С v8.3 1С:Управление торговлей 11 Россия Абонемент ($m)

Пример добавления отчета в расширение в типовые конфигурации на БСП на примере УТ 11.5, с добавлением в типовые меню отчетов.

1 стартмани

31.01.2024    840    DarkPinch222    0    

9
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. sdemon72 25 02.07.19 18:58 Сейчас в теме
Что-то не получается. Версия 1.6.17.174. Глобальным поиском не нашел даже вызов процедуры "ПриОпределенииНастроекОтчета"
2. dmitriy_saladin 132 03.07.19 11:32 Сейчас в теме
(1) Процедура "ПриОпределенииНастроекОтчета" находится в модуле объекта почти каждого отчета в конфигурации УНФ, и аналогичную нужно создать в модуле объекта внешнего отчета.
Desnyanka; sdemon72; +2 Ответить
3. sdemon72 25 03.07.19 16:04 Сейчас в теме
Ага. Прошу прощения, в поиске стояли фильтры, поэтому сначала ничего не нашел. Разобрался, вот этот текст я у вас прозевал: "для начала нужно создать реквизит отчета "ЭтоОтчетУНФ" с типом булево".
Создал реквизит, теперь все работает.
Большое спасибо!
user848218; +1 Ответить
4. dmitriy_saladin 132 03.07.19 16:06 Сейчас в теме
5. transt 1 16.07.19 05:26 Сейчас в теме
Ага, тоже на первом заходе пропустил про доп реквизит...
Сейчас "без гонки" внимательно перечитал и всё получилось!
Для справки: проверял сейчас на версии 1.6.9.36
6. Stepka1206 02.08.19 01:10 Сейчас в теме
Спасибо тебе добрый человек! думал уже я такой, а не лыжи...
7. Sersh2010 6 01.10.19 22:52 Сейчас в теме
В параметры регистрации для отчетов, команды передавать не обязательно, поэтому, если быть более кратким, то:
Функция СведенияОВнешнейОбработке() Экспорт
	
	Сведения = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке(СтандартныеПодсистемыСервер.ВерсияБиблиотеки());
	Сведения.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиОтчет();
	Сведения.Версия = "1.0";
	Сведения.Наименование = "Мой отчет";
	
	Возврат Сведения;
	
КонецФункции

Процедура ПриОпределенииНастроекОтчета(НастройкиОтчета, НастройкиВариантов) Экспорт
	НастройкиВариантов["ИмяВарианта"].Теги = "Продажи";
КонецПроцедуры

ЭтоОтчетУНФ = Истина;
Показать
dmitriy_saladin; +1 Ответить
8. dmitriy_saladin 132 08.10.19 10:43 Сейчас в теме
(7) Не совсем так, таблицу команд всё равно необходимо создать, но вот заполнять, действительно не обязательно.
В функции "СведенияОВнешнейОбработке", таблица как раз и создаётся.
9. pyrkin_vanya 488 02.12.19 21:46 Сейчас в теме
10. dmitriy_saladin 132 30.12.19 15:41 Сейчас в теме
Недавно кто-то спрашивал про вывод изображения образца, но правда после удалил комментарий. Всё же решил дописать статью, надеюсь кому-нибудь пригодится.
11. PavelKolobkov 25.03.20 17:27 Сейчас в теме
(10) Спасибо за подробную статью! Очень пригодилось!
12. Hellen_Aleksandrova 30.03.20 18:32 Сейчас в теме
Добрый день.

Релиз УНФ 1.6.18.145, платформы 8.3.15.1830.

Сделала внешний отчет с использованием ФормаОтчетаУНФ. При открытии через меню Файл-Открыть отчет отрабатывает "как надо".
Теперь нужно поместить отчет в расширение - добавила, туда же перенесла общую форму. Теперь при открытии ошибка :

Неверный первый параметр Ссылка в функции ОбщегоНазначения.ЗначенияРеквизитовОбъекта:
- Значение должно быть ссылкой или именем предопределенного элемента
{ОбщийМодуль.ОбщегоНазначения.Модуль(173)}: НСтр("ru = 'Неверный первый параметр Ссылка в функции ОбщегоНазначения.ЗначенияРеквизитовОбъекта:
{ОбщийМодуль.ОбщегоНазначения.Модуль(347)}: Результат = ЗначенияРеквизитовОбъекта(Ссылка, ИмяРеквизита, ВыбратьРазрешенные);
{ОбщаяФорма.ФормаОтчетаУНФ.Форма(323)}: ЗначениеРеквизитаПользовательский = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ДопВариант, "Пользовательский");


Попробовала вынести во внешний отчет - ошибка такая же. Спасите помогите.
13. dmitriy_saladin 132 30.03.20 20:08 Сейчас в теме
(12) Вы выбрали в качестве формы отчета общую форму: "ФормаОтчетаУНФ".
Попробуйте выбрать общую форму "ФормаОтчета".
14. Hellen_Aleksandrova 30.03.20 22:04 Сейчас в теме
(13) Форма открылась, но данные теперь неверно заполняются. Работа с параметрами периодов в этой форме отличается. Спасибо
15. user1338598 29.04.20 14:59 Сейчас в теме
Есть совсем простой способ. Возможно, кому-то подойдет.

Добавить теги и изображение внешнего отчета можно в режиме предприятия.

1. Добавляем внешний отчет
2. Через любой раздел открываем все отчеты, устанавливаем фильтр "Внешние", фильтр по разделу убираем
3. Вызываем контекстное меню нашего отчета, выбираем пункт "Настройки отчета"
4. Добавляем нужные теги (у меня - CRM и Продажи), описание, изображение
5. Теперь в разделах, указанных в тегах, в списке отчетов будет наш отчет с изображением

Минус этого способа - при обновлении внешнего отчета установленные выше настройки слетят и нужно будет их устанавливать заново.





lexxmaster; +1 Ответить
16. user1338598 29.04.20 15:00 Сейчас в теме
Есть совсем простой способ. Возможно, кому-то подойдет.

Добавить теги и изображение внешнего отчета можно в режиме предприятия.

1. Добавляем внешний отчет
2. Через любой раздел открываем все отчеты, устанавливаем фильтр "Внешние", фильтр по разделу убираем
3. Вызываем контекстное меню нашего отчета, выбираем пункт "Настройки отчета"
4. Добавляем нужные теги (у меня - CRM и Продажи), описание, изображение
5. Теперь в разделах, указанных в тегах, в списке отчетов будет наш отчет с изображением

Минус этого способа - при обновлении внешнего отчета установленные выше настройки слетят и нужно будет их устанавливать заново.
Прикрепленные файлы:
begemot; lexxmaster; umni4ka; dmitriy_saladin; user1401084; +5 Ответить
17. dmitriy_saladin 132 30.04.20 17:06 Сейчас в теме
(16) Да, но этот единственный минус, перекрывает все плюсы))
Бывает клиент говорит, а добавьте то, а переделайте это и т.д. и каждый раз эта свистопляска с тегами утомила. Поэтому решил разобраться, интересно же докопаться до истины, понять как это всё устроено и как работает.
18. ulterior 05.09.20 17:26 Сейчас в теме
Спасибо за статью.

через внешний отчет все получилось, а вот если отчёт добавить в конфигурацию, то не показывает в списке "Все отчёты" (т.е в регистр сведения "Настройки варианта отчетов УНФ" не попадают данные по моему отчёту), а отображается в Панели действий -> Отчёты (рис. в приложении)

редакция 1.6 (1.6.10.55)
Прикрепленные файлы:
19. dmitriy_saladin 132 07.09.20 09:11 Сейчас в теме
(18) Добрый день!
Статья и писалась именно про добавление внешнего отчета.
Плюс версия конфигурации у вас достаточно старая, возможно на тот момент использовались немного другие механизмы.
Могу лишь посоветовать посмотреть какой-либо встроенный отчет в вашей конфигурации и по аналогии сделать свой.
26. kvovka 32 14.05.21 09:15 Сейчас в теме
(18) Я руками сделал запись в регистре Настройки вариантов отчетов УНФ, добавил реквизит в отчет тип Булево - ЭтоОтчетУНФ, добавил функцию без тела:

Процедура ОбновитьНастройкиНаФорме(НастройкиОтчета, НастройкиСКД, Форма) Экспорт



КонецПроцедуры

После этого отчет появился, но без изображения.
20. compaud 28.10.20 13:32 Сейчас в теме
Пока не добавил в сведенияОВнешнейОбработки


	СтрокаКоманды = ПараметрыРегистрации.Команды.Добавить();	
	строкаКоманды.Идентификатор 		= ИмяОтчета;	
	строкаКоманды.Представление 		= Синоним;	
	строкаКоманды.ПоказыватьОповещение 	= Истина;	
	строкаКоманды.Использование 		= "ОткрытиеФормы";


отчет так и не появился в программе.


Еще вопрос чем вид "отчет" отличается от вида "ДополнительныйОтчет"?
У себя поставил "ДополнительныйОтчет"
21. dmitriy_saladin 132 29.10.20 10:54 Сейчас в теме
(20) В прочих конфигурациях (например в БП 3.0), если указать вид дополнительной обработки "Отчет", то отчет появляется в меню "Отчеты" на форме объекта или списка.
Если выбрать "Дополнительный отчет", то в списке соответствующих подсистем в меню "Сервис" - "Дополнительные отчеты".

Но в УНФ это всё лишено смысла, так как по сути, что "Отчет", что "Дополнительный отчет" всё работает одинаково.
В приведённом примере, я не стал указывать "Дополнительный отчет", так как в данном случае, при добавлении отчета появляются дополнительные настройки (пользовательская видимость и размещение в разделах), которые никак не функционируют и ни на что не влияют. И для того, чтобы эти "дополнительные настройки" не заводили людей в заблуждение, я указал просто "Отчет".

По поводу команды, только что всё проверил на последней УНФ (1.6.23.61), всё отлично работает и без неё.
22. zif74 11 05.11.20 21:09 Сейчас в теме
23. dmitriy_saladin 132 05.11.20 22:18 Сейчас в теме
24. user1232351 08.11.20 19:01 Сейчас в теме
25. user1232351 08.02.21 18:18 Сейчас в теме
Чтобы увидеть изменения отчетов, возможно нужно будет запустить Обновление отчетов в разделе Компания - Администрирование - Печатные формы, отчеты и обработки.
А то добавил картинку образца, а ничего не работало.
27. Светлый ум 406 05.08.21 07:11 Сейчас в теме
28. MIKE_V 27.08.21 13:20 Сейчас в теме
Почему-то хранилище вариантов не доступно для выбора в свойствах отчёта. Пусто, нет ничего. Как так ?
29. dmitriy_saladin 132 30.08.21 10:39 Сейчас в теме
(28) это очень странно, должно быть. Хранилище вариантов отчетов это объект типовой конфигурации УНФ 1.6.
30. vic_msu 05.09.21 12:58 Сейчас в теме
1С-ники убрали тэги из внешних отчетов. Как же они задолбали со своими полуфабрикатами и вечными переделками. Никому ненужная УНФ, от которой плюются и хотят сбежать большинство компаний ее использующие
31. dmitriy_saladin 132 05.09.21 15:00 Сейчас в теме
(30) Развернул демку версии 1.6.25.212, добавил внешний отчет из публикации, картинки встали, тэги на месте, не понимаю, что не так?
Если честно, уже почти год не работаю с УНФ, чему несказанно рад))
42. RustIG 1351 17.05.22 13:57 Сейчас в теме
(31)
Если честно, уже почти год не работаю с УНФ, чему несказанно рад))

Почему несказанно рады? И с какой конфигурацией у вас лучшие отношения?
33. Touch_Of_Soul 29 16.12.21 08:19 Сейчас в теме
(30)
Поделитесь пожалуйста как на релизе 1.6.26.162 теперь добавлять внешние отчеты и что в настройках изменилось так как этот метод что описан тут более не работает(
41. RustIG 1351 17.05.22 13:57 Сейчас в теме
(30)
Никому ненужная УНФ, от которой плюются и хотят сбежать большинство компаний ее использующие

Почему вы так считаете?

ПС. вот справочник внедрений - более 11 тыс.
https://1c.ru/solutions/public/
Прикрепленные файлы:
32. Touch_Of_Soul 29 16.12.21 08:18 Сейчас в теме
После обновления на релиз 1.6.26.162 этот метод больше не работает((( Все внешние отчеты перестали отображаться и работают теперь только через файл открыть(
Как исправить не могу понять, что изменилось.
34. dmitriy_saladin 132 16.12.21 10:25 Сейчас в теме
(32) Рано или поздно это должно было произойти))
Обещаю, в ближайшее время посмотрю.
35. Touch_Of_Soul 29 16.12.21 10:50 Сейчас в теме
(34)очень сильно жду. Все отчеты встали((
36. Touch_Of_Soul 29 16.12.21 14:12 Сейчас в теме
Теперь работает так
	#Область РегистрацияОтчета
	Функция СведенияОВнешнейОбработке() Экспорт

	ИмяОтчета = ЭтотОбъект.Метаданные().Имя; 
	Синоним = ЭтотОбъект.Метаданные().Синоним; 
	Синоним = ?(ЗначениеЗаполнено(Синоним),Синоним, ИмяОтчета);         
	РегистрационныеДанные = Новый Структура;
	РегистрационныеДанные.Вставить("Вид","ДополнительныйОтчет"); //может быть – ПечатнаяФорма, ЗаполнениеОбъекта (для вн.обработки), ДополнительныйОтчет, СозданиеСвязанныхОбъектов… 
	РегистрационныеДанные.Вставить("Наименование", Синоним); //имя под которым обработка будет зарегестрирована в справочнике внешних обработок
	РегистрационныеДанные.Вставить("Версия", "1.0");
	РегистрационныеДанные.Вставить("БезопасныйРежим", Ложь);
	РегистрационныеДанные.Вставить("Информация", "Отчет "+Синоним); //так будет выглядеть описание вн.отчета для пользователя
	ТаблицаКоманд = ПолучитьТаблицуКоманд();
	ДобавитьКоманду(ТаблицаКоманд, Синоним, "СформироватьОтчет" , "ОткрытиеФормы", Истина, );
	РегистрационныеДанные.Вставить("Команды", ТаблицаКоманд);

	Возврат РегистрационныеДанные;

	КонецФункции

	Функция ПолучитьТаблицуКоманд()

	Команды = Новый ТаблицаЗначений;
	Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка")); 
	Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
	Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
	Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
	Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));
	Возврат Команды;

	КонецФункции

	Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование = "ОткрытиеФормы", ПоказыватьОповещение = Ложь, Модификатор = "ПечатьMXL")
	НоваяКоманда = ТаблицаКоманд.Добавить();
	НоваяКоманда.Представление = Представление;
	НоваяКоманда.Идентификатор = Идентификатор;
	НоваяКоманда.Использование = Использование;
	НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
	НоваяКоманда.Модификатор = Модификатор;

	КонецПроцедуры 
	#КонецОбласти
Показать

И размещается так
Прикрепленные файлы:
37. dmitriy_saladin 132 16.12.21 15:32 Сейчас в теме
(36) Думаете вернулись к истокам и отказались от "тэгов"? Странно, надо посмотреть.
39. dmitriy_saladin 132 23.12.21 11:55 Сейчас в теме
(36) Коллега, ещё раз хочу выразить благодарность, за обнаруженные изменения в УНФ.
И хочу сообщить, что добавил изменения в публикацию.
38. AlenaSa 30 16.12.21 20:30 Сейчас в теме
Отличная статья! Спасибо автору!!
40. gamletspb 100 17.03.22 09:45 Сейчас в теме
Никто не в курсе, почему при добавлении своих внешних отчетов в форме настройки отчета пропадает пункт "Макет оформления"? Никак не могу понять, что за это отвечает? Релиз УНФ 1.6.26.213.
Прикрепленные файлы:
Оставьте свое сообщение