MADINAABAZA

Функция ПолучитьДанныеДляПечатиСоглашение(МассивОбъектов)
   
   МассивСотрудников    = Новый Массив;
   МассивФизическихЛиц = Новый Массив;
   
   Если ТипЗнч(МассивОбъектов[0]) = Тип("ДокументСсылка.ПриемНаРаботу") Тогда
      Для каждого ПриемНаРаботу Из МассивОбъектов Цикл
         МассивСотрудников.Добавить(ПриемНаРаботу.Сотрудник);
         МассивФизическихЛиц.Добавить(ПриемНаРаботу.Сотрудник.ФизическоеЛицо);
      КонецЦикла; 
   ИначеЕсли ТипЗнч(МассивОбъектов[0]) = Тип("СправочникСсылка.Сотрудники") Тогда
      Для каждого Сотрудник Из МассивОбъектов Цикл
         МассивСотрудников.Добавить(Сотрудник);
         МассивФизическихЛиц.Добавить(Сотрудник.ФизическоеЛицо);
      КонецЦикла;   
   КонецЕсли; 
   
   
   МассивПараметров = Новый Массив;
   
   РеквизитыОрганизаций = Новый Соответствие;
   ДанныеСотрудников = КадровыйУчет.КадровыеДанныеСотрудников(Ложь, МассивСотрудников, "Должность,ФИОПолные,ИНН,Пол,ДатаПриема,ДатаУвольнения, Организация", ТекущаяДатаСеанса());
   
   ДанныеФизическихЛиц = КадровыйУчет.КадровыеДанныеФизическихЛиц(Ложь, МассивФизическихЛиц, "ДокументПредставление,СтраховойНомерПФР, АдресПоПропискеПредставление", ТекущаяДатаСеанса());
   
   Для каждого Сотрудник Из МассивСотрудников Цикл
   
      ПараметрыСотрудника = ПараметрыДанныеСотрудника();
      
      ПараметрыСотрудника.Ссылка = Сотрудник;
      
      ДанныеСотрудника    = ДанныеСотрудников.Найти(Сотрудник, "Сотрудник");
      ЗаполнитьЗначенияСвойств(ПараметрыСотрудника, ДанныеСотрудника);
      
      ДанныеФизЛица      = ДанныеФизическихЛиц.Найти(Сотрудник.ФизическоеЛицо, "ФизическоеЛицо");
      ЗаполнитьЗначенияСвойств(ПараметрыСотрудника, ДанныеФизЛица);
      
      Если НЕ ЗначениеЗаполнено(ДанныеСотрудника.Организация) Тогда
      
         Сообщение = Новый СообщениеПользователю;
         СообщениеТекст = НСтр("ru='У сотрудника %Замена% не удалось определить организацию'");
         СообщениеТекст = СтрЗаменить(СообщениеТекст, "%Замена%", Сотрудник);
         Сообщение.Текст = СообщениеТекст;
         Сообщение.Сообщить();   
         Продолжить;
      
      КонецЕсли; 
      
      РеквизитыОрганизации    = ПолучитьРеквизитыОрганизации(РеквизитыОрганизаций, ДанныеСотрудника.Организация, ТекущаяДатаСеанса());
      ЗаполнитьЗначенияСвойств(ПараметрыСотрудника, РеквизитыОрганизации);
      
      МассивПараметров.Добавить(ПараметрыСотрудника);
      
   КонецЦикла;
   
   Возврат МассивПараметров;
   
КонецФункции

Процедура ВывестиДанныСоглашениеВТабличныйДокумент(Макет, ТабличныйДокумент, МассивДанныхЗаполнения, ОбъектыПечати)
   
   Если Макет <> Неопределено Тогда
      
      ПервыйДокумент = Истина;
      Для каждого ПараметрыМакета Из МассивДанныхЗаполнения Цикл
         Если Не ПервыйДокумент Тогда
            ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
         Иначе
            ПервыйДокумент = Ложь;
         КонецЕсли;
         
         НомерСтрокиНачало = ТабличныйДокумент.ВысотаТаблицы + 1;
         
         Макет.Параметры.Заполнить(ПараметрыМакета);
         ТабличныйДокумент.Вывести(Макет);
         
         УправлениеПечатью.ЗадатьОбластьПечатиДокумента(ТабличныйДокумент, НомерСтрокиНачало, ОбъектыПечати, ПараметрыМакета.Ссылка);   
         
      КонецЦикла;
      
      ТабличныйДокумент.АвтоМасштаб          = Истина;
      ТабличныйДокумент.ДвусторонняяПечать    = ТипДвустороннейПечати.ПереворотВлево;
      
   КонецЕсли;
   
КонецПроцедуры

Функция ПолучитьТабличныйДокументСоглашение(Макет, МассивОбъектов, ОбъектыПечати, ВыводитьТорговыеТочки = Истина)
   
   ДокументРезультат = Новый ТабличныйДокумент;
   НомерСтрокиНачало = ДокументРезультат.ВысотаТаблицы + 1;
   
   ДокументРезультат.КлючПараметровПечати = "ПараметрыПечати_ОписьЛичногоДела";
   МассивДанныхЗаполнения = ПолучитьДанныеДляПечатиСоглашение(МассивОбъектов);   
   
   ВывестиДанныСоглашениеВТабличныйДокумент(Макет, ДокументРезультат, МассивДанныхЗаполнения, ОбъектыПечати);
   
   Возврат ДокументРезультат;
   
КонецФункции