Чтение группировок табличного документа

20.11.16

Разработка - Универсальные функции

Есть mxl, табличный документ, в котором сделана группировка строк, и надо прочитать из него данные с учётом этих группировок, т.е. иерархически. Сам документ читаем по ячейкам, но как быть с иерархией? На помощь приходит сериализация.

По сути, это простой пример по следам решения простой конкретной задачи. Но, к своему удивлению, навскидку я не нашёл таких решений, а значит, почему бы и не выложить.

Представленный вариант - для толстого клиента или для сервера. Желающие могут превратить таблицу и дерево значений в коллекции или данные формы, сути это не меняет. Суть очень проста - сериализовать в XDTO, через XML в DOM и прочитать сведения об иерархии по нужным узлам-тегам. Производительность на больших объёмах будет, естественно, не ахти, что надо учитывать; ну и если построитель DOM не потянет, придётся копать последовательным чтением XML. Мысль публикации лишь в том, что, хотя во встроенном языке нет возможности выяснить уровень области, данные об этом любой табличный документ хранит. Я поработал с группировками строк, нечто подобное можно сделать и для группировок колонок - это, к примеру, для любителей курочить выходной таб.документ СКД.

Итак:

// вспомогательная к ПрочитатьТабДокументСГруппировкамиВДерево
Процедура ЗаполнитьДеревоПоТаблицеРекурсивно(рРодитель,тДанных)
	Для каждого рВетка Из рРодитель.Строки Цикл
		ЗаполнитьДеревоПоТаблицеРекурсивно(рВетка,тДанных);
		мстро=тДанных.НайтиСтроки(Новый Структура("НомерПозицииРодителя",рВетка.НомерПозиции));
		Для каждого стро Из мстро Цикл
			ЗаполнитьЗначенияСвойств(рВетка.Строки.Добавить(),стро);
		КонецЦикла;
	КонецЦикла;
КонецПроцедуры

	
Функция ПрочитатьТабДокументСГруппировкамиВДерево(ТабДокумент,мИмёнКолонок) Экспорт
Попытка	
	тДанных=Новый ТаблицаЗначений;
	тДанных.Колонки.Добавить("НомерПозицииРодителя",Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,0,ДопустимыйЗнак.Любой))); // у старших - 0, у родителей -1
	дДанных=Новый ДеревоЗначений;
	дДанных.Колонки.Добавить("НомерПозиции",Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,0,ДопустимыйЗнак.Неотрицательный))); // у старших - 0
	// добавление смысловых колонок
	Для каждого знч Из мИмёнКолонок Цикл
		// тип у них у всех строковый
		тДанных.Колонки.Добавить(знч.Имя);
		дДанных.Колонки.Добавить(знч.Имя);
	КонецЦикла;
	
	Для й=1 По ТабДокумент.ВысотаТаблицы Цикл
		ОбработкаПрерыванияПользователя();
		стро=тДанных.Добавить();
		Для каждого знч Из мИмёнКолонок Цикл
			стро[знч.Имя]=СокрЛП(ТабДокумент.Область(й,знч.Столбец,й,знч.Столбец).Текст);
		КонецЦикла;
	КонецЦикла;
	Если тДанных.Количество()=0 Тогда
		Возврат дДанных;
	КонецЕсли;
	
	рЗапись=Новый ЗаписьXML;
	рЗапись.УстановитьСтроку("UTF-8");
	СериализаторXDTO.ЗаписатьXML(рЗапись,ТабДокумент);
	рЧтение=Новый ЧтениеXML;
	рЧтение.УстановитьСтроку(рЗапись.Закрыть());
	пострДом=Новый ПостроительDOM;
	докдом=пострДом.Прочитать(рЧтение);
	
	мУзловГрупп=докдом.ПолучитьЭлементыПоИмени("vg");
	Для каждого рУзелГруппы Из мУзловГрупп Цикл
		ОбработкаПрерыванияПользователя();
		рНачало=0; рКонец=0;
		Для каждого рПодузел Из рУзелГруппы.ДочерниеУзлы Цикл
			ОбработкаПрерыванияПользователя();
			Если рПодузел.ИмяУзла="b" Тогда
				рНачало=Число(СокрЛП(рПодузел.ТекстовоеСодержимое));
			ИначеЕсли рПодузел.ИмяУзла="e" Тогда
				рКонец=Число(СокрЛП(рПодузел.ТекстовоеСодержимое));
			КонецЕсли;
		КонецЦикла;
		Если рНачало=0 Тогда Продолжить КонецЕсли;
		Если рКонец=0 Тогда рКонец=рНачало КонецЕсли; // одна позиция в подгруппе
		рКонец=рКонец+1; // обязательная поправка
		// первому не ставим указание, он и есть родитель
		рВеткаГруппы=дДанных.Строки.Найти(рНачало-1,"НомерПозиции",Истина); // ищем родителя этого родителя
		Если рВеткаГруппы=Неопределено Тогда рВеткаГруппы=дДанных КонецЕсли;
		рВеткаДанных=рВеткаГруппы.Строки.Добавить();
		ЗаполнитьЗначенияСвойств(рВеткаДанных,тДанных[рНачало-1]);
		рВеткаДанных.НомерПозиции=рНачало; // именно так
		тДанных[рНачало-1].НомерПозицииРодителя=-1;
		// ставим в таблицу
		Для й=рНачало+1 По рКонец Цикл
			ОбработкаПрерыванияПользователя();
			тДанных[й-1].НомерПозицииРодителя=рНачало;
		КонецЦикла;
	КонецЦикла;
	
	тДанных.Индексы.Добавить("НомерПозицииРодителя");
	ЗаполнитьДеревоПоТаблицеРекурсивно(дДанных,тДанных);
	
	дДанных.Колонки.Удалить("НомерПозиции");
	Возврат дДанных;
	
