Функция получения даты из текста по форматной строке

03.10.13

Разработка - Универсальные функции

Преобразует текст в дату при условии наличия форматной строки

Несколько громоздская, но полезная функция.

Добавил распознование строковых месяцев, но только на русском языке.

Очень красивое решение предоставил ildarovich, советую использовать сразу его код:

Функция СтрокаВДату(Знач ФорматДаты, Знач Дано, Ошибка = Ложь) Экспорт 
	Попытка 
		ё = Формат('00010101', "ДФ=" + ФорматДаты) // - необязательная проверка первого правильности параметра 
	Исключение 
		Ошибка = Истина; 
		Возврат '00010101' 
	КонецПопытки; 
	Ч = Новый Соответствие; 
	Для ё = 1 По СтрДлина(ФорматДаты) + 7 Цикл 
		Ч[Сред(ФорматДаты + "dMyHhms", ё, 1)] = 0	// - инициализация частей даты 
	КонецЦикла; 
	Для ё = 1 По 12 Цикл 
		Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMММ"), Формат(ё, "ЧЦ=4; ЧВН=")); // - замена названий месяцев числами 
		Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMМ" ), Формат(ё, "ЧЦ=3; ЧВН=")) 
	КонецЦикла; 
	Для ё = 1 По СтрДлина(ФорматДаты) Цикл 
		Ч[Сред(ФорматДаты, ё, 1)] = 10 * Ч[Сред(ФорматДаты, ё, 1)] + Найти("123456789", Сред(Дано, ё, 1)); // - накопление частей даты 
		Ошибка = Ошибка ИЛИ Найти("dMyHhms", Сред(ФорматДаты, ё, 1)) И НЕ Найти("0123456789", Сред(Дано, ё, 1)) // - необязательная проверка на цифры 
	КонецЦикла; 
	Ч["y"] = Ч["y"] + ?(Ч["y"] < 50, 2000, ?(Ч["y"] < 100, 1900, 0)); // - дополнение двух цифр года до четырех 
	Попытка 
		Возврат Дата(Ч["y"], Ч["M"], Ч["d"], Ч["H"] + Ч["h"], Ч["m"], Ч["s"]) 
	Исключение 
		Ошибка = Истина; 
		Возврат '00010101' 
	КонецПопытки 
КонецФункции

Моя функция:

Функция ПолучитьДатуИзТекста(Текст,ФорматнаяСтрока) Экспорт
	Перем Значение;
	
	ПустаяДата = '00010101';
	Год = 1; Месяц=1; День = 1; час = 0; Мин=0; Сек=0;
	тмпТекст = Текст;
	ЗначащиеСимволы = "dMyHhms";
	СтрокаПараметра = "";
	ФорматнаяСтрока = СокрЛП(ФорматнаяСтрока)+" ";
	ПредСимв = Лев(ФорматнаяСтрока,1);
	Для к=1 по СтрДлина(ФорматнаяСтрока) Цикл
		Симв = Сред(ФорматнаяСтрока,к,1);
		Если ПредСимв<>Симв Тогда
			Если Найти(ЗначащиеСимволы,ПредСимв)>0 Тогда
				//ЭтоПараметр
				Если СтрДлина(СтрокаПараметра)=2 Тогда
					Попытка
						Значение = Число(Лев(тмпТекст,2));
					Исключение
						#Если Клиент Тогда
							Предупреждение("Не удалось выполнить преобразование!");
						#КонецЕсли
						Возврат ПустаяДата;
					КонецПопытки;
					
					тмпТекст = Сред(тмпТекст,3);
				ИначеЕсли СтрокаПараметра="yyyy" Тогда
					Попытка
						Значение = Число(Лев(тмпТекст,4));
					Исключение
						#Если Клиент Тогда
							Предупреждение("Не удалось выполнить преобразование!");
						#КонецЕсли
						Возврат ПустаяДата;
					КонецПопытки;
					тмпТекст = Сред(тмпТекст,5);
				ИначеЕсли СтрДлина(СтрокаПараметра)=1 Тогда
					дл = "";
					Попытка
						Значение = Число(Лев(тмпТекст,2));
					Исключение
						Попытка
							Значение = Число(Лев(тмпТекст,1));
							дл=1;
						Исключение
							#Если Клиент Тогда
								Предупреждение("Не удалось выполнить преобразование!");
							#КонецЕсли
							Возврат ПустаяДата;
						КонецПопытки;
					КонецПопытки;
					
					Если дл="" Тогда
						Если (СтрокаПараметра = "d" и Значение>31)ИЛИ(СтрокаПараметра = "M" и Значение>12)ИЛИ(СтрокаПараметра = "H" и Значение>23)
							ИЛИ(СтрокаПараметра = "h" и Значение>12)ИЛИ(СтрокаПараметра = "m" и Значение>59)ИЛИ(СтрокаПараметра = "s" и Значение>59) Тогда
							Попытка
								Значение = Число(Лев(тмпТекст,2));
								дл=2;
							Исключение
								#Если Клиент Тогда
									Предупреждение("Не удалось выполнить преобразование!");
								#КонецЕсли
								Возврат ПустаяДата;
							КонецПопытки;
						Иначе
							Попытка
								Значение = Число(Лев(тмпТекст,1));
								дл=1;
							Исключение
								#Если Клиент Тогда
									Предупреждение("Не удалось выполнить преобразование!");
								#КонецЕсли
								Возврат ПустаяДата;
							КонецПопытки;
						КонецЕсли;	
					КонецЕсли;	
					
					тмпТекст = Сред(тмпТекст,дл+1);
				ИначеЕсли СтрокаПараметра="MMM" или СтрокаПараметра="MMMM" Тогда
					Значение = 0;
					Для м=1 по 12 Цикл
						ТекстМесяца = Сред(Формат(Дата(2000,м,1),"ДФ=d."+СтрокаПараметра),3);
						Если Найти(тмпТекст,ТекстМесяца)>0 Тогда
							Значение = м;
							Прервать;
						КонецЕсли;
					КонецЦикла;
					Если Значение = 0 Тогда
						#Если Клиент Тогда
							Предупреждение("Не удалось выполнить преобразование!");
						#КонецЕсли
						Возврат ПустаяДата;
					КонецЕсли;
					тмпТекст = Сред(тмпТекст,СтрДлина(ТекстМесяца)+1);
				Иначе
					#Если Клиент Тогда
						Предупреждение("Не верный формат даты или форматной строки!");
					#КонецЕсли
					Возврат ПустаяДата;
				КонецЕсли;
				
				//Установим параметры
				Если ПредСимв = "d" Тогда
					День = Значение;
				ИначеЕсли ПредСимв = "M" Тогда
					Месяц = Значение;
				ИначеЕсли ПредСимв = "y" Тогда
					Если СтрокаПараметра = "yy" Тогда
						ТекВек = 100*Цел(Год(ТекущаяДата())/100);
						год = ?(Значение>=Год(ТекущаяДата())-текВек+50,ТекВек-100,ТекВек)+Значение;
					Иначе
						Год = Значение;
					КонецЕсли;
				ИначеЕсли ПредСимв = "H" Тогда
					час = Значение;
				ИначеЕсли ПредСимв = "h" Тогда
					час = Значение;
					#Если Клиент Тогда
						Сообщить("Вычисление часа не гарантировано.");
					#КонецЕсли
				ИначеЕсли ПредСимв = "m" Тогда
					Мин = Значение;
				ИначеЕсли ПредСимв = "s" Тогда
					Сек = Значение;
				КонецЕсли;
				
			Иначе
				//Это Разделитель
				тмпТекст = Сред(тмпТекст,СтрДлина(СтрокаПараметра)+1);
			КонецЕсли;
			СтрокаПараметра = Симв;
		Иначе
			СтрокаПараметра=СтрокаПараметра+Симв;
		КонецЕсли;
		ПредСимв = Симв;
	КонецЦикла;
	Возврат Дата(Год,Месяц,День,час,Мин,Сек);
КонецФункции		

См. также

Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024    2670    0    John_d    8    

54

GUID в 1С 8.3 - как с ними быть

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.

12.02.2024    4607    atdonya    22    

45

Переоткрытие внешних обработок

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    3961    ke.92@mail.ru    16    

61

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8821    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2071    21    progmaster    7    

3

Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    16143    133    sapervodichka    112    

129

Система контроля ведения учета [БСП]

Универсальные функции Механизмы типовых конфигураций БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данном материале рассмотрим типовой алгоритм подсистемы контроля учета БСП в конфигурациях на примерах.

18.07.2022    7243    quazare    8    

109
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Поручик 4670 09.09.13 01:35 Сейчас в теме
(0) Вместо Предупреждение() лучше использовать Сообщить().
26. Eremkin 03.09.20 11:00 Сейчас в теме
(1)Вместо Сообщить() лучше использовать Новый СообщениеПользователю()
2. kapustinag 09.09.13 08:36 Сейчас в теме
(0) Вот в этом месте нужно более интеллектуально:
Если СтрокаПараметра = "yy" Тогда
Год = 2000+Значение;

Если Значение="99", то год должен быть 1999, а если ="13", то год 2013. Часто применяют сравнение с 50. Если значение меньше 50, то считаем нынешний век, а если больше - двадцатый век. Впрочем, это уже зависит от смысла ожидаемых данных. Может быть, на Ваших данных именно Ваше условие правильное.
6. Crazy Professor 24 24.09.13 08:58 Сейчас в теме
(2) kapustinag,
Кстати да, но я не знаю по какому принципу 1с сама это дело конвертирует у меня переключает на прошлый век с 30 включительно, но я не уверен, что это как-то зависит от текущей даты.

Сделал так:

ТекВек = 100*Цел(Год(ТекущаяДата())/100);
год = ?(Значение>=Год(ТекущаяДата())-текВек+50,ТекВек-100,ТекВек)+Значение;
3. ildarovich 7850 09.09.13 17:19 Сейчас в теме
В статье Выразить строку как число и строку как дату в запросе показано, как тоже самое можно сделать в запросе. Ну а данное решение нужно сократить раз в десять - объем кода не соответствует сложности решаемой задачи.
7. Crazy Professor 24 24.09.13 09:07 Сейчас в теме
(3) ildarovich,
Предложите готовое решение, пожалуйста - я с радостью его применю для своих целей.
Статья занятная, но не уверен, что универсальное решение будет менее громоздким чем обычный код. Однако, для больших объемов данных применение запроса может увеличить производительность.
11. ildarovich 7850 25.09.13 00:42 Сейчас в теме
(7) Вот готовое решение
//
Функция СтрокаВДату(Знач ФорматДаты, Знач Дано, Ошибка = Ложь) Экспорт
    Попытка 
        ё = Формат('00010101', "ДФ=" + ФорматДаты) // - необязательная проверка первого правильности параметра
    Исключение
        Ошибка = Истина;
        Возврат '00010101'
    КонецПопытки;
    Ч = Новый Соответствие;
    Для ё = 1 По СтрДлина(ФорматДаты) + 7 Цикл
        Ч[Сред(ФорматДаты + "dMyHhms", ё, 1)] = 0	// - инициализация частей даты
    КонецЦикла;
    Для ё = 1 По 12 Цикл
        Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMММ"), Формат(ё, "ЧЦ=4; ЧВН=")); // - замена названий месяцев числами
        Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMМ" ), Формат(ё, "ЧЦ=3; ЧВН="))
    КонецЦикла;
    Для ё = 1 По СтрДлина(ФорматДаты) Цикл
        Ч[Сред(ФорматДаты, ё, 1)] = 10 * Ч[Сред(ФорматДаты, ё, 1)] + Найти("123456789", Сред(Дано, ё, 1)); // - накопление частей даты
        Ошибка = Ошибка ИЛИ Найти("dMyHhms", Сред(ФорматДаты, ё, 1)) И НЕ Найти("0123456789", Сред(Дано, ё, 1)) // - необязательная проверка на цифры
    КонецЦикла;
    Ч["y"] = Ч["y"] + ?(Ч["y"] < 50, 2000, ?(Ч["y"] < 100, 1900, 0)); // - дополнение двух цифр года до четырех
    Попытка  
        Возврат Дата(Ч["y"], Ч["M"], Ч["d"], Ч["H"] + Ч["h"], Ч["m"], Ч["s"])
    Исключение
        Ошибка = Истина;
        Возврат '00010101'
    КонецПопытки
