Построитель отчета

16.03.09

Разработка - Механизмы платформы 1С

Вот тут статейку в инете нашел, решил выложить. По построителю не так много информации.

Построитель отчета

Автор: Печенкин Роман

1. Что такое построитель отчета?

Построитель отчета — это объект, позволяющий на основе заданного текста запроса и настроек получить результат и вывести его в табличный документ или диаграмму.

Настройки построителя отчета включают:

  • группировки (пример: “Номенклатура”, “Контрагент”…),
  • показатели (пример: “Количество”, “Сумма”…),
  • дополнительные поля (пример: “Номенклатура.Услуга”, “Контрагент.Код”…),
  • фильтр (пример: по конкретной номенклатуре, по группе контрагентов…) и
  • сортировка (пример: “Номенклатура.Код”, “Контрагент.Наименование”…)

Настройки построителя имеют средства визуализации, что позволяет программисту с минимальными трудозатратами предоставить пользователю интерфейс для их установки.

Перед выводом макет построителя отчета можно оформить с помощью макета оформления.

Вывод результата выполнения запроса построителя отчета осуществляется одной командой.

2. Где можно использовать построитель отчета?

С помощью построителя отчета можно проектировать основную массу отчетов (пример: “Остатки товаров”, “Продажи за период”…). При этом время на их разработку и программный код существенно сократятся, а качество оформления и функциональность — повысятся.

Кроме того, построитель отчета можно использовать в тех случаях, когда не нужен вывод результата, но требуется настройка пользователем элементов запроса, к примеру, группировок или фильтра (пример: выгрузка номенклатуры в xml-файл или обработка проведения документов по заданному фильтру).

Поскольку построитель отчета недоступен на сервере 1С:Предприятия и не используется в модуле внешнего соединения, то в этих случаях необходимо использовать построитель запроса, который аналогичен построителю отчета, но не имеет визуальных свойств и методов (“Макет”, “ВыводитьЗаголовокОтчета”, “Вывести()”, “ОформитьМакет()”…).

3. Немного о понятиях

По сравнению с версией 7.7 в версии 8.0 произошла небольшая смена понятий, поэтому стоит немного остановиться на этом.

Понятие
Описание
Измерения строки Список группировок, по которым будет осуществляться вывод по строкам (пример: “Номенклатура”, “Контрагент”…)
Измерения колонки Список группировок, по которым будет осуществляться вывод по колонкам (пример: “Склад”, “Месяц”…).
Отбор Набор различных фильтров (пример: по группе контрагентов, по заданной организации…).
Порядок Набор полей сортировки (пример: “Номенклатура.Код”, “ДокументПродажи.Ответственный”…).
Поле Одно из полей выборки запроса (пример: “Номенклатура”, “Контрагент.Код”, “Количество”, “Сумма”…).
Выбранные поля Список выбранных полей, включает в себя показатели (пример: “Количество”, “Сумма”…) и дополнительные поля (реквизиты группировок) (пример: “Номенклатура.Группа”, “Контрагент.Код”…).
Доступные поля Список полей, доступных для добавления в группировки, фильтр, сортировку и выбранные поля. Заполняется, как правило, списком полей выборки запроса, но может быть программно отредактирован (можно добавлять, изменять и удалять доступные поля).

Важно понимать, что поля группировки, фильтра, сортировки и выбранные поля не связаны напрямую с доступными полями, это разные объекты.

Главное отличие заключается в том, что доступное поле не имеет свойства “ПутьКДанным” (пример: “Номенклатура.Код”, “Количество”), так как это просто своеобразное описание поля, по которому будет произведена попытка найти соответствие среди полей выборки запроса в момент добавления его в список группировок, фильтра, сортировки или выбранных полей.

При этом нет возможности программно добавить одно из доступных полей в какой-либо из вышеперечисленных списков, так как, с одной стороны, у доступного поля нет методов а-ля “ДобавитьВОтбор()” или “ДобавитьВВыбранныеПоля()”, а, с другой стороны, при добавлении нового элемента в любой из вышеперечисленных списков требуется указать свойство “ПутьКДанным”, которое не всегда совпадает с именем поля (пример: поля “Номенклатура.Родитель” и “Номенклатура.Родитель.Родитель” имеют одинаковое имя “Родитель”).

4. Типовой вариант использования построителя отчета

В общем случае последовательность действий при работе с построителем отчета следующая:

  1. Создать новый объект “ПостроительОтчета”;
  2. Присвоить свойству “Текст” текст запроса;
  3. Если в тексте запроса не были заданы настройки построителя отчета, то выполнить метод “ЗаполнитьНастройки()”;
  4. Предоставить пользователю возможность изменения настроек построителя отчета;
  5. При необходимости можно отказаться от автогенерации макета построителем отчета и присвоить свойству “Макет” фиксированный макет;
  6. При необходимости можно присвоить свойству “МакетОформления” один из стандартных или свой макет, при этом, если автогенерируемый макет построителя отчета был заменен на фиксированный, то выполнить метод “ОформитьМакет()”;
  7. Вызвать метод “Выполнить()”;
  8. Вызвать метод “Вывести()”.

