Сумма в запросе нарастающим итогом

Форум Программирование Общие вопросы программирования (Dev)

Запросы

1. MaximKor 20 22.03.17 07:38 Сейчас в теме

Здравствуйте! Помогите пожалуйста разобраться. Пытаюсь получить сумму нарастающим итогом в запросе. Т.е. при выводе печ формы из первого документа в этом году, сумма его реализации, последующие реализации по этому договору, уже сумма в печ форму должна быть нарастающим итогом. Мой запрос:

ВЫБРАТЬ 
    ПродажиОбороты.Период КАК МоментВремени1,
    ПродажиОбороты.СтоимостьОборот КАК Сумма1,
    ПродажиОбороты.Регистратор
ПОМЕСТИТЬ ВремТаб
ИЗ
    РегистрНакопления.Продажи.Обороты(, , Регистратор, ) КАК ПродажиОбороты
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ
    ВремТаб.МоментВремени1, 
    ВремТаб.Сумма1,
    СУММА(ВремТаб.Сумма1) КАК Сумма11
ИЗ
    ВремТаб КАК ВремТаб
        ЛЕВОЕ СОЕДИНЕНИЕ ВремТаб КАК ВремТаб1
        ПО ВремТаб.МоментВремени1 >= ВремТаб1.МоментВремени1
ГДЕ
    ВремТаб.Регистратор = &Регистратор
    И ВремТаб.МоментВремени1 МЕЖДУ &НачалоГода И &ТекПериод 

СГРУППИРОВАТЬ ПО 
    ВремТаб.МоментВремени1, 
    ВремТаб.Сумма1

Показать

Спасибо, заранее!

По теме из базы знаний

Ответы

Подписаться на ответы Инфостарт бот

Свернуть все

2. PhoenixAOD 62 22.03.17 08:04 Сейчас в теме

(1)То есть в каждой последующей реализации у вас должно быть уже имеющаяся сумма + сумма текущей реализации?

3. MaximKor 20 22.03.17 08:42 Сейчас в теме

(2) да, всё верно

4. PhoenixAOD 62 22.03.17 09:14 Сейчас в теме

(3)Тогда просто сделай отбор по контрагенту с периодом по текущую дату регистратора и суммируйте) по сути Вам требуется Весь оборот по контрагенту с текущим документов. Печатаете все равно после проведения документа.

5. starjevschik 22.03.17 09:38 Сейчас в теме

(1) запрос вот такой

	               |ВЫБРАТЬ
	               |	Реализации.Период,
	               |	Реализации.Реализация,
	               |	Реализации.СуммаРеализации,
	               |	Реализации.Договор,
	               |	Реализации.Контрагент,
	               |	Реализации.Проект,
	               |	Реализации.МоментВремени,
	               |	СУММА(ЕСТЬNULL(ПредыдущиеРеализации.СуммаВзаиморасчетов, 0)) КАК СуммаНарастания
	               |ПОМЕСТИТЬ РеализацииНарастающийИтог
	               |ИЗ
	               |	ВсеРеализации КАК Реализации
	               |		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
	               |			СУММА(Взаиморасчеты.СуммаВзаиморасчетов) КАК СуммаВзаиморасчетов,
	               |			Взаиморасчеты.ДоговорКонтрагента КАК ДоговорКонтрагента,
	               |			Взаиморасчеты.Регистратор КАК Регистратор,
	               |			Взаиморасчеты.МоментВремени КАК МоментВремени
	               |		ИЗ
	               |			РегистрНакопления.ВзаиморасчетыСКонтрагентами КАК Взаиморасчеты
	               |		ГДЕ
	               |			Взаиморасчеты.Регистратор ССЫЛКА Документ.РеализацияТоваровУслуг
	               |			И ВЫБОР
	               |					КОГДА &Договор = ЗНАЧЕНИЕ(Справочник.ДоговорыКонтрагентов.ПустаяСсылка)
	               |						ТОГДА ИСТИНА
	               |					ИНАЧЕ Взаиморасчеты.ДоговорКонтрагента = &Договор
	               |				КОНЕЦ
	               |			И Взаиморасчеты.Контрагент = &Контрагент
	               |		
	               |		СГРУППИРОВАТЬ ПО
	               |			Взаиморасчеты.ДоговорКонтрагента,
	               |			Взаиморасчеты.Регистратор,
	               |			Взаиморасчеты.МоментВремени) КАК ПредыдущиеРеализации
	               |		ПО Реализации.Договор = ПредыдущиеРеализации.ДоговорКонтрагента
	               |			И Реализации.МоментВремени > ПредыдущиеРеализации.МоментВремени
	               |
	               |СГРУППИРОВАТЬ ПО
	               |	Реализации.Договор,
	               |	Реализации.Контрагент,
	               |	Реализации.Реализация,
	               |	Реализации.МоментВремени,
	               |	Реализации.Период,
	               |	Реализации.Проект,
	               |	Реализации.СуммаРеализации

Показать

6. ipoloskov 162 22.03.17 09:45 Сейчас в теме

(1) вместо
СУММА(ВремТаб.Сумма1) КАК Сумма11
нужно
СУММА(ВремТаб1.Сумма1) КАК Сумма11

Называйте переменные и имена синонимов таблиц нормально, и таких проблем не будет возникать

7. MaximKor 20 22.03.17 10:19 Сейчас в теме

(6) не срабатывает, показывает сумму текущей реализации в Сумма1 и какие то странные числа по Сумма11.
там всего два документа у контрагента, сумма известна какая должны быть

8. ditp 91 22.03.17 10:42 Сейчас в теме

ВЫБРАТЬ
	ЕСТЬNULL(ПР.ДоговорКонтрагента.Владелец, ЗНАЧЕНИЕ(Справочник.Контрагенты.ПустаяСсылка)) КАК Контрагент,
	ПР.ДоговорКонтрагента КАК Договор,
	ПР.Период КАК Период,
	ПР.Регистратор,
	ПР.СтоимостьОборот КАК Сумма
ПОМЕСТИТЬ ВремТаб
ИЗ
	РегистрНакопления.Продажи.Обороты(, , Регистратор, ) КАК ПР
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	Л.Контрагент КАК Контрагент,
	Л.Договор КАК Договор,
	Л.Период КАК Период,
	Л.Регистратор КАК Регистратор,
	Л.Сумма,
	СУММА(П.Сумма) КАК СуммаНараст
ИЗ
	ВремТаб КАК Л
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВремТаб КАК П
		ПО Л.Контрагент = П.Контрагент
			И Л.Договор = П.Договор
			И (Л.Регистратор = П.Регистратор
				ИЛИ Л.Период > П.Период
				ИЛИ Л.Период = П.Период
					И Л.Регистратор > П.Регистратор)

СГРУППИРОВАТЬ ПО
	Л.Контрагент,
	Л.Договор,
	Л.Период,
	Л.Регистратор,
	Л.Сумма

УПОРЯДОЧИТЬ ПО
	Контрагент,
	Договор,
	Период,
	Регистратор

Показать

9. MaximKor 20 22.03.17 10:45 Сейчас в теме

добавил отбор по контрагенту и взял поля из ВремТаб1. всё вроде заработало.
Всем спасибо за отзыв!

Оставьте свое сообщение

E-mail: