ЭСЧФ Беларусь

Процедура ПроверкаОбязательныхПолей(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Обязательное - 1
	Если Не ЗначениеЗаполнено(СтруктураДанных.НомерЭСЧФ) Тогда
		
		ТекстОшибки = "Поле ""Номер ЭСЧФ <number>"" должно быть заполнено!";
		Отказ = Истина;
		
	//Обязательное - 2
	ИначеЕсли Не ЗначениеЗаполнено(СтруктураДанных.ТипЭСЧФ) Тогда
			
		ТекстОшибки = "Поле ""Тип ЭСЧФ <documentType>"" должно быть заполнено!";
		Отказ = Истина;
		
	//Обязательное - 3
	ИначеЕсли Не ЗначениеЗаполнено(СтруктураДанных.ДатаСовершенияОперации) Тогда
			
		ТекстОшибки = "Поле ""Дата совершения операции <dateTransaction>"" должно быть заполнено!";
		Отказ = Истина;
				
	//Обязательное - 4
	ИначеЕсли Не ЗначениеЗаполнено(СтруктураДанных.СтатусПоставщика) Тогда
			
		ТекстОшибки = "Поле ""Статус поставщика <providerStatus>"" должно быть заполнено!";
		Отказ = Истина;
				
	//Обязательное - 5-8 и 13-16 и 18-26 всегда заполнены в хмл
	//Обязательное - 9-11 пустые теги могут быть, проверка не возможна
	//Обязательное - 12
	ИначеЕсли Не ЗначениеЗаполнено(СтруктураДанных.СтатусПолучателя) Тогда
			
		ТекстОшибки = "Поле ""Статус получателя <recipientStatus>"" должно быть заполнено!";
		Отказ = Истина;
		
	//Обязательное - 17				
	Иначе
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			Если Не ЗначениеЗаполнено(Строка.НоменклатураСтр) Тогда
			
				ТекстОшибки = "Поле ""Наименование товаров (работ, услуг), имущественных прав (roster) <name>"" должно быть заполнено!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
		
		КонецЦикла;
	
	КонецЕсли;
	
КонецПроцедуры 

#Область ПроверкаЗаполненияПолей

//Правило-1 
//	Если тип ЭСЧФ – Дополнительный (со ссылкой на ЭСЧФ) или Исправленный, то
//	поле «К ЭСЧФ» обязательно для заполнения.
//Правило-1.1
//	Дата совершения дополнительного ЭСЧФ не должна быть меньше (раньше) даты
//	совершения исходного (исправленного) ЭСЧФ.
//
Процедура ПроверкаЗаполненияПолейПравило1(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Дополнительный ИЛИ
		СтруктураДанных.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исправленный Тогда
		
		//Поле 5 должно быть заполнено
		Если ЗначениеЗаполнено(СтруктураДанных.ИсходныйЭСЧФ) Тогда
			
			//Поле 5.1 не должно быть меньше даты совершения исходного (исправленного) ЭСЧФ
			Если СтруктураДанных.ДатаСовершенияОперации < Документ.ДатаСовершенияОперации Тогда 
				
				ТекстОшибки = "Поле 3. Дата совершения операции не должно быть меньше даты совершения исходного (исправленного) ЭСЧФ!";
				Отказ = Истина;
			
			КонецЕсли;
				
		Иначе
			
			ТекстОшибки = "Поле 5. Исходный ЭСЧФ не заполнено!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;
	
КонецПроцедуры 

//Правило-2
//	При заполнении поля «К ЭСЧФ», можно ввести только номер Исходного или Исправленного ЭСЧФ.
//
Процедура ПроверкаЗаполненияПолейПравило2(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Поле 5 должно быть заполнено
	Если ЗначениеЗаполнено(СтруктураДанных.ИсходныйЭСЧФ) Тогда 
	
		Если Не (Документ.ИсходныйЭСЧФ.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исходный ИЛИ
			Документ.ИсходныйЭСЧФ.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исправленный) Тогда
			
			ТекстОшибки = "В поле 5. Исходный ЭСЧФ можно ввести только номер Исходного или Исправленного ЭСЧФ!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-3
//	ЭСЧФ, номер которого прописывается в поле 5. "К ЭСЧФ" должен быть со статусом
//  «Выставлен» или «Выставлен. Подписан получателем».
//Правило-3.1 
//	У родительского и дочерних ЭСЧФ должен быть один составитель (sender).
//
Процедура ПроверкаЗаполненияПолейПравило3(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Поле 5 должно быть заполнено
	Если ЗначениеЗаполнено(СтруктураДанных.ИсходныйЭСЧФ) Тогда 
		
		СтатусНаПортале = "";
		
		Запрос = Новый Запрос;
		Запрос.Текст = "ВЫБРАТЬ
		               |	СостоянияЭД.ДействияСоСтороныДругогоУчастника КАК СтатусНаПортале 
		               |ИЗ
		               |	РегистрСведений.СостоянияЭД КАК СостоянияЭД
		               |ГДЕ
		               |	СостоянияЭД.СсылкаНаОбъект = &СсылкаНаОбъект";
		
		Запрос.УстановитьПараметр("СсылкаНаОбъект", Документ.ИсходныйЭСЧФ);
		
		РезультатЗапроса = Запрос.Выполнить();
		
		Выборка = РезультатЗапроса.Выбрать();
		
		Пока Выборка.Следующий() Цикл
			СтатусНаПортале = Выборка.СтатусНаПортале;
		КонецЦикла;
	
		Если СтатусНаПортале = "Выставлен" ИЛИ СтатусНаПортале = "Выставлен. Подписан получателем" Тогда
			
			Если Документ.Организация <> Документ.ИсходныйЭСЧФ.Организация Тогда
				
				ТекстОшибки = "У родительского и дочерних ЭСЧФ должна быть одна организация!";
				Отказ = Истина;			
				
			КонецЕсли;						
			
		Иначе
			
			ТекстОшибки = "ЭСЧФ в поле 5. Исходный ЭСЧФ должна быть со статусом «Выставлен» или «Выставлен. Подписан получателем»!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-4
//	Если тип ЭСЧФ – Исправленный, то поле «дата аннулирования» обязательно для заполнения.
//
Процедура ПроверкаЗаполненияПолейПравило4(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исправленный Тогда 
		
		Если Не ЗначениеЗаполнено(СтруктураДанных.ДатаАннулирования) Тогда
			
			ТекстОшибки = "Поле 5.1. Дата аннулирования обязательно для заполнения!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-5-удалено
//	Дата аннулирования у исправленного может быть либо равна дате совершения Исходного
//	(предыдущего Исправленного), либо дате совершения исправленного
//Правило-5.1
//	Дата аннулирования не должна быть меньше даты совершения одного ЭСЧФ
//
Процедура ПроверкаЗаполненияПолейПравило5(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исправленный Тогда
		
		Если СтруктураДанных.ДатаАннулирования < СтруктураДанных.ДатаСовершенияОперации Тогда 
			
			ТекстОшибки = "Дата аннулирования не должна быть меньше даты совершения операции!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-6
//	Статус поставщика зависит от статуса получателя (смотрите таблицу соответствия).
//
Процедура ПроверкаЗаполненияПолейПравило6(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Продавец
	Если СтруктураДанных.СтатусПоставщика = "SELLER" Тогда 
		
		//Покупатель / Потребитель / Комиссионер
		Если Не (СтруктураДанных.СтатусПолучателя = "CUSTOMER" ИЛИ
			СтруктураДанных.СтатусПолучателя = "CONSUMER" ИЛИ
			СтруктураДанных.СтатусПолучателя = "COMMISSIONAIRE") Тогда
			
			ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Комитент
	ИначеЕсли СтруктураДанных.СтатусПоставщика = "CONSIGNOR" Тогда
		
		//Комиссионер
		Если Не СтруктураДанных.СтатусПолучателя = "COMMISSIONAIRE" Тогда
			
			ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Комиссионер
	ИначеЕсли СтруктураДанных.СтатусПоставщика = "COMMISSIONAIRE" Тогда
		
		//Покупатель / Потребитель / Комитент / Комиссионер
		Если Не (СтруктураДанных.СтатусПолучателя = "CUSTOMER" ИЛИ
			СтруктураДанных.СтатусПолучателя = "CONSUMER" ИЛИ
			СтруктураДанных.СтатусПолучателя = "CONSIGNOR" ИЛИ
			СтруктураДанных.СтатусПолучателя = "COMMISSIONAIRE") Тогда
			
			ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Плательщик, передающий налоговые вычеты
	ИначеЕсли СтруктураДанных.СтатусПоставщика = "TAX_DEDUCTION_PAYER" Тогда
		
		//Покупатель, получающий налоговые вычеты
		Если Не СтруктураДанных.СтатусПолучателя = "TAX_DEDUCTION_RECIPIENT" Тогда
			
			ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Доверительный управляющий
	ИначеЕсли СтруктураДанных.СтатусПоставщика = "TRUSTEE" Тогда
		
		//Покупатель
		Если Не СтруктураДанных.СтатусПолучателя = "CUSTOMER" Тогда
			
			ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Иностранная организация
	ИначеЕсли СтруктураДанных.СтатусПоставщика = "FOREIGN_ORGANIZATION" Тогда
		
		//Покупатель / Покупатель объектов у иностранной организации
		Если Не (СтруктураДанных.СтатусПолучателя = "CUSTOMER" ИЛИ
			СтруктураДанных.СтатусПолучателя = "FOREIGN_ORGANIZATION_BUYER") Тогда
			
			ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Посредник	
	ИначеЕсли СтруктураДанных.СтатусПоставщика = "AGENT" Тогда
		
		//Потребитель
		Если Не СтруктураДанных.СтатусПолучателя = "CONSUMER" Тогда
			
			ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Заказчик (застройщик)	
	ИначеЕсли СтруктураДанных.СтатусПоставщика = "DEVELOPER" Тогда
		
		//Потребитель
		Если Не СтруктураДанных.СтатусПолучателя = "CONSUMER" Тогда
			
			ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Плательщик, передающий обороты по реализации	
	ИначеЕсли СтруктураДанных.СтатусПоставщика = "TURNOVERS_ON_SALE_PAYER" Тогда
		
		//Плательщик, получающий обороты по реализации
		Если Не СтруктураДанных.СтатусПолучателя = "TURNOVERS_ON_SALE_RECIPIENT" Тогда
			
			ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
			Отказ = Истина;
			
		КонецЕсли;
		
	Иначе
		
		ТекстОшибки = "Статус поставщика не удовлетворяет статусу получателя!";
		Отказ = Истина;
			
	КонецЕсли;

КонецПроцедуры

//Правило-7
//	Если субъект хозяйствования, составляющий ЭСЧФ, является получателем, то поля ЭСЧФ
//	6.1, 6.2, 6.3, 6.4 должны принимать значение false
//
Процедура ПроверкаЗаполненияПолейПравило7(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если Документ.Получатель = Документ.Организация.Контрагент Тогда 
		
		Если СтруктураДанных.ПоставщикПризнакВзаимозависимогоЛица ИЛИ
			СтруктураДанных.ПоставщикПризнакКрупногоПлательщика ИЛИ
			СтруктураДанных.ПоставщикПризнакСделкиСРезидентомОффшорнойЗоны ИЛИ
			СтруктураДанных.ПоставщикПризнакСделкиСТоварамиПоПеречню Тогда
			
			ТекстОшибки = "Поля ЭСЧФ 6.1, 6.2, 6.3, 6.4 должны принимать значение false!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-8
//	Если указан признак взаимозависимого лица у продавца или получателя, 
//	то поля «код ТНВЭД ЕАЭС» (от 4 до 10 цифр) или «код ОКЭД» (5 цифр)
//	являются обязательными для заполнения для всех строк.
//
Процедура ПроверкаЗаполненияПолейПравило8(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.ПоставщикПризнакВзаимозависимогоЛица ИЛИ
		СтруктураДанных.ПолучательПризнакВзаимозависимогоЛица Тогда 
		
		ЕстьОшибка = Ложь;
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			Если Не (ЗначениеЗаполнено(Строка.ТНВЭД) ИЛИ ЗначениеЗаполнено(Строка.ОКЭД)) Тогда				
				ЕстьОшибка = Истина;
				Прервать;                                                                     
			КонецЕсли;
			
		КонецЦикла;
		
		Если ЕстьОшибка Тогда
			
			ТекстОшибки = "«код ТНВЭД ЕАЭС» (от 4 до 10 цифр) или «код ОКЭД» (5 цифр) являются обязательными для заполнения для всех строк!";
			Отказ = Истина;
			
		КонецЕсли;		
		
	КонецЕсли;

КонецПроцедуры

//Правило-9
//	Если статус поставщика – «иностранная организация», то страной поставщика не
//	может быть Республика Беларусь
//
Процедура ПроверкаЗаполненияПолейПравило9(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Иностранная организация
	Если СтруктураДанных.СтатусПоставщика = "FOREIGN_ORGANIZATION" Тогда 
		
		Если СтруктураДанных.КодСтраныПоставщика = "112" Тогда
			
			ТекстОшибки = "Статус поставщика – «иностранная организация», тогда страной поставщика не может быть Республика Беларусь!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-10
//	Если пользователь указал статус любой, кроме «иностранная организация», то УНП поставщика
//	должен соответствовать УНП субъекта хозяйствования, составляющего ЭСЧФ (элемент sender).
//
Процедура ПроверкаЗаполненияПолейПравило10(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Иностранная организация
	Если Не СтруктураДанных.СтатусПоставщика = "FOREIGN_ORGANIZATION" Тогда 
		
		Если СтруктураДанных.УНППоставщика <> Документ.Организация.ИНН Тогда
			
			ТекстОшибки = "УНП поставщика должен соответствовать УНП субъекта хозяйствования, составляющего ЭСЧФ (элемент sender)!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-11
//	В разделе поставщика или получателя должен быть указан УНП, отраженный в
//	элементе sender (субъект хозяйствования, составляющий ЭСЧФ).
//
Процедура ПроверкаЗаполненияПолейПравило11(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.УНППоставщика <> Документ.Организация.ИНН И СтруктураДанных.УНППолучателя <> Документ.Организация.ИНН Тогда 
		
		ТекстОшибки = "В разделе поставщика или получателя должен быть указан УНП, отраженный в элементе sender (субъект хозяйствования, составляющий ЭСЧФ)!";
		Отказ = Истина;
		
	КонецЕсли;

КонецПроцедуры

//Правило-12
//	 УНП продавца и получателя не должны быть одинаковыми в одном ЭСЧФ.
//
Процедура ПроверкаЗаполненияПолейПравило12(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.УНППоставщика = СтруктураДанных.УНППолучателя Тогда 
		
		ТекстОшибки = "УНП продавца и получателя не должны быть одинаковыми в одном ЭСЧФ!";
		Отказ = Истина;
		
	КонецЕсли;

КонецПроцедуры

//Правило-13
//	Если поле УНП для которого проставлена страна Беларусь не пустое, то УНП должен
//	существовать в реестре налогоплательщиков.
//Правило-13-1
//	Название организации обязательно, если указана страна Беларусь и поле УНП не пустое
//
Процедура ПроверкаЗаполненияПолейПравило13(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	МассивПроверкиУНП = Новый Массив;
	
	Если СтруктураДанных.КодСтраныПоставщика = "112" Тогда
		Если ЗначениеЗаполнено(СтруктураДанных.УНППоставщика) Тогда
			//Правило-13-1
			Если Не ЗначениеЗаполнено(СтруктураДанных.ИмяПоставщика) Тогда
				ТекстОшибки = "Название организации обязательно, если указана страна Беларусь и поле УНП не пустое!";
				Отказ = Истина;				
				Возврат;
			КонецЕсли;				
			МассивПроверкиУНП.Добавить(СтруктураДанных.УНППоставщика);
		КонецЕсли;		
	КонецЕсли;
	
	Если СтруктураДанных.КодСтраныПолучателя = "112" Тогда
		Если ЗначениеЗаполнено(СтруктураДанных.УНППолучателя) Тогда
			//Правило-13-1
			Если Не ЗначениеЗаполнено(СтруктураДанных.ИмяПолучателя) Тогда
				ТекстОшибки = "Название организации обязательно, если указана страна Беларусь и поле УНП не пустое!";
				Отказ = Истина;				
				Возврат;
			КонецЕсли;				
			МассивПроверкиУНП.Добавить(СтруктураДанных.УНППолучателя);
		КонецЕсли;		
	КонецЕсли;
	
	Для Каждого Строка Из СтруктураДанных.Грузоотправитель Цикл 		
		Если Строка.КодСтраныГрузоотправитель = "112" Тогда
			Если ЗначениеЗаполнено(Строка.УНПГрузоотправитель) Тогда
				МассивПроверкиУНП.Добавить(Строка.УНПГрузоотправитель);
			КонецЕсли;		
		КонецЕсли; 		
	КонецЦикла;
	
	Для Каждого Строка Из СтруктураДанных.Грузополучатель Цикл  		
		Если Строка.КодСтраныГрузополучатель = "112" Тогда
			Если ЗначениеЗаполнено(Строка.УНПГрузополучатель) Тогда
				МассивПроверкиУНП.Добавить(Строка.УНПГрузополучатель);
			КонецЕсли;		
		КонецЕсли; 		
	КонецЦикла;
	
	Для Каждого СтрокаУНП Из МассивПроверкиУНП Цикл
		
		СтатусПроверки = Справочники.Контрагенты.ПроверкаНалогоплательщика(СтрокаУНП);
		
		Если СтатусПроверки = Ложь Тогда
			
			ТекстОшибки = "Если поле УНП для которого проставлена страна Беларусь не пустое, то УНП должен существовать в реестре налогоплательщиков!";
			Отказ = Истина;
			Прервать;
			
		ИначеЕсли СтатусПроверки = Неопределено Тогда
			
			ТекстОшибки = "Не удалось проверить существование УНП в реестре налогоплательщиков! Повторите проверку.";
			Отказ = Истина;
			Прервать;
			
		КонецЕсли;		
		
	КонецЦикла;
	
КонецПроцедуры

//Правило-14
//	Если заполнено поле «номер» или «дата» в пунктах 14, 21, то поля «дата» и «номер»
//	обязательны для заполнения для одних и тех же пунктов.
//
Процедура ПроверкаЗаполненияПолейПравило14(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если ЗначениеЗаполнено(СтруктураДанных.ПоставщикНомерЗаявленияОВвозеТоваров) ИЛИ 
		ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаЗаявленияОВвозеТоваров) Тогда 
		
		Если Не (ЗначениеЗаполнено(СтруктураДанных.ПоставщикНомерЗаявленияОВвозеТоваров) И
			ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаЗаявленияОВвозеТоваров)) Тогда
			
			ТекстОшибки = "Если заполнено поле «номер» или «дата» в пунктах 14, 21, то поля «дата» и «номер» обязательны для заполнения для одних и тех же пунктов!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;
	
	Если ЗначениеЗаполнено(СтруктураДанных.ПолучательНомерЗаявленияОВвозеТоваров) ИЛИ 
		ЗначениеЗаполнено(СтруктураДанных.ПолучательДатаЗаявленияОВвозеТоваров) Тогда 
		
		Если Не (ЗначениеЗаполнено(СтруктураДанных.ПолучательНомерЗаявленияОВвозеТоваров) И
			ЗначениеЗаполнено(СтруктураДанных.ПолучательДатаЗаявленияОВвозеТоваров)) Тогда
			
			ТекстОшибки = "Если заполнено поле «номер» или «дата» в пунктах 14, 21, то поля «дата» и «номер» обязательны для заполнения для одних и тех же пунктов!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-15-удалено
//	Поля 11. «Номер ЭСЧФ комитента» (номер и дата) и поле 12. «Номер ЭСЧФ продавца»
//	(номер и дата) являются взаимоисключающими друг друга, т.е. если заполнено, например,
//	поле 11, то поле 12 должно оставаться пустым.
//Правило-15.1 
//	ЭСЧФ, указанный в 11. «Номер ЭСЧФ комитента» или 12. «Номер ЭСЧФ продавца» и ЭСЧФ, 
//	в котором указывается номер комитента или номер продавца, должны отправляться
//	на Портал разными поставщиками, т. е. УНП в таких ЭСЧФ в полях sender должны отличаться.
//
Процедура ПроверкаЗаполненияПолейПравило15(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если Документ.Организация.Контрагент = Документ.НомерСчетаКомитента.Поставщик ИЛИ
		Документ.Организация.Контрагент = Документ.НомерСчетаПродавца.Поставщик Тогда	
	
		ТекстОшибки = "ЭСЧФ, указанный в 11. «Номер ЭСЧФ комитента» или 12. «Номер ЭСЧФ продавца» и ЭСЧФ, в котором указывается номер комитента или номер продавца, должны отправляться на Портал разными поставщиками, т. е. УНП в таких ЭСЧФ в полях sender должны отличаться!";
		Отказ = Истина;
		
	КонецЕсли;

КонецПроцедуры

//Правило-16
//	Поле 11. «Номер ЭСЧФ комитента» доступно для заполнения, если в поле статус поставщика
//	проставлено значение «комиссионер», а в поле статус получателя – «покупатель». 
//
Процедура ПроверкаЗаполненияПолейПравило16(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если ЗначениеЗаполнено(СтруктураДанных.НомерСчетаКомитента) Тогда 
		
		//Комиссионер и Покупатель
		Если Не (СтруктураДанных.СтатусПоставщика = "COMMISSIONAIRE" И СтруктураДанных.СтатусПолучателя = "CUSTOMER") Тогда
			
			ТекстОшибки = "Поле 11. «Номер ЭСЧФ комитента» доступно для заполнения, если в поле статус поставщика проставлено значение «комиссионер», а в поле статус получателя – «покупатель»!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-17
//	Если в полях статусов поставщика - получателя проставлены значения «комиссионер» – «покупатель»,
//	поле 11. «Номер ЭСЧФ комитента» – обязательно для заполнения
//
Процедура ПроверкаЗаполненияПолейПравило17(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Комиссионер и Покупатель
	Если СтруктураДанных.СтатусПоставщика = "COMMISSIONAIRE" И СтруктураДанных.СтатусПолучателя = "CUSTOMER" Тогда
		
		Если Не ЗначениеЗаполнено(СтруктураДанных.НомерСчетаКомитента) Тогда		
			
			ТекстОшибки = "Если в полях статусов поставщика - получателя проставлены значения «комиссионер» – «покупатель»,	поле 11. «Номер ЭСЧФ комитента» – обязательно для заполнения!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-18
//	В поле 11. «Номер ЭСЧФ комитента» должен быть указан номер ЭСЧФ, в котором текущий
//	субъект хозяйствования указан как получатель.
//
Процедура ПроверкаЗаполненияПолейПравило18(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если ЗначениеЗаполнено(СтруктураДанных.НомерСчетаКомитента) Тогда 
		
		Если СтруктураДанных.УНППоставщика <> Документ.НомерСчетаКомитента.Получатель.ИНН Тогда
			
			ТекстОшибки = "В поле 11. «Номер ЭСЧФ комитента» должен быть указан номер ЭСЧФ, в котором текущий субъект хозяйствования указан как получатель!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-19
//	Если в полях статусов поставщика-получателя проставлены: «комиссионер» –
//	«комитент», «посредник» – «потребитель», то 12. «Номер ЭСЧФ продавца», 
//	13.	«Регистрационный номер выпуска товаров» или 
//	14. «Реквизиты заявления о ввозе товаров и уплате косвенных налогов» – 
//	один из реквизитов обязателен для заполнения.
//Правило-19.1
//	Если в полях статусов поставщика-получателя проставлены: «комиссионер» –
//	«комиссионер», то 11. Номер ЭСЧФ комитента, 12. «Номер ЭСЧФ продавца», 
//	13. «Регистрационный номер выпуска товаров» или 
//	14. «Реквизиты заявления о ввозе товаров и уплате косвенных налогов» –
//	одно из полей обязательно для заполнения.
//
Процедура ПроверкаЗаполненияПолейПравило19(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Комиссионер и Комитент / Посредник и Потребитель 
	Если СтруктураДанных.СтатусПоставщика = "COMMISSIONAIRE" И СтруктураДанных.СтатусПолучателя = "CONSIGNOR" ИЛИ
		СтруктураДанных.СтатусПоставщика = "AGENT" И СтруктураДанных.СтатусПолучателя = "CONSUMER" Тогда
		
		Если Не ЗначениеЗаполнено(СтруктураДанных.НомерСчетаПродавца) И
			Не ЗначениеЗаполнено(СтруктураДанных.ПоставщикРегистрационныйНомерВыпускаТоваров) ИЛИ
			Не (ЗначениеЗаполнено(СтруктураДанных.ПоставщикНомерЗаявленияОВвозеТоваров) И
			ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаЗаявленияОВвозеТоваров)) Тогда
			
			ТекстОшибки = "Правило-19 не выполнено! См. правила заполнения полей.";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Комиссионер и Комиссионер 
	ИначеЕсли СтруктураДанных.СтатусПоставщика = "COMMISSIONAIRE" И СтруктураДанных.СтатусПолучателя = "COMMISSIONAIRE" Тогда
		
		Если Не ЗначениеЗаполнено(СтруктураДанных.НомерСчетаПродавца) И
			Не ЗначениеЗаполнено(СтруктураДанных.ПоставщикРегистрационныйНомерВыпускаТоваров) ИЛИ
			Не (ЗначениеЗаполнено(СтруктураДанных.ПоставщикНомерЗаявленияОВвозеТоваров) И
			ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаЗаявленияОВвозеТоваров)) Тогда
			
			ТекстОшибки = "Правило-19.1 не выполнено! См. правила заполнения полей.";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-20
//	Поле 12. «Номер ЭСЧФ продавца» доступно для заполнения, если в поле статус
//	поставщика проставлено значение «комиссионер» – «комитент», «посредник» – «потребитель»
//	или «заказчик (застройщик)» – «потребитель»
//
Процедура ПроверкаЗаполненияПолейПравило20(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Комиссионер и Комитент / Посредник и Потребитель / Заказчик (застройщик) и Потребитель 
	Если СтруктураДанных.СтатусПоставщика = "COMMISSIONAIRE" И СтруктураДанных.СтатусПолучателя = "CONSIGNOR" ИЛИ
		СтруктураДанных.СтатусПоставщика = "AGENT" И СтруктураДанных.СтатусПолучателя = "CONSUMER" ИЛИ
		СтруктураДанных.СтатусПоставщика = "DEVELOPER" И СтруктураДанных.СтатусПолучателя = "CONSUMER" Тогда
		
		Если ЗначениеЗаполнено(СтруктураДанных.НомерСчетаПродавца) Тогда
			
			ТекстОшибки = "Поле 12. «Номер ЭСЧФ продавца» доступно для заполнения, если в поле статус поставщика проставлено значение «комиссионер» – «комитент», «посредник» – «потребитель» или «заказчик (застройщик)» – «потребитель»!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-21
//	В поле 12. «Номер ЭСЧФ продавца» можно указать номер ЭСЧФ, в котором текущий
//	субъект хозяйствования указан как получатель.
//
Процедура ПроверкаЗаполненияПолейПравило21(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если ЗначениеЗаполнено(СтруктураДанных.НомерСчетаПродавца) Тогда 
		
		Если Документ.НомерСчетаПродавца.Получатель <> Документ.Организация.Контрагент Тогда
			
			ТекстОшибки = "В поле 12. «Номер ЭСЧФ продавца» можно указать номер ЭСЧФ, в котором текущий субъект хозяйствования указан как получатель!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-22
//	Поле 13. Регистрационный номер выпуска товаров доступно для заполнения, если 
//	1) В поле статусов поставщика – получателя проставлены: 
//	«комиссионер» – «комитент», «посредник» – «потребитель», «заказчик(застройщик)» – «потребитель» 
//	вне зависимости от значений в полях «код страны».
//	2) При статусах «продавец» – «покупатель»:
//	2.1) в строке 7. «Код страны поставщика» должна быть указана Республика Беларусь, а
//	в строке 16. «Код страны получателя» – код страны, не входящей в страны ЕАЭС; 
//	или 2.2) в строке 16. «Код страны получателя» указывается код страны,
//	входящей в страны ЕАЭС (и не Республика Беларусь), а в строке 26. «Код страны грузополучателя» - код
//	страны, не входящей в страны ЕАЭС.
//Правило-22.1 
//	Если в полях статусов поставщика-получателя проставлены «продавец» - «покупатель» и при этом, 
//	указана страна покупателя любая кроме Республики Беларусь, а также, хотя бы для одной строки
//	заполнен 3.1. Код ТН ВЭД и 8. Ставка НДС равна 0%, то строка 13 "Регистрационный номер выпуска товаров"
//	или 14. "Реквизиты заявления о ввозе товаров и уплате косвенных налогов" обязательны для заполнения.
//
Процедура ПроверкаЗаполненияПолейПравило22(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если ЗначениеЗаполнено(СтруктураДанных.ПоставщикРегистрационныйНомерВыпускаТоваров) Тогда
		//Правило 22		
		//22 п. 1) Комиссионер и Комитент / Посредник и Потребитель / Заказчик (застройщик) и Потребитель 
		Если СтруктураДанных.СтатусПоставщика = "COMMISSIONAIRE" И СтруктураДанных.СтатусПолучателя = "CONSIGNOR" ИЛИ
			СтруктураДанных.СтатусПоставщика = "AGENT" И СтруктураДанных.СтатусПолучателя = "CONSUMER" ИЛИ
			СтруктураДанных.СтатусПоставщика = "DEVELOPER" И СтруктураДанных.СтатусПолучателя = "CONSUMER" Тогда 		
			
		//22 п. 2) Продавец и Покупатель  	
		ИначеЕсли СтруктураДанных.СтатусПоставщика = "SELLER" И СтруктураДанных.СтатусПолучателя = "CUSTOMER" Тогда
			
			//22 п. 2.1 и п.2.2
			ТипГрузополучатель = 1;
			
			Для Каждого Строка Из Документ.Грузополучатель Цикл 				
				
				ТипГрузополучатель = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Строка.Грузополучатель);
				
				Если ТипГрузополучатель = 3 Тогда  					
					Прервать;  					
				КонецЕсли;
				
			КонецЦикла;  			
			
			ТипПолучателя = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Документ.Получатель);  			
			
			Если СтруктураДанных.КодСтраныПоставщика = "112" И ТипПолучателя = 3 ИЛИ 
				ТипПолучателя = 2 И СтруктураДанных.КодСтраныПолучателя <> "112" И ТипГрузополучатель = 3 Тогда 				
				
			Иначе
				
				ТекстОшибки = "Поле 13. Регистрационный номер выпуска товаров не доступно для заполнения!";
				Отказ = Истина; 
			
			КонецЕсли;
			
		Иначе
			
			ТекстОшибки = "Поле 13. Регистрационный номер выпуска товаров не доступно для заполнения!";
			Отказ = Истина; 
					
		КонецЕсли;
		
	КонецЕсли;

	//Продавец и Покупатель
	Если СтруктураДанных.СтатусПоставщика = "SELLER" И СтруктураДанных.СтатусПолучателя = "CUSTOMER" Тогда
		
		//22.1
		ЗаданКодТНВЭД = Ложь;
		СтавкаНоль = Ложь;
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл			
			
			Если ЗначениеЗаполнено(Строка.ТНВЭД) Тогда
				ЗаданКодТНВЭД = Истина;
				Если СтавкаНоль Тогда
					Прервать;
				КонецЕсли;
			КонецЕсли;
			
			Если Строка.СтавкаНДС = 0 Тогда
				СтавкаНоль = Истина;
				Если ЗаданКодТНВЭД Тогда
					Прервать;
				КонецЕсли;				
			КонецЕсли;
			
		КонецЦикла;
		
		//Правило-22.1 
		Если СтруктураДанных.КодСтраныПолучателя <> "112" И ЗаданКодТНВЭД И СтавкаНоль Тогда
			
			Если Не (ЗначениеЗаполнено(СтруктураДанных.ПоставщикРегистрационныйНомерВыпускаТоваров) ИЛИ
				ЗначениеЗаполнено(СтруктураДанных.ПоставщикНомерЗаявленияОВвозеТоваров) ИЛИ
				ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаЗаявленияОВвозеТоваров)) Тогда
				
				ТекстОшибки = "13 ""Регистрационный номер выпуска товаров"" или 14. ""Реквизиты заявления о ввозе товаров и уплате косвенных налогов"" обязательны для заполнения!";
				Отказ = Истина; 
				
			КонецЕсли;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-23
//	Если заполнено поле 13 «Регистрационный номер выпуска товаров» и статус поставщика
//	– "Продавец", а получателя – "Покупатель", то даты из полей ЭСЧФ 13.1 и 13.2 тоже
//	обязательны для заполнения.
//Правило-23.1
//	Если заполнены поля 13.1 "Дата выпуска товара" и 13.2 "Дата разрешения на убытие товаров",
//	то поле 13 «Регистрационный номер выпуска товаров» - обязательное для заполнения.
//
Процедура ПроверкаЗаполненияПолейПравило23(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Продавец и Покупатель
	Если ЗначениеЗаполнено(СтруктураДанных.ПоставщикРегистрационныйНомерВыпускаТоваров) И 	
		СтруктураДанных.СтатусПоставщика = "SELLER" И СтруктураДанных.СтатусПолучателя = "CUSTOMER" Тогда 
		
		Если Не (ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаВыпускаТоваров) И 
			ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаРазрешенияНаУбытиеТоваров)) Тогда
			
			ТекстОшибки = "Если заполнено поле 13 «Регистрационный номер выпуска товаров» и статус поставщика – ""Продавец"", а получателя – ""Покупатель"", то даты из полей ЭСЧФ 13.1 и 13.2 тоже обязательны для заполнения!";
			Отказ = Истина;
			
		КонецЕсли;
		
	//Правило-23.1	
	ИначеЕсли ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаВыпускаТоваров) И 
		ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаРазрешенияНаУбытиеТоваров) Тогда
		
		Если Не ЗначениеЗаполнено(СтруктураДанных.ПоставщикРегистрационныйНомерВыпускаТоваров) Тогда
			
			ТекстОшибки = "Если заполнены поля 13.1 ""Дата выпуска товара"" и 13.2 ""Дата разрешения на убытие товаров"", то поле 13 «Регистрационный номер выпуска товаров» - обязательное для заполнения!";
			Отказ = Истина;
			
		КонецЕсли;
				
	КонецЕсли;

КонецПроцедуры

//Правило-24-удалено
//	Поля 13. «Реквизиты деклараций на товары», 14. «Реквизиты заявления о ввозе
//	товаров и уплате косвенных налогов», 20. «Регистрационный номер выпуска товаров», 21.
//	«Реквизиты заявления о ввозе товаров и уплате косвенных налогов» являются
//	взаимоисключающими друг друга. Т.е., если заполнено поле, например, 21. «Реквизиты
//	заявления о ввозе товаров и уплате косвенных налогов», то поля под номерами 13,14, и 20
//	должны оставаться пустыми.
//
Процедура ПроверкаЗаполненияПолейПравило24(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли;	
	
КонецПроцедуры

//Правило-25
//	Поле 14. «Реквизиты заявления о ввозе товаров и уплате косвенных налогов» доступно для заполнения, если: 
//	1) в поле статусов поставщика – получателя проставлены: «комиссионер» – «комитент»,
//	«посредник» – «потребитель», «заказчик (застройщик)» – «потребитель» вне зависимости от значений
//	в полях «код страны»;
//	2) При статусах «продавец» – «покупатель»:
//	2.1) «код страны поставщика» – Республика Беларусь, а в строке 16 «код страны получателя»
//	указана страна, входящая в страны ЕАЭС (и не Республика Беларусь);
//	2.2) покупатель – плательщик из стран, не входящих в страны ЕАЭС (и не Республики Беларусь),
//	а грузополучатель – плательщик, являющийся резидентом страны из ЕАЭС (и не из Республики Беларусь).
//
Процедура ПроверкаЗаполненияПолейПравило25(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если ЗначениеЗаполнено(СтруктураДанных.ПоставщикНомерЗаявленияОВвозеТоваров) ИЛИ 
		ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаЗаявленияОВвозеТоваров) Тогда
		
		ТипПолучателя = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Документ.Получатель);
		
		ГрузополучательЕАЭС = Ложь;
		
		Для Каждого Строка Из СтруктураДанных.Грузополучатель Цикл
			
			ТипГрузополучателя = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Документ.Грузополучатель[СтруктураДанных.Грузополучатель.Индекс(Строка)].Грузополучатель);
			
			Если Строка.КодСтраныГрузополучатель <> "112" И ТипГрузополучателя = 2 Тогда
				ГрузополучательЕАЭС = Истина;
				Прервать;				
			КонецЕсли;
			
		КонецЦикла; 		
		
		//Комиссионер и Комитент / Посредник и Потребитель / Заказчик (застройщик) и Потребитель 
		Если СтруктураДанных.СтатусПоставщика = "COMMISSIONAIRE" И СтруктураДанных.СтатусПолучателя = "CONSIGNOR" ИЛИ
			СтруктураДанных.СтатусПоставщика = "AGENT" И СтруктураДанных.СтатусПолучателя = "CONSUMER" ИЛИ
			СтруктураДанных.СтатусПоставщика = "DEVELOPER" И СтруктураДанных.СтатусПолучателя = "CONSUMER" Тогда
						
		//Продавец и Покупатель	
		ИначеЕсли СтруктураДанных.СтатусПоставщика = "SELLER" И СтруктураДанных.СтатусПолучателя = "CUSTOMER" Тогда   	
			
			Если СтруктураДанных.КодСтраныПоставщика = "112" И СтруктураДанных.КодСтраныПолучателя <> "112" И ТипПолучателя = 2 Тогда 				
				
			ИначеЕсли ТипПолучателя = 3 И ГрузополучательЕАЭС Тогда
				
			Иначе
				
				ТекстОшибки = "Поле 14. «Реквизиты заявления о ввозе товаров и уплате косвенных налогов» не доступно для заполнения!";
				Отказ = Истина;			
				
			КонецЕсли;
			
		Иначе
			
			ТекстОшибки = "Поле 14. «Реквизиты заявления о ввозе товаров и уплате косвенных налогов» не доступно для заполнения!";
			Отказ = Истина;
						
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-26
//	Если субъект хозяйствования, составляющий ЭСЧФ, является поставщиком, то поля
//	15.1, 15.2, 15.3, 15.4 должны принимать значение false.
//
Процедура ПроверкаЗаполненияПолейПравило26(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если Документ.Поставщик = Документ.Организация.Контрагент Тогда 
		
		Если СтруктураДанных.ПолучательПризнакВзаимозависимогоЛица ИЛИ
			СтруктураДанных.ПолучательПризнакКрупногоПлательщика ИЛИ
			СтруктураДанных.ПолучательПризнакСделкиСРезидентомОффшорнойЗоны ИЛИ
			СтруктураДанных.ПолучательПризнакСделкиСТоварамиПоПеречню Тогда
			
			ТекстОшибки = "Поля ЭСЧФ 15.1, 15.2, 15.3, 15.4 должны принимать значение false!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-27
//	Если субъект хозяйствования, составляющий ЭСЧФ, указал статус поставщика –
//	«иностранная организация», то УНП получателя должен соответствовать УНП 
//	субъекта хозяйствования, составляющего ЭСЧФ (элемент sender).
//
Процедура ПроверкаЗаполненияПолейПравило27(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Иностранная организация
	Если СтруктураДанных.СтатусПоставщика = "FOREIGN_ORGANIZATION" Тогда 
		
		Если СтруктураДанных.УНППолучателя <> Документ.Организация.Контрагент.ИНН Тогда
			
			ТекстОшибки = "Если субъект хозяйствования, составляющий ЭСЧФ, указал статус поставщика – «иностранная организация», то УНП получателя должен соответствовать УНП субъекта хозяйствования, составляющего ЭСЧФ (элемент sender)!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-28-удалено
//	Нет описания
//
Процедура ПроверкаЗаполненияПолейПравило28(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли;	
	
КонецПроцедуры

//Правило-29
//	Поле 20. «Регистрационный номер выпуска товаров» или 21. «Реквизиты заявления о
//	ввозе товаров и уплате косвенных налогов» обязательно для заполнения, если у поставщика 
//	проставлен статус «Иностранная организация», а у получателя статус «Покупатель».
//
Процедура ПроверкаЗаполненияПолейПравило29(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Иностранная организация и Покупатель
	Если СтруктураДанных.СтатусПоставщика = "FOREIGN_ORGANIZATION" И
		СтруктураДанных.СтатусПолучателя = "CUSTOMER" Тогда 
		
		Если Не (ЗначениеЗаполнено(СтруктураДанных.ПолучательРегистрационныйНомерВыпускаТоваров) ИЛИ
			ЗначениеЗаполнено(СтруктураДанных.ПолучательНомерЗаявленияОВвозеТоваров) ИЛИ
			ЗначениеЗаполнено(СтруктураДанных.ПолучательДатаЗаявленияОВвозеТоваров)) Тогда
			
			ТекстОшибки = "Поле 20. «Регистрационный номер выпуска товаров» или 21. «Реквизиты заявления о ввозе товаров и уплате косвенных налогов» обязательно для заполнения, если у поставщика проставлен статус «Иностранная организация», а у получателя статус «Покупатель»!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-30
//	Поле 20. Регистрационный номер выпуска товаров доступно для заполнения, если поставщик – 
//	иностранная организация (субъект хозяйствования страны, не входящей в ЕАЭС или 
//	страна не указана),	а получатель – субъект хозяйствования Республики Беларусь, а также, 
//	когда продавец – субъект хозяйствования страны, входящей в ЕАЭС (но не Беларусь),
//	а грузоотправитель – плательщик из стран, не входящих в ЕАЭС.
//
Процедура ПроверкаЗаполненияПолейПравило30(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если ЗначениеЗаполнено(СтруктураДанных.ПолучательРегистрационныйНомерВыпускаТоваров) Тогда 
		
		ТипПоставщика = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Документ.Поставщик);
		ТипПолучателя = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Документ.Получатель);
		ТипГрузоотправитель = 1;
			
		Для Каждого Строка Из Документ.Грузоотправитель Цикл 				
			
			ТипГрузоотправитель = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Строка.Грузоотправитель);
			
			Если ТипГрузоотправитель = 3 Тогда  					
				Прервать;  					
			КонецЕсли;
			
		КонецЦикла;
			
		Если (Не ЗначениеЗаполнено(СтруктураДанных.КодСтраныПоставщика) ИЛИ ТипПоставщика = 3) И
			(СтруктураДанных.КодСтраныПолучателя = "112" ИЛИ 
			СтруктураДанных.КодСтраныПолучателя <> "112" И ТипПолучателя = 2 И ТипГрузоотправитель = 3) Тогда
			
		Иначе
			
			ТекстОшибки = "Поле 20. Регистрационный номер выпуска товаров не доступно для заполнения!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-31
//	Поле 21.Реквизиты заявления о ввозе товаров и уплате косвенных налогов и
//	21.1. Дата ввоза товара доступно для заполнения, если поставщик – 
//	иностранная организация (субъект хозяйствования страны, входящей в ЕАЭС или 
//	страна не указана), а получатель – субъект хозяйствования Республики Беларусь, 
//	а также, когда продавец - субъект хозяйствования страны, не входящей в ЕАЭС, 
//	а грузоотправитель – субъект хозяйствования страны, входящей в ЕАЭС (не Беларусь).
//
Процедура ПроверкаЗаполненияПолейПравило31(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если ЗначениеЗаполнено(СтруктураДанных.ПолучательНомерЗаявленияОВвозеТоваров) ИЛИ 
		ЗначениеЗаполнено(СтруктураДанных.ПолучательДатаЗаявленияОВвозеТоваров) ИЛИ 
		ЗначениеЗаполнено(СтруктураДанных.ПолучательДатаВвозаТоваров) Тогда 
		
		ТипПоставщика = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Документ.Поставщик);
		ТипПолучателя = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Документ.Получатель);
		
		ГрузоотправительЕАЭС = Ложь;
			
		Для Каждого Строка Из Документ.Грузоотправитель Цикл 				
			
			ТипГрузоотправитель = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Строка.Грузоотправитель);
			
			Если ТипГрузоотправитель = 3 Тогда  					
				Прервать;  					
			КонецЕсли;
			
		КонецЦикла;
		
		ГрузоотправительЕАЭС = Ложь;
		
		Для Каждого Строка Из СтруктураДанных.Грузоотправитель Цикл
			
			ТипГрузоотправителя = Документы.ЭлектронныйСчетФактура.ПолучитьТипКонтрагента(Документ.Грузоотправитель[СтруктураДанных.Грузоотправитель.Индекс(Строка)].Грузоотправитель);
			
			Если Строка.КодСтраныГрузоотправитель <> "112" И ТипГрузоотправителя = 2 Тогда
				ГрузоотправительЕАЭС = Истина;
				Прервать;				
			КонецЕсли;
			
		КонецЦикла;	
		
		Если (Не ЗначениеЗаполнено(СтруктураДанных.КодСтраныПоставщика) ИЛИ ТипПоставщика = 2) И
			(СтруктураДанных.КодСтраныПолучателя = "112" ИЛИ 
			ТипПолучателя = 3 И ГрузоотправительЕАЭС) Тогда
			
		Иначе
			
			ТекстОшибки = "Поле 21.Реквизиты заявления о ввозе товаров и уплате косвенных налогов и 21.1. Дата ввоза товара не доступно для заполнения!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-32
//	Если заполнено поле 21 (номер или дата), то поле 21.1 – обязательно для заполнения.
//
Процедура ПроверкаЗаполненияПолейПравило32(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если ЗначениеЗаполнено(СтруктураДанных.ПолучательНомерЗаявленияОВвозеТоваров) ИЛИ 
		ЗначениеЗаполнено(СтруктураДанных.ПолучательДатаЗаявленияОВвозеТоваров) Тогда 
		
		Если Не ЗначениеЗаполнено(СтруктураДанных.ПолучательДатаВвозаТоваров) Тогда
			
			ТекстОшибки = "Если заполнено поле 21 (номер или дата), то поле 21.1 – обязательно для заполнения!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-33
//	Если пользователь указал ТТН-1 в разделе 30.«Условия поставки», то в разделах
//	грузоотправитель и грузополучатель должен быть заполнены все поля
//
Процедура ПроверкаЗаполненияПолейПравило33(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	ЕстьТТН1 = Ложь;
	
	Для Каждого Строка Из СтруктураДанных.ДокументыБСО Цикл
		
		Если Строка.КодДокументаУсловияПоставкиБСО = "603" Тогда
			ЕстьТТН1 = Истина;
			Прервать;			
		КонецЕсли;		
		
	КонецЦикла;
	
	Если ЕстьТТН1 Тогда 
		
		Если СтруктураДанных.Грузоотправитель.Количество() > 0 И СтруктураДанных.Грузополучатель.Количество() > 0 Тогда  
			
			НеЗаполненыВсеПоля = Ложь;
			
			Для Каждого Строка Из СтруктураДанных.Грузоотправитель Цикл
				
				Если Не (ЗначениеЗаполнено(Строка.АдресГрузоотправитель) И ЗначениеЗаполнено(Строка.ИмяГрузоотправитель) И
					ЗначениеЗаполнено(Строка.КодСтраныГрузоотправитель) И ЗначениеЗаполнено(Строка.УНПГрузоотправитель)) Тогда
					НеЗаполненыВсеПоля = Истина;
					Прервать;
				КонецЕсли;
				
			КонецЦикла;
			
			Если Не НеЗаполненыВсеПоля Тогда 
				
				Для Каждого Строка Из СтруктураДанных.Грузополучатель Цикл
					
					Если Не (ЗначениеЗаполнено(Строка.АдресГрузополучатель) И ЗначениеЗаполнено(Строка.ИмяГрузополучатель) И
						ЗначениеЗаполнено(Строка.КодСтраныГрузополучатель) И ЗначениеЗаполнено(Строка.УНПГрузополучатель)) Тогда
						НеЗаполненыВсеПоля = Истина;
						Прервать;
					КонецЕсли;
					
				КонецЦикла;
				
			КонецЕсли;		
			
			Если НеЗаполненыВсеПоля Тогда
				
				ТекстОшибки = "В разделах грузоотправитель и грузополучатель должны быть заполнены все поля!";
				Отказ = Истина;
				
			КонецЕсли;
			
		Иначе
			
			ТекстОшибки = "В разделах грузоотправитель и грузополучатель должны быть заполнены все поля!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-34-удалено
//	Если пользователь указал информацию в строках 14 «Реквизиты заявления о ввозе
//	товаров и уплате косвенных налогов» или 21 «Реквизиты заявления о ввозе товаров и
//	уплате косвенных налогов», то даты всех указанных документов, указанных в строке 30
//	(условия поставки) должны совпадать.
//
Процедура ПроверкаЗаполненияПолейПравило34(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
КонецПроцедуры

//Правило-35
//	Если пользователь указал грузоотправителя или грузополучателя (любой из реквизитов),
//	то должны быть указан хотя бы один из документов «условия поставки» (вид документа, дата и номер).
//
Процедура ПроверкаЗаполненияПолейПравило35(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.Грузоотправитель.Количество() > 0 ИЛИ СтруктураДанных.Грузополучатель.Количество() > 0  Тогда 
		
		Если СтруктураДанных.ДокументыБСО.Количество() < 1 Тогда
			
			ТекстОшибки = "Если пользователь указал грузоотправителя или грузополучателя (любой из реквизитов), то должны быть указан хотя бы один из документов «условия поставки» (вид документа, дата и номер)!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

//Правило-36-удалено
//	Если заполнены данные документа (тип, или номер, или дата), то данные (номер и
//	дата) договора (контракта) обязательны для заполнения.
//
Процедура ПроверкаЗаполненияПолейПравило36(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
КонецПроцедуры

//Правило-37
//	Если заполнен один из реквизитов документа: тип, или номер, или дата, то
//	остальные (тип, номер и дата) – обязательны для заполнения
//
Процедура ПроверкаЗаполненияПолейПравило37(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Для Каждого Строка Из СтруктураДанных.ДокументыБСО Цикл
		
		Если ЗначениеЗаполнено(Строка.КодДокументаУсловияПоставкиБСО) ИЛИ ЗначениеЗаполнено(Строка.НомерБСО) ИЛИ
			ЗначениеЗаполнено(Строка.ДатаДокументаБСО) Тогда 
			
			Если Не (ЗначениеЗаполнено(Строка.КодДокументаУсловияПоставкиБСО) И ЗначениеЗаполнено(Строка.НомерБСО) И
				ЗначениеЗаполнено(Строка.ДатаДокументаБСО)) Тогда
				
				ТекстОшибки = "Поля 30. документы, подтверждающие поставку тип, номер и дата – обязательны для заполнения!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
			
		КонецЕсли;
		
	КонецЦикла;

КонецПроцедуры

//Правило-38
//	Если пользователь указал документ ТТН-1 или ТН-2 как документы, подтверждающие поставку товара,
//	то поля вид документа, дата, код типа бланка, серия и номер – обязательны для заполнения
//
Процедура ПроверкаЗаполненияПолейПравило38(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Для Каждого Строка Из СтруктураДанных.ДокументыБСО Цикл
		
		Если Строка.КодДокументаУсловияПоставкиБСО = "602" ИЛИ Строка.КодДокументаУсловияПоставкиБСО = "603" Тогда 
			
			Если Не (ЗначениеЗаполнено(Строка.ВидДокументаБСО) И ЗначениеЗаполнено(Строка.ДатаДокументаБСО) И
				ЗначениеЗаполнено(Строка.КодТипаБланкаБСО) И ЗначениеЗаполнено(Строка.СерияБСО) И ЗначениеЗаполнено(Строка.НомерБСО)) Тогда
				  
				ТекстОшибки = "Поля 30. документы, подтверждающие поставку вид документа, дата, код типа бланка, серия и номер – обязательны для заполнения!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
			
		КонецЕсли;
		
	КонецЦикла;

КонецПроцедуры

//Правило-39-удалено
//	Если пользователь указал "В том числе сумма акциза", то поле «код ТН ВЭД ЕАЭС»
//	– обязательно для заполнения для строки (10 цифр).
//
Процедура ПроверкаЗаполненияПолейПравило39(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 

КонецПроцедуры

//Правило-40
//	Поле 3.1. «ТН ВЭД ЕАЭС» и поле 3.2. «ОКЭД» являются взаимоисключающими друг друга. 
//	Т.е. если заполнено, например, поле 3.1, то поле 3.2 должно оставаться пустым.
//
Процедура ПроверкаЗаполненияПолейПравило40(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
		
		Если ЗначениеЗаполнено(Строка.ТНВЭД) И ЗначениеЗаполнено(Строка.ОКЭД) Тогда
			
			ТекстОшибки = "Поле 3.1. «ТН ВЭД ЕАЭС» и поле 3.2. «ОКЭД» являются взаимоисключающими друг друга!";
			Отказ = Истина;
			Прервать;
			
		КонецЕсли;
		
	КонецЦикла;

КонецПроцедуры

//Правило-41
//	Если указаны статусы поставщика-получателя "Иностранная организация"-"Покупатель", 
//	при этом, пользователь указывает ставку НДС 10% фиксированной ставки, то должен быть
//	указан 10-значный код 3.1. «код ТН ВЭД ЕАЭС» из перечня кодов
//	Указа Президента Республики Беларусь от 21 июня 2007 г. 
//	№287 "О налогообложении продовольственных товаров и товаров для детей".
//Правило-41.1 
//	Если статусы поставщика-получателя "Иностранная организация" – "Покупатель" и
//	в товарной строке указана 8. "В том числе сумма акциза", то должен быть указан
//	10-значный код 3.1. «код ТН ВЭД ЕАЭС».
//Правило-41.2 
//	Если заполнены поля 13 "Регистрационный номер выпуска товаров" или 
//	14 "Реквизиты заявления о ввозе товаров и уплате косвенных налогов", 
//	в товарной строке указана 8. "В том числе сумма акциза", то для этой товарной строки 
//	должен быть указан код 3.1. «код ТН ВЭД ЕАЭС» (10 цифр).
//Правило-41.3 
//	Если статусы поставщика-получателя "Иностранная организация" – "Покупатель",
//	в товарной строке не указана 8. "В том числе сумма акциза", а также 
//	фиксированная ставка НДС не равна 10%, то должен быть указан 
//	код 3.1. «код ТН ВЭД ЕАЭС» (от 4 до 10 цифр).
//
Процедура ПроверкаЗаполненияПолейПравило41(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Иностранная организация и Покупатель
	Если СтруктураДанных.СтатусПоставщика = "FOREIGN_ORGANIZATION" И СтруктураДанных.СтатусПолучателя = "CUSTOMER" Тогда  		
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			//41
			Если Строка.СтавкаНДС = "10" И Не ЗначениеЗаполнено(Строка.ТНВЭД) Тогда
				
				ТекстОшибки = "Для товарной строки должен быть указан код 3.1. «код ТН ВЭД ЕАЭС» (10 цифр)!";
				Отказ = Истина;
				Прервать;
				
			//41.1
			ИначеЕсли ЗначениеЗаполнено(Строка.Акциз) И Не ЗначениеЗаполнено(Строка.ТНВЭД) Тогда
				
				ТекстОшибки = "Для товарной строки должен быть указан код 3.1. «код ТН ВЭД ЕАЭС» (10 цифр)!";
				Отказ = Истина;
				Прервать;
				
			//41.3
			ИначеЕсли Не ЗначениеЗаполнено(Строка.Акциз) И Строка.СтавкаНДС <> "10" И Не ЗначениеЗаполнено(Строка.ТНВЭД) Тогда
				
				ТекстОшибки = "Для товарной строки должен быть указан код 3.1. «код ТН ВЭД ЕАЭС» (10 цифр)!";
				Отказ = Истина;
				Прервать;
							
			КонецЕсли;
			
		КонецЦикла; 
				
	КонецЕсли;

	//41.2
	Если ЗначениеЗаполнено(СтруктураДанных.ПоставщикРегистрационныйНомерВыпускаТоваров) ИЛИ
		ЗначениеЗаполнено(СтруктураДанных.ПоставщикНомерЗаявленияОВвозеТоваров) ИЛИ
		ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаЗаявленияОВвозеТоваров) Тогда
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			Если ЗначениеЗаполнено(Строка.Акциз) И Не ЗначениеЗаполнено(Строка.ТНВЭД) Тогда
				
				ТекстОшибки = "Для товарной строки должен быть указан код 3.1. «код ТН ВЭД ЕАЭС» (10 цифр)!";
				Отказ = Истина;
				Прервать;			
				
			КонецЕсли;
			
		КонецЦикла;  
		
	КонецЕсли;
	
КонецПроцедуры

//Правило-42-удалено
//	Если указана ставка НДС 10% и «код ТН ВЭД ЕАЭС», то «код ТН ВЭД ЕАЭС»
//	должен быть в перечне кодов Указа Президента Республики Беларусь от 21 июня 2007 г.
//	№287 "О налогообложении продовольственных товаров и товаров для детей".
//
Процедура ПроверкаЗаполненияПолейПравило42(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
КонецПроцедуры

//Правило-43-удалено
//	Если заполнены поля 13 или 14 и в атрибуте sender указан УНП поставщика (т.е.
//	отправитель является поставщиком в данном ЭСЧФ), то для данной ЭСЧФ для всех
//	товарных позиций должен быть указан ТН ВЭД ЕАЭС» (от 4 до 10 цифр).   
//
Процедура ПроверкаЗаполненияПолейПравило43(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 

КонецПроцедуры

//Правило-44
//	Если заполнены поля 13."Регистрационный номер выпуска товаров" или 
//	14 "Реквизиты заявления о ввозе товаров и уплате косвенных налогов" 
//	и статусы поставщика – получателя соответственно равны «продавец» – «покупатель», 
//	«посредник» – «потребитель», «заказчик (застройщик)» – «потребитель», 
//	то для данного ЭСЧФ для всех товарных позиций должен быть указан «ТН ВЭД ЕАЭС» (от 4 до 10 цифр).
//
Процедура ПроверкаЗаполненияПолейПравило44(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Продавец и Покупатель / Посредник и Потребитель / Заказчик (застройщик) и Потребитель 
	Если (ЗначениеЗаполнено(СтруктураДанных.ПоставщикРегистрационныйНомерВыпускаТоваров) ИЛИ
		ЗначениеЗаполнено(СтруктураДанных.ПоставщикНомерЗаявленияОВвозеТоваров) ИЛИ
		ЗначениеЗаполнено(СтруктураДанных.ПоставщикДатаЗаявленияОВвозеТоваров)) И
		(СтруктураДанных.СтатусПоставщика = "SELLER" И СтруктураДанных.СтатусПолучателя = "CUSTOMER" ИЛИ
		СтруктураДанных.СтатусПоставщика = "AGENT" И СтруктураДанных.СтатусПолучателя = "CONSUMER" ИЛИ
		СтруктураДанных.СтатусПоставщика = "DEVELOPER" И СтруктураДанных.СтатусПолучателя = "CONSUMER") Тогда  		
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			Если Не (ЗначениеЗаполнено(Строка.ТНВЭД) ИЛИ ЗначениеЗаполнено(Строка.ОКЭД)) Тогда
				
				ТекстОшибки = "Для всех товарных позиций должен быть указан «ТН ВЭД ЕАЭС» (от 4 до 10 цифр)!";
				Отказ = Истина;
				Прервать;			
				
			КонецЕсли;
			
		КонецЦикла;

	КонецЕсли;

КонецПроцедуры

//Правило-45-удалено
//	Если заполнены поля 20 или 21 и статусы поставщика – получателя соответственно
//	равны «иностранная организация» - «покупатель», то для данной ЭСЧФ для всех товарных
//	позиций должен быть указан ТН ВЭД ЕАЭС» (от 4 до 10 цифр).
//
Процедура ПроверкаЗаполненияПолейПравило45(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
КонецПроцедуры

//Правило-46
//	6. Цена (тариф) за единицу товара (работы, услуги) имущественных прав без учета НДС
//	в Разделе 12 не должна быть отрицательной.
//
Процедура ПроверкаЗаполненияПолейПравило46(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
		
		Если Строка.Цена < 0 Тогда 
			
			ТекстОшибки = "6. Цена (тариф) за единицу товара (работы, услуги) имущественных прав без учета НДС в Разделе 12 не должна быть отрицательной!";
			Отказ = Истина;
			Прервать;
			
		КонецЕсли;
		
	КонецЦикла;

КонецПроцедуры

//Правило-47
//	В разделе 6, в поле 10. «НДС сумма» и в поле 8. «В том числе сумма акциза» числа
//	должны быть одного знака (если они есть).
//	Например, если НДС сумма по данной позиции положительная, то и сумма акцизы
//	должна быть положительной.
//
Процедура ПроверкаЗаполненияПолейПравило47(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
		
		СуммаНДС = Строка.СуммаНДС;
		СуммаАкциз = Строка.Акциз;
		
		Если ЗначениеЗаполнено(СуммаНДС) И ЗначениеЗаполнено(СуммаАкциз) Тогда 
			
			Если СуммаНДС > 0 И СуммаАкциз < 0 ИЛИ СуммаНДС < 0 И СуммаАкциз > 0 Тогда
				
				ТекстОшибки = "В разделе 6, в поле 10. «НДС сумма» и в поле 8. «В том числе сумма акциза» числа	должны быть одного знака (если они есть)!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
		
		КонецЕсли;
		
	КонецЦикла;

КонецПроцедуры

//Правило-48
//	Если пользователь указал ставку НДС 0% или "без НДС", то в поле "НДС сумма" должен прописываться 0.
//
Процедура ПроверкаЗаполненияПолейПравило48(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
		
		Если Строка.ТипСтавки = "ZERO" ИЛИ Строка.ТипСтавки = "NO_VAT" Тогда 
			
			Если Строка.СуммаНДС <> 0 Тогда
				
				ТекстОшибки = "Если пользователь указал ставку НДС ""0"" или ""без НДС"", то в поле ""НДС сумма"" должен прописываться 0!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
		
		КонецЕсли;
		
	КонецЦикла;

КонецПроцедуры

//Правило-49
//	Общая сумма всех НДС перевыставляемых не должна превышать суммы входящего НДС, 
//	на который он ссылается в пунктах 11. «Номер ЭСЧФ комитента» или 
//	продавца 12. «Номер ЭСЧФ продавца»
//	Иначе, ЭСЧФ будет отклонен
//
//	ЭСЧФ, указанный в поле 11 или 12, должен обладать следующими показателями:
//	1. Тип должен быть исходный, исправленный или дополнительный без ссылки на ЭСЧФ;
//	2. Статус (в том числе его дополнительных) должен быть "Выставлен. Подписан получателем"
//	или "Выставлен. Начато аннулирование";
//	3. Перевыставляемыми суммами НДС считаются только значения из граф "Сумма НДС" строк, 
//	для которых применен признак "Не подлежит вычету" (в текущем ЭСЧФ и всех дополнительных к нему).
//
//	ЭСЧФ, который ссылается в 11 или 12 поле, должен обладать следующими показателями:
//	1. Тип должен быть исходный, исправленный или дополнительный без ссылки на ЭСЧФ;
//	2. Статус (в том числе его дополнительных) должен быть "Выставлен", "Выставлен.Подписан получателем"
//	или "Выставлен.Начато аннулирование";
//	3. Перевыставляемыми суммами НДС считаются только значения из граф "Всего по счету Сумма НДС" для всех ЭСЧФ,
//	которые ссылаются на одну и тоже ЭСЧФ, и их дополнительных.
//
//	Таким образом, система отклоняет выставление ЭСЧФ в следующих случаях:
//	1. Когда перевыставляемая сумма НДС из ЭСЧФ (или его дополнительного), который
//	ссылается в 11 или 12 поле, в случае выставления, будет превышать
//	Перевыставляемую сумму НДС из ЭСЧФ, указанного в поле 11 или 12;
//	2. Когда к ЭСЧФ, указанному в поле 11 или 12, составляется (подается) дополнительный ЭСЧФ
//	с минусовыми показателями, которые в случае выставления этого ЭСЧФ, вызовет превышение
//	уже перевыставленной суммы НДС над входящим с учетом дополнительных.
//	3. Когда у ЭСЧФ, указанному в поле 11 или 12, получатель попытается поменять
//	признак "Не подлежит вычету" примененный к строкам, что вызовет превышение 
//	уже перевыставленной суммы НДС над входящим с учетом дополнительных.
//
Процедура ПроверкаЗаполненияПолейПравило49(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	
	//Ждем пока доработаю правило и компоненту, на текущий момент не реализуемо через 1С!
	//11
	Если ЗначениеЗаполнено(СтруктураДанных.НомерСчетаКомитента) Тогда
		
		ТекстОшибки = "Правило 49 в разработке!";
		Отказ = Истина;
		
		//Если Документ.НомерСчетаКомитента.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исходный ИЛИ
		//	Документ.НомерСчетаКомитента.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исправленный ИЛИ
		//	Документ.НомерСчетаКомитента.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.ДополнительныйБезСсылки Тогда
		//	
		//	//Статус (в том числе его дополнительных) должен быть "Выставлен. Подписан получателем" или "Выставлен. Начато аннулирование"
		//	Если Не Документ.НомерСчетаКомитента.СтатусАннулирован Тогда
		//		
		//	Иначе
		//		
		//		ТекстОшибки = "В поле 11 статус (в том числе его дополнительных) должен быть ""Выставлен. Подписан получателем"" или ""Выставлен. Начато аннулирование""!";
		//		Отказ = Истина;				
		//		
		//	КонецЕсли;
		//	
		//Иначе
		//	
		//	ТекстОшибки = "В поле 11 тип должен быть исходный, исправленный или дополнительный без ссылки на ЭСЧФ!";
		//	Отказ = Истина;	
		//	
		//КонецЕсли;
		
	//12
	ИначеЕсли ЗначениеЗаполнено(СтруктураДанных.НомерСчетаПродавца) Тогда
		
		ТекстОшибки = "Правило 49 в разработке!";
		Отказ = Истина;
		
		//Если Документ.НомерСчетаПродавца.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исходный ИЛИ
		//	Документ.НомерСчетаПродавца.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исправленный ИЛИ
		//	Документ.НомерСчетаПродавца.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.ДополнительныйБезСсылки Тогда
		//	
		//	//Статус (в том числе его дополнительных) должен быть "Выставлен. Подписан получателем" или "Выставлен. Начато аннулирование"
		//	Если Не Документ.НомерСчетаКомитента.СтатусАннулирован Тогда
		//		
		//	Иначе
		//		
		//		ТекстОшибки = "В поле 12 статус (в том числе его дополнительных) должен быть ""Выставлен. Подписан получателем"" или ""Выставлен. Начато аннулирование""!";
		//		Отказ = Истина;				
		//		
		//	КонецЕсли;
		//				
		//Иначе
		//	
		//	ТекстОшибки = "В поле 12 тип должен быть исходный, исправленный или дополнительный без ссылки на ЭСЧФ!";
		//	Отказ = Истина;	
		//	
		//КонецЕсли;
		
	КонецЕсли;
	
КонецПроцедуры

//Правило-50
//	Сумма, указанная в графе 8. «В том числе сумма акциза» должна быть не больше
//	суммы, указанной в графе 7. «Стоимость товаров» (по модулю).
//
Процедура ПроверкаЗаполненияПолейПравило50(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
		
		Если Строка.Сумма >= 0 Тогда 
			
			Если Строка.Акциз < 0 ИЛИ Строка.Сумма < Строка.Акциз Тогда
			
				ТекстОшибки = "Сумма, указанная в графе 8. «В том числе сумма акциза» должна быть не больше суммы, указанной в графе 7. «Стоимость товаров» (по модулю)!";
				Отказ = Истина;
				Прервать;
			
			КонецЕсли;
			
		Иначе
			
			Если Строка.Акциз > 0 ИЛИ Строка.Сумма > Строка.Акциз Тогда
				
				ТекстОшибки = "Сумма, указанная в графе 8. «В том числе сумма акциза» должна быть не больше суммы, указанной в графе 7. «Стоимость товаров» (по модулю)!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
		
		КонецЕсли;
		
	КонецЦикла;
	
КонецПроцедуры

//Правило-51-удалено
//	Если заполнены поля 20. «Регистрационный номер выпуска товаров» или 21.
//	«Реквизиты заявления о ввозе товаров и уплате косвенных налогов», то в шестом разделе
//	для всех строк товара в графе 12 (дополнительные данные) должен быть указан "Ввозной НДС".
//
Процедура ПроверкаЗаполненияПолейПравило51(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 

КонецПроцедуры

//Правило-52
//	Если пользователь указал статус поставщика – "иностранная организация", а статус
//	получателя – "Покупатель", то в разделе 6, графе 12 должен быть указан "Ввозной НДС" 
//	– для всех товарных позиций 
//
Процедура ПроверкаЗаполненияПолейПравило52(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Иностранная организация и Покупатель 
	Если СтруктураДанных.СтатусПоставщика = "FOREIGN_ORGANIZATION" И СтруктураДанных.СтатусПолучателя = "CUSTOMER" Тогда  		
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			Если Не Строка.ДополнительныеДанные = "IMPORT_VAT" Тогда
				
				ТекстОшибки = "В разделе 6, графе 12 должен быть указан ""Ввозной НДС"" – для всех товарных позиций!";
				Отказ = Истина;
				Прервать;			
				
			КонецЕсли;
			
		КонецЦикла;

	КонецЕсли; 

КонецПроцедуры

#КонецОбласти

#Область ПроверкаЗаполненияПолейПосле52

//Правило-53
//	Если в ЭСЧФ указан любой статус поставщика, кроме "Иностранная организация", 
//	и для товарной строки указана ставка НДС "Без НДС", то для этой строки в графе 12 
//	должен быть указан один из признаков: «Вычет в полном объеме»,
//	«Освобождение от НДС» или «Реализация за пределами РБ».
//Правило-53.1 
//	Если в ЭСЧФ указан статус поставщика "Иностранная организация" и для товарной
//	строки указана ставка НДС "Без НДС", то для этой строки в графе 12 должен быть указан
//	признак «Освобождение от НДС».
//
Процедура ПроверкаЗаполненияПолейПравило53(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//53.1 Иностранная организация
	Если СтруктураДанных.СтатусПоставщика = "FOREIGN_ORGANIZATION" Тогда 
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			//Без НДС и Освобождение от НДС
			Если Строка.ТипСтавки = "NO_VAT" И Строка.ДополнительныеДанные <> "VAT_EXEMPTION" Тогда 
				
				ТекстОшибки = "В графе 12 должен быть указан признак «Освобождение от НДС»!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
			
		КонецЦикла; 
		
	Иначе
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			//Без НДС и Вычет в полном объеме или Освобождение от НДС или Реализация за пределами РБ
			Если Строка.ТипСтавки = "NO_VAT" И (Строка.ДополнительныеДанные <> "DEDUCTION_IN_FULL" ИЛИ
				Строка.ДополнительныеДанные <> "VAT_EXEMPTION" ИЛИ Строка.ДополнительныеДанные <> "OUTSIDE_RB") Тогда 
				
				ТекстОшибки = "В графе 12 должен быть указан один из признаков: «Вычет в полном объеме», «Освобождение от НДС» или «Реализация за пределами РБ»!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
			
		КонецЦикла;
		
	КонецЕсли;

КонецПроцедуры

//Правило-54
//	Количество товара, суммы и стоимости, указанные в 6 разделе Исходного или
//	Исправленного ЭСЧФ, не должны быть отрицательными.
//
Процедура ПроверкаЗаполненияПолейПравило54(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исходный ИЛИ
		СтруктураДанных.ТипЭСЧФ = Перечисления.КодыТиповСчетовФактур_Локализация.Исправленный Тогда 
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			Количество = Строка.Количество;
			Сумма = Строка.Сумма;
			Всего = Строка.Всего;
			
			Если Количество < 0 ИЛИ Сумма < 0 ИЛИ Всего < 0 Тогда 
				
				ТекстОшибки = "Количество товара, суммы и стоимости, указанные в 6 разделе Исходного или Исправленного ЭСЧФ, не должны быть отрицательными!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
			
		КонецЦикла;
		
	КонецЕсли;

КонецПроцедуры

//Правило-55
//	Значения столбцов "Стоимость товаров, работ, услуг, имущественных прав без НДС",
//	"В том числе сумма акциза", "НДС сумма", "Стоимость товаров, работ, услуг,
//	имущественных прав с учетом НДС" строки «Всего по счету» должны соответствовать
//	сумме значений соответствующих столбцов по всем товарным строкам.
//
Процедура ПроверкаЗаполненияПолейПравило55(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.ТаблицаДанных.Итог("Акциз") <> СтруктураДанных.СуммаАкциза ИЛИ
		СтруктураДанных.ТаблицаДанных.Итог("Всего") <> СтруктураДанных.СуммаДокумента ИЛИ 
		СтруктураДанных.ТаблицаДанных.Итог("Сумма") <> СтруктураДанных.СуммаДокументаБезНДС ИЛИ
		СтруктураДанных.ТаблицаДанных.Итог("СуммаНДС") <> СтруктураДанных.СуммаДокументаНДС Тогда 
		
		ТекстОшибки = "Значения столбцов ""Стоимость товаров, работ, услуг, имущественных прав без НДС"", ""В том числе сумма акциза"", ""НДС сумма"", ""Стоимость товаров, работ, услуг, имущественных прав с учетом НДС"" строки «Всего по счету» должны соответствовать сумме значений соответствующих столбцов по всем товарным строкам!";
		Отказ = Истина;
		
	КонецЕсли;

КонецПроцедуры

//Правило-56
//	Получатель может подписать исправленный со статусом "На согласовании" только тогда,
//	когда в БД нет неаннулированных ЭСЧФ, в которых в 11 или 12 поле указан номер из 5
//	поля данного исправленного ЭСЧФ со статусом "На согласовании"
//
Процедура ПроверкаЗаполненияПолейПравило56(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Проверка возможна только на портале

КонецПроцедуры

//Правило-57
//	Получатель не может дать согласие на аннулирование ЭСЧФ, если к данному ЭСЧФ
//	есть исправленный "на согласовании". При подписании получателем исправленного ЭСЧФ,
//	исходный ЭСЧФ должен быть аннулирован автоматически.
//
Процедура ПроверкаЗаполненияПолейПравило57(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Проверка возможна только на портале
	
КонецПроцедуры

//Правило-58
//	При перевыставлении позволять ссылаться на ЭСЧФ продавца, когда составитель
//	текущего ЭСЧФ и ЭСЧФ продавца - с/х с одним и тем же УНП. Данный УНП в ЭСЧФ продавца
//	должен быть получателем со статусом «Покупатель объектов у иностранной организации».
//
Процедура ПроверкаЗаполненияПолейПравило58(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//Ждем пока доработаю правило и компоненту, на текущий момент не реализуемо через 1С!
	Если ЗначениеЗаполнено(СтруктураДанных.НомерСчетаКомитента) ИЛИ
		ЗначениеЗаполнено(СтруктураДанных.НомерСчетаПродавца) Тогда

		ТекстОшибки = "Правило 50 в разработке!";
		Отказ = Истина;
		
	КонецЕсли;
		
КонецПроцедуры

//Правило-59
//	Если заполнен реквизит 6.1 Взаимозависимое лицо и реквизит 16. Код страны получателя - РБ,
//	то реквизит 17. УНП получателя обязательно для заполнения
//
Процедура ПроверкаЗаполненияПолейПравило59(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	Если СтруктураДанных.ПоставщикПризнакВзаимозависимогоЛица И СтруктураДанных.КодСтраныПолучателя = "112" Тогда 
		
		Если Не ЗначениеЗаполнено(СтруктураДанных.УНППолучателя) Тогда
			
			ТекстОшибки = "Реквизит 17. УНП получателя обязателен для заполнения!";
			Отказ = Истина;
			
		КонецЕсли;
		
	КонецЕсли;

КонецПроцедуры

#КонецОбласти

//Правило-53
//	Если в ЭСЧФ указан любой статус поставщика, кроме "Иностранная организация", 
//	и для товарной строки указана ставка НДС "Без НДС", то для этой строки в графе 12 
//	должен быть указан один из признаков: «Вычет в полном объеме»,
//	«Освобождение от НДС» или «Реализация за пределами РБ».
//Правило-53.1 
//	Если в ЭСЧФ указан статус поставщика "Иностранная организация" и для товарной
//	строки указана ставка НДС "Без НДС", то для этой строки в графе 12 должен быть указан
//	признак «Освобождение от НДС».
//
Процедура ПроверкаЗаполненияПолейПравило53(СтруктураДанных, Документ, ТекстОшибки, Отказ);

	Если Отказ Тогда		
		Возврат;    		
	КонецЕсли; 
	
	//53.1 Иностранная организация
	Если СтруктураДанных.СтатусПоставщика = "FOREIGN_ORGANIZATION" Тогда 
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			//Без НДС и Освобождение от НДС
			Если Строка.ТипСтавки = "NO_VAT" И Строка.ДополнительныеДанные <> "VAT_EXEMPTION" Тогда 
				
				ТекстОшибки = "В графе 12 должен быть указан признак «Освобождение от НДС»!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
			
		КонецЦикла; 
		
	Иначе
		
		Для Каждого Строка Из СтруктураДанных.ТаблицаДанных Цикл
			
			//Без НДС и не Вычет в полном объеме или Освобождение от НДС или Реализация за пределами РБ
			Если Строка.ТипСтавки = "NO_VAT" И Не (Строка.ДополнительныеДанные = "DEDUCTION_IN_FULL" ИЛИ
				Строка.ДополнительныеДанные = "VAT_EXEMPTION" ИЛИ Строка.ДополнительныеДанные = "OUTSIDE_RB") Тогда 
				
				ТекстОшибки = "В графе 12 должен быть указан один из признаков: «Вычет в полном объеме», «Освобождение от НДС» или «Реализация за пределами РБ»!";
				Отказ = Истина;
				Прервать;
				
			КонецЕсли;
			
		КонецЦикла;
		
	КонецЕсли;

КонецПроцедуры