Пример:

Построитель = Новый "ПостроительОтчета";
Построитель.Текст = 
"ВЫБРАТЬ РАЗРЕШЕННЫЕ
|	ДенежныеСредстваКомпанииОстатки.СтруктурнаяЕдиница,
|	СУММА(ДенежныеСредстваКомпанииОстатки.СуммаОстаток) КАК Сумма
|
|ИЗ
|	РегистрНакопления.ДенежныеСредстваКомпании.Остатки(, {СтруктурнаяЕдиница.*})
|
|СГРУППИРОВАТЬ ПО
|	ДенежныеСредстваКомпанииОстатки.СтруктурнаяЕдиница
|
|ИТОГИ СУММА(Сумма) ПО
|	ОБЩИЕ,
|	СтруктурнаяЕдиница";
Построитель.ЗаполнитьНастройки();
//Здесь можно дать пользователю возможность
//изменить настройки построителя отчета
Построитель.Макет = ПолучитьМакет("СвойМакет");
Построитель.МакетОформления = ПолучитьМакетОформления(СтандартноеОформление.Классика);
Построитель.ОформитьМакет();
Построитель.Выполнить();
Построитель.Вывести();

5. Описание некоторых свойств построителя отчета

Свойство
Описание
Текст Содержит текст запроса построителя отчета. Если текст запроса построителя отчета не содержит элементов настройки “{…}”, то можно с помощью метода “ЗаполнитьНастройки()” автоматически заполнить настройки на основе текста запроса.
ТекстЗаголовка Текст, который будет выводиться в заголовке отчета (пример: “Остатки товаров на 01.01.2004”, “Продажи за январь 2004 года”…).
ВыводитьЗаголовокОтчета
ВыводитьШапкуТаблицы
ВыводитьОбщиеИтоги
ВыводитьПодвалТаблицы
ВыводитьПодвалОтчета
Эти свойства определяют, будут ли выводиться, соответственно, заголовок отчета, шапка таблицы, общие итоги, подвал таблицы и подвал отчета.
ВыводитьДетальныеЗаписи Свойство отвечает за принудительный вывод или запрет вывода детальных записей.
АвтоДетальныеЗаписи Если свойство “АвтоДетальныеЗаписи” установить в Истина, то каждая детальная запись будет выводиться только в том случае, если она отличается от групповой.
ДоступныеПоля Содержит список полей, доступных для добавления в группировки, фильтр, выбранные поля и сортировку.
ИзмеренияСтроки
ИзмеренияКолонки
Содержат список группировок, соответственно, по строкам и по колонкам.
Отбор Содержит список фильтров, заданных построителю отчета.
ВыбранныеПоля содержит список выбранных показателей и реквизитов группировок.
Порядок содержит список полей сортировки.
Параметры Содержит список параметров построителя (объявленных в тексте запроса построителя с помощью символа “&”).
Результат Содержит результат выполнения запроса построителя отчета (объект типа РезультатЗапроса).

6. Обработка Расшифровки с помощью построителя отчета

Свойство “ЗаполнениеРасшифровки” содержит один из трех вариантов заполнения расшифровки при выводе:

1-ый вариант: не заполнять (не использовать расшифровку).

2-ой вариант: значения группировок (при расшифровке ячейки будет открываться значение группировки, выведенное в ней).

3-ий вариант: расшифровка (расшифровка будет заполняться структурой, содержащей значения всех группировок). В этом случае требуется обрабатывать событие табличного документа “Обработка расшифровки”, где нужно анализировать переданную структуру и выполнять те или иные действия.

Важным моментом является то, что в третьем варианте нельзя осуществлять вывод в генерируемый табличный документ, так как тогда невозможно обработать расшифровку, обработка события которой происходит в модуле той формы, на которой расположено поле табличного документа.

Если используется третий вариант заполнения расшифровки, то можно использовать метод “НастроитьРасшифровку()”, предназначенный для того, чтобы выполнить и вывести отчет с учетом расшифровки, выполненной пользователем.

Построитель отчета может использоваться тот же самый или новый. При настройке расшифровки все фильтры настраиваемого построителя отчета будут удалены и добавлены все установленные фильтры исходного построителя запроса плюс фильтры по значениям группировок из расшифровки.

Пример:

Процедура РезультатТаблицаОбработкаРасшифровки 
                                                       (Элемент, Расшифровка, СтандартнаяОбработка)

              СтандартнаяОбработка = Ложь;

              Построитель.НастроитьРасшифровку(Построитель, Расшифровка);
              Построитель.Выполнить();
              Построитель.Вывести();

КонецПроцедуры

7. Оформление отчета

Свойство “Макет” содержит макет, который используется при выводе результата в табличный документ. Если Неопределенно, то макет генерируется автоматически.

Свойства “МакетЗаголовкаОтчета”, “МакетШапкиТаблицы”, “МакетДетальныхЗаписей”, “МакетОбщихИтогов”, “МакетПодвалаТаблицы” и “МакетПодвалаОтчета” содержат имя области в макете построителя отчета или отдельные макеты, используемые при выводе, соответственно, заголовка отчета, шапки таблицы, детальных записей, общих итогов, подвала таблицы и подвала отчета в табличный документ. Если имена областей соответствуют именам в макете построителя отчета, то свойства заполнять не требуется.

