ЭСЧФ Беларусь

	// подключение к порталу ЭСФЧ
	Если EVatService.Connect("https://ws.vat.gov.by:443/InvoicesWS/services/InvoicesPort") = 0 Тогда	// рабочий
	//Если EVatService.Connect("https://185.32.226.170:4443/InvoicesWS/services/InvoicesPort") = 0 Тогда	// тестовый
		Сообщить( "Подключение успешно");
	Иначе
		Сообщить( "Ошибка подключения: " + EVatService.LastError);
		возврат;
	КонецЕсли;
	
	ИмяФайла = СокрЛП(хмлКаталогXML) + СокрЛП(НомерЭСЧФ) + ".xml";
	// Чтение файла
	InvVatXml = EVatService.CreateEDoc;
	Если InvVatXml.Document.LoadFromFile(ИмяФайла) <> 0 Тогда
		Сообщить( "Ошибка чтения файла: " + EVatService.LastError);
		возврат;
	КонецЕсли;
	
	// Проверка XML файла на соответствие  xsd-схеме
	InvVatType = InvVatXml.Document.GetXmlNodeValue("issuance/general/documentType");
	Если InvVatType ="ORIGINAL" Тогда
		xsd = "MNSATI_original.xsd";
	ИначеЕсли InvVatType = "FIXED" Тогда
		xsd = "MNSATI_fixed.xsd";
	ИначеЕсли InvVatType = "ADDITIONAL" Тогда
		xsd = "MNSATI_additional.xsd";
	ИначеЕсли InvVatType = "ADD_NO_REFERENCE" Тогда
		xsd = "MNSATI_add_no_reference.xsd";
	Иначе
		Сообщить("Файл " + ИмяФайла +"  содержит неверный тип документа");	  
		Возврат;
	КонецЕсли;
	флаг = InvVatXml.Document.ValidateXML(СокрЛП(хмлКаталогXDS) + xsd, 0);
	Если флаг <> 0 Тогда
		Сообщить(EVatService.LastError + " Документ не соответствует требуемой схеме xsd");
		Возврат;
	КонецЕсли;
	Сообщить("Файл " + ИмяФайла + " соответствует схеме!");
	
	// Выработка подписи
	флаг = InvVatXml.Sign(0);
	Если флаг <> 0 Тогда
		Сообщить("Ошибка выработки подписи: " + EVatService.LastError);
		Возврат;
	КонецЕсли;
	
	// Сохранение подписанного файла с расширением ".edoc.xml"
	fn = СтрЗаменить(СокрЛП(ИмяФайла), ".xml", "") + ".edoc.xml";
	res = InvVatXml.SaveToFile(fn);
	Если res <> 0 Тогда
		Сообщить("Ошибка сохранения подписанного документа: " + EVatService.LastError);
		Возврат;
	КонецЕсли;
	
	// Отправка подписанного документа на портал ЭСФЧ
	res = EVatService.SendEDoc(InvVatXml);
	Если res <> 0 Тогда
		Сообщить( "Ошибка отправки: " + EVatService.LastError);
		возврат;
	Иначе
		Сообщить("Документ отправлен");
	КонецЕсли;
	
	// Ответ от портала ЭСФЧ будет сохранен в фале с расширением ".ticket.error.xml" в случае 
	// ошибки  и с ".ticket.xml"  в случае успешного принятия файла сервисом
	InvVatTicket = EVatService.Ticket;
	Если InvVatTicket.Accepted <> 0 Тогда
		Сообщить( "Документ не принят: " + InvVatTicket.Message);
		fn = ИмяФайла + ".ticket.error.xml";
	Иначе
		TicketIssuerUri = InvVatTicket.Document.GetXmlNodeAttribute("ticket/issuer/URI") ;
		Сообщить("Документ успешно принят сервисом " + TicketIssuerUri);
		fn = ИмяФайла + ".ticket.xml";
	КонецЕсли;  
	
	// Сохранение квитанции
	res = InvVatTicket.SaveToFile(fn);
	Если res <> 0 Тогда
		Сообщить("Ошибка сохранения квитанции: " + EVatService.LastError );
		возврат;
	Иначе
		Сообщить("Файл квитанции " + fn + " сохранен");
	КонецЕсли;