Исключение
	Сообщить("ПрочитатьТабДокументСГруппировкамиВДерево, ошибка: "+ОписаниеОшибки(),СтатусСообщения.Важное);
	Возврат Неопределено;
КонецПопытки;
КонецФункции

P.S.  Если это баян, киньте в меня тапочком ссылкой.

Табличный документ группировки mxl сериализация

См. также

Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024    2670    0    John_d    8    

54

GUID в 1С 8.3 - как с ними быть

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.

12.02.2024    4610    atdonya    22    

45

Переоткрытие внешних обработок

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    3961    ke.92@mail.ru    16    

61

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8824    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2072    21    progmaster    7    

3

Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    16146    133    sapervodichka    112    

129

Система контроля ведения учета [БСП]

Универсальные функции Механизмы типовых конфигураций БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данном материале рассмотрим типовой алгоритм подсистемы контроля учета БСП в конфигурациях на примерах.

18.07.2022    7243    quazare    8    

109
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. json 3297 20.11.16 14:41 Сейчас в теме
Есть замечания к оформлению кода:
1. Процедуры и функции более верхнего уровня обычно располагаются выше, а используемые в них - под ними. Это логично и проще воспринимается. В вашем случае экспортная функция является методом более верхнего уровня и должна быть первой, а все неэкспортные под ней. (см. рекомендации по оформлению кода "Чистый код" Р.Мартин, либо можно открыть практически любой модуль в типовой конфигурации, и увидеть, что сначала идет секция ПрограммныйИнтерфейс, потом СлужебныйПрограммныйИнтерфейс и лишь в конце СлужебныеПроцедурыИФункции)
2. Также полезно было бы ознакомиться с рекомендациями образования имен переменных на диске ИТС (http://its.1c.ru/db/v8std#content:2149184103:hdoc). См. пункт 2 Пример некорректных имен переменных
3. Неужели так трудно давать переменным имена без сокращений? (Например в публикации на текущий момент вижу такие имена: мстро, рВетка, стро, знч) Я бы не хотел оказаться на месте разработчиков, которым придется поддерживать такое в продакшене!

Вообще мне кажется, что кода не так уж и много, чтобы причесать его перед тем, как публиковать. А по хорошему, причесывать надо каждый раз перед помещением в продуктив.
user756416; mvxyz; olegol; kaa_erpcentr; CyberCerber; a.kuznetsov; WaterSmith; Chif13; trntv; Sun_Storm; premierex; shalimski; +12 3 Ответить
2. Yashazz 4709 20.11.16 14:47 Сейчас в теме
(1) yurii_host, вы далеко не первый, кто мне это говорит)))
1. Расскажите это разработчикам типовых конфигураций)
2. Имена промежуточных и вспомогательных переменных не обязательно должны быть говорящими. Классический код на общепринятых языках программирования спокойно рассматривает "i" "j" "k" в качестве итераторов. Так что не довод) Опять же, сравните стандарты 1С и реальный код 1С, посмеётесь. И, думаете, я, автор тиражных решений, не знаю эти стандарты?))
3. См.п2, понять и так можно, и это несложно.