Свойство “МакетОформления” содержит макет, используемый для оформления макета построителя отчета. Оформление ячеек в макете оформления будет применено к ячейкам макета построителя отчета.

Для получения одного из стандартного вариантов оформления можно использовать метод глобального контекста “ПолучитьМакетОформления()”.

В случае, если свойству “Макет” построителя отчета был присвоен фиксированный макет, для его оформления требуется выполнить метод “ОформитьМакет()”.

Свойство “РазмещениеИзмеренийВСтроках определяет один из трех вариантов вывода группировок по строкам.
1-ый вариант: вместе (в одной колонке).
Пример:



2-ой вариант: отдельно (в разных колонках).
Пример:



3-ий вариант: отдельно и только в итогах.
Пример:

Свойство “РазмещениеИзмеренийВКолонках” определяет один из трех вариантов вывода группировок по колонкам.
1-ый вариант: вместе (в одной строке).
Пример:



2-ой вариант: отдельно (в разных строках).
Пример:

3-ий вариант: отдельно и только в итогах.
Пример:



Свойство “РазмещениеИтоговВСтроках” определяет один из четырех способов вывода итогов в строках.
1-ый вариант: в заголовке (только выше последующих группировок и детальных записей).



2-ой вариант: в заголовке и подвале (выше и ниже последующих группировок и детальных записей).



3-ий вариант: в подвале (ниже последующих группировок и детальных записей, выше них выводится только описание группировки).



4-ый вариант: только в подвале (только ниже последующих группировок и детальных записей).



Свойство “РазмещениеИтоговВКолонках” определяет один из четырех способов вывода итогов в колонках.

1-ый вариант: в заголовке (только левее последующих группировок и детальных записей).



2-ой вариант: в заголовке и подвале (левее и правее последующих группировок и детальных записей).



3-ий вариант: в подвале (правее последующих группировок и детальных записей, левее них выводится только описание группировки).



4-ый вариант: только в подвале (только правее последующих группировок и детальных записей).



Свойство “РазмещениеРеквизитовИзмеренийВСтроках” определяет один из трех вариантов вывода реквизитов группировок по строкам.

1-ый вариант: вместе (в одной дополнительной колонке).
Пример:



2-ой вариант: вместе с измерениями (в колонках с группировками).
Пример:



3-ий вариант: отдельно (в разных дополнительных колонках).
Пример:



Свойство “РазмещениеРеквизитовИзмеренийВКолонках” определяет один из трех вариантов вывода реквизитов группировок по колонкам.

1-ый вариант: вместе (в одной дополнительной строке).
Пример:

2-ой вариант: вместе с измерениями (в строках с группировками).
Пример:



3-ий вариант: отдельно (в разных дополнительных строках).
Пример:

8. Вывод построителя отчета

Метод “Выполнить()” выполняет запрос построителя отчета и заполняет свойство “Результат”.
С помощью метода “ПолучитьЗапрос()” можно получить запрос построителя отчета, который выполняется при вызове метода “Выполнить()”.

Метод “Вывести()” выводит результат в табличный документ или диаграмму. Если не указать объект, в который требуется выполнить вывод, то будет создан новый табличный документ.

Пример вывода в новый табличный документ:
Построитель.Вывести();

Пример вывода в существующий табличный документ:
Построитель.Вывести(ЭлементыФормы.РезультатТаблица);

Пример вывода в диаграмму:
Построитель.Вывести(ЭлементыФормы.РезультатДиаграмма, " Количество");

Если требуется вывести результат построителя отчета в сводную таблицу или сводную диаграмму, то тогда нужно не использовать метод “Вывести()”, а заполнять свойство сводной таблицы или сводной диаграммы “ИсточникДанных”. В качестве источника можно указать результат построителя отчета или сам построитель отчета. Результат построителя отчета не требует перевыполнения запроса, зато построитель отчета позволяет менять состав группировок.

9. Сохранение и восстановление настроек построителя

Метод “ПолучитьНастройки()” позволяет получить текущие настройки построителя отчета с возможностью указания, какие именно (пример: только фильтр, фильтр и сортировку…).

Метод “УстановитьНастройки()” позволяет загрузить настройки построителя отчета с возможностью указания, какие именно (пример: только фильтр, фильтр и сортировку…).

10. Группировки и поля построителя отчета

Измерение построителя отчета – это группировка по строкам или колонкам.

Основными реквизитами группировки являются

  • “Имя” (идентификатор реквизита) (пример: “Номенклатура”, “Контрагент”…),
  • “Представление” (представление при выводе) (пример: “Документ продажи”, “Единица измерения”…),
  • “ПутьКДанным” (путь к полю выборки запроса) (пример: “Номенклатура”, “ДокументПродажи.Организация”…)

и, если группировка строится по справочнику, то еще

  • “ТипИзмерения” (один из вариантов фильтра по значениям поля: иерархия (элементы и группы), только иерархия (только группы) или элементы (только элементы)).

Кроме этого, есть несколько свойств, позволяющих назначить группировке макеты, которые будут использоваться при выводе в табличный документ.

  • “Макет” – имя области в макете построителя отчета или отдельный макет, используемый при выводе группировки.
  • “МакетИерархии” – имя области в макете построителя отчета или отдельный макет, используемый при выводе иерархии группировки.
  • “МакетПодвала” – имя области в макете построителя или отдельный макет, используемый при выводе подвала группировки.
  • “МакетПодвалаИерархии” – имя области в макете построителя или отдельный макет, используемый при выводе подвала иерархии группировки.
  • “МакетыПодваловУровней” – массив макетов подвалов для различных уровней группировок.
  • “МакетыУровней” – массив макетов для различных уровней группировок.

Поле построителя отчета – это одно из выбранных полей. Основными реквизитами поля являются

  • “Имя” (идентификатор поля) (пример: “Количество”, “КодНоменклатуры”, “Период”…),
  • “Представление” (представление при выводе) (пример: “Кол-во”, “Код”, “Период”…) и
  • “ПутьКДанным” (путь к полю выборки запроса) (пример: “Количество”, “Номенклатура. Код”, “Период”…).

Со списком группировок или полей можно выполнять ряд действий.

  • “Вставить()“ – добавить группировку/поле в указанную позицию.
  • “Добавить()“ – добавить группировку/поле в конец списка.
  • “Индекс()“ – получить индекс группировки/поля в списке.
  • “Количество()“ – получить количество группировок/полей в списке.
  • “Найти()“ – найти группировку/поле в списке по имени.
  • “Очистить()“ – очистить список группировок/полей.
  • “Получить()“ – получить группировку/поле по индексу.
  • “Сдвинуть()“ – сдвинуть группировку/поле на указанное количество позиций.
  • “Удалить()“ – удалить группировку/поле из списка.

11. Язык построителя

Построитель отчета имеет свой язык. Это обычный язык запросов, дополненный конструкциями “{…}”. С помощью этих конструкций можно отказаться от метода “ЗаполнитьНастройки()” и настроить построитель отчета в тексте запроса.
Таким образом можно настроить элементы “ВЫБРАТЬ”, “ГДЕ”, “УПОРЯДОЧИТЬ ПО”, “ИТОГИ ПО”, а также сделать еще несколько интересных вещей. В этом случае основной текст запроса построителя будет являться настройками по умолчанию, в то время как конструкции {…} будут описывать доступные настройки.

Если поле выборки позволяет получить что-то через точку, то можно указать “.*” после поля, тогда пользователь сможет выбирать реквизиты поля. Например, “Номенклатура.*” позволяет сделать сортировку по “Номенклатура.Код” или отбор по “Номенклатура.Услуга”. А вот “Количество.*” смысла не имеет, так как поле “Количество” реквизитов не имеет, а, значит, достаточно указать просто “Количество”.

Поля, указанные в конструкции “ВЫБРАТЬ”, ограничивают список полей, доступных пользователю.
Поля, указанные в конструкции “ГДЕ”, ограничивают список полей, которые можно использовать в фильтре.
Поля, указанные в конструкции “УПОРЯДОЧИТЬ ПО”, ограничивают список полей для сортировки.
Поля, указанные в конструкции “ИТОГИ ПО”, ограничивают список полей для группировки итогов.

А теперь интересные вещи.

Во-первых, в основном тексте запроса можно в параметрах источников также использовать конструкции {…}. К примеру, если вместо
|ИЗ
| РегистрНакопления.ОстаткиТоваровКомпании.Остатки(&ДатаОкончания)
указать
|ИЗ
| РегистрНакопления.ОстаткиТоваровКомпании.Остатки({&ДатаОкончания})
то в этом случае можно будет задать фильтр по полю “ДатаОкончания”.

При этом, в первом случае обязательно требуется установить параметр построителя отчета “ДатаОкончания”, во втором же случае этого не требуется, кроме того, если отбор по полю “ДатаОкончания” не будет задан, то этот параметр таблицы “РегистрНакопления.ОстаткиТоваровКомпании.Остатки” вообще не будет учитываться.

Во-вторых, источники в тексте запроса можно помечать как необязательные, помещая их в конструкцию “{…}”. К примеру, если составить такой текст запроса

|ВЫБРАТЬ
| ОстаткиТоваровКомпанииОстатки.Номенклатура КАК Номенклатура,
| ОстаткиТоваровКомпанииОстатки.КоличествоОстаток КАК Количество,
| ПартииТоваровКомпанииОстатки.КоличествоОстаток КАК КоличествоПоПартиям
|
|{ВЫБРАТЬ
| ОстаткиТоваровКомпанииОстатки.Номенклатура КАК Номенклатура,
| ОстаткиТоваровКомпанииОстатки.КоличествоОстаток КАК Количество,
| ПартииТоваровКомпанииОстатки.КоличествоОстаток КАК КоличествоПоПартиям}
|
|ИЗ
| РегистрНакопления.ОстаткиТоваровКомпании.Остатки КАК ОстаткиТоваровКомпанииОстатки
| {ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ПартииТоваровКомпании.Остатки КАК ПартииТоваровКомпанииОстатки
| ПО ОстаткиТоваровКомпанииОстатки.Номенклатура = ПартииТоваровКомпанииОстатки.Номенклатура}
|
|ИТОГИ СУММА(Количество), СУММА(КоличествоПоПартиям) ПО
| ОБЩИЕ,
| Номенклатура

то левое соединение по регистру партий будет выполняться только в том случае, если в списке выбранных полей будет присутствовать поле “КоличествоПоПартиям”.

В-третьих, в параметрах источников можно указать, что в случае задания фильтров по возможности применять их не к результату выполнения запроса с помощью элемента “ГДЕ”, а к самому источнику. Таким образом, вместо
| РегистрНакопления.ОстаткиТоваровКомпании.Остатки()

имеет смысл писать

| РегистрНакопления.ОстаткиТоваровКомпании.Остатки(, {Номенклатура.*, СкладКомпании.*, Заказ.*, ЦенаВРознице, ХарактеристикаНоменклатуры.*})

Ну и, в-четвертых, самое вкусное, на мой взгляд. В случае указания в источнике параметра “Периодичность” (для таблиц, позволяющих получать обороты) его также можно задать как “{…}”, и, в результате небольшой манипуляции с текстом запроса построителя мы можем использовать группировки по периодам.

              Пример:
        |ВЫБРАТЬ РАЗРЕШЕННЫЕ
   |	ПартииТоваровКомпанииОбороты.Номенклатура,
   |	СУММА(ПартииТоваровКомпанииОбороты.СтоимостьПриход) КАК СтоимостьПриход,
   |	СУММА(ПартииТоваровКомпанииОбороты.СтоимостьРасход) КАК СтоимостьРасход
   |
   |ИЗ
   |	РегистрНакопления.ПартииТоваровКомпании.Обороты(, , {&Периодичность}, 
   |  {Номенклатура.*}) КАК ПартииТоваровКомпанииОбороты
   |
   |СГРУППИРОВАТЬ ПО
   |	ПартииТоваровКомпанииОбороты.Номенклатура
   |
   |ИТОГИ СУММА(СтоимостьПриход), СУММА(СтоимостьРасход) ПО
   |	ОБЩИЕ,
   |	Номенклатура
   |
   |{ВЫБРАТЬ
   |	ПартииТоваровКомпанииОбороты.Номенклатура.*,
   |	Регистратор.*,
   |	НачалоПериода(Период, День) КАК ПериодДень,
   |	НачалоПериода(Период, Неделя) КАК ПериодНеделя,
   |	НачалоПериода(Период, Декада) КАК ПериодДекада,
   |	НачалоПериода(Период, Месяц) КАК ПериодМесяц,
   |	НачалоПериода(Период, Квартал) КАК ПериодКвартал,
   |	НачалоПериода(Период, Полугодие) КАК ПериодПолугодие,
   |	НачалоПериода(Период, Год) КАК ПериодГод,
   |	СУММА(ПартииТоваровКомпанииОбороты.СтоимостьПриход) КАК СтоимостьПриход,
   |	СУММА(ПартииТоваровКомпанииОбороты.СтоимостьРасход) КАК СтоимостьРасход}
   |
   |{УПОРЯДОЧИТЬ ПО
   |	ПартииТоваровКомпанииОбороты.Номенклатура.*,
   |	Регистратор.*,
   |	СтоимостьПриход,
   |	СтоимостьРасход}
   |
   |{ГДЕ
   |	ПартииТоваровКомпанииОбороты.Номенклатура.*,
   |	Регистратор.*,
   |	СУММА(ПартииТоваровКомпанииОбороты.СтоимостьПриход) КАК СтоимостьПриход,
   |	СУММА(ПартииТоваровКомпанииОбороты.СтоимостьРасход) КАК СтоимостьРасход}
   |
   |{ИТОГИ ПО
   |	Номенклатура.*,
   |	Регистратор.*,
   |	НачалоПериода(Период, День) КАК ПериодДень,
   |	НачалоПериода(Период, Неделя) КАК ПериодНеделя,
   |	НачалоПериода(Период, Декада) КАК ПериодДекада,
   |	НачалоПериода(Период, Месяц) КАК ПериодМесяц,
   |	НачалоПериода(Период, Квартал) КАК ПериодКвартал,
   |	НачалоПериода(Период, Полугодие) КАК ПериодПолугодие,
   |	НачалоПериода(Период, Год) КАК ПериодГод}

Есть один нюанс, для того, чтобы группировка по периодам работала, необходимо добавить фильтр по параметру “Периодичность”. Чтобы не делать это вручную, для удобства можно перед выполнением построителя отчета программно его добавлять, а после выполнения удалять, чтобы он не смущал, так как с точки зрения здравого смысла понять такой фильтр невозможно. Делается это примерно так

Если ПостроительОтчета.ДоступныеПоля.Найти("Периодичность") <> Неопределено   Тогда
   
   Периодичность = Неопределено;
   
   Если ПостроительОтчета.ИзмеренияСтроки.Найти("ПериодГод") <> Неопределено
   ИЛИ ПостроительОтчета.ИзмеренияКолонки.Найти("ПериодГод") <> Неопределено   Тогда
   
         Периодичность = 9;
   
   КонецЕсли;
   
   Если ПостроительОтчета.ИзмеренияСтроки.Найти("ПериодПолугодие") <> Неопределено
   ИЛИ ПостроительОтчета.ИзмеренияКолонки.Найти("ПериодПолугодие") <> Неопределено   Тогда
   
         Периодичность = 8;
   
   КонецЕсли;
   
   Если ПостроительОтчета.ИзмеренияСтроки.Найти("ПериодКвартал") <> Неопределено
   ИЛИ ПостроительОтчета.ИзмеренияКолонки.Найти("ПериодКвартал") <> Неопределено   Тогда
    
         Периодичность = 7;
   
   КонецЕсли;
   
   Если ПостроительОтчета.ИзмеренияСтроки.Найти("ПериодМесяц") <> Неопределено
   ИЛИ ПостроительОтчета.ИзмеренияКолонки.Найти("ПериодМесяц") <> Неопределено   Тогда
   
         Периодичность = 6;
   
   КонецЕсли;
   
   Если ПостроительОтчета.ИзмеренияСтроки.Найти("ПериодДекада") <> Неопределено
   ИЛИ ПостроительОтчета.ИзмеренияКолонки.Найти("ПериодДекада") <> Неопределено   Тогда
   
         Периодичность = 5;
   
   КонецЕсли;
   
   Если ПостроительОтчета.ИзмеренияСтроки.Найти("ПериодНеделя") <> Неопределено
   ИЛИ ПостроительОтчета.ИзмеренияКолонки.Найти("ПериодНеделя") <> Неопределено   Тогда
   
         Периодичность = 4;
   
   КонецЕсли;
   
   Если ПостроительОтчета.ИзмеренияСтроки.Найти("ПериодДень") <> Неопределено
   ИЛИ ПостроительОтчета.ИзмеренияКолонки.Найти("ПериодДень") <> Неопределено   Тогда
   
         Периодичность = 3;
   
   КонецЕсли;
   
   Если ПостроительОтчета.ИзмеренияСтроки.Найти("Регистратор") <> Неопределено
   ИЛИ ПостроительОтчета.ИзмеренияКолонки.Найти("Регистратор") <> Неопределено
   ИЛИ ПостроительОтчета.ВыбранныеПоля.Найти("Регистратор") <> Неопределено   Тогда
   
          Периодичность = 2;
   
   КонецЕсли;
   
   Если Периодичность <> Неопределено Тогда
   
          ПолеОтбораПоПериодичности = ПостроительОтчета.Отбор.Добавить("Периодичность");
   
          ПолеОтбораПоПериодичности.Значение = Периодичность;
          ПолеОтбораПоПериодичности.Использование = Истина;
   
   КонецЕсли;
   
КонецЕсли;
Построитель.Выполнить();
Если ПолеОтбораПоПериодичности <> Неопределено Тогда
                 
   ПостроительОтчета.Отбор.Удалить(ПостроительОтчета.Отбор.Индекс(ПолеОтбораПоПериодичности));
   
КонецЕсли;

12. Пользовательская настройка построителя

Для того, чтобы дать пользователю возможность изменить список группировок, фильтр, выбранные поля или сортировку, достаточно создать реквизит отчета “Построитель” и разместить на форме отчета табличное поле и указать ему в качестве источника данных “Построитель.ИзмеренияСтроки”, “Построитель.ИзмеренияКолонки”, “Построитель.Отбор”, “Построитель.ВыбранныеПоля” или “Построитель.Порядок”.

Кроме того, можно также в качестве источника данных указать “Построитель.ДоступныеПоля” и, таким образом, во-первых видеть список доступных полей, а, во-вторых с помощью контекстного меню добавлять поля в группировки, отбор, выбранные поля или фильтр.

См. также

Поинтегрируем: сервисы интеграции – новый стандарт или просто коннектор?

Обмен между базами 1C Администрирование СУБД Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

В платформе 8.3.17 появился замечательный механизм «Сервисы интеграции». Многие считают, что это просто коннектор 1С:Шины. Так ли это?

11.03.2024    4487    dsdred    53    

71

Как готовить и есть массивы

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Все мы используем массивы в своем коде. Это один из первых объектов, который дают ученикам при прохождении обучения программированию. Но умеем ли мы ими пользоваться? В этой статье я хочу показать все методы массива, а также некоторые фишки в работе с массивами.

24.01.2024    5286    YA_418728146    25    

63

Планы обмена VS История данных

Обмен между базами 1C Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Вы все еще регистрируете изменения только на Планах обмена и Регистрах сведений?

11.12.2023    6401    dsdred    36    

111

1С-ная магия

Механизмы платформы 1С Бесплатно (free)

