Отступление: в примерах используется оборотный регистр накопления Продажи следующей структуры: Контрагент, Товар, Проект, Страна, Количество, Сумма. Для большей наглядности регистра извлекаются записи физической таблицы, а не виртуальной, чтобы записи не группировались автоматически.
|
Контрагент |
Товар |
Проект |
Страна |
Количество |
Сумма |
КОНСТРУКЦИЯ 1: СГРУППИРОВАТЬ ПО (GROUP BY)
Аналог в языке SQL – GROUP BY, именно в эту конструкцию и транслируется СГРУППИРОВАТЬ ПО.
Секция позволяет получить итоги по комбинации выбранных реквизитов без промежуточных итогов (говоря языком методов таблицы значений, свернуть):
ПРИМЕР 1
ЗАПРОС:
|
ВЫБРАТЬ |
К |
Т |
П |
С |
АГРЕГАТНЫЕ ФУНКЦИИ |
к |
с |
|
|
СГРУППИРОВАТЬ ПО |
К |
Т |
П |
С |
ВЫБРАТЬ
Продажи.Контрагент КАК Контрагент,
Продажи.Товар КАК Товар,
Продажи.Проект КАК Проект,
Продажи.Страна КАК Страна,
СУММА(Продажи.Сумма) КАК Сумма,
СУММА(Продажи.Количество) КАК Количество
ИЗ
РегистрНакопления.Продажи КАК Продажи
СГРУППИРОВАТЬ ПО
Продажи.Контрагент,
Продажи.Товар,
Продажи.Проект,
Продажи.Страна
РЕЗУЛЬТАТ:
|
К |
Т |
П |
С |
к |
с |
Если нужно получить итоги по разным комбинациям группируемых реквизитов в одном запросе, то понадобится конструкция ОБЪЕДИНИТЬ [ВСЕ] (UNION [ALL]) (аналог в языке SQL – UNION [ALL]):
ПРИМЕР 2
ЗАПРОС :
|
ВЫБРАТЬ |
К |
NULL |
П |
NULL |
АГРЕГАТНЫЕ ФУНКЦИИ |
к |
с |
|
СГРУППИРОВАТЬ ПО |
К |
П |
|||||
|
ОБЪЕДИНИТЬ |
|||||||
|
ВЫБРАТЬ |
NULL |
Т |
NULL |
NULL |
АГРЕГАТНЫЕ ФУНКЦИИ |
к |
с |
|
СГРУППИРОВАТЬ ПО |
Т |
||||||
|
ОБЪЕДИНИТЬ |
|||||||
|
ВЫБРАТЬ |
NULL |
Т |
NULL |
С |
АГРЕГАТНЫЕ ФУНКЦИИ |
к |
с |
|
СГРУППИРОВАТЬ ПО |
Т |
С |
ВЫБРАТЬ
Продажи.Контрагент,
NULL,
Продажи.Проект,
NULL,
СУММА(Продажи.Сумма) КАК Сумма,
СУММА(Продажи.Количество) КАК Количество
ИЗ
РегистрНакопления.Продажи КАК Продажи
СГРУППИРОВАТЬ ПО
Продажи.Контрагент,
Продажи.Проект
ОБЪЕДИНИТЬ
ВЫБРАТЬ
NULL,
Продажи.Товар,
NULL,
NULL,
СУММА(Продажи.Сумма) КАК Сумма,
СУММА(Продажи.Количество) КАК Количество
ИЗ
РегистрНакопления.Продажи КАК Продажи
СГРУППИРОВАТЬ ПО
Продажи.Товар
ОБЪЕДИНИТЬ
ВЫБРАТЬ
NULL,
Продажи.Товар,
NULL,
Продажи.Страна,
СУММА(Продажи.Сумма) КАК Сумма,
СУММА(Продажи.Количество) КАК Количество
ИЗ
РегистрНакопления.Продажи КАК Продажи
СГРУППИРОВАТЬ ПО
Продажи.Товар,
Продажи.Страна
РЕЗУЛЬТАТ:
|
К |
П |
к |
с |
||
|
Т |
к |
с |
|||
|
Т |
С |
к |
с |
Можно использовать разные агрегатные функции в подзапросах, хотя в данном конкретном примере это явно неуместно, тем не менее, задачи бывают разные.
КОНСТРУКЦИЯ 2: ИТОГИ ПО [ОБЩИЕ] (TOTALS BY [OVERALL])
Аналог в языке SQL – WITH ROLLUP, но конструкция ИТОГИ ПО не транслируется в SQL-запрос, а обрабатывается самой платформой.
Конструкция позволяет применить к исходной выборке дополнительные группировки и присоединить к выборке полученные итоги. Итоги собираются по автоматически формирующимся комбинациям реквизитов секции ПО по следующему правилу: комбинация из первого реквизита, комбинация из первых двух реквизитов, комбинация из первых трех реквизитов и т.д. до последнего реквизита. Результат вполне себе можно назвать деревом с итогами по узлам, что, в общем-то, закрывает большинство задач по группировке данных одинэсника.
ПРИМЕР 3
ЗАПРОС:
|
ВЫБРАТЬ |
К |
Т |
П |
С |
|||
|
ИТОГИ |
АГРЕГАТНЫЕ ФУНКЦИИ |
к |
с |
||||
|
ПО |
К |
П |
С |
ВЫБРАТЬ
Продажи.Контрагент КАК Контрагент,
Продажи.Товар КАК Товар,
Продажи.Проект КАК Проект,
Продажи.Страна КАК Страна,
Продажи.Сумма КАК Сумма,
Продажи.Количество КАК Количество
ИЗ
РегистрНакопления.Продажи КАК Продажи
ИТОГИ
СУММА(Сумма),
СУММА(Количество)
ПО
Контрагент,
Проект,
Страна
РЕЗУЛЬТАТ:
|
К |
к |
с |
|||
|
К |
П |
к |
с |
||
|
К |
П |
С |
к |
с |
|
|
К |
Т |
П |
С |
к |
с |
|
К |
Т |
П |
С |
к |
с |
Отобрано по значению «Контрагент 4» для наглядности:
Если используется ключевое слово ОБЩИЕ, то дополнительно добавляется итоговая строка самого верхнего уровня.
Запрос с секцией ИТОГИ ПО может содержать секцию СГРУППИРОВАТЬ ПО (в языке SQL он как раз-таки должен содержать ее), но со своими агрегатными функциями (в отличие от SQL). В этом случае есть ограничение: реквизиты, агрегированные в секции СГРУППИРОВАТЬ ПО, не могут выступать реквизитами группировки в секции ИТОГИ ПО, например, если количество было уже просуммировано агрегатной функцией, итоги по нему как по полю группировки посчитать уже не получится (в языке SQL и для группировки, и для итогов используются одни и те же агрегатные функции.
ПРИМЕР 4
ЗАПРОС:
|
ВЫБРАТЬ |
К |
Т |
П |
С |
АГРЕГАТНЫЕ ФУНКЦИИ |
к |
с |
|
СГРУППИРОВАТЬ ПО |
К |
Т |
П |
С |
|||
|
ИТОГИ |
АГРЕГАТНЫЕ ФУНКЦИИ |
к |
|||||
|
ПО |
К |
П |
С |
ВЫБРАТЬ
Продажи.Контрагент КАК Контрагент,
Продажи.Товар КАК Товар,
Продажи.Проект КАК Проект,
Продажи.Страна КАК Страна,
СУММА(Продажи.Сумма) КАК Сумма,
СУММА(Продажи.Количество) КАК Количество
ИЗ
РегистрНакопления.Продажи КАК Продажи
СГРУППИРОВАТЬ ПО
Продажи.Контрагент,
Продажи.Товар,
Продажи.Проект,
Продажи.Страна
ИТОГИ
СРЕДНЕЕ(Количество)
ПО
Контрагент,
Проект,
Страна
РЕЗУЛЬТАТ:
|
К |
к |
с |
|||
|
К |
П |
к |
с |
||
|
К |
П |
С |
к |
с |
|
|
К |
Т |
П |
С |
к |
с |
КОНСТРУКЦИЯ 3: СГРУППИРОВАТЬ ПО ГРУППИРУЮЩИМ НАБОРАМ (GROUP BY GROUPING SETS)
Аналог в языке SQL - GROUP BY GROUPING SETS, именно в эту конструкцию и транслируется СГРУППИРОВАТЬ ПО ГРУППИРУЮЩИМ НАБОРАМ.
Начиная с версии платформы 1С 8.3.16 в языке запросов появилось расширение ГРУППИРУЮЩИМ НАБОРАМ секции СГРУППИРОВАТЬ ПО. В конструкторе запросов это выглядит следующим образом:
Данная конструкция позволяет существенно упростить запрос из примера 2 (за тем исключением, что нет возможности использовать разные агрегатные функции для разных комбинаций реквизитов):
ПРИМЕР 5
ЗАПРОС:
|
ВЫБРАТЬ |
К |
Т |
П |
С |
АГРЕГАТНЫЕ ФУНКЦИИ |
к |
с |
|
СГРУППИРОВАТЬ ПО ГРУППИРУЮЩИМ НАБОРАМ |
К |
П |
|||||
|
Т |
|||||||
|
Т |
С |
ВЫБРАТЬ
Продажи.Контрагент КАК Контрагент,
Продажи.Товар КАК Товар,
Продажи.Проект КАК Проект,
Продажи.Страна КАК Страна,
СУММА(Продажи.Сумма) КАК Сумма,
СУММА(Продажи.Количество) КАК Количество
ИЗ
РегистрНакопления.Продажи КАК Продажи
СГРУППИРОВАТЬ ПО ГРУППИРУЮЩИМ НАБОРАМ
(
( Продажи.Контрагент,Продажи.Проект),
( Продажи.Товар),
( Продажи.Товар,
Продажи.Страна)
)
РЕЗУЛЬТАТ:
|
К |
П |
к |
с |
||
|
Т |
к |
с |
|||
|
Т |
С |
к |
с |
Отмечу, что если указать единственный набор из всех реквизитов группировки, то результат запроса будет идентичен запросу без расширения ПО ГРУППИРУЮЩИМ НАБОРАМ, т.е. обычная группировка по всем реквизитам, как в запросе из примера 1.
Если область применения предыдущих конструкций вопросов не вызывает, то ценность конструкции СГРУППИРОВАТЬ ПО ГРУППИРУЮЩИМ НАБОРАМ не сразу очевидна рядовому одинэснику. Я не стал копировать пример из Зазеркалья https://wonderland.v8.1c.ru/blog/podderzhka-grouping-sets-v-yazyke-zaprosov/, а решил придумать свой. Хороший пример в данном случае придумать непросто, т.к. большинство наборов данных в типовых конфигурациях можно успешно описать деревом, за счет чего минимальный функционал СКД закрывает большую часть задач. Кроме того, такие типичные отчеты, как дебиторская/кредиторская задолженность, продажи, как правило, содержат связанные или даже подчиненные друг другу аналитики, например, договор подчинен контрагенту, документ содержит ссылку на договор и т.д., вследствие чего получение итогов по нескольким отдельным аналитикам требуется крайне редко. Но есть сфера, в которой подобные разреженные матрицы используются повсеместно – это OLAP. Потенциально конструкция может принести в этой сфере, если запросы к OLAP-источникам пишутся на языке 1С.
Я попытался придумать такую структуру данных для примеров, которая позволила бы описать более-менее приближенную к жизни ситуацию (может, у меня и не получилось), где программисту пригодится конструкция СГРУППИРОВАТЬ ПО ГРУППИРУЮЩИМ НАБОРАМ. Итак, есть компания, продающая товары различным холдингам, разбросанным по всему миру, в рамках разных проектов, т.е. аналитики никак между собой логически не связаны. Учредителю может понадобиться информация о продажах в разрезе любой комбинации аналитик Контрагент, Товар, Проект, Страна. Таким образом, для решения подобной задачи лучше всего подойдет конструкция СГРУППИРОВАТЬ ПО ГРУППИРУЮЩИМ НАБОРАМ. Пример довольно искусственный, но, надеюсь, он приблизил вас к пониманию того, где можно применить конструкцию. Если же вы будете использовать СКД, то система компоновки все сделает за вас, и группировать запрос вам будет ни к чему.
Стоит добавить, что в языке SQL у секции GROUP BY есть расширение WITH CUBE, выводящее итоги по всем возможным комбинациям реквизитов группировки. Его аналога в языке запросов 1С нет, но с помощью конструкций, использованных в примерах 2 и 5 можно добиться того же результата, хотят и с бОльшими трудозатратами.
Всем добра!