Вообще, это мой стиль и служит своеобразным "авторским клеймом". Я всегда отличу свой код от чужого, особенно бывает удобно, если его скопирайтили против моей воли. Считайте это авторским почерком и некоей обфускацией. Так что "причёсывать" тут, равно как и в других публикациях, не считаю нужным.
По делу есть замечания?
ivv1970; user1632423; +2 Ответить
10. json 3297 23.11.16 11:59 Сейчас в теме
(1) меня удивил минус к первому моему посту. Уважаемый Корум, не могли бы пояснить свою точку зрения с каким именно пунктом Вы не согласны?) Я вроде все обосновал и мало того привел еще и ссылки на рекомендации. Вы не согласны с тем, что код - вырвиглазный?

Позиция автора мне абсолютно понятна, она субъективна и направлена на отстаивание собственной правоты. Причем автор в своей манере отвечает общими фразами без конкретных фактов:
- так и не привел конкретные примеры про типовые конфигурации. Что именно по его мнению не соответствует рекомендациям, в каком модуле/процедуре можно увидеть это несоблюдение. Вместо этого привел зачем-то версию конфигурации. Если он слабо знаком с Системой стандартов и методик разработки конфигураций для платформы 1С:Предприятие 8, то как он может отследить такое несоблюдение?
- я указал на сокращения переменных, а он начал объяснять про итераторы. Это вроде как не одно и то же. Если посмотреть на ссылку, которую я привел в посту 1, то там явно сказано, что "Использование коротких имен допускается только для счетчиков циклов" и к этому у меня нет претензий.
- кроме того, сокращения крайне затрудняют командную разработку. Ведь это же очевидно. Смотрите, по поводу сокращений у каждого человека свой набор правил, кто-то вообще любит сокращать на гласную букву (см. в публикации переменная мстро). И даже если можно догадаться из контекста что именно означает сокращение, то все равно читать чужой код, который пестрит сокращениями - очень неприятное занятие. Голова очень быстро перегружается, т.к. она должна помнить, что означает каждое сокращение. Спросите у коллеги, который будет поддерживать ваш код, хочет ли он, чтобы вы использовали сокращения. Или сами подумайте, хотите ли разбираться в чужом коде, в котором все переменные построены через сокращения? Ответ здорового человека может быть только один - "нет"
- про авторское клеймо - кому-нибудь еще кроме автора нужно это клеймо? Есть ли в нем какая-либо логическая целесообразность, которая бы давала преимущества и упрощала работу другим программистам? Ответ - "нет". Это просто такая своеобразная "причуда", которая скорее вредна, чем полезна.
- также автор стал приводить примеры из других языков программирования (при чем тут они), хотя читаемость кода зависит ведь не от языка программирования, а от программиста!!! Практически все современные языки программирования имеют средства для написания читаемого кода. Та же самая упомянутая автором Java. Ведь именно разработчики из этого языка внесли огромный вклад в построение читаемого и расширяемого кода

(2)
- еще автор считает, что "понять и так можно, и это несложно." Ведь тут всего то менее 100 строк кода. А представьте себе, что автор, к примеру, каждый день пишет и выкладывает в продуктив такое вот добро))) Это по-моему катастрофа, потому что такого кода становится все больше и больше, и он иногда покрывает важные функции системы, которые потом потребуется развивать. И разобраться что в нем происходит, при доработке каких-то сложных алгоритмов - и сложно и неприятно одновременно. Такой код не вызывает отторжения только у разработчиков, которые не читали профессиональную литературу и привыкли ориентироваться на свой опыт и опыт коллег.

Я повторю свой вопрос, Корум, не могли бы обосновать свою точку зрения, очень любопытно было бы услышать/прочитать с чем вы не согласны
mvxyz; astrallight; kaa_erpcentr; a.kuznetsov; unichkin; +5 Ответить
11. shard 279 23.11.16 12:58 Сейчас в теме
(1) yurii_host, не скажу за Корума, но поясню свое мнение:
1) ссылки на закрытые форумы и статьи выглядят неуважительно по отношению к не имеющим подписку ИТС.
2) требование размещать функции по порядку напомнило одного "специалиста" одной весьма крупной структуры, связанной с оказанием услуг в финансовой сфере, который высказывал весьма громкое "фи" касательно отсутствия пробелов в коде (при этом согласно рекомендациям пробелы отсутствовали только между // и текстом комментария), но незнакомого с иерархией элементов справочника.
user1194102; Yashazz; json; +3 1 Ответить
12. json 3297 23.11.16 13:20 Сейчас в теме
(11) shard, Ваша претензия по поводу ссылок на ИТС - абсолютно справедлива. Я этот нюанс выпустил из вида.
Но к сожалению, 1С не выкладывает их в общий доступ, а копировать полный текст и выкладывать на общем ресурсе - нарушение авторских прав.

Лично у меня не всегда есть доступ к сайту 1С. Поэтому основные разделы я себе скопировал и обращаюсь к ним периодически, независимо от наличия доступа. При этом разумеется, что на общедоступных ресурсах я это не выкладываю.

По моему скромному мнению, рекомендации формулируют требования, продиктованные здравым смыслом. В них другими словами перечислены основные моменты, которые описаны и в других книгах по написанию кода. Для тех, у кого нет доступа на ИТС, я бы рекомендовал прочитать книгу, упомянутую в первом посте. По моему мнению (и не только по моему) в ней собраны самые основные правила по построению читаемого кода, при этом автор приводит вполне убедительные аргументы. Эта книжка - меняет программистов, я наблюдал это примере своих коллег. При этом рекомендации, описанные в ней согласуются с рекомендациями, описанными в "Системе стандартов и методик..."

По поводу порядка процедур, рекомендация тоже взята тоже из книги "Чистый код". И как я привел пример, подтверждается построением кода в типовых, хотя на ИТС явно такое требование не описано. Такое расположение процедур удобно, т.к. человек привык читать код сверху вниз. Поэтому он ожидает сначала увидеть общую картину, а затем детали этой картины (при необходимости) т.е. по принципу декомпозиции. Поэтому логичнее сначала располагать процедуры более верхнего уровня, а под ними вложенные в них. Но Ваше право не соглашаться с таким подходом.

В любом случае благодарю за конструктивную обратную связь!
20. PLAstic 295 14.10.19 16:58 Сейчас в теме
(11) (12) Позволю себе в корне не согласиться. Если человек называет себя программистом, то он обязан иметь доступ к ИТС.
Если ты во франче, у тебя есть доступ к ИТС автоматом. Если ты в конторе, то ей надо поддерживать используемые продукты 1С и у них тоже должна быть подписка. Стоит она не так дорого для организации, а новые версии ПП и поддержка нужны всем.
Да и невозможно поддерживать свой уровень без доступа к документации.
21. shard 279 14.10.19 23:09 Сейчас в теме
(20) про фри Вы благополучно забыли. Из Вашего утверждения можно сделать вывод что программисты - это либо фра, либо фикс; остальные - унтерменши.

К тоже же сильно бросаются в глаза штампы "надо поддерживать используемые продукты 1С", "обязан иметь доступ к ИТС" (по сути - "обязан платить налог 1с"), штамп "стоит...не так дорого" (по сути - "ну купите, что вам стоит, или совсем нищеброды?"). Отвечу: если доступ к документации "не так дорог", тогда может это 1с его открыть надо?

Про невозможность поддерживать уровень без доступа к документации - истина, но как много Вы можете назвать контор не ИТ-профиля, которые могут выделить время программиста/сисадмина на повышение квалификации? Не знаю ни одной, в лучшем случае - "можешь взять отгул без сохранения", но обычно: "лучше иди квартал Мариванне закрой, или Танечке поступления вбей. Кстати ты уже сделал систему прогнозирования курса доллара, которую мы тебя уже с начала года просим?".
bds22; user1194102; +2 Ответить
22. PLAstic 295 15.10.19 08:36 Сейчас в теме
(21) Фри я не забыл, это не программист по моей терминологии. :) Далее в своём посте вы соглашаетесь, что уровень поддерживать нельзя без доступа к свежим обновлениям, к БСП и метод.материалам. Значит, это простой любитель.
Про ИТС можно сколько угодно спорить и взывать кому что надо сделать, но "собака лает, караван идёт" - вы ничего не измените. И я тоже когда-то называл ИТС налогом 1С. Если говорить беспристрастно, у вас должна быть подписка ИТС, если вы считает себя программистом.
Всё, что выкладывается на ресурсах, включая ИС - это добрая воля авторов, поэтому притязать на "неуважительно по отношению к не имеющим подписку ИТС" - ну, это сродни "вы должны мне всё выложить здесь и сейчас, т.к. я не хочу/не могу купить подписку ИТС". Вам никто ничего не должен. Есть регламентированный фирмой 1С информационный ресурс и ссылки на него, наоборот, должны приветствоваться для желающих пруфов или расширения представленных в статьях со ссылками знаний.
Про обучение - это ваш личный выбор. Не пускают на работе даже за свой счёт? Зачем вам такая работа? Я каждые 5 лет хожу за свой счёт на пачку курсов просто чтобы быть в теме, что появилось нового.
19. BenGunn 247 27.12.18 11:23 Сейчас в теме
(1) Меня все чаще и чаще стал удивлять подход я-ля критиков к чужой работе: вместо того, чтобы оценить новизну решения задачи, они пытаются искать субъективные причины, чтобы занизить профессиональные качества кодера. А, собственно, зачем это надо и кому? Не нравится стиль написания кода - перепиши под себя. Все просто, как мычание коровы
bds22; user1194102; +2 Ответить
3. json 3297 20.11.16 15:21 Сейчас в теме
1. Насколько я замечал, в типовых обычно соблюдают свои же рекомендации. Отклонение от рекомендаций - обычно редкость, которая связана либо с обоснованной необходимостью, либо с тем, когда недоглядели за автором кода. Буду признателен, если приведете конкретные примеры, вместо общих фраз.