Язык программирования 1С содержит много нюансов и особенностей, которые могут приводить к неожиданным для разработчика результатам. Сталкиваясь с ними, программист начинает лучше понимать логику платформы, а значит, быстрее выявлять ошибки и видеть потенциальные узкие места своего кода там, где позже можно было бы ещё долго медитировать с отладчиком в поисках источника проблемы. Мы рассмотрим разные примеры поведения кода 1С. Разберём результаты выполнения и ответим на вопросы «Почему?», «Как же так?» и «Зачем нам это знать?». 

06.10.2023    18467    SeiOkami    46    

118

Дефрагментация и реиндексация после перехода на платформу 8.3.22

Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Начиная с версии платформы 8.3.22 1С снимает стандартные блокировки БД на уровне страниц. Делаем рабочий скрипт, как раньше.

14.09.2023    12086    human_new    27    

74

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8806    YA_418728146    6    

141

Внешние компоненты Native API на языке Rust - Просто!

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Внешние компоненты для 1С можно разработывать очень просто, пользуясь всеми преимуществами языка Rust - от безопасности и кроссплатформенности до удобного менеджера библиотек.

20.08.2023    6274    sebekerga    54    

94

Все скопируем и вставим! (Буфер обмена в 1С 8.3.24)

Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Рассмотрим новую возможность 8.3.24 и как её можно эффективно использовать

27.06.2023    15976    SeiOkami    31    

103
Вознаграждение за ответ
Показать полностью
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Just 2 16.03.09 14:14 Сейчас в теме
А есть файликом стянуть откуда, а то картиночки не все подгружаются.
2. Natasha1c 16.03.09 14:17 Сейчас в теме
картинки не все грузяться
3. ediks 335 16.03.09 15:41 Сейчас в теме
на мисте http://www.mista.ru/v8/repbuilder.htm со всеми картинками
alk; Xershi; abasovit; NN2P; shalimski; Патриот; konster72; BoBaH; Demon80; pizhenkov; comptr; +11 Ответить
4. venger 2121 17.03.09 20:48 Сейчас в теме
Н-дя, в картинках ссылки на инфостарт надо www.infostart писать, тогда не сьедает урлы...
5. СветикК 16.05.09 19:32 Сейчас в теме
почему картинке не все, но на мисте ру такая же статья
6. nikresh 28.08.09 09:33 Сейчас в теме
Прекрасно.
но как быть с этим:
проверяется на Демонстрационной базе "Управление Торговлей 8"
РезультатПостроительОтчета=РезультатПостроительЗапроса <>РезультатЗапрос
ПРОВЕРЕНО (на разных БД) - РезультатЗапрос правильный.

Процедура КнопкаСформироватьНажатие(Кнопка)
	// Вставить содержимое обработчика.
	 ТекстХЗ = "
	 |ВЫБРАТЬ РАЗЛИЧНЫЕ
	 | ЗаказыПокупателейОстатки.ЗаказПокупателя,
	 | ЗаказыПокупателейОстатки.Номенклатура,
	 | ЗаказыПокупателейОстатки.ХарактеристикаНоменклатуры,
	 | ЗаказыПокупателейОстатки.КоличествоОстаток
	 |ПОМЕСТИТЬ ТабЗаказНужно
	 |ИЗ
	 | РегистрНакопления.ЗаказыПокупателей.Остатки КАК ЗаказыПокупателейОстатки
	 |ГДЕ
	 | ЗаказыПокупателейОстатки.КоличествоОстаток > 0
	 | И ЗаказыПокупателейОстатки.СуммаУпрОстаток > 0
	 |;
	 |
	 |ВЫБРАТЬ РАЗЛИЧНЫЕ
	 | ТабЗаказНужно.Номенклатура КАК Номенклатура,
	 | ТабЗаказНужно.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
	 | СУММА(ТабЗаказНужно.КоличествоОстаток) КАК Нужно
	 |ИЗ
	 | ТабЗаказНужно КАК ТабЗаказНужно
	 |
	 |СГРУППИРОВАТЬ ПО
	 | ТабЗаказНужно.Номенклатура,
	 | ТабЗаказНужно.ХарактеристикаНоменклатуры
	 |
	 |УПОРЯДОЧИТЬ ПО
	 | ТабЗаказНужно.Номенклатура.Наименование,
	 | ХарактеристикаНоменклатуры
	 |";

	 строительОтчета = Новый ПостроительОтчета;
	 строительОтчета.Текст = ТекстХЗ;
	 ТабПостроительОтчета = строительОтчета.Результат.Выгрузить();
	 ТабПостроительОтчета.ВыбратьСтроку("ПостроительОтчета, КоличествоСтрок "+ТабПостроительОтчета.Количество(),);

	 строительЗапроса = Новый ПостроительЗапроса;
	 строительЗапроса.Текст = ТекстХЗ;
	 ТабПостроительЗапроса = строительЗапроса.Результат.Выгрузить();
	 ТабПостроительЗапроса.ВыбратьСтроку("ПостроительЗапроса, КоличествоСтрок "+ТабПостроительЗапроса.Количество(),);

	 Запрос = Новый Запрос;
	 Запрос.Текст = ТекстХЗ;
	 ТабЗапрос= Запрос.Выполнить().Выгрузить();
	 ТабЗапрос.ВыбратьСтроку("Запрос, КоличествоСтрок "+ТабЗапрос.Количество(),);
	 
	 
	Построитель = Новый ПостроительОтчета;
	Построитель.Текст = ТекстХЗ;
	Построитель.ЗаполнитьНастройки();
	//Здесь можно дать пользователю возможность
	//изменить настройки построителя отчета
	//Построитель.Макет = ПолучитьМакет("СвойМакет");
	Построитель.МакетОформления = ПолучитьМакетОформления(СтандартноеОформление.Классика);
	Построитель.ОформитьМакет();
	Построитель.Выполнить();
	Построитель.Вывести();
 
 КонецПроцедуры
