Стабильная платформа 8.3. Кто какую использует?

'ИНИЦИАЛИЗАЦИЯ ПЕРЕМЕННЫХ
ServerName = "ИМЯ СЕРВЕРА"
ServerNameAgent = "ИМЯ РАБОЧЕГО СЕРВЕРА" (обычно = ServerName) 
KlasterPortNumber = 1541
InfoBaseName = "ИМЯ БАЗЫ"

LockMessageText = "Выполняется архивация базы! Попробуйте войти через 15-20 минут." 'Текст сообщения о блокировке подключений к ИБ
LockPermissionCode = "12345" 'Ключ для запуска заблокированной ИБ
ClasterAdminName = "" 'Имя администратора кластера
ClasterAdminPass = "" 'Пароль администратора кластера
InfoBasesAdminName = "Логин" 'Имя администратора ИБ
InfoBasesAdminPass = "Пароль" 'Пароль администратора ИБ

TimeSleep = 5 'Время задержки между установкой запрета и завершением сеансов (в минутах)
TimeBeginLock = Now ' Время начала блокировки ИБ
TimeEndLock = Now+1' Время окончания блокировки ИБ (+день)

v8exe = "C:\Program Files (x86)\1cv8\8.3.5.1119\bin\1cv8.exe" 'Путь к исполняемому файлу 1С:Предприятия 8.3
OutDir = "\\БэкапСервер\1C\BackUp\"+InfoBaseName+"\"
Out = OutDir+"arc.log"

Set fs = CreateObject("Scripting.FileSystemObject")
Set OutFile = fs.OpenTextFile(Out, 8, True)

OutFile.WriteLine(CStr(Now) + " ************************НАЧАЛО ВЫГРУЗКИ ИНФОРМАЦИОННОЙ БАЗЫ************************")

FindInfoBase = False 'Флаг, что ИБ найдена

OutFile.WriteLine(CStr(Now) + " Создание COM-коннектора")
Set ComConnector = CreateObject("v83.COMConnector")

OutFile.WriteLine(CStr(Now) + " Подключение к агенту сервера")
Set ServerAgent = ComConnector.ConnectAgent(ServerNameAgent)

' Получим массив кластеров сервера у агента сервера
OutFile.WriteLine(CStr(Now) + " Получение массива кластеров сервера у агента сервера")
Clasters = ServerAgent.GetClusters()

OutFile.WriteLine(CStr(Now) + " Начало завершения работы пользователей")

' Найдем необходимый нам кластер по IP адресу
OutFile.WriteLine(CStr(Now) + " Начало цикла нахождения необходимого кластера по известному IP-адресу")
For i = LBound(Clasters) To UBound(Clasters)
   If Clasters(i).MainPort = KlasterPortNumber Then
       
       OutFile.WriteLine(CStr(Now) + " Аутефикация к найденному кластеру: " + Clasters(i).ClusterName)
       ServerAgent.Authenticate Clasters(i), ClasterAdminName, ClasterAdminPass

       ' Получаем список рабочих процессов
       OutFile.WriteLine(CStr(Now) + " Получение списка работающих рабочих процессов и обход в цикле")
       WorkingProcesses = ServerAgent.GetWorkingProcesses(Clasters(i))

       For j = LBound(WorkingProcesses) To UBound(WorkingProcesses)

           If WorkingProcesses(j).Running = 1 Then

               ' Для каждого рабочего процесса создаем соединение с рабочим процессом
               OutFile.WriteLine(CStr(Now) + " Создание соединения с рабочим процессом " + WorkingProcesses(j).HostName + ":" + CStr(WorkingProcesses(j).MainPort))
               Set ConnectToWorkProcess = ComConnector.ConnectWorkingProcess("tcp://" + WorkingProcesses(j).HostName + ":" + CStr(WorkingProcesses(j).MainPort))
               OutFile.WriteLine(CStr(Now) + "Соединились! с рабочим процессом")
               
               ConnectToWorkProcess.AuthenticateAdmin ClasterAdminName, ClasterAdminPass
               ConnectToWorkProcess.AddAuthentication InfoBasesAdminName, InfoBasesAdminPass
               OutFile.WriteLine(CStr(Now) + " Аунтификация прошла успешно")

               If Not FindInfoBase Then

                   ' Получаем список ИБ рабочего процесса
                   OutFile.WriteLine(CStr(Now) + " Получение списка ИБ рабочего процесса")
                   InfoBases = ConnectToWorkProcess.GetInfoBases()
                   OutFile.WriteLine(CStr(Now) + " Поиск нужной ИБ")
                   For h = LBound(InfoBases) To UBound(InfoBases)
                       ' Ищем нужную базу
                       OutFile.WriteLine(CStr(Now) + " Обрабатывается ИБ: " + InfoBases(h).Name)
                       If InfoBases(h).Name = InfoBaseName Then
                           Set InfoBase = InfoBases(h)
                           FindInfoBase = True
                           OutFile.WriteLine(CStr(Now) + " Нашли нужную ИБ")
                           Exit For
                       End If
                   Next

                   If Not FindInfoBase Then
                       OutFile.WriteLine(CStr(Now) + " Не нашли нужную ИБ")
                       Exit For
                   End If

                   ' Устанавливаем запрет на подключение новых соединений
                   OutFile.WriteLine(CStr(Now) + " Установка запрета на подключения к ИБ: " + InfoBase.Name)
                   InfoBase.ConnectDenied = True
                   InfoBase.ScheduledJobsDenied = True
                   InfoBase.DeniedFrom = TimeBeginLock
                   InfoBase.DeniedTo   = TimeEndLock
                   InfoBase.DeniedMessage = LockMessageText
                   InfoBase.PermissionCode = LockPermissionCode
                   ConnectToWorkProcess.UpdateInfoBase(InfoBase)

                   ' Устанавливаем задержку выполнения
                   OutFile.WriteLine(CStr(Now) + " Задержка перед началом завершения работы пользователей")
                   set WshShell = WScript.CreateObject("WScript.Shell")
                   WScript.Sleep 60000 * TimeSleep

               End If
               
               ' Устанавливаем задержку выполнения
               OutFile.WriteLine(CStr(Now) + " Задержка перед началом завершения работы пользователей 2")
               set WshShell = WScript.CreateObject("WScript.Shell")
               WScript.Sleep 60000 * 2

               OutFile.WriteLine(CStr(Now) + " Начало завершение работы пользователей с ИБ " + InfoBase.Name)
               If FindInfoBase Then
                   ' Получаем массив соединений с ИБ
                   Connections = ConnectToWorkProcess.GetInfoBaseConnections(InfoBase)
                   OutFile.WriteLine(CStr(Now) + " Обработка списка соединений")
                   For k = LBound(Connections) To UBound(Connections)
                       ' Разрываем Connections с ИБ
                       OutFile.WriteLine(CStr(Now) + " Обрабатывается соединение: Пользователь " + Connections(k).UserName + ", компьютер " + Connections(k).HostName + ", установлено " + CStr(Connections(k).ConnectedAt) + ", режим " + Connections(k).AppID)
                       ConnectToWorkProcess.Disconnect(Connections(k))
                   Next
               End If

           End If

       Next

   End If

