Как загрузить TXT файл ?

// ===============================
Процедура ДанныеВТбЗн(ИмяФайла,ТбЗн,Разделитель,ПропуститьСтрок)  
   
   Т = СоздатьОбъект("Текст");
   Если ФС.СуществуетФайл(ИмяФайла)=0 Тогда
      Предупреждение("Не могу найти файл данных "+ ИмяФайла + РазделительСтрок +
      "Проверьте каталог импорта.");
      Возврат;
   КонецЕсли;
   Т.Открыть(ИмяФайла);
   Если Т.КоличествоСтрок()=0  Тогда
      Предупреждение("Файл данных "+ИмяФайла+" пуст!");
      Возврат;
   КонецЕсли;
   НомСтр=0;
   Для С=1 По Т.КоличествоСтрок() Цикл  
      Если С <= ПропуститьСтрок Тогда  
         Продолжить;
      КонецЕсли;
      Данные=Т.ПолучитьСтроку(С);  
      Если СокрЛП(Данные)<>"" Тогда
         СтрТмп = Данные;
         НомСтр=НомСтр+1;
         ТбЗн.НоваяСтрока(НомСтр);
         НомКол = 0;
         Пока СтрДлина(СтрТмп) <> 0 Цикл
            Поз = Найти(СтрТмп,Разделитель);
            Если Поз <> 0 Тогда
               НомКол = НомКол + 1;  
               Попытка
                  ТбЗн.УстановитьЗначение(НомСтр,НомКол, Сред(СтрТмп,1,Поз-1));
               Исключение   
                  Сообщить("Не загружена колонка "+СокрЛП(Строка(НомКол))+", недостаточно колонок в таблице значений.");
               КонецПопытки;            
               СтрТмп = Сред(СтрТмп,Поз+1,СтрДлина(СтрТмп)-Поз);
            Иначе
               НомКол = НомКол + 1;
               ТбЗн.УстановитьЗначение(НомСтр, НомКол, СтрТмп);
               СтрТмп = "";
            КонецЕсли;
         КонецЦикла;
      КонецЕсли;           
   КонецЦикла;
КонецПроцедуры
            
ФайлИмпорта = "C:\import.txt";   
Разделитель = ",";
КоличествоКолонок = 10;
ПропуститьСтрок = 0; // если есть шапка (описание полей) указать сколько строк пропустить
ТбЗн = СоздатьОбъект("ТаблицаЗначений");
ТбЗн.КоличествоКолонок(КоличествоКолонок);
ДанныеВТбЗн(ФайлИмпорта,ТбЗн,Разделитель,ПропуститьСтрок);