КонецФункции
//
Показать
ELInfinito; Simonov_NPM; rise; Valkiriyaaaa; Crazy Professor; bulpi; +6 Ответить
12. Crazy Professor 24 02.10.13 10:02 Сейчас в теме
(11) ildarovich,
Ну да, я ламмер, очень изящно - преклоняю колено.
15. kuzyara 1900 30.08.16 06:24 Сейчас в теме
(12) код (11) с ошибками.
Январь прописью не проходит, зачем-то "h" парсит и т.д.
13. Crazy Professor 24 02.10.13 10:03 Сейчас в теме
(11) ildarovich,
Можно вынести в шапку с указанием авторства? Вдруг кому нужно будет.
14. ildarovich 7850 02.10.13 11:05 Сейчас в теме
(13) Да, конечно, пожалуйста. Только просьба стандартные отступы восстановить (они пропали при вставке кода в комментарий).
25. rise 12.07.19 10:56 Сейчас в теме
(11) Круто, но к сожалению некорректно обрабатывает форматы "d" и "M", когда число знаков переменное. d.M.yyyy дает 12.7.2019

И в этой строке кажется надо в формат числа добавить ЧГ=0
Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMММ"), Формат(ё, "ЧЦ=4; ЧВН="));
4. spetzpozh 10.09.13 14:35 Сейчас в теме
Сообщить(), если учитывать рекомендации 1С, использовать не стоит вообще никогда :) СообщениеПользователю есть.
5. diver.sun 21 11.09.13 11:13 Сейчас в теме
Почитал, подумал, написал свой вариант, жутко не экономично, но зато абсолютно универсально
Процедура КнопкаВыполнитьНажатие(Кнопка)
	лФорматнаяСтрока = "Л=en; ДФ='yyyy МММ dd HH/mm/s'";
	лСтрокаДаты = "2013 Sep 11 09/58/5";
	
	
	лМассивДатНачальный = Новый Массив;
	лМассивДатНачальный.Добавить(1900);
	лМассивДатНачальный.Добавить(1);
	лМассивДатНачальный.Добавить(1);
	лМассивДатНачальный.Добавить(0);
	лМассивДатНачальный.Добавить(0);
	лМассивДатНачальный.Добавить(0);

	
	лДиапазонГода = ВернутьДиапазонЗначимыхЗначений(0,1999,2001,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,0,1900,2100,лФорматнаяСтрока,лДиапазонГода,лСтрокаДаты);
	
	лДиапазонМесяца = ВернутьДиапазонЗначимыхЗначений(1,1,12,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,1,1,12,лФорматнаяСтрока,лДиапазонМесяца,лСтрокаДаты);
	
	лДиапазонДаты = ВернутьДиапазонЗначимыхЗначений(2,1,31,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,2,1,31,лФорматнаяСтрока,лДиапазонДаты,лСтрокаДаты);
	
	лДиапазонЧаса = ВернутьДиапазонЗначимыхЗначений(3,0,23,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,3,0,23,лФорматнаяСтрока,лДиапазонЧаса,лСтрокаДаты);
	
	лДиапазонМинуты = ВернутьДиапазонЗначимыхЗначений(4,0,59,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,4,0,59,лФорматнаяСтрока,лДиапазонМинуты,лСтрокаДаты);
	
	лДиапазонСекунды = ВернутьДиапазонЗначимыхЗначений(5,0,59,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,5,0,59,лФорматнаяСтрока,лДиапазонСекунды,лСтрокаДаты);
	
	РезДата = Дата(лМассивДатНачальный[0],лМассивДатНачальный[1],лМассивДатНачальный[2],лМассивДатНачальный[3],лМассивДатНачальный[4],лМассивДатНачальный[5]);	