Показать
7. пользователь 12.01.12 15:04
Сообщение было скрыто модератором.
...
8. пользователь 12.01.12 15:06
Сообщение было скрыто модератором.
...
9. veyron21 133 17.04.12 12:08 Сейчас в теме
В таких статьях надо обязательно указывать источник!
Потому что та статья на Мисте - это практически букварь для разработчика, столкнувшегося с построителем, и про нее (статью) знают достаточно много специалистов.
alk; NN2P; +2 Ответить
10. Ткачев 74 05.03.13 07:53 Сейчас в теме
А как можно сбросить настройки, ?

Процедура ПриОткрытии()
	
	ЗаполнитьПостроительОтчета();
	НастройкиПостроителя = ВосстановитьЗначение("НастройкиПостроителя");
	Если НастройкиПостроителя <> Неопределено Тогда
		ПостроительОтчета.УстановитьНастройки(НастройкиПостроителя);
	КонецЕсли;
	
КонецПроцедуры
Показать


Иногда надо сбросить установленные настройки, как ?
11. Светлый ум 406 11.03.14 08:10 Сейчас в теме
Пример бы приложил какой: "со своим макетом", а то и в правду - содранная статья с мисты.
iCortezik; +1 Ответить
12. 7OH 69 13.04.20 11:33 Сейчас в теме
Видимо внутренние "специалисты" 1С тоже читали статью, особенно "Поскольку построитель отчета недоступен на сервере".
В СП сказано, что очень даже доступен, МакетОформления тоже доступен.
А вот ПолучитьМакетОформления забыли сделать доступным на сервере.
И вот теперь задача - как на сервере задать оформление табличному документу ?
3dice; uri1978; Suslik_Johns; +3 Ответить
13. Suslik_Johns 08.06.20 10:42 Сейчас в теме
(12) Сейчас тоже с этим столкнулись.
Глобальный контекст (Global context)
ПолучитьМакетОформления (GetAppearanceTemplate)
Синтаксис:
ПолучитьМакетОформления(<Оформление>)

Доступность:
Толстый клиент.

Как так-то?
15. gorakh 26 07.10.20 13:28 Сейчас в теме
(12)т.к. ПолучитьМакетОформления() не работает на сервере вышел из положения так:
Выполнил в консоли
Макет = ПолучитьМакетОформления(СтандартноеОформление.Классика);
получил табличный документ перенес его содержимое в Общий макет "МакетОформленияКлассика" и дальше
МакетОформления = ПолучитьОбщийМакет("МакетОформленияКлассика");
max_zhilin; +1 Ответить
17. Suslik_Johns 01.04.21 11:06 Сейчас в теме
(15) А в какой консоли можно совершить эти действия?
18. gorakh 26 01.04.21 11:08 Сейчас в теме
1
(15) УПП (обычные формы) коносль из портативных инструментов разработчика.
20. Suslik_Johns 01.04.21 11:09 Сейчас в теме
(18)спасибо, надо поискать
14. uri1978 137 13.07.20 15:47 Сейчас в теме
Тоже столкнулся. Не могу оформить отчет при рассылке (выполняется регламентным на сервере).
16. Diyversus 19.03.21 09:53 Сейчас в теме
Кто может привести пример: что можно сделать через построитель и нельзя через СКД?
19. Suslik_Johns 01.04.21 11:09 Сейчас в теме
Вывожу Таблицу значений (результат запроса) через построитель на форму - в реквизит формы Табличный документ.
И почему-то выводит с 4 строчки таблицу.
А первые 3 строки остаются пустыми.
Почему так, кто-нибудь знает? На какую-то шапку отведены что ли эти строки?
21. Suslik_Johns 01.04.21 11:16 Сейчас в теме
(19) ВыводитьЗаголовокОтчета = Ложь
и эти строчки ушли
22. VarLone 11.06.21 15:23 Сейчас в теме
Обновите, пожалуйста, картинки
в (3) ссылка недействительна.
Спасибо
23. deathogre 21.07.21 11:08 Сейчас в теме
Обновить бы под 8.3
Stirlitz; +1 Ответить
24. Stirlitz 16 09.11.23 13:48 Сейчас в теме
(23) Согласен, либо обновите либо удалите.
Статья безнадежно устарела, чего стоит, например, утверждение о том, что Построитель недоступен на сервере.
Оставьте свое сообщение