2. Если вам часто это говорили, то может быть стоит к ним прислушаться? Ведь наверное не новички вам такое говорили? А вы сами пытались задуматься, почему требования именно такие? Может быть в них действительно есть разумное зерно?

3. На заявление, что это ваш стиль и визитная карточка обычно приводят такую фразу :
"Весь хороший код одинаков, кривой код - крив по-своему."
К сожалению, очень большое количество разработчиков думают примерно также. Когда одну конфигурацию дописывают несколько таких программистов, каждый со своей "визитной карточкой", то радости от поддержки такого кода не испытываешь никакой.
Мое мнение следующее: стилем разработчика должны быть красивые алгоритмы, интересные и простые решения, а никак не код! Код должен легко читаться и не выполнять никаких дополнительных функций, в том числе функцию визитной карточки.

4. Понять - да можно. Доработать в продуктиве такой код - скорее всего нет.

5. Неужели вы считаете так часто ваш код кто-то копирайтит?

6. Выкладываете код - значит отвечаете за него. Это по делу. Если он нечитаемый - какие-то ошибки в нем визуально найти очень сложно. Приведите сначала в читаемый вид, а потом будут вам замечания "по делу"
PLAstic; mivari; pavlov_dv; klinval; qwe_QWE; +5 Ответить
9. Dementor 1015 23.11.16 10:30 Сейчас в теме
(3) yurii_host, ваши слова - прямо танец по моим больным мозолям. В последнюю неделю помогал навести порядок в конфигурации, где в реализацию к типовым Количество и Количество мест добавили реквизиты - Колво, Колмест, Кмест (и еще парочку сокращений, которые не имели отношения к количествам). Прежде чем вообще начинать что-либо делать нужно было пройти квест "угадай что это и зачем его сюда влепили" с беганьем по интерфейсу формы и анализом доработок в проведении документа. А что бы работа была не скучной, предыдущий разработчик удалил конфигурацию поставщика и затер в свойствах версию конфигурации - видимо это элемент фирменного стиля :)
13. Yashazz 4709 23.11.16 21:31 Сейчас в теме
(9) За такие имена реквизитов действительно надо убивать, согласен. Но, повторюсь, вспомогательные служебные переменные совершенно не требуют нотации в духе ЭлементМассиваИзСтруктурыСоответствийГдеХранятсяДанныеДляОбр­аботки. Ну вот совсем это лишнее. Меру знать надо. Давеча тоже копался в конфе с реквизитами вроде "СпВопОтнос".
Комментарии - вещь строго обязательная, каковые и делаю)

А любителям говорить об уважении к, могу посоветовать посмотреть на БП 3.0 - я не знаю, как надо соблюдать чистоту разработки и испытывать уважение к тем, кто будет потом иметь с ней дело, если даже реквизиты в документах по алфавиту не отсортированы. Ломайте глаза, господа. Так? Никто не хочет пару баллонов на Фогеля накатить?
23. user1194102 19.01.20 16:09 Сейчас в теме
(9) это частный случай, в любой сфере есть люди на своем месте и не на своем, но бить себя в грудь, что у тебя есть подписка ИТС и ты по правилам 1С расставляешь переменные, еще не значит, что ты хороший программист, скорее наоборот. В любом коде главное это алгоритм как решение задачи и правильность/оптимальность кода, стиль тоже важен, но стиль это вторично. О чем вообще сыр бор? Все согласны что на стиль надо обращать внимание и по возможности писать код понятный другим. Еще мне не понятны принципы самого форума, плюсы ставить можно в темах , а минусы нельзя, если баллов меньше 30. Похоже правила на форуме писали тоже те, для кого важнее чистота кода, чем сам код. Сочувствую вам.
4. Yashazz 4709 20.11.16 16:11 Сейчас в теме
1. УТ 11.2 нескольких первых поколений. Многие места в БСП от лета прошлого года (релиз не помню).
2. Может быть)
3. Найдёте кривизну кода - приму с удовольствием и постараюсь исправить. Если это решение не интересное и не простое - обоснуйте. Если этот алгоритм некрасив - укажите, в чём)
4. Не согласен.
5. Были прецеденты, в т.ч. на ИС, были))
6. Если такой код лично для Вас нечитаемый - радуйтесь, что не работали на Паскале или PL, а уж тем паче на Фортране) Ну и что не работаете на Java, например. Переменная "е" привела бы Вас в негодование)))
5. Yashazz 4709 20.11.16 16:22 Сейчас в теме
Я уж молчу про гнуснейшую манеру называть переменные зарезервированными именами и ключевыми словами, которая, имхо, гораздо более вредна и опасна. Но нет, написать БлокировкаДанных=Новый БлокировкаДанных - это нормально. А назвать рБлокировка, чтобы не огрести щастья в некоторых релизах (как, например, 8.3.7) - это низя, это нихарашё. Ну, кому эстетика, а кому прагматика.
1giga; корум; +2 Ответить
6. vikad 129 20.11.16 19:06 Сейчас в теме
7. Yashazz 4709 21.11.16 12:47 Сейчас в теме
(6) vikad, ага, проблема упоминалась. Решение - нет. Я не уверен, что фиксин, при всех его понтах навроде "был найден хитрый трюк", делал именно так. Я предложенный вариант хитрым трюком бы не назвал бы))
8. Dementor 1015 23.11.16 10:23 Сейчас в теме
Код как я вижу имеет смысл для MXL полученного со стороны, в котором сделали группировки не отступами, а с помощью НачатьГруппуСтрок(). Очевидно, что для своего MXL, который делается на коленке намного проще самостоятельно оставить "хлебные крошки", что бы потом героически не парсить результат.

А у СКД (который вы совершенно не в тему статьи вспомнили) есть расшифровки (тип ЭлементРасшифровкиКомпоновкиДанныхПоля) с замечательным методом ПолучитьРодителей(). Поэтому когда я делаю свои обработчики расшифровок, то мне получить значение ячеек и значение группировочных полей - занятие простое, а вот для получения дополнительных параметров из соседних ячеек отчета уже приходится анализировать адрес активной ячейки и двигаться по табличному документу.
14. Vasja-k 21.09.17 11:15 Сейчас в теме
Скорректировал на случай нескольких подряд идущих группировок. Комментировать (=флудить) лень. Код рабочий.
Скрытый текст
ulvisultanov; ovasiliev; acanta; andryandry; Chif13; +5 Ответить
18. andryandry 94 27.10.18 11:57 Сейчас в теме
(14) Вот это годный код! А комментаторам "по поводу именования переменных" не так как им нравится - для вас в аду отдельный котел ?
15. WKBAPKA 214 21.04.18 15:47 Сейчас в теме
Автору респект. Для одной своей задачи сушил голову, как... спасибо
16. WKBAPKA 214 21.04.18 18:22 Сейчас в теме
Реально выручил... спасибо)
17. ABIZYAEV 18.10.18 17:38 Сейчас в теме
24. ivanchai 187 20.02.20 16:04 Сейчас в теме
Интересное решение, но у меня не работает. Похоже что алгоритм косячный. На файле который прикрепил вообще дерево кривое получается.
Прикрепленные файлы:
nomenclatures_10.09.2019_16.15.37_0.34187400 1568121337 Без заголовка шапки.mxl
26. Yashazz 4709 20.02.20 18:31 Сейчас в теме
(24)
Похоже что алгоритм косячный

Не исключено. Я мог не учесть какой-то вариант.
27. ivanchai 187 20.02.20 20:10 Сейчас в теме
(26) Могу вас попросить посмотреть загрузку на файле который я приложил, в чем косяк. В отладчике смотрел но смысл механизма с DOM так и не понял
28. Yashazz 4709 20.02.20 20:57 Сейчас в теме
(27) ОК, но не раньше вечера субботы. И лучше продолжим в личке.
25. ivanchai 187 20.02.20 16:05 Сейчас в теме
29. mp40 10 10.11.22 23:02 Сейчас в теме
Проблема алгоритма в том, что он построен по принципу "на строчку выше всегда родительская группировка будет". И не учитывает наличие нескольких дочерних группировок.
"Группировка 1
Группировка 1_1
Группировка 1_2
Группировка 2
Группировка 2_1
Группировка 2_2
Группировка 2_3 "
Вот такую структуру не обработает, точнее не правильно. Он превратит ее в такую.
"Группировка 1
Группировка 1_1
Группировка 1_2
Группировка 2
Группировка 2_1
Группировка 2_2
Группировка 2_3 " Ну и вложенные если будут, тоже понятное дело поплывут.
Но сама схема хорошая, рабочая. Только надо отслеживать и верхнюю и нижнюю границы группировок. Доработал, делюсь кодом.
// вспомогательная к ПрочитатьТабДокументСГруппировкамиВДерево
Процедура ЗаполнитьДеревоПоТаблицеРекурсивно(рРодитель,ТаблицаДанных)
	Для каждого рВетка Из рРодитель.Строки Цикл
		ЗаполнитьДеревоПоТаблицеРекурсивно(рВетка,ТаблицаДанных);
		мстро=ТаблицаДанных.НайтиСтроки(Новый Структура("НомерПозицииРодителя",рВетка.НомерПозицииНачала));
		Для каждого стро Из мстро Цикл
			ЗаполнитьЗначенияСвойств(рВетка.Строки.Добавить(),стро);
		КонецЦикла;
	КонецЦикла;
КонецПроцедуры

	
Функция ПрочитатьТабДокументСГруппировкамиВДерево(ТабДок,мИмёнКолонок) Экспорт
	Попытка	
		ТаблицаДанных=Новый ТаблицаЗначений;
		ТаблицаДанных.Колонки.Добавить("НомерПозицииРодителя",Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,0,ДопустимыйЗнак.Любой))); // у старших - 0, у родителей -1
		ДеревоДанных=Новый ДеревоЗначений;
		ДеревоДанных.Колонки.Добавить("НомерПозицииНачала",Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,0,ДопустимыйЗнак.Неотрицательный))); // у старших - 0
		ДеревоДанных.Колонки.Добавить("НомерПозицииКонца",Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,0,ДопустимыйЗнак.Неотрицательный))); // у старших - 0
		Для каждого знч Из мИмёнКолонок Цикл
			// тип у них у всех строковый
			ТаблицаДанных.Колонки.Добавить(знч.Имя);
			ДеревоДанных.Колонки.Добавить(знч.Имя);
		КонецЦикла;
		
		Для к=1 По ТабДок.ВысотаТаблицы Цикл
			стро=ТаблицаДанных.Добавить();
			Для каждого Кол Из мИмёнКолонок Цикл
				стро[Кол.Имя]=СокрЛП(ТабДок.Область(к,Кол.Столбец,к,Кол.Столбец).Текст);
			КонецЦикла;
		КонецЦикла;
		Если ТаблицаДанных.Количество()=0 Тогда
			Возврат ДеревоДанных;
		КонецЕсли;
		
		Путь = ПолучитьИмяВременногоФайла("xml");
		рЗапись=Новый ЗаписьXML;
		рЗапись.УстановитьСтроку("UTF-8");
		СериализаторXDTO.ЗаписатьXML(рЗапись,ТабДок);
		рЧтение=Новый ЧтениеXML;
		рЧтение.УстановитьСтроку(рЗапись.Закрыть());
		пострДом=Новый ПостроительDOM;
		докдом=пострДом.Прочитать(рЧтение);

		мУзловГрупп=докдом.ПолучитьЭлементыПоИмени("vg");
		Для Каждого ЭлементПартнер Из мУзловГрупп[0].ДочерниеУзлы Цикл
			Название = ЭлементПартнер.ТекстовоеСодержимое;
			Для Каждого ЭлементКонтрагент Из ЭлементПартнер.ДочерниеУзлы Цикл
				Конт = ЭлементКонтрагент.ТекстовоеСодержимое;
				Для Каждого ЭлементБанк Из ЭлементКонтрагент.ДочерниеУзлы Цикл
					Банк = ЭлементБанк.ТекстовоеСодержимое;
				КонецЦикла;
			КонецЦикла;
		КонецЦикла;
		Для каждого рУзелГруппы Из мУзловГрупп Цикл
			рНачало=0; рКонец=0;
			Для каждого рПодузел Из рУзелГруппы.ДочерниеУзлы Цикл
				Если рПодузел.ИмяУзла="b" Тогда
					рНачало=Число(СокрЛП(рПодузел.ТекстовоеСодержимое));
				ИначеЕсли рПодузел.ИмяУзла="e" Тогда
					рКонец=Число(СокрЛП(рПодузел.ТекстовоеСодержимое));
				КонецЕсли;
			КонецЦикла;
			Если рНачало=0 Тогда Продолжить КонецЕсли;
			Если рКонец=0 Тогда рКонец=рНачало КонецЕсли; // одна позиция в подгруппе
			рКонец=рКонец+1; // обязательная поправка
			// первому не ставим указание, он и есть родитель
			рВеткаГруппы = Неопределено;
			Для Каждого Ветка Из ДеревоДанных.Строки Цикл
				//рВеткаГруппы=ДеревоДанных.Строки.Найти(рНачало-Поиск,"НомерПозиции",Истина); // ищем родителя этого родителя
				Если Ветка.НомерПозицииНачала <= рНачало И Ветка.НомерПозицииКонца >= рКонец+1 Тогда
					рВеткаГруппы = Ветка;
					Прервать;
				КонецЕсли;
			КонецЦикла;
			Если рВеткаГруппы=Неопределено Тогда
				рВеткаГруппы=ДеревоДанных
			КонецЕсли;
			рВеткаДанных=рВеткаГруппы.Строки.Добавить();
			ЗаполнитьЗначенияСвойств(рВеткаДанных,ТаблицаДанных[рНачало-1]);
			рВеткаДанных.НомерПозицииНачала=рНачало; // именно так
			рВеткаДанных.НомерПозицииКонца=рКонец+1; // именно так
			ТаблицаДанных[рНачало-1].НомерПозицииРодителя=-1;
			// ставим в таблицу
			Для н=рНачало+1 По рКонец Цикл
				ТаблицаДанных[н-1].НомерПозицииРодителя=рНачало;
			КонецЦикла;
		КонецЦикла;
		
		ТаблицаДанных.Индексы.Добавить("НомерПозицииРодителя");
		ЗаполнитьДеревоПоТаблицеРекурсивно(ДеревоДанных,ТаблицаДанных);
		
		ДеревоДанных.Колонки.Удалить("НомерПозицииНачала");
		ДеревоДанных.Колонки.Удалить("НомерПозицииКонца");
		Возврат ДеревоДанных;
		
	Исключение
		Сообщить("ПрочитатьТабДокументСГруппировкамиВДерево, ошибка: "+ОписаниеОшибки(),СтатусСообщения.Важное);
		Возврат Неопределено;
	КонецПопытки;
КонецФункции
Показать


К тапкам и критике готов. )))
extralook; Yashazz; +2 Ответить
Оставьте свое сообщение