КонецПроцедуры

Процедура ПодобратьЗначение(пМассивПараметровДаты,лНомерПараметра,пСтарт,пСтоп,пФорматнаяСтрока,пСтрПоложения,пРазбираемаяСтрока)
	Если пСтрПоложения.С = -1 Тогда
		Возврат;
	КонецЕсли;
	Для Ном = пСтарт по пСтоп Цикл
		пМассивПараметровДаты[лНомерПараметра] = Ном;
		лДата = Дата(пМассивПараметровДаты[0],пМассивПараметровДаты[1],пМассивПараметровДаты[2],пМассивПараметровДаты[3],пМассивПараметровДаты[4],пМассивПараметровДаты[5]);
		лСтрПредставленияДаты = Формат(лДата,пФорматнаяСтрока);
		Если Сред(пРазбираемаяСтрока,пСтрПоложения.С,пСтрПоложения.По-пСтрПоложения.С+1) = Сред(лСтрПредставленияДаты,пСтрПоложения.С,пСтрПоложения.По-пСтрПоложения.С+1) Тогда
			Прервать;
		КонецЕсли;
	КонецЦикла;
КонецПроцедуры

Функция ВернутьДиапазонЗначимыхЗначений(лНомерПараметра,пСтарт,пСтоп,пФорматнаяСтрока)
	лМассивПараметров = Новый Массив;
	лМассивПараметров.Добавить(1900);
	лМассивПараметров.Добавить(1);
	лМассивПараметров.Добавить(1);
	лМассивПараметров.Добавить(0);
	лМассивПараметров.Добавить(0);
	лМассивПараметров.Добавить(0);
	лДатаНачальная = Дата(лМассивПараметров[0],лМассивПараметров[1],лМассивПараметров[2],лМассивПараметров[3],лМассивПараметров[4],лМассивПараметров[5]);
	лСтрПредставление = Формат(лДатаНачальная,пФорматнаяСтрока);
	
	лСтрРазностная = Новый Структура("С,ПО",10000,-1);
	
	Для лНом = пСтарт по пСтоп Цикл
		лМассивПараметров[лНомерПараметра] = лНом;
		лСтрНовая = Формат(Дата(лМассивПараметров[0],лМассивПараметров[1],лМассивПараметров[2],лМассивПараметров[3],лМассивПараметров[4],лМассивПараметров[5]),пФорматнаяСтрока);
		Если лСтрПредставление <> лСтрНовая Тогда
			СтрРазличий = ВернутьСтрРазличияВСтроках(лСтрПредставление,лСтрНовая);
			лСтрРазностная.С = Мин(лСтрРазностная.С,СтрРазличий.С);
			лСтрРазностная.ПО = Макс(лСтрРазностная.ПО,СтрРазличий.ПО);
		КонецЕсли;
	КонецЦикла;
	Если лСтрРазностная.С = 10000 Тогда
		лСтрРазностная.С = -1;
	КонецЕсли;
	Возврат лСтрРазностная; 
КонецФункции

Функция ВернутьСтрРазличияВСтроках(пСтрока1,пСтрока2)
	пПервыйРазличныйСимвол = -1;
	пПоследнийРазличныйСимвол = -1;
	Для Ном = 1 по СтрДлина(пСтрока1) Цикл
		Если Сред(пСтрока1,Ном,1) =  Сред(пСтрока2,Ном,1) И пПервыйРазличныйСимвол <> -1 Тогда
			пПоследнийРазличныйСимвол = Ном - 1;
			Прервать;
		ИначеЕсли Сред(пСтрока1,Ном,1) <>  Сред(пСтрока2,Ном,1) И пПервыйРазличныйСимвол = -1 Тогда
			пПервыйРазличныйСимвол = Ном;
		КонецЕсли;
	КонецЦикла;
	Если пПоследнийРазличныйСимвол = -1 Тогда
		пПоследнийРазличныйСимвол = СтрДлина(пСтрока1);
	КонецЕсли;
	Возврат Новый Структура("С,ПО",пПервыйРазличныйСимвол,пПоследнийРазличныйСимвол);
	
КонецФункции
Показать
8. Crazy Professor 24 24.09.13 09:37 Сейчас в теме
(5) diver.sun,
Чего-то я не понял как эта обработка должна отрабатывать при изменении порядка элементов форматной строки или вообще при исчезновении некоторых (например такой "yyMMdd", из данных с которыми я работаю). Но идея занятная - от обратного. В упрощенном варианте можно было перебирать все значения с точностью до секунды от -50 до +50 лет от текущей даты и искать подходящее через запрос :).
9. diver.sun 21 24.09.13 10:43 Сейчас в теме
Тогда она не находит позиции старта стопа изменяемого значения.
10. Crazy Professor 24 24.09.13 10:58 Сейчас в теме
(9) diver.sun, твой метод дал идею по распознаванию месяцев строкового формата.
16. Xershi 1474 20.04.18 16:46 Сейчас в теме
Кому интересно повозиться сервер вернул дату формата: "Tue, 10 Oct 2017 15:25:00 +0300".
Форматная строка выходит "Л=en; ДФ='ddd, dd MMM yyyy HH:mm:ss'" плюс часовой пояс.
17. smaharbA 08.11.18 17:14 Сейчас в теме
(16)
"Tue, 10 Oct 2017 15:25:00 +0300"


Пока СтрНайти(Стр,"  ")>0 Цикл
	Стр=СтрЗаменить(Стр,"  ","");
КонецЦикла;
МассивДаты=СтрРазделить(Стр," ");
Для ч=1 По 12 Цикл
	Стр=Прав("0"+ч,2);
	Если ВРег(МассивДаты[2])=ВРег(Формат(Дата("2018"+Стр+"01000000"),"Л=en; ДФ='MMM'")) Тогда
		Сообщить(Дата(МассивДаты[3]+Стр+МассивДаты[1]+СтрЗаменить(МассивДаты[4],":",""))+(60*60*5));
		Возврат;
	КонецЕсли;
КонецЦикла;
Показать
18. spacecraft 08.11.18 17:18 Сейчас в теме
(17)
Пока СтрНайти(Стр," ")>0 Цикл
Стр=СтрЗаменить(Стр," ","");
КонецЦикла;
МассивДаты=СтрРазделить(Стр," ");

Вот это можно описать одной строкой:
МассивДаты=СтрРазделить(Стр," ", Ложь);
19. smaharbA 14.11.18 15:57 Сейчас в теме
Можно, но лучче заменять все двойные пробелы на один.
20. spacecraft 14.11.18 16:40 Сейчас в теме
21. dobrynin.i.s 92 19.11.18 02:42 Сейчас в теме
функцию привожу из https://infostart.ru/public/886103/

Функция ПолучитьДатуВремяИзСтроки(ДатаВремя) Экспорт
	
	Результат = Неопределено;
	ДатаВремя = СтрЗаменить(ДатаВремя, "-", "");
	ДатаВремя = СтрЗаменить(ДатаВремя, ":", "");
	Если СтрДлина(ДатаВремя) - Найти(ДатаВремя, " ") = 5 Тогда // время в формате Ч:ММ:СС
		ДатаВремя = СтрЗаменить(ДатаВремя, " ", "0");
	ИначеЕсли Найти(ДатаВремя, "T") > 0 Тогда //время в формате ГГГГММДДTЧЧММСС
		ДатаВремя = СтрЗаменить(ДатаВремя, "T", "");
	Иначе // время в формате ЧЧ:ММ:СС
		ДатаВремя = СтрЗаменить(ДатаВремя, " ", "");
	КонецЕсли;
	
	ОписаниеТипа = Новый ОписаниеТипов("Дата");
	Результат = ОписаниеТипа.ПривестиЗначение(ДатаВремя);  // дата и время в виде "ГГГГММДДЧЧММСС"
	Если Не ЗначениеЗаполнено(Результат) Тогда
		Результат = ОписаниеТипа.ПривестиЗначение(Лев(ДатаВремя, 8));  // только дата "ГГГГММДД"
	КонецЕсли;

	Возврат Результат;
	
КонецФункции
Показать
22. user1040271 23.11.18 11:50 Сейчас в теме
(21)
Что-то не уверен, что эта функция универсальна, поскольку не задается ожидаемый формат.
Как он интерпретирует 11.11.11? Или 11.11 или 11?
Думаю, что она работает только с фиксированными форматами, используемыми в конкретно той задаче для работы с http
23. dobrynin.i.s 92 25.11.18 03:00 Сейчас в теме
(22)
в коде есть пояснения

11.11 или 11 - это вообще не даты.
11.11 ещё можно догадатся что 11.11.2018 - текущий год (2018), а
11 - что такое год , месяц, день или секунда
24. user1040271 26.11.18 10:25 Сейчас в теме
(23)
Об этом и речь - только по данным не всегда можно точно определить формат, особенно по единичному элементу этих данных.
Если есть ограниченный набор вариантов - то тут, конечно, не проблема: в коде отработать исключения (убрать "Т", например). Уверен, что большинство тут решало такие задачи в ходе своей практики.
Но универсальные методы на то и универсальные, что бы не привязываться к конкретным случаям.
27. prog2019 44 29.10.21 15:05 Сейчас в теме
Что-то не работает функция, которая приведена вверху как образец.

ПервоначальнаяСтрока = "2021-10-28 22:47:38"

Достаточно убрать разделители из строки:
			СтрокаДатаТочки = СтрЗаменить(ПервоначальнаяСтрока, "-", "");
			СтрокаДатаТочки = СтрЗаменить(СтрокаДатаТочки, " ", "");
			СтрокаДатаТочки = СтрЗаменить(СтрокаДатаТочки, ":", "");
			НужнаяДата = Дата(СтрокаДатаТочки);

и всё работает.
28. IvStark 19.01.22 16:38 Сейчас в теме
В Функции СтрокаВДату, в строках:
Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMММ"), Формат(ё, "ЧЦ=4; ЧВН=")); // - замена названий месяцев числами 
Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMМ" ), Формат(ё, "ЧЦ=3; ЧВН=")) 

значения форматной строки содержат как латиницу, так и кириллицу (переведено в нижний регистр для наглядности):
"ДФ=mmмм" и "ДФ=mmм" 

На старых платформах с такой форматной строкой работает некорректно, например, у нас на 8.3.11.3034.
И функция "СтрокаВДату" коверкает дату и выдаёт ошибочную. Нужно исправить форматные строкм на "ДФ=ММММ" "ДФ=МММ".
А например, на 8.3.18.1563 всё работает, функция "Формат" не различает латиницу и кириллицу в форматной строке.
29. fixin 4252 09.08.22 15:08 Сейчас в теме
Вот мои функции, делюсь:
Функция СтрокаДаты_ДД_ММ_ГГГГ_ВДату(Строка)
    Д = Число(Сред(Строка, 1, 2));
    М = Число(Сред(Строка, 4, 2));
    Г = Число(Сред(Строка, 7, 4));
    Возврат Дата(Г, М, Д);
    
КонецФункции

Функция СтрокаДаты_ГГГГ_ММ_ДД_ВДату(Строка)
    Д = Число(Сред(Строка, 9, 2));
    М = Число(Сред(Строка, 6, 2));
    Г = Число(Сред(Строка, 1, 4));
    Возврат Дата(Г, М, Д);
    
КонецФункции

