Паузы при исполнении кода (Sleep для 1С)

28.11.17

Разработка - Инструментарий разработчика

Решил проверить все найденные варианты паузы для 1С. В результате получилась обработка для тестирования и небольшая статья с итогом.

Скачать файлы

Наименование Файл Версия Размер
Паузы при исполнении кода (Sleep для 1с):
.epf 11,61Kb
26
.epf 11,61Kb 26 Скачать

По результатам чтения форума http://forum.infostart.ru/forum9/topic42820/ и некоторых других форумов, остался вопрос: а какой вариант работает, какой лучше использовать. Для проверки была создана предлагаемая обработка. В ней можно протестировать найденные варианты. Для себя я нашел только 2 варианта: с использованием ping и winmgmts.

Более подробно про проверенные варианты:

1) ping и winmgmts. Оба варианта прекрасно работают, практически не нагружая процессор.

2) Пустой цикл. Вариант работающий, часто предлагаемый на форумах. Имеет большой минус - грузит процессор.

3) Вариант с использованием Sleep. Насколько я понимаю, требуют наличия программы sleep.exe. На моем компьютере такой нет, варианты проверить не удалось.

4) SleepJs и SleepVbs. Работают. Неплохой вариант. Варианты отличаются только алгоритмом запуска команды.

5) TimeoutWs и Timeout. Работают. Неплохой вариант. Варианты отличаются только алгоритмом запуска команды. Timeout показывает черное окно при каждом запуске паузы.

6) DynamicWrapper. Нужна dll. Этот вариант не проверял, так как искал вариант без внешних компонент.

В прилагаемой обработке все варианты можно протестировать в своей базе и выбрать наиболее подходящий.

Есть обычная и управляемая форма, поэтому запускать можно в любой базе. Код открыт.