Next

If FindInfoBase Then

   OutFile.WriteLine(CStr(Now) + " Окончаение завершения работы пользователей")
   OutFile.WriteLine(CStr(Now) + " Начало создания архивной копии")
   OutFile.Close()
   
   Set Sh = CreateObject("WScript.Shell")
   ' СОЗДАДИМ АРХИВНУЮ КОПИЮ
   LineExe = """" + v8exe + """ DESIGNER /S" + ServerName + ":" + CStr(KlasterPortNumber) + "\" + InfoBaseName + " /N""" + InfoBasesAdminName + """ /P""" + InfoBasesAdminPass + """ /WA- /DumpIB "+OutDir+InfoBaseName+"_"+CStr(Day(Now))+"."+CStr(Month(Now))+"."+CStr(Year(Now))+".dt"" /UC""" + LockPermissionCode + """ /Out""" + Out + """ -NoTruncate /DisableStartupMessages"
   Sh.Run LineExe, 5, True
   
   Set OutFile = fs.OpenTextFile(Out, 8, True)
   OutFile.WriteLine(CStr(Now) + " Завершение создания архивной копии")
   OutFile.WriteLine(CStr(Now) + " Начало обновление конфигурации базы данных")
   OutFile.Close()
   
   ' ОБНОВИМ КОНФИГУРАЦИЮ БД
   LineExe = """" + v8exe + """ DESIGNER /S" + ServerName + ":" + CStr(KlasterPortNumber) + "\" + InfoBaseName + " /N""" + InfoBasesAdminName + """ /P""" + InfoBasesAdminPass + """ /WA- /Upd ateDBCfg -Server /UC""" + LockPermissionCode + """ /Out""" + Out + """ -NoTruncate /DisableStartupMessages"
   Sh.Run LineExe, 5, True
   
   Se t OutFile = fs.OpenTextFile(Out, 8, True)
   OutFile.WriteLine(CStr(Now) + " Завершение обновление конфигурации базы данных")
   OutFile.WriteLine(CStr(Now) + " Установка разрешения подключения к ИБ")

   'Установим разрешение на доступ к ИБ
   ' Устанавливаем разрешение на подключение соединений
   InfoBase.ConnectDenied = False
   InfoBase.ScheduledJobsDenied = False
   InfoBase.DeniedMessage = ""
   InfoBase.PermissionCode = ""
   ConnectToWorkProcess.UpdateInfoBase(InfoBase)

End If

OutFile.WriteLine(CStr(Now) + " ************************ЗАВЕРШЕНИЕ ВЫГРУЗКИ ИНФОРМАЦИОННОЙ БАЗЫ************************")
                  
OutFile.Close()

ComConnector = Null
ServerAgent = Null
Clasters = Null
WorkingProcesses = Null
ConnectToWorkProcess = Null
InfoBases = Null
InfoBase = Null
Connections = Null