Функция ДатаИзСтрокиСНазваниемМесяца(ДатаСтрокой) Экспорт     
    //Из строки вида 2 октября 2022
    М = СтрРазделить(СокрЛП(ДатаСтрокой), " ", ложь);
    Если М.Количество() = 3 Тогда
        Попытка                         
            День = Число(СокрЛП(М[0]));
            Месяцы = Новый Массив();
            Месяцы.Добавить("ЯНВАРЯ"); Месяцы.Добавить("ФЕВРАЛЯ"); Месяцы.Добавить("МАРТА");
            Месяцы.Добавить("АПРЕЛЯ"); Месяцы.Добавить("МАЯ"); Месяцы.Добавить("ИЮНЯ");
            Месяцы.Добавить("ИЮЛЯ"); Месяцы.Добавить("АВГУСТА"); Месяцы.Добавить("СЕНТЯБРЯ");
            Месяцы.Добавить("ОКТЯБРЯ"); Месяцы.Добавить("НОЯБРЯ"); Месяцы.Добавить("ДЕКАБРЯ");
            Месяц = Месяцы.Найти(Врег(СокрЛП(М[1]))) + 1;
            Год = Число(СокрЛП(М[2]));
        Возврат Дата(Год, Месяц, День);
        Исключение
        КонецПопытки;
    КонецЕсли;
    Возврат Дата(1, 1, 1);
КонецФункции
Показать
30. yuranxy 26.12.23 17:19 Сейчас в теме
Немного допилил функцию от ildarovich, теперь можно распознать месяцы на разных языках

Функция СтрокаВДатуПоФорматнойСтроке(Знач ФорматнаяСтрока, Знач ДатаСтрока, ЯзыкФорматнойСтроки = "ru_RU", Отказ = Ложь)
	
	Язык = "Л=" + ЯзыкФорматнойСтроки +";"; // код языка брать из конструктора форматной строки
	
	Попытка 
        Сч = Формат('00010101', "ДФ=" + ФорматнаяСтрока) // - необязательная проверка первого правильности параметра
    Исключение
        Отказ = Истина;
        Возврат '00010101'
    КонецПопытки;
	
	Ч = Новый Соответствие;
	
	Для Сч = 1 По СтрДлина(ФорматнаяСтрока) + 7 Цикл
        Ч[Сред(ФорматнаяСтрока + "dMyHhms", Сч, 1)] = 0 // - инициализация частей даты
    КонецЦикла;
	
	Для Сч = 1 По 12 Цикл
        ДатаСтрока = СтрЗаменить(ДатаСтрока, Формат(Дата(1, Сч, 2), Язык + "ДФ=MMММ"), Формат(Сч, "ЧЦ=4; ЧВН=")); // - замена названий месяцев числами
        ДатаСтрока = СтрЗаменить(ДатаСтрока, Формат(Дата(1, Сч, 2), Язык + "ДФ=MMМ" ), Формат(Сч, "ЧЦ=3; ЧВН="))
    КонецЦикла;
	
	Для Сч = 1 По СтрДлина(ФорматнаяСтрока) Цикл
        Ч[Сред(ФорматнаяСтрока, Сч, 1)] = 10 * Ч[Сред(ФорматнаяСтрока, Сч, 1)] + Найти("123456789", Сред(ДатаСтрока, Сч, 1)); // - накопление частей даты
        Отказ = Отказ ИЛИ Найти("dMyHhms", Сред(ФорматнаяСтрока, Сч, 1)) И НЕ Найти("0123456789", Сред(ДатаСтрока, Сч, 1)) // - необязательная проверка на цифры
    КонецЦикла;
	
	Ч["y"] = Ч["y"] + ?(Ч["y"] < 50, 2000, ?(Ч["y"] < 100, 1900, 0)); // - дополнение двух цифр года до четырех
	
	Попытка  
        Возврат Дата(Ч["y"], Ч["M"], Ч["d"], Ч["H"] + Ч["h"], Ч["m"], Ч["s"])
    Исключение
        Отказ = Истина;
        Возврат '00010101'
	КонецПопытки
	
КонецФункции

Показать
Оставьте свое сообщение