ArtemiFD

Функция ПолучитьКППОрганизацииИзСервиса(ИНН)
   
   // ДЕМО ПРИМЕР
   // --
   // Для получения информации по организации используем сервис https://dadata.ru/, требуется только регистрация;
   // выбрал findById (т.е.: "Организация по ИНН или ОГРН"),
   // информацию о сервисе смотри в документации: https://dadata.ru/api/find-party/,
   // в примере из всей информации получаю только КПП.
   // --
   // Стоимость: Бесплатно до 10 тысяч запросов в день. Больше — в составе годовой подписки.
   
   
   //******************
   //* Результат
   КПП = Неопределено;
   
   
   //******************
   //* НАСТРОЙКИ
   Токен = "тут должен быть токен";
   
   Прокси = Неопределено;
   //Прокси = Новый ИнтернетПрокси;
   //Прокси.Установить("https", "СЕРВЕР", ПОРТ);
   
   
   
   //******************
   //* ТЕЛО ОБРАБОТЧИКА
   
   SSL = Новый ЗащищенноеСоединениеOpenSSL();
   Попытка
      Соединение = Новый HTTPСоединение("suggestions.dadata.ru",,,, Прокси,, SSL);
   Исключение
      ИнфОш = ИнформацияОбОшибке();
      ВызватьИсключение КраткоеПредставлениеОшибки(ИнфОш);
   КонецПопытки;
   
   ДанныеЗапрса = Новый Структура("query", ИНН);
   ДанныеЗапрсаJSON = ЗначениеВСтрокуJSON(ДанныеЗапрса);
   
   АдресРесурса = "/suggestions/api/4_1/rs/findById/party";
   
   HTTPЗапрос = Новый HTTPЗапрос(АдресРесурса);
   HTTPЗапрос.Заголовки.Вставить("Content-Type" , "application/json; charset=utf-8");
   HTTPЗапрос.Заголовки.Вставить("Accept"       , "application/json");
   HTTPЗапрос.Заголовки.Вставить("Authorization", "Token " + Токен);
   HTTPЗапрос.УстановитьТелоИзСтроки(ДанныеЗапрсаJSON, КодировкаТекста.UTF8);
   
   Попытка
      HTTPОтвет = Соединение.ОтправитьДляОбработки(HTTPЗапрос);
   Исключение
      ИнфОш = ИнформацияОбОшибке();
      ВызватьИсключение КраткоеПредставлениеОшибки(ИнфОш);
   КонецПопытки;
   
   Если HTTPОтвет.КодСостояния = 200 Тогда 
      
      СтрокаJSON = HTTPОтвет.ПолучитьТелоКакСтроку(КодировкаТекста.UTF8);
      
      Значение = ЗначениеИЗСтрокиJSON(СтрокаJSON);
      
      ДанныеПоОрганизации  = Значение.suggestions[0];
      
      КПП = ДанныеПоОрганизации.data.kpp;
      
   КонецЕсли;
   
   Возврат КПП;
   
КонецФункции

Функция ЗначениеВСтрокуJSON(Значение)
   ЗаписьJSON = Новый ЗаписьJSON;
   ЗаписьJSON.УстановитьСтроку( Новый ПараметрыЗаписиJSON(, Символы.Таб));
   ЗаписатьJSON(ЗаписьJSON, Значение);
   Возврат ЗаписьJSON.Закрыть();
КонецФункции

Функция ЗначениеИЗСтрокиJSON(СтрокаJSON)
   ЧтениеJSON = Новый ЧтениеJSON;
   ЧтениеJSON.УстановитьСтроку(СтрокаJSON);
   Значение = ПрочитатьJSON(ЧтениеJSON);
   ЧтениеJSON.Закрыть();
   Возврат Значение;
КонецФункции

SEL ECT 
   CONVERT(dec(15,2), SUM(size)/(128.0 * 1024)) size 
FR OM sys.database_files;

SELECT  
   CONVERT (dec (15,2), SUM( Size * Growth * 1.0 / 1024) / 1024 / 1024) AS size
FROM sys.database_files;