Протестировано на версиях 8.2 и 8.3.11.

 
Процедура СделатьПаузу(ЗадержкаСекунд = 3, Вариант = "Ping")
	
    Если ЗадержкаСекунд = 0 Тогда
        Возврат
    КонецЕсли;
	
	Если ТранзакцияАктивна() Тогда
		ЗафиксироватьТранзакцию();
	КонецЕсли;
	
	Сообщить("начало: "+ТекущаяДата());
	
	Если Вариант = "Ping" Тогда
		
		СтрокаЗапроса = "ping -n 1 -w "+Формат(1000 * ЗадержкаСекунд, "ЧДЦ=0; ЧГ=") + " 127.255.255.255"; 
		WshShell = Новый COMОбъект("WScript.Shell"); 
		WshShell.Run(СтрокаЗапроса, 0, -1); 
		
	ИначеЕсли Вариант = "smaharbA" Тогда
		
		Для к = 1 По ЗадержкаСекунд Цикл
			ПолучитьCOMОбъект("winmgmts:").ExecNotificationQuery("Select * from __instancemodificationevent where TargetInstance isa 'Win32_UTCTime'").NextEvent();
		КонецЦикла;
		
	ИначеЕсли Вариант = "Пустой цикл" Тогда
		
		// грузит процессор
		ДатаВыхода = ТекущаяДата() + ЗадержкаСекунд;
		Пока ТекущаяДата() < ДатаВыхода Цикл
			ОбработкаПрерыванияПользователя();
		КонецЦикла;
		
	ИначеЕсли Вариант = "Sleep" Тогда
		
		// не работает
		
		scr = Новый ComОбъект("WScript.Shell"); 
		scr.Run("sleep "+Формат(ЗадержкаСекунд, "ЧДЦ=0; ЧГ="), 0, 1);
		
	ИначеЕсли Вариант = "SleepJs" Тогда
		
		// работает
		
		Скрипт = Новый ТекстовыйДокумент(); 
		Скрипт.УстановитьТекст 
		( 
		"if (WScript.Arguments.Count()==0) 
		| WScript.Quit(); 
		|else 
		| if (isNaN(parseInt(WScript.Arguments(0)))) 
		| WScript.Quit(); 
		|WScript.Sleep(WScript.Arguments(0));" 
		); 
		Скрипт.Записать(КаталогВременныхФайлов()+"sleep.js", КодировкаТекста.ANSI); 
		WshShell = Новый COMОбъект("wscript.shell"); 
		WshShell.Run("wscript.exe """+КаталогВременныхФайлов()+"sleep.js"" "+Формат(ЗадержкаСекунд*1000,"ЧГ=0"), 0, -1); 
		УдалитьФайлы(КаталогВременныхФайлов()+"sleep.js"); 
		
	ИначеЕсли Вариант = "SleepVbs" Тогда
		
		// работает
		
		Сигнатура = Формат(ТекущаяДата(), "ДФ=yyyyMMddhhmmss");
		ПутьСкрипта = КаталогВременныхФайлов()+"SleepScript"+Сигнатура+".vbs";
		СкриптФайл = Новый ТекстовыйДокумент;
		СкриптФайл.ДобавитьСтроку("WScript.Sleep("+Формат(ЗадержкаСекунд*1000, "ЧГ=0")+")");
		СкриптФайл.Записать(ПутьСкрипта, КодировкаТекста.OEM);
		WSHShell = Новый COMОбъект("WScript.Shell");
		WSHShell.Run("wscript.exe """+ПутьСкрипта+"""", 0, 1);
		УдалитьФайлы(ПутьСкрипта);
		
	ИначеЕсли Вариант = "TimeoutWS" Тогда
		
		// работает
		
		КомандаWindows = "Timeout /T " + Формат(ЗадержкаСекунд, "ЧГ=0") + " /NoBreak";
		
		WshShell = Новый COMОбъект("WScript.Shell"); 
		WshShell.Run(КомандаWindows, 0, -1);
		
	ИначеЕсли Вариант = "Timeout" Тогда
		
		// работает, показывает черное окно
		
		КомандаWindows = "Timeout /T " + Формат(ЗадержкаСекунд, "ЧГ=0") + " /NoBreak";
		ЗапуститьПриложение(КомандаWindows,,Истина);
		
	ИначеЕсли Вариант = "DynamicWrapper" Тогда
		
		// нужна библиотека
		
		Wrapper = Новый ComОбъект("DynamicWrapper"); 
		Wrapper.Register("KERNEL32.DLL", "Sleep", "i=l", "f=s"); 
		
		Wrapper.Sleep(ЗадержкаСекунд);
		
	КонецЕсли;
	
	Сообщить("^^^^^^: "+ТекущаяДата());
		
КонецПроцедуры

 

 

пауза sleep

См. также

SALE! 20%

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

13000 10400 руб.

02.09.2020    122152    670    389    

714

SALE! 25%

Infostart PrintWizard

Пакетная печать Печатные формы Инструментарий разработчика Платформа 1С v8.3 Запросы 1С:Зарплата и кадры бюджетного учреждения 1С:Конвертация данных 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 Платные (руб)

Инструмент, позволяющий абсолютно по-новому взглянуть на процесс разработки печатных форм. Благодаря конструктору можно значительно снизить затраты времени на разработку печатных форм, повысить качество и "прозрачность" разработки, а также навести порядок в многообразии корпоративных печатных форм.

18000 15300 руб.

06.10.2023    7292    21    6    

39

SALE! 20%

Infostart УДиФ: Управление данными и формами

Инструменты администратора БД Инструментарий разработчика Роли и права Платформа 1С v8.3 Конфигурации 1cv8 Россия Платные (руб)

Расширение позволяет без изменения кода конфигурации выполнять проверки при вводе данных, скрывать от пользователя недоступные ему данные, выполнять код в обработчиках. Не изменяет данные конфигурации, легко устанавливается практически на любую конфигурацию на управляемых формах.

10000 8000 руб.

10.11.2023    3536    11    1    

34

SALE! 30%

PowerTools

Инструментарий разработчика Инструменты администратора БД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Россия Платные (руб)

Универсальный инструмент программиста для администрирования конфигураций. Сборник наиболее часто используемых обработок под единым интерфейсом.

3600 2520 руб.

14.01.2013    177747    1073    0    

849

Многопоточность. Универсальный «Менеджер потоков» 2.1

Инструментарий разработчика Платформа 1С v8.3 Конфигурации 1cv8 Россия Платные (руб)

Восстановление партий или взаиморасчетов, расчет зарплаты, пакетное формирование документов или отчетов - теперь все это стало доступнее. * Есть желание повысить скорость работы медленных алгоритмов! Но... * Нет времени думать о реализации многопоточности? * о запуске и остановке потоков? * о поддержании потоков в рабочем состоянии? * о передаче данных в потоки и как получить ответ из потока? * об организации последовательности? Тогда ЭТО - то что надо!!!

5000 руб.

07.02.2018    99347    239    97    

296

[ЕХТ] Фреймворк для Расширений 1С

Инструментарий разработчика Платформа 1С v8.3 Управляемые формы Платные (руб)

"Фреймворк для Расширений 1С" это универсальное и многофункциональное решение, упрощающее разработку и поддержку создаваемых Расширений. Поставляется в виде комплекта из нескольких Расширений с открытым исходным кодом. Работает в любых Конфигурациях в режиме Управляемого приложения с режимом совместимости 8.3.12 и выше без необходимости внесения изменений в Конфигурацию.

3000 руб.

27.08.2019    18112    6    8    

39

1С HTML Шаблоны / HTML Templates

Инструментарий разработчика Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Быстрая и удобная обработка для работы с шаблонами HTML. Позволяет легко и быстро формировать код HTML.

2040 руб.

27.12.2017    28109    3    10    

15

Выполнение произвольного кода или запроса с параметрами через Web-сервис (замена COM-подключений)

Инструментарий разработчика Обмен между базами 1C Платформа 1С v8.3 Платные (руб)

В процессе работы в 1С часто возникает потребность получить данные из другой базы.  Обычно это делается через COM-соединение, и время выполнения запроса при этом оставляет желать лучшего. В данной публикации представлено универсальное решение, позволяющее практически моментально выполнить произвольный код или запрос с параметрами в другой информационной базе через Web-сервис.

2400 руб.

24.09.2019    23601    15    15    

32
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. CyberCerber 852 28.11.17 17:45 Сейчас в теме
Странно, что не работает SleepVbs. Я обычно таким методом пользуюсь, на компах с Виндовс работает.
13. swimdog 765 29.11.17 13:04 Сейчас в теме
(1) Сравнил с (7). Работает, у меня пауза была не в секундах, а в миллисекундах, поэтому я решил, что не работает.
2. Infector 199 29.11.17 07:11 Сейчас в теме
Процедура Ожидание(Секунд)
	
	КомандаWindows = "Timeout /T " + Строка(Секунд) + " /NoBreak";
	ЗапуститьПриложение(КомандаWindows,,Истина);
	
КонецПроцедуры	
AdmKmpt; rtihov; user1525588; s0u1; Grubly; Емельянов Алексей; +6 Ответить
15. swimdog 765 29.11.17 13:20 Сейчас в теме
(2) Добавил в статью
Емельянов Алексей; +1 Ответить
3. maikl007 91 29.11.17 08:04 Сейчас в теме
Все работает...

Процедура ПаузаWSH(Секунд) Экспорт
	
	ПолноеИмяФайла  = КаталогВременныхФайлов() + "sleep.vbs";
	Текст = Новый ТекстовыйДокумент;
	Текст.ДобавитьСтроку("wscript.sleep wscript.arguments(0)");
	Текст.Записать(ПолноеИмяФайла, КодировкаТекста.OEM);
	
	WshShell = Новый COMОбъект("Wscript.Shell");
	WshShell.Run("Wscript.exe """+ПолноеИмяФайла+""" "+Секунд*1000, 0, 1);
  
КонецПроцедуры
Показать
4. japopov 68 29.11.17 08:15 Сейчас в теме
Почему-то забыли для УФ асинхронный диалог вопроса? Он принимает параметр Таймаут (который нам и нужен), и заодно выводит юзеру сообщение - а обратная связь не помешает, ведь так? Я обычно вызываю что-то вроде

&НаКлиенте
Процедура ПриОткрытии(Отказ)

	СписокКнопок = Новый СписокЗначений;
	СписокКнопок.Добавить(КодВозвратаДиалога.Прервать,"Прервать");
	ЗадержкаВСекундах = 5;
	ПоказатьВопрос(Новый ОписаниеОповещения("ПриОткрытииЗавершение", ЭтаФорма), "Выполняется Супер-обработка. Подажуйста, подождите",СписокКнопок,ЗадержкаВСекундах,,"Длительная операция");

КонецПроцедуры

&НаКлиенте
Процедура ПриОткрытииЗавершение(РезультатВопроса, ДополнительныеПараметры) Экспорт
	
	Если РезультатВопроса=КодВозвратаДиалога.Таймаут Тогда
		ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Вы дождались, ура!");
	Иначе
		ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Невтерпёж, да?");
	КонецЕсли;
	
КонецПроцедуры

Показать


Кроме очевидного - задержки, не нагружая системные ресурсы - этот метод даёт пользователю возможность прервать длительный процесс, а нам - корректно отработать это прерывание и сделать всё красиво.

Ах, да, и самое, наверное, важное: этот метод работает с любым клиентом в любой операционной системе. В отличие от.
user646807_kazako.a911; NittenRenegade; ktb; EVKash; Ali_q; Irwin; user1334089; viktor3d; independ; Merkalov; hydro2588_2015; user1058740; SV6; adhocprog; seperblunt2; DarkUser; y.dyachenko; TreeDogNight; necropunk; jif; Yakud3a; Gluk_1C; mickey.1cx; vano-ekt; forseil; NeviD; WizaXxX; +27 1 Ответить
5. zqzq 23 29.11.17 08:41 Сейчас в теме
(4) +1, какой-то набор вредных советов в статье :) Если только нужно именно на сервере пауза, в очень редких случаях.

Есть ещё
ПодключитьОбработчикОжидания()

работает и в обычных и в управляемых формах.
semagin@gmail.com; mutoc@mail.ru; +2 3 Ответить
27. gigabyte_artur 26.12.18 12:31 Сейчас в теме
Найдено в недрах БСП:

Процедура Пауза(Секунд) Экспорт
	
	ТекущийСеансИнформационнойБазы = ПолучитьТекущийСеансИнформационнойБазы();
	ФоновоеЗадание = ТекущийСеансИнформационнойБазы.ПолучитьФоновоеЗадание();
	
	Если ФоновоеЗадание = Неопределено Тогда
		Параметры = Новый Массив;
		Параметры.Добавить(Секунд);
		ФоновоеЗадание = ФоновыеЗадания.Выполнить("ОбщегоНазначенияБТС.Пауза", Параметры);
	КонецЕсли;
		
	Попытка
		ФоновоеЗадание.ОжидатьЗавершения(Секунд);
	Исключение
		Возврат;
	КонецПопытки;
	
КонецПроцедуры
Показать


Платформо-независимо, работает на сервере, не нагружает процессор.
Вызов из БСП:

ОбщегоНазначенияБТС.Пауза(5);
user693240_abramovskaya; RibD; mtv79; Риник; BenDigget; user1436515; indefinitum000; orfos; ixijixi; polyplastic; KirillZ44; x_under; Alex_Iz; murat_; smit1c; 0vrcr; AndrewKop; user1232941; ktb; Mechanist; EVKash; user1374747; Ali_q; user1114234; Orlando Skibraves; Egovigor; Tangram; alenakrr; Samson-lim; Vovhik; ybatiaev; kyrasol; Irwin; Jeka44; fuser; Andrei_Ivanov; FuJluH; user1188623; NikeeNik; Anosov_EP; wolder; sodrk; KirinaAS; Aleskey_K; Invodev; KostyaLavr; Merkalov; axsebur; serg1c; vita8383; beardlyhich; Mi4man; hydro2588_2015; KilloN; davdykin; user990914; Anything; batusai_00; Alex_Prodigy; aezdakov; QZet; json; dreamerr7; adhocprog; Vampeg; leonidt84; boogie; noon; uno-c; +69 Ответить
28. gigabyte_artur 26.12.18 12:34 Сейчас в теме
Найдено в недрах БСП:

Процедура Пауза(Секунд) Экспорт
	
	ТекущийСеансИнформационнойБазы = ПолучитьТекущийСеансИнформационнойБазы();
	ФоновоеЗадание = ТекущийСеансИнформационнойБазы.ПолучитьФоновоеЗадание();
	
	Если ФоновоеЗадание = Неопределено Тогда
		Параметры = Новый Массив;
		Параметры.Добавить(Секунд);
		ФоновоеЗадание = ФоновыеЗадания.Выполнить("ОбщегоНазначенияБТС.Пауза", Параметры);
	КонецЕсли;
		
	Попытка
		ФоновоеЗадание.ОжидатьЗавершения(Секунд);
	Исключение
		Возврат;
	КонецПопытки;
	
КонецПроцедуры
Показать


Платформо-независимо, работает на сервере, не загружает процессор.
Вызов из БСП (пример):

ОбщегоНазначенияБТС.Пауза(5);
KirillZ44; Alex_Iz; pavelzdv; Danila7Zz; mikhanik1; Samson-lim; oneworker; user1525588; Irwin; suepifanov; beardlyhich; MrBukas; Anything; Емельянов Алексей; user774630; Alogy; Vampeg; +17 Ответить
45. Reserv1st 01.04.21 16:36 Сейчас в теме
(28)
Прикрепленные файлы:
46. WSeReGaW 01.04.21 19:58 Сейчас в теме
(45) Все верно, это старый метод, с 8.3.13 использовать надо "ОжидатьЗавершенияВыполнения"
51. sodrk 13.08.21 08:59 Сейчас в теме
БСП жеж, (3.1.3.548):
// Останавливает выполнение кода на заданное время.
//
// Параметры:
//  Секунд - Число - время ожидания в секундах.
//
Процедура Пауза(Секунд) Экспорт
	
	ТекущийСеансИнформационнойБазы = ПолучитьТекущийСеансИнформационнойБазы();
	ФоновоеЗадание = ТекущийСеансИнформационнойБазы.ПолучитьФоновоеЗадание();
	
	Если ФоновоеЗадание = Неопределено Тогда
		Параметры = Новый Массив;
		Параметры.Добавить(Секунд);
		ФоновоеЗадание = ФоновыеЗадания.Выполнить("ОбщегоНазначенияБТС.Пауза", Параметры);
	КонецЕсли;
		
	ФоновоеЗадание.ОжидатьЗавершенияВыполнения(Секунд);
	
КонецПроцедуры
Показать
Mechanist; anten22; +2 Ответить
60. sandr13 32 25.10.23 18:30 Сейчас в теме
(51)Не во всякой БСП это есть, в 3.1.9.179 этой функции нет, как и модуля такого.
59. sandr13 32 25.10.23 18:22 Сейчас в теме
(28)
ОбщегоНазначенияБТС
Не во всякой БСП это есть, в 3.1.9.179 этой функции нет, как и модуля такого.
48. NoRazum 29 05.07.21 12:04 Сейчас в теме
(5) Эти очень редкие случаи когда встречаются. То вредные советы очень нужны.
16. bulpi 215 29.11.17 13:53 Сейчас в теме
(4)
То, что Вы предлагаете, принципиально не годится, именно из-за асинхронности. Нужна ПАУЗА! А у Вас не будет никакой паузы. Висящий вопрос в асинхронном режиме - это не пауза, т.к. программа уже пошла вовсю дальше работать.
17. japopov 68 29.11.17 14:44 Сейчас в теме
(16)
То, что Вы предлагаете, принципиально не годится, именно из-за асинхронности. Нужна ПАУЗА! А у Вас не будет никакой паузы. Висящий вопрос в асинхронном режиме - это не пауза, т.к. программа уже пошла вовсю дальше работать.


То есть, как делать формы для работы в асинхронном режиме, Вы не умеете. Но это - недостаток Вас как специалиста, а не моего ответа как алгоритма.

Подскажу для тех, кто в танке: код в методе ПриОткрытииЗавершение() выполнится только после завершения ожидания.
Переносите в него всё, что должно было отработать после паузы, и всё!

А вообще, сайт its.1c.ru, и RTFM
ermek6; victorree; +2 2 Ответить
21. bulpi 215 29.11.17 17:54 Сейчас в теме
(17)
То есть, смысл моего замечания Вы не поняли. Но это - недостаток Вас как специалиста, а не моего замечания :).
Уж конечно, я понимаю, что "код в методе ПриОткрытииЗавершение() выполнится только после завершения ожидания". Но вот то, что ПОСЛЕ ПоказатьВопрос - выполнится сразу. И вот этот "гениальный" подход : "Переносите в него всё, что должно было отработать после паузы, и всё" - применим не всегда. Или для этого нужно извратиться так, как рвать гланды через Ж. Статья вообще не об этом, а о паузе. А это не ПАУЗА ( впрочем, что-то я повторяюсь, а зачем ? )
igrned; SanchoD; +2 Ответить
6. d_protos 29.11.17 09:33 Сейчас в теме
Статья не настолько полезна, насколько вредна.
Если нужна пауза в клиентском коде, то есть ПодключитьОбработчикОжидания() и не нужно изобретать велосипед.
Если нужна пауза в серверном коде, то что-то не так с логикой приложения.
semagin@gmail.com; DarkUser; +2 15 Ответить
8. ediks 335 29.11.17 10:16 Сейчас в теме
(6)
Если нужна пауза в серверном коде, то что-то не так с логикой приложения.

Вы считаете, что обработкам, выполняющимся на сервере, совсем никогда не нужна задержка выполнения?
Реальный пример кода, где обработка ждет, когда все задания отправятся на принтер. Кстати, применен один из методов паузы, описанный автором статьи:
Пока пОбъектПринтер.cCountOfPrintjobs < пКоличествоЗадачПечати И ТекущаяДата() <= ПаузаОкончание Цикл
	//Wait until all print jobs have entered the print queue
	Если пКоличествоЗадачПечати = 0 Тогда Прервать КонецЕсли; 
КонецЦикла;
9. Yimaida 37 29.11.17 10:40 Сейчас в теме
(6) пример из жизни. нужна была пауза при отправке смс, т.к. оператор устанавливал лимит на количество сообщений в очереди в секунду.
P.S. Сделал через ПодключитьОбработчикОжидания()
Alex_Iz; ktb; Egovigor; Cерый; arsvlg; Емельянов Алексей; echo77; sasha777666; +8 Ответить
7. ediks 335 29.11.17 09:53 Сейчас в теме
(0)
3) Варианты с использованием Sleep. Насколько я понимаю, требуют наличия программы sleep.exe.

Не соглашусь с автором - вариант SleepJs прекрасно работает.

СкриптФайл  = Новый ТекстовыйДокумент;
СкриптФайл.УстановитьТекст("WScript.Sleep(5000)");
СкриптФайл.Записать(КаталогВременныхФайлов() + "clean.vbs",КодировкаТекста.ANSI);
Сообщить(ТекущаяДата());
ЗапуститьПриложение("""" + КаталогВременныхФайлов() + "clean.vbs""",, Истина);
Сообщить(ТекущаяДата());
14. swimdog 765 29.11.17 13:04 Сейчас в теме
(7) Работает, у меня пауза была не в секундах, а в миллисекундах, поэтому я решил, что не работает.
10. МихаилМ 29.11.17 11:25 Сейчас в теме
все варианты работают в windows. укажите чисто 1с метод через HTTPСоединение или ожидания блокировки
19. Darklight 32 29.11.17 16:34 Сейчас в теме
(10) Через HTTPСоединение
функция ОжидатьЧерезHTTP(Знач Таймаут)
	хтп = новый HTTPСоединение("1C.ru",11111,,,,Таймаут);
	Попытка
		хтп.получить(новый HTTPЗапрос (""));
	исключение
		
	Конецпопытки;
КонецФункции
Показать


Будет платформенонезависимо, будет работать на клиенте. Но опять-таки, не работает в безопасном режиме (хотя на сервере профиль безопасности можно настроить, чтобы работало - для КОРП лицензии сервера).

И, главное, чтобы строка соединения в "HTTPСоединение" была указана корректная - чтобы доступ к HTTP ресурсу в принципе был!
OslikIA; Емельянов Алексей; alk; adhocprog; +4 Ответить
11. troubleshooter 27 29.11.17 11:28 Сейчас в теме
Если очень хочется ждать на сервере, то на мой взгляд наименее костыльный способ - это ожидание фоновым заданием самого себя.

Процедура ЖдатьНаСервереВФоновомЗадании(Знач Таймаут) Экспорт
		
	Ключ = Строка(Новый УникальныйИдентификатор());
	Наименование = "Фоновое ожидание";
	
	МассивПараметров = Новый Массив;
	МассивПараметров.Добавить(Таймаут);
	МассивПараметров.Добавить(Ключ);
	МассивПараметров.Добавить(Наименование);
	
	ФЗ = ФоновыеЗадания.Выполнить("ОбщегоНазначения.ЖдатьЗавершенияФонового", МассивПараметров, Ключ, Наименование);
	ФЗ.ОжидатьЗавершения();
	
КонецПроцедуры


Процедура ЖдатьЗавершенияФонового(Таймаут,Ключ,Наименование) Экспорт
	
	Попытка
		ФоновыеЗадания.ПолучитьФоновыеЗадания(Новый Структура("Наименование,Ключ", Наименование, Ключ))[0].ОжидатьЗавершения(Таймаут);
	Исключение
	КонецПопытки;	
	
КонецПроцедуры
Показать
EvgeTrofi; json; adhocprog; uno-c; KEV_SZK; JohnyDeath; Evil Beaver; Krio2; Darklight; nixel; azubar; Labotamy; +12 Ответить
18. Darklight 32 29.11.17 15:48 Сейчас в теме
Ожидание на фоновом задании - самое интересное решение (сам только что хотел предложить такое же) - но, надо бы проверить как будет вести себя в файловой базе. Предложу ещё фичу - один раз запустить "бесконечное" регл. задание (аналогично ждущее завершения самого себя) - и всем остальным сеансам обращаться на ожидание завершения ФЗ этого регл. задания. Но будет одна пользовательская лицензия расходоваться на регл. задание. Но ФЗ доступны только на сервере или в толстом клиенте - но для длительного ожидания можно и в серверный контекст переходить - это не проблема.

Остальные все советы платформенозависимые (хотя некоторые подходы можно переработать так, чтобы они имели реализацию для разных платформ).
Использовать WshShell
WshShell = Новый COMОбъект("Wscript.Shell");
WshShell.Run("Wscript.exe...")

Всё же не рекомендую - 10-я версия платформы на это может ругаться, да ещё и в безопасном режиме работать не будет.
Но если надо так - то лучше "ЗапуститьПриложение(КомандаWindows,,Истина);" - по крайней мере будет работать в Windows, Linux и MacOS (c WEB-клиентом могут быть проблемы), где теперь тоже есть клиенты 1С.

Если нужно чисто на клиенте - то придётся извращаться с "ПодключитьОбработчикОжидания" - если нужно платформеннонезависимое решение, работающее в безопасном режиме, без модальности.

Но прямо среди кода остановиться так не получится - но, на мой взгляд, если такой код разбить на части через "ПодключитьОбработчикОжидания" не получится - значит там явно очень плохой дизайн.

Либо, нужно просто написать классический бесконечный цикл (думаю, что сюда попадут лишь короткие паузы - не более пары секунд- можно и покрутить проц клиента - коли уж очень нужно).

Или писать платформеннозависимый не безопасный код через вызов «ЗапуститьПриложение» или, ожидать на фоновом задании (регламентном или специально запускаемом), ждущим самого себя; с заходом в серверный контекст выполнения (если это не толстый клиент).

В общем всё ещё ждём, когда 1С встроит в платформу системную функцию паузы... давно ждём....
sulfur17; uno-c; Krio2; troubleshooter; +4 Ответить
61. sandr13 32 25.10.23 18:32 Сейчас в теме
(11)Не во всякой БСП это есть, в 3.1.9.179 этой функции нет, как и модуля такого.
12. azubar 45 29.11.17 12:27 Сейчас в теме
Можно еще так фоновое задание+блокировки:

// Процедура - Ожидание
//
// Параметры:
// Длительность - Число - длительность ожидания в секундах.
//
Процедура Ожидание(Длительность) Экспорт
 
     Идентификатор = Новый УникальныйИдентификатор;
 
     НачатьТранзакцию();
 
     Блокировка = Новый БлокировкаДанных; 
     Элемент = Блокировка.Добавить("РегистрСведений.сшпБлокировкаОчереди");
     Элемент.Режим = РежимБлокировкиДанных.Исключительный;
     Элемент.УстановитьЗначение("Идентификатор", Идентификатор); 
     Блокировка.Заблокировать();
 
     мсвПараметров = Новый Массив;
     мсвПараметров.Добавить(Идентификатор);
     Задание = ФоновыеЗадания.Выполнить("сшпОбщегоНазначения.ВыполнитьПаузу", мсвПараметров,, "Выполнить паузу "+Длительность+" сек.");
 
     Попытка
          Задание.ОжидатьЗавершения(Длительность);
          Исключение
     КонецПопытки; 
 
     ОтменитьТранзакцию();
 
КонецПроцедуры
Показать


// Процедура - Выполнить паузу
//
// Параметры:
// Идентификатор - УникальныйИдентификатор - идентификатор сессии ожидания.
//
Процедура ВыполнитьПаузу(Идентификатор) Экспорт
 
     НачатьТранзакцию();
     Блокировка = Новый БлокировкаДанных;
 
     Элемент = Блокировка.Добавить("РегистрСведений.сшпБлокировкаОчереди");
     Элемент.Режим = РежимБлокировкиДанных.Исключительный;
     Элемент.УстановитьЗначение("Идентификатор", Идентификатор);
 
     Попытка
          Блокировка.Заблокировать();
     Исключение
     КонецПопытки;
     ОтменитьТранзакцию();
 
КонецПроцедуры
Показать
62. sandr13 32 25.10.23 18:32 Сейчас в теме
(12)Не во всякой БСП это есть, в 3.1.9.179 этой функции нет, как и модуля такого.
20. opx 794 29.11.17 16:40 Сейчас в теме
Я думаю, что это хороший пример того как писать не надо.
sashapere; +1 1 Ответить
24. user966794 27.04.18 21:13 Сейчас в теме
(20)Павел, здравствуйте! Пишу не по теме, но хотелось бы проконсультироваться с Вами по поводу Вашего плагина для вордпресс opcity. Как с Вами можно связаться?
55. opx 794 24.09.21 16:06 Сейчас в теме
Я не там комментарий написал
54. sulfur17 59 24.09.21 16:02 Сейчас в теме
(20) я думаю это хороший пример как не надо писать комментарии.
Если хотите подсказать как надо - напишите как надо.
А так полезной информации вы даете ноль, только автора демотивируете.
Bob_Dobr; ixijixi; pogroleg; +3 Ответить
22. Infector 199 30.11.17 12:34 Сейчас в теме
Думаю, что многие уже сами догадались, но все-таки нужно поотделять мух от котлет хотя бы для новичков, которые могут это читать:

Вариант с пингами:
&НаКлиенте
Процедура Ping_01(Секунд)
	
	КомандаWindows = "ping -n 1 -w "+Формат(1000 * Секунд, "ЧДЦ=0; ЧГ=") + " 127.255.255.255"; 
	WshShell = Новый COMОбъект("WScript.Shell"); 
	WshShell.Run(КомандаWindows, 0, -1); 
	
КонецПроцедуры


Трансформируется в:
&НаКлиенте
Процедура Ping_02(Секунд)
	
	КомандаWindows =  "ping -n 1 -w "+Формат(1000 * Секунд, "ЧДЦ=0; ЧГ=") + " 127.255.255.255"; 
    ЗапуститьПриложение(КомандаWindows,,Истина);
	
КонецПроцедуры


Аналогично Timeout, который я выложил в комментариях
&НаКлиенте
Процедура Timeout_03(Секунд)
	
	КомандаWindows = "Timeout /T " + Строка(Секунд) + " /NoBreak";
    ЗапуститьПриложение(КомандаWindows,,Истина);
	
КонецПроцедуры


Трансформируется в:
&НаКлиенте
Процедура Timeout_04(Секунд)            
	
	КомандаWindows = "Timeout /T " + Строка(Секунд) + " /NoBreak";

	WshShell = Новый COMОбъект("WScript.Shell"); 
	WshShell.Run(КомандаWindows, 0, -1); // Вставить содержимое обработчика.
	
КонецПроцедуры
Показать


Соответственно все эти варианты обращаются к командам, которые можно вводить через консольку операционной системы, использовать в CMD-файлах, но следует различать:
Во-первых обратиться можно к разным командам ОС (Ping, Timeout)
Во-вторых способ, которым можно обратиться - (Оператор платформы "ЗапуститьПриложение" и COMОбъект("WScript.Shell"); )

Соответственно - на клиенте "ЗапуститьПриложение" выкидывает черное окно с консолью, на сервере его никто не видит
COMОбъект("WScript.Shell") - обходится без визуальных эффектов.

А что из этого использовать - дело другое Timeout команда для задержки собственно и предназначенная, но в старых операционных системах (Windows 2000 точно, Windows XP не помню точно) отсутствовала. Проблема с CMD в те времена решалась похишением Timiout.exe с серверной операционной системы аналогичной давности и помещением в System32 на целевой машине.

А вот найти машину не поддерживающую Ping и лишенную TCP/IP напрочь уже тогда было сложно. (Хотя мне это удалось)
Bob_Dobr; HalWin; leemuar; Yasasha; serg_infostart; Alligator84; swimdog; +7 Ответить
23. fish249 05.12.17 09:45 Сейчас в теме
Спасибо, очень полезная статья.
25. swimdog 765 06.06.18 11:16 Сейчас в теме
Кусок функционала из БСП:

Функция ПроверитьДоступностьСервера(АдресСервера)
                
                СистемнаяИнформация = Новый СистемнаяИнформация();
                ЭтоWindows = (СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86) 
                               Или (СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86_64);
                               
                Если ЭтоWindows Тогда
                               ШаблонКоманды = "ping %1 -n 2 -w 500";
                Иначе
                               ШаблонКоманды = "ping -c 2 -w 500 %1";
                КонецЕсли;
                
                СтрокаКоманды = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(ШаблонКоманды, АдресСервера);
                
                Результат = ЗапуститьПрограмму(СтрокаКоманды, ПараметрыЗапускаПрограммы);
Показать
26. nordcomp 05.12.18 09:43 Сейчас в теме
Ссылка на эту статью есть в публикации, которую использовали. Взяли на заметку
29. mevgenym 87 14.03.19 12:46 Сейчас в теме
+ в копилку
типовой из подсистемы Меркурий (первая версия подсистемы опубликована в июле 2018)

Функция Ожидать(ВремяОжидания) Экспорт
	
	Если ВремяОжидания <> 0 Тогда
		
		НастройкиПрокси = Новый ИнтернетПрокси(Ложь);
		НастройкиПрокси.НеИспользоватьПроксиДляЛокальныхАдресов = Истина;
		НастройкиПрокси.НеИспользоватьПроксиДляАдресов.Добавить("127.0.0.0");
		
		Попытка
			Loopback = Новый HTTPСоединение(
				"127.0.0.0",,,,НастройкиПрокси,
				ВремяОжидания);
			Loopback.Получить(Новый HTTPЗапрос());
		Исключение
			ВремяОжидания = 0;
		КонецПопытки;
		
	КонецЕсли;
	
КонецФункции
Показать


Подобный вариант уже предлагали выше и обсуждали на мисте
https://www.forum.mista.ru/topic.php?id=686617

понравилось :)
Функция Слиип(Сек)
  КонДата = ТекущаяДата() + Сек;
  Пока ТекущаяДата() < КонДата Цикл
      ОтправитьПисьмоНуралиеву("Боря добавь Sleep() в 1С");
  КонецЦикла;
КонецФункции
RibD; sizeoff; G_101343795907160391674; KirillZ44; user859207; ImHunter; mart-sha; SerVer1C; KilloN; EMelihoff; acanta; uno-c; +12 Ответить
30. uno-c 234 19.03.19 01:35 Сейчас в теме
(29)Сами же мучаются, но написать встроенную в язык паузу - все никак ... Автору спасибо и за статью, и за то, что статья получилась собиратель полезных комментариев. Конструктивным комментаторам тоже ++. Мой пример серверной потребности в паузе: в регламентном задании отправляю на сторонний php скрипт картинки порциями, скрипт их закачивает и параллельно создает миниатюры, иногда не успевает к моей следующей отправке порции картинок - нужна пауза несколько секунд.
31. juker 252 02.06.19 18:14 Сейчас в теме
Спасибо автору и комьюнити, не пришлось изобретать велосипед.
32. SirYozha 222 04.06.19 12:12 Сейчас в теме
Еще из БСП (обработка УправлениеДоступом):
&НаКлиенте
Процедура Пауза(ИнтервалОжидания)
	
	ЗапуститьСОжиданиемЗавершенияРаботыПриложения("timeout /t " + Формат(ИнтервалОжидания, "ЧГ=0"), "Пауза", 0);
	
КонецПроцедуры

&НаКлиенте
Функция ЗапуститьСОжиданиемЗавершенияРаботыПриложения(СтрокаЗапуска, Контекст, ВидОкнаЗапускаемогоПриложения = 1)
	
#Если МобильныйКлиент Тогда
	ПоказатьПредупреждение(, НСтр("ru = 'Инструмент ""Управление доступом"" не доступен в веб-клиенте и мобильном клиенте, необходимо использовать тонкий клиент.'"));
	Возврат Неопределено;
#Иначе
	КодВозврата = -1;
	СистемныйПроцесс = Новый COMОбъект("WScript.Shell");
	
	Попытка
		КодВозврата = СистемныйПроцесс.Run(СтрокаЗапуска, ВидОкнаЗапускаемогоПриложения, Истина);
	Исключение
		ТекстОшибки = НСтр("ru = 'Ошибка запуска в %1: %2
			|Строка запуска: %3'");
		
		ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			ТекстОшибки, Контекст, ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()), СтрокаЗапуска);
		
	КонецПопытки;
	
	Возврат КодВозврата;
#КонецЕсли

КонецФункции
Показать
33. scream 31 15.10.19 14:14 Сейчас в теме
34. andryandry 94 08.12.19 14:59 Сейчас в теме
САМЫЙ КОШЕРНЫЙ SLEEP - платформонезависимый, не требует прав пользователя\расширения на запуск внешних процессов

Процедура Sleep(КоличествоСекунд)
   Попытка
     Соединение = Новый HTTPСоединение("127.0.0.0",,,,,КоличествоСекунд);
     Соединение.Получить(Новый HTTPЗапрос());
   Исключение
   Конецпопытки;	
КонецПроцедуры
Показать
sandr13; OslikIA; Емельянов Алексей; janit; Andy.Shel; aairt; AKunitsyn; AndrewKop; Infector; Sothale; TimIrkutsk; soci0pat; Eeeehhhh; Sergey_Borisovi4; b00ker; unichkin; KUAvanesov; stvorl; curdate; Leo_A; acanta; +21 2 Ответить
35. user799503 6 01.02.20 12:01 Сейчас в теме
Делаем что-то

Для н=1 По 75000 Цикл
//ожидание
КонецЦикла;

Делаем что-то другое

у меня 75000 - приблизительно 2/3 секунды
36. user799503 6 02.02.20 09:14 Сейчас в теме
Кстати с секундной задержкой ещё проще

ТДата=ТекущаяДата()+х, где х - это количество целых секунд.

Пока ТДата>ТекущаяДата() Цикл
КонецЦикла;
37. swimdog 765 02.02.20 17:33 Сейчас в теме
(36) Вариант 2 в статье. Там же написаны его минусы.
38. user1096076 09.03.20 17:18 Сейчас в теме
Мой вариант:

ВремяЗавершения = ТекущаяДата() + Время;
	Пока ТекущаяДата() < ВремяЗавершения Цикл
	КонецЦикла;
39. nuctoh 31 30.04.20 12:18 Сейчас в теме
(38) Сильно нагружает процессор и жрет память. Никогда так не делай!
40. user1096076 27.05.20 08:46 Сейчас в теме
(39) так в КА типовой сделано)).
41. swimdog 765 31.05.20 12:43 Сейчас в теме
(40) Это потому, что они инфостарт мало читают.
RibD; Merkalov; KilloN; +3 Ответить
47. Alien_job 190 21.06.21 03:39 Сейчас в теме
(42) Вроде нет - там не добавили Спать(), Ждать можно только другой код и мы возвращаемся к изначальной проблеме.
43. Sergynia 4 08.01.21 14:07 Сейчас в теме
Спасибо, очень помогло.
44. berezin84 27.01.21 19:27 Сейчас в теме
// Код из ут 10.3
// Время в секундах
Процедура Пауза(Время)

	ВремяЗавершения = ТекущаяДата() + Время;
	Пока ТекущаяДата() < ВремяЗавершения Цикл
	КонецЦикла;

КонецПроцедуры
sashapere; GATTUSO; b00ker; Maximysis; +4 4 Ответить
49. Aligator69 08.07.21 11:47 Сейчас в теме
Мне больше всего нравиться такая реализация

Процедура ПаузаWSH(Секунд) Экспорт
    
    ПолноеИмяФайла  = КаталогВременныхФайлов() + "sleep.vbs";
    Текст = Новый ТекстовыйДокумент;
    Текст.ДобавитьСтроку("wscript.sleep wscript.arguments(0)");
    Текст.Записать(ПолноеИмяФайла, КодировкаТекста.OEM);
    
    WshShell = Новый COMОбъект("Wscript.Shell");
    WshShell.Run("Wscript.exe """+ПолноеИмяФайла+""" "+Секунд*1000, 0, 1);
  
КонецПроцедуры

Показать
50. ImHunter 312 04.08.21 07:37 Сейчас в теме
Кстати, Паузу из БТС нужно немного допилить, если Пауза требуется при работе фонового задания.
	
// Останавливает выполнение кода на заданное время.
//
// Параметры:
//  Секунд - Число - время ожидания в секундах.
//	ИдентификаторЗадания	-	УникальныйИдентификатор - Уникальный идентификатор задания, если Пауза выполняется в фоновом задании.
//
Процедура Пауза(Секунд, ИдентификаторЗадания = Неопределено) Экспорт
	
	ТекущийСеансИнформационнойБазы = ПолучитьТекущийСеансИнформационнойБазы();
	ФоновоеЗадание = ТекущийСеансИнформационнойБазы.ПолучитьФоновоеЗадание();
	Если ИдентификаторЗадания<>Неопределено И ФоновоеЗадание.УникальныйИдентификатор=ИдентификаторЗадания Тогда
		ФоновоеЗадание = Неопределено
	КонецЕсли;
	
	Если ФоновоеЗадание = Неопределено Тогда
		Параметры = Новый Массив;
		Параметры.Добавить(Секунд);
		Параметры.Добавить(ИдентификаторЗадания);
		ФоновоеЗадание = ФоновыеЗадания.Выполнить("АвтоматическийРасчет.Пауза", Параметры);
	КонецЕсли;
		
	ФоновоеЗадание.ОжидатьЗавершенияВыполнения(Секунд);
	
КонецПроцедуры
Показать
52. ImHunter 312 13.08.21 12:14 Сейчас в теме
(51) Только не БСП, а БТС. Теор, в конфе БТС может и не быть.
53. aleksey.kubovtsov 116 06.09.21 10:49 Сейчас в теме
smaharbA работает, процессор не нагружает
Клиент-Серверный режиме, sql
1С:Предприятие 8.3 (8.3.17.2231)
1С:Комплексная автоматизация 2 (2.4.13.243)
Вариант с фоновыми не проверял
...
ФоновоеЗадание.ОжидатьЗавершенияВыполнения(Секунд)
56. quick 583 09.02.22 11:26 Сейчас в теме
А ведь что стоило разрабам платформы добавить одну простую функцию?!!! Приходится заниматься всякими извращениями.
GV.; Roxan220; sergathome; PowerBoy; SP2000; +5 Ответить
57. Lubocka 36 08.05.22 22:59 Сейчас в теме
а можно без секунд?
мне нужно что то на подобии как в VBA EXCEL
Application.ScreenUpdating = True
Application.ScreenUpdating = False

а то у меня экран прыгает)
58. AlOkt 74 31.08.23 18:40 Сейчас в теме
&НаКлиенте
Процедура ОболочкаОбработчика ()
ОбработатьОжидание();
КонецПроцедуры


&НаСервере
Процедура ОбработатьОжидание()
// делаем всё, что требуется
КонецПроцедуры

//....
ПодключитьОбработчикОжидания("ОболочкаОбработчика", 3, Истина);
Оставьте свое сообщение