Вызов конструктора запроса для кода на встроенном языке 1С, заданного в пользовательском режиме

25.12.13

Разработка - Запросы

Конструктор запроса легко вызывается для строки, содержащей готовый текст запроса. Так работают все консоли запросов. Но задача становится нетривиальной, если у нас есть код не на языке запросов, а на встроенном языке 1С:Предприятия. В нём запрос является лишь частью текста и он представлен не в чистом виде, а в виде строковой константы с переносами строк, двойными кавычками и прочими "неудобствами".

Скачать файлы

Наименование Файл Версия Размер
ВызовКонструктораЗапросовВКонсолиКода.epf
.epf 15,34Kb
66
.epf 1 15,34Kb 66 Скачать

Необходимость задавать исполняемый код в пользовательском режиме появляется не так уж и редко. Для этого создано множество инструментов - универсальные регламентные задания,  консоли кода,  динамические подписки на события и т.д. С помощью этих инструментов можно создавать код, содержащий запросы, и хорошо бы иметь возможность вызывать для этих запросов конструктор. Более того, во всем известных "Инструментах разработчика" уже есть решение этой задачи для обычных форм с применением библиотеки регулярных выражений (внешней библиотеки, подключаемой как COM-объект).


Мы же рассмотрим решение исключительно средствами 1С, которое вы сможете легко встраивать в свои формы, и которое будет подходить как для обычной, так и для управляемой формы (в толстом клиенте). Следующая иллюстрация показывает, чего мы хотим добиться от нашего алгоритма:

 

То есть нам необходимо получить возможность работать с запросами в коде аналогичную той, что дает Конфигуратор - открывать существующий запрос, изменять его, и затем возвращать измененный запрос в код на языке 1С с форматированием и сохранением позиции курсора. Эта задача сложна лишь потому, что у поля тестового документа 1С мало методов для работы с текстом и их придется "изобретать" самостоятельно.


Сначала опишем алгоритм на человеческом языке, а затем перейдем к реализации алгоритма на языке платформы.
Нам нужно:

1) Определить позицию курсора в поле текстового документа на форме.

2) Извлечь текст до курсора и после курсора.

3) В тексте, расположенном до курсора, найти открывающую запрос кавычку. В тексте расположенном после курсора найти первую несдвоенную кавычку от начала строки, это будет закрывающая кавычка.

4) Отделить текст запроса, расположенный между открывающей и закрывающей кавычками. А также выделить код, расположенный до начала запроса и после него.

5) Преобразовать код запроса таким образом, чтобы он нормально воспринимался конструктором запроса. Вместо двойных кавычек подставить одинарные, убрать символы вертикальной черты. После чего передать полученный текст в конструктор.

6) После закрытия конструктора сделать обратное преобразование полученного из него кода запроса. Добавить отступы и привести его к виду, который будет нормально воспринят интерпретатором языка 1С.

7) Соединить новый код запроса с текстом, который раньше располагался до и после текста запроса. Загрузить полученный код в поле формы и восстановить позицию курсора.

 


 

Теперь перейдем к поэтапной реализации этого алгоритма на языке 1С. Для демонстрации выберем обычную форму. Для управляемой формы код будет отличаться всего несколькими строками, и он также есть в прикрепленном к этой публикации файле. Пусть поле текстового документа на нашей форме имеет имя "Поле".


1) Упростим процесс кодирования введением дополнительных переменных и определим текущую позицию курсора. Позицию курсора запишем в переменные НачалоСтроки и НачалоКолонки. Значение переменной НачалоСтроки  в ходе алгорима менять не будем. Оно понадобится в конце для восстановления позиции курсора: 

    //БЛОК №1 - ИНИЦИАЛИЗАЦИЯ ПЕРЕМЕННЫХ

   
ЭлементПоля = ЭлементыФормы.Поле;
   
Кавычка = """";
   
ДвойнаяКавычка = """""";
   
ЗаменаДляДвойнойКавычки = Строка(Новый УникальныйИдентификатор);
   
КоличествоСтрок = ЭлементПоля.КоличествоСтрок();

   
НачалоСтроки = 0;
   
НачалоКолонки = 0;
   
КонецСтроки = 0;
   
КонецКолонки = 0;

   
ЭлементПоля.ПолучитьГраницыВыделения(НачалоСтроки, НачалоКолонки, КонецСтроки, КонецКолонки);
   
ЭлементПоля.УстановитьГраницыВыделения(НачалоСтроки, НачалоКолонки, Началостроки, НачалоКолонки);

 

2) Определим текст, расположенный до курсора и после него. Для этого поле текстового документа дает нам только одну возможность - устанавливать границы выделения и получать выделенный текст. Далее нам придется искать открывающую и закрывающую запрос кавычку. Сильной помехой в этом могут оказаться двойные кавычки. Чтобы избежать лишнего кода по обработке двойных кавычек используем следующий прием. Временно заменим все двойные кавычки на уникальную строку. Обратную замену будем проводить в конце алгоритма, при получении нового кода:

    //БЛОК №2 - ОПРЕДЕЛЕНИЕ ТЕКСТА ДО КУРСОРА И ПОСЛЕ КУРСОРА
   
ЭлементПоля.УстановитьГраницыВыделения(1, 1, Началостроки, НачалоКолонки);
   
ТекстДоКурсора = ЭлементПоля.ВыделенныйТекст;
   
ЭлементПоля.УстановитьГраницыВыделения(НачалоСтроки, НачалоКолонки, КоличествоСтрок+1, 1);
   
ТекстПослеКурсора = ЭлементПоля.ВыделенныйТекст;

   
ЭлементПоля.УстановитьГраницыВыделения(НачалоСтроки, НачалоКолонки, Началостроки, НачалоКолонки);

   
//гарантируем отсутствие в тексте двойных кавычек
   
ТекстДоКурсора = СтрЗаменить(ТекстДоКурсора, ДвойнаяКавычка, ЗаменаДляДвойнойКавычки);
   
//в тексте после курсора необходимо оставить первую кавычку, если сразу после нее идет двойная
    //случай подряд идущих кавычек в количестве более 5-ти штук обрабатывать не будем
   
ТекстПослеКурсора СтрЗаменить(Лев(ТекстПослеКурсора, 1) +
         
СтрЗаменить(Сред(ТекстПослеКурсора, 2), ДвойнаяКавычка, ЗаменаДляДвойнойКавычки), ДвойнаяКавычка, ЗаменаДляДвойнойКавычки) ;

 

3) Двигаясь по строке кода, расположенного до курсора, находим открывающую запрос кавычку. Поскольку мы избавились от двойных кавычек, то найти ее несложно. Нужно просто найти кавычку, которая не была закрыта следующей за ней. Правда, нужно учитывать, что кавычки в комментариях надо пропустить, перемещаясь сразу к концу строки, а также то, что курсор сам мог находиться внутри двойной кавычки в строке запроса:

    //БЛОК №3 - ИЩЕМ ПОЗИЦИЮ ОТКРВАЮЩЕЙ И ЗАКРЫВАЮЩЕЙ КАВЫЧКИ ДЛЯ СТРОКИ ЗАПРОСА

   
ПозицияОткрывающейКавычки = 0;
   
ПозицияЗакрывающейКавычки = 0;

   
ВСтроке = Ложь;
   
КавычкиЕсть = Ложь;
   
ПозицияПредыдущейКавычки = 0;
   
ПоизцияПоследнейКавычки = 0;

   
Позиция = 1;
   
ДлинаТекстаДоКурсора = СтрДлина(ТекстДоКурсора);

   
//ИЩЕМ ОТКРЫВАЮЩУЮ КАВЫЧКУ
   
Пока Позиция <= ДлинаТекстаДоКурсора Цикл

       
ТекущийСимвол = Сред(ТекстДоКурсора, Позиция, 1);

       
ПредыдущийСимвол = " ";
        Если
Позиция > 1 Тогда
           
ПредыдущийСимвол = Сред(ТекстДоКурсора, Позиция-1, 1);
        КонецЕсли;

        Если
ТекущийСимвол = Кавычка Тогда
           
ВСтроке = НЕ ВСтроке;
           
ПозицияПредыдущейКавычки = ПоизцияПоследнейКавычки;
           
ПоизцияПоследнейКавычки = Позиция;
           
КавычкиЕсть = Истина;
        КонецЕсли;

       
//Обработка комментария - начало
       
Если НЕ ВСтроке И ПредыдущийСимвол = "/" И ТекущийСимвол = "/" Тогда
           
//это комментарий, пропускаем символы до конца строки
           
Пока ТекущийСимвол <> Символы.LF И ТекущийСимвол <> Символы.CR Цикл
               
Позиция = Позиция +1;
                Если
Позиция > ДлинаТекстаДоКурсора Тогда
                    Прервать;
                КонецЕсли;
               
ТекущийСимвол = Сред(ТекстДоКурсора, Позиция, 1);
            КонецЦикла;

            Продолжить;
        КонецЕсли;
       
//Обработка комментария - конец

       
Позиция = Позиция + 1;
    КонецЦикла;

   
//ОСОБЫМ ОБРАЗОМ ОБРАБОТАЕМ СЛУЧАЙ НАХОЖДЕНИЯ КУРСОРА В
    //ДВОЙНОЙ КАВЫЧКЕ ВНУТРИ СТРОКИ ЗАПРОСА
   
Если НЕ ВСтроке И КавычкиЕсть И СтрДлина(ТекстПослеКурсора) > 0 Тогда
        Если 
Сред(ТекстДоКурсора, ДлинаТекстаДоКурсора, 1) = Кавычка И Лев(ТекстПослеКурсора,1) = Кавычка Тогда
           
ВСтроке = Истина;
           
ПоизцияПоследнейКавычки = ПозицияПредыдущейКавычки;
           
ТекстДоКурсора = Лев(ТекстДоКурсора, ДлинаТекстаДоКурсора-1);
           
ТекстПослеКурсора = ЗаменаДляДвойнойКавычки + Сред(ТекстПослеКурсора, 2);
        КонецЕсли;
    КонецЕсли;

   
//ЕСЛИ НАШИЛИ ОТКРЫВАЮЩУЮ КАВЫЧКУ, ТО ИЩЕМ ЗАКРЫВАЮЩУЮ
   
Если ВСтроке Тогда
       
ПозицияОткрывающейКавычки = ПоизцияПоследнейКавычки;
       
ПозицияЗакрывающейКавычки = Найти(ТекстПослеКурсора, Кавычка);
    КонецЕсли;

 

4) Теперь можно выделить код между кавычками (запрос) и код расположенный до и после запроса. Чтобы текст запроса был воспринят конструктором его необходимо преобразовать, убрав из начала каждой его строки вертикальную черту:

    //БЛОК №4 - ОПРЕДЕЛЯЕМ ТЕКСТ ДО ЗАПРОСА, ТЕКСТ ЗАПРОСА И ТЕКСТ ПОСЛЕ ЗАПРОСА
    //ПОСЛЕ ЧЕГО ВОЗРАЩАЕМ ДВОЙНЫЕ КАВЫЧКИ В КОД, НЕ ЯВЛЯЮЩИЙСЯ ЧАСТЬЮ ЗАПРОСА

   
Конструктор = Новый("КонструкторЗапроса");
   
ГраницыЗапросаНайдены = ПозицияОткрывающейКавычки <> 0 И ПозицияЗакрывающейКавычки <> 0;

    Если НЕ
ГраницыЗапросаНайдены Тогда
       
Сообщение = "ЗАПРОС НЕ ОБНАРУЖЕН, БУДЕТ СОЗДАН НОВЫЙ ЗАПРОС";
       
ПоказатьОповещениеПользователя(Сообщение, , Сообщение);
       
ТекстДоНачалаЗапроса = ТекстДоКурсора + Кавычка;
       
ТекстПослеКонцаЗапроса = Кавычка + ТекстПослеКурсора ;
    Иначе

       
ТекстДоНачалаЗапроса = Лев(ТекстДоКурсора, ПозицияОткрывающейКавычки);
       
ТекстПослеКонцаЗапроса = Сред(ТекстПослеКурсора, ПозицияЗакрывающейКавычки);

       
ТекстЗапросаССимвовамиВертикальнойЧерты = Сред(ТекстДоКурсора, ПозицияОткрывающейКавычки + 1)

                + Лев(ТекстПослеКурсора, ПозицияЗакрывающейКавычки -1);

        //для конструктора запроса вместо двойной кавычки будем подставлять одинарную
       
ТекстЗапросаССимвовамиВертикальнойЧерты =

                СтрЗаменить(ТекстЗапросаССимвовамиВертикальнойЧерты, ЗаменаДляДвойнойКавычки, Кавычка);

       
КоличествоСтрокВТексте = СтрЧислоСтрок(ТекстЗапросаССимвовамиВертикальнойЧерты);
       
ТекстЗапроса = "";
        Для
К = 1 To КоличествоСтрокВТексте Цикл
           
СтрокаИзТекстаЗапроса = СокрЛП(СтрПолучитьСтроку(ТекстЗапросаССимвовамиВертикальнойЧерты, К));
            Если
Лев(СтрокаИзТекстаЗапроса, 1) = "|" Тогда
               
//для конструктора запроса убираем вертикальную черту в начале строки
               
СтрокаИзТекстаЗапроса = Сред(СтрокаИзТекстаЗапроса, 2);
            КонецЕсли;

           
ТекстЗапроса = ТекстЗапроса + СтрокаИзТекстаЗапроса + Символы.LF;
        КонецЦикла;

       
Конструктор.Текст = ТекстЗапроса;
    КонецЕсли;

   
//возвращаем двойные кавычки
   
ТекстДоНачалаЗапроса = СтрЗаменить(ТекстДоНачалаЗапроса, ЗаменаДляДвойнойКавычки, ДвойнаяКавычка);
   
ТекстПослеКонцаЗапроса = СтрЗаменить(ТекстПослеКонцаЗапроса, ЗаменаДляДвойнойКавычки, ДвойнаяКавычка);

 

5) Передаем текст запроса в конструктор и, если конструктор отработал успешно, вычисляем отступ, который будем добавлять к строкам запроса. Отступ необходимо добавлять, чтобы код запроса вставился на форму красиво, а не безусловно лепился к левому краю текстового поля:

    //БЛОК №5 - ОТКРЫВАЕМ КОНСТРУКТОР ЗАПРОСА С ПОЛУЧЕННОЙ СТРОКОЙ ЗАПРОСА И В СЛУЧАЕ УСПЕШНОГО
    //РЕЗУЛЬТАТА ВЫЧИСЛЯЕМ ОТСТУП, КОТОРЫЙ БУДЕМ ДОБАВЛЯТЬ К КАЖДОЙ СТРОКЕ ЗАПРОСА

   
Если НЕ Конструктор.ОткрытьМодально() Тогда
        Возврат;
    КонецЕсли;

   
ТекстЗапроса = Конструктор.Текст;
    Если
ПустаяСтрока(ТекстЗапроса) Тогда
        Возврат;
    КонецЕсли;


   
ДлинаТекстаДоНачалаЗапроса = СтрДлина(ТекстДоНачалаЗапроса);
   
Позиция = ДлинаТекстаДоНачалаЗапроса-1;

    Пока
Позиция >= 1 Цикл
        Если
Сред(ТекстДоНачалаЗапроса, Позиция, 1) = Символы.LF Тогда
            Прервать;
        КонецЕсли;
       
Позиция = Позиция - 1;
    КонецЦикла;

   
СтрокаОтступа = Сред(ТекстДоНачалаЗапроса, Позиция+1, ДлинаТекстаДоНачалаЗапроса - Позиция -1);
   
ДлинаСтрокиОтступа = СтрДлина(СтрокаОтступа);
   
СтрокаОтступаИзПробеловИТабуляций = "";


    Для
К = 1 To ДлинаСтрокиОтступа Цикл
        Если
Сред(СтрокаОтступа, К, 1) = Символы.Tab Тогда
           
СтрокаОтступаИзПробеловИТабуляций = СтрокаОтступаИзПробеловИТабуляций + Символы.Tab;
        Иначе
           
СтрокаОтступаИзПробеловИТабуляций = СтрокаОтступаИзПробеловИТабуляций + " ";
        КонецЕсли;
    КонецЦикла;

 

6) Теперь у нас есть текст запроса на языке запросов. Нужно преобразовать его в строку на встроенном языке 1С. Добавляем символы вертикальной черты и отступы, преобразуем одинарные кавычки в двойные:

    //БЛОК №6 - ОБРАБАТЫВАЕМ РЕЗУЛЬТАТ, ЗАМЕНЯЕМ ОДИНАРНЫЕ КАВЫЧКИ НА ДВОЙНЫЕ,
    //ДОБАВЛЯЕМ ОТСТУП И ВЕРТИКАЛЬНУЮ ЧЕРТУ СТРОКАМ ЗАПРОСА НАЧИНАЯ СО ВТОРОЙ

   
ТекстЗапроса = СтрЗаменить(ТекстЗапроса, Кавычка, ДвойнаяКавычка);
   
КоличествоСтрокВТексте = СтрЧислоСтрок(ТекстЗапроса);
   
ТекстЗапросаССимвовамиВертикальнойЧерты = СтрПолучитьСтроку(ТекстЗапроса, 1);

    Для
К = 2 To КоличествоСтрокВТексте Цикл
       
ТекстЗапросаССимвовамиВертикальнойЧерты = ТекстЗапросаССимвовамиВертикальнойЧерты +

                   Символы.LF + СтрокаОтступаИзПробеловИТабуляций + "|" + СтрПолучитьСтроку(ТекстЗапроса, К);
    КонецЦикла;


7) Задача фактически решена. Склеиваем код, располагавшийся до запроса, новую строку запроса и код, располагавшийся после запроса. Загружаем получившуюся строку в поле формы и восстанавливаем позицию курсора:

    //ЗАГРУЖАЕМ НОВЫЙ КОД В ТЕКСТОВОЕ ПОЛЕ И УСТАНАВЛИВАЕМ КУРСОР НА ПРЕЖНЮЮ ПОЗИЦИЮ
   
ИтоговыйКод = ТекстДоНачалаЗапроса + ТекстЗапросаССимвовамиВертикальнойЧерты + ТекстПослеКонцаЗапроса;
   
ЭлементПоля.УстановитьТекст(ИтоговыйКод);

   
НоваяКолонка = СтрДлина(СтрокаОтступаИзПробеловИТабуляций)+2;
   
ЭлементПоля.УстановитьГраницыВыделения(НачалоСтроки, НоваяКолонка, НачалоСтроки, НоваяКолонка);
   
ЭтаФорма.ТекущийЭлемент = ЭлементПоля;

 


 

Для применения этого метода в своих разработках вам достаточно заменить в коде имя одного элемента формы - поля текстового документа.

К публикации прилагается обработка с реализацией этого алгоритма, в которой есть обычная и управляемая форма. Обработка предназначена для работы в толстом клиенте управляемого или обычного приложения. При работе с управляемой формой есть незначительные отличия в коде. Например, восстанавливать положение курсора приходится через отложенный вызов процедуры, через обработчик ожидания.

 

Алгоритм был создан с целью применения в новой версии универсальной подсистемы   Динамические подписки на события v.3.  Не проходите мимо этой разработки, она может облегчить поддержку ваших баз:

 

  

 

конструктор запроса вызов открытие управляемой обычной форме пользовательском режиме предприятие консоль код

См. также

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

13000 руб.

02.09.2020    119967    656    389    

701

Для чего используют конструкцию запроса "ГДЕ ЛОЖЬ" в СКД на примере конфигурации 1С:ERP

Запросы СКД Платформа 1С v8.3 Запросы Система компоновки данных 1С:ERP Управление предприятием 2 Бесплатно (free)

В типовых конфигурациях разработчики компании 1С иногда используют в отчетах, построенных на СКД, такую конструкцию, как "ГДЕ ЛОЖЬ". Такая конструкция говорит о том, что данные в запросе не будут получены совсем. Для чего же нужен тогда запрос?

13.02.2024    5622    KawaNoNeko    23    

23

Набор-объект для СКД по тексту или запросу

Запросы СКД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    1964    2    Yashazz    0    

29

Запрос 1С copilot

Инструментарий разработчика Запросы Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Пишем на человеческом языке, что нам надо, и получаем текст запроса на языке 1С. Используются большие языковые модели (LLM GPT) от OpenAI или Яндекс на выбор.

5 стартмани

15.01.2024    6094    29    mkalimulin    23    

48

PrintWizard: поддержка представлений ЗУП в конструкторе

Инструментарий разработчика Запросы Платформа 1С v8.3 Бесплатно (free)

Одной из интересных задач, стоящих в процессе разработки, была поддержка механизма представлений в ЗУП. Но не просто возможность исполнения запросов с ними. Основная проблема была в том, чтобы с ними было удобно работать, а именно: создавать, модифицировать и отлаживать. Кратко о том, что в итоге получилось...

14.12.2023    1714    vandalsvq    7    

28

Объектная модель запроса "Схема запроса" 2

Запросы Платформа 1С v8.3 Запросы Конфигурации 1cv8 Бесплатно (free)

Далеко уже не новый тип данных "Схема запроса". Статья о том, как использовать его "попроще". Примеры создания текста запроса с нуля и изменение имеющегося запроса.

06.12.2023    5287    user1923546    26    

43

Начните уже использовать хранилище запросов

HighLoad оптимизация Запросы

Очень немногие из тех, кто занимается поддержкой MS SQL, работают с хранилищем запросов. А ведь хранилище запросов – это очень удобный, мощный и, главное, бесплатный инструмент, позволяющий быстро найти и локализовать проблему производительности и потребления ресурсов запросами. В статье расскажем о том, как использовать хранилище запросов в MS SQL и какие плюсы и минусы у него есть.

11.10.2023    15962    skovpin_sa    14    

98
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Dzenn 869 26.12.13 07:34 Сейчас в теме
я ничего не понял из написанного
3. Vladimir Litvinenko 2865 26.12.13 08:13 Сейчас в теме
(1) Публикация предназначена для тех, кто создаёт или планирует создавать инструменты, позволяющие управлять исполняемым кодом 1С прямо из пользовательского режима. Если вам интересно, то пройдите по приведенным в начале публикации ссылкам. Консоль кода - простейший пример инструмента, где это может пригодиться.

А писалось всё это дело для "динамических подписок", которые позволяют не лезть каждый раз в конфигуратор и выгонять пользователей из базы, чтобы добавить/изменить подписку на событие, а задать нужный код из режима 1С:Предприятия.

Это особенно полезно, когда нужно срочно добавить какой-нибудь контроль/запрет при создании/изменении объектов базы. Конструктор запросов позволяет быстрее вносить изменения в такой код.

(2) Учту.
AnKonAlm; +1 Ответить
2. Dzenn 869 26.12.13 07:36 Сейчас в теме
хотелось бы, чтобы гифки шли помедленнее, либо сопроводить их набором жпегов
AnKonAlm; +1 Ответить
4. OneS 5 26.12.13 11:24 Сейчас в теме
Вот какое дело... Человеку не знающему, в контексте поставленной задачи, конструктор не поможет. А кто знает, тому конструктор как то уже и не очень нужен. Консоль запросов тому подтверждение.

Опять же, нужно ли подвергать себя риску обрушить базу ваяя на лету в пользовательском режиме нечто настолько сложное, что без конструктора не обойтись?

Однако автор старался, так что респект однозначно.
AnKonAlm; +1 Ответить
5. Vladimir Litvinenko 2865 26.12.13 12:23 Сейчас в теме
(4) Первую часть вопроса не очень понял. И консоль запросов и консоль кода все активно используют. Более того, есть разработки, где большая часть нового кода задается сначала в пользовательском режиме. Например Мета-конфигуратор в "СКАТ-Профессионал".

В пользовательском режиме можно не "ваять на лету" новые запросы, а быстро изменять уже существующие.

Представьте, что Вам поставили задачу запретить изменение документов, удовлетворяющих сложному условию, которое оптимальнее проверять через запрос. Что вы сделаете? Добавите в конфигураторе подписку на событие "ПередЗаписью" и выгоните всех пользователей из базы? А если через некоторое время это условие поменяется, ведь бизнес у нас переменчив?

Вместо того, чтобы каждый раз менять конфигурацию или придумывать разные регистры правил, которые могут никогда больше не пригодиться, гораздо проще немного откорректировать запрос в пользовательском режиме. Большинству программистов это будет под силу без риска обрушить базу :) Ну а если не хотите рисковать, то всегда есть тестовая база, где можно никому не мешая и в конфигураторе код написать и в пользовательском режиме его протестить.

Посмотрите вот этот скриншот:
http://infostart.ru/upload/iblock/b8e/Pic5.PNG
6. wowik 884 26.12.13 13:17 Сейчас в теме
я так понял это аналог обработок "Выполнить" из ИР.
8. Vladimir Litvinenko 2865 26.12.13 14:23 Сейчас в теме
(6) wowik,
Да, ориентировался на ИР и сначала хотел использовать именно функции ИР для вызова конструктора. Но оказалось, что они используют внешние библиотеки для разбора строк, чего хотелось бы избежать. Еще не получилось связать ИР-овский конструктор и управляемую форму. Может быть плохо старался и еще получится это сделать :) Надеюсь что смогу использовать ИР для вызова контекстной подсказки, там тоже внешние библиотеки задействованы, но без этого уже не обойтись.

(7) Yashazz,
Я рад, что где-то в недрах Ваших обработок существует подобный алгоритм. Осталось подождать пока Вселенский Коллективный Разум объединит мозги всех 1С-ников в единое целое. Тогда мы перестанем делиться алгоритмами и будем создавать идеальные разработки. Кстати не нашел подобного в Ваших публикациях. Вот это не в счет. Там просто строка вставляется, а открыть запрос в конструкторе нельзя.
9. Yashazz 4707 26.12.13 15:55 Сейчас в теме
(8) Не, там нету, я в первую очередь о ней вспомнил и проверил, нифига. В других каких-то было, сейчас не вспомню.

Дело в другом - это ведь фрагмент, кусок, не очень понимаю смысл так его разжёвывать. Впрочем, это лично моё недоумение.
А что до "некрасиво" - после того, как я видел подобные решения на регулярных выражениях, всё остальное меркнет...
10. Vladimir Litvinenko 2865 26.12.13 16:38 Сейчас в теме
(9) Yashazz,
Разжевывать нужно чтобы не только "суперпрофессионалы" всё поняли. Жаль, что многие программисты забывают, что они не всегда были гуру, а когда-то тоже учились.

К тому же политика Инфостарта такова, что для скачивания нужно потратить 1$m и насколько я понял для многих это проблема. Поэтому код по возможности вставляю в статью. Дополнительные комментарии по сравнению с этим - мелочь.



Что до RegExp, то это внешняя по отношению к 1С библиотека. Конечно это своего рода стандарт, но "стандарт" и 1С - вещи слабо совместимые. RegExp используется в 1С через COM-интерфейс, который например не поддерживается в Linux, для которого с недавнего времени тоже есть толстый клиент. Если писать простое универсальное решение для 1С, то лучше чтобы оно зависело только от 1С.
Бывалый77; DigSl; +2 Ответить
15. Yashazz 4707 27.12.13 16:19 Сейчас в теме
(10) Учить новичков - это не на ИС, а на других сайтах, флаг в руки. Здесь - сайт профессионалов.
(12) Ага, я про это и говорил. Безо всяких ВК, сам пробовал, нормально работает.
16. Vladimir Litvinenko 2865 28.12.13 04:10 Сейчас в теме
(15) Субъективное суждение. Потому что одни из самых рейтинговых публикаций на ИС - это разного рода обучалки, переработанные пересказы документации и обработки, направленные на самую широкую аудиторию. Значит есть люди, для которых это полезно и нет ничего плохого в том, чтобы с ними этим делиться.

И мне тоже бывает интересно увидеть новую интерпретацию уже знакомой информации. Не думаю что имеет смысл это обсуждать ибо ведет к холивару.
17. Vladimir Litvinenko 2865 28.12.13 04:14 Сейчас в теме
(15) Это все таки ВК:
В поставку входит два файла:
•rex32.dll - для работы в 32-битных клиентах и сервере
•rex64.dll - для работы в 64-битном сервере
Основные планы на ближайшее будещее - сделать linux-версию.
18. tormozit 7133 28.12.13 07:57 Сейчас в теме
(17) Нет. Это "полуВК" и "полуРасширениеОбъектнойМодели". Когда попробуешь, поймешь.
19. Sitex 30.12.13 09:13 Сейчас в теме
(10) в целом неплохо. Особенно когда в рутине дел это может позабыться.

(15) Yashazz, По вашему суждению, можно при регистрации сделать на ИС сдачу теории...т.п. Чтобы лишних как статье так и комментариев не было.
Прикрепленные файлы:
20. Yashazz 4707 31.12.13 18:36 Сейчас в теме
(19) Это не моё суждение, это определение сайта как такового, посмотрите сами. Впрочем, увы, ИС действительно медленно, но верно превращается во второй DevTrain. :(
21. Vladimir Litvinenko 2865 01.01.14 08:33 Сейчас в теме
(20)
ИС действительно медленно, но верно превращается во второй DevTrain

Ваши претензии безосновательны. Вы не привели ссылку на другую публикацию, где аналогичная работа с конструктором велась бы без подключения внешних dll-библиотек. То, что именно это является целью данной публикации указано в самом её начале. Подробность изложения материала также считаю плохой мишенью для критики.


Дальнейшее обсуждение "элементарщины", "баянов" и причитания о судьбе Инфостарта предлагаю перенести в ЭТУ или ЭТУ публикации за Вашим авторством. Они подходят для этого гораздо больше. Признак непрофессионализма - это тратить время на поиск соринки в чужом глазу, вместо того, чтобы улучшать качество собственных работ.
МимохожийОднако; +1 Ответить
24. Yashazz 4707 01.01.14 22:54 Сейчас в теме
(21) Вы, вероятно, не видели вот этого: http://infostart.ru/about/, где в первой же строке сказано "Профессиональное сообщество". Ознакомьтесь, потом будете спорить.Это и вообще всех касается, кто считает ИС "лягушатником для начинающих". И про специалистов, оказывающих профессиональные услуги, тоже, считаю, доступно написано.

Что до меня, я всегда честно оговариваю, что является баяном и что нет, поэтому вы можете переносить разговор куда угодно и о чём угодно, но реплика про соринку и качество работ в любом случае мимо, уважаемый. Признак непрофессионализма в данном случае - явный переход на личности, попытка флейма и переваливания с больной головы на здоровую (сиречь попытки переноса в темы, не имеющие отношения к). Советую быть вежливее и терпимее, и не путать критику публикации с критикой автора. Учитесь уважать окружающих.
Засим участие прекращаю, ибо бессмысленно тратить время не привык.
7. Yashazz 4707 26.12.13 13:32 Сейчас в теме
Баян, да ещё и некрасиво сделанный. Я решил такую задачу давным-давно и её решений видел несметно, ибо элементарщина. Воистину, скоро дождёмся мегапопулярных публикаций на тему "как выбрать элементы из справочника", но зато красивых, с гифками и попунктным разжёвыванием каждой строки.

25. Vladimir Litvinenko 2865 02.01.14 12:28 Сейчас в теме
Да я и так старался избежать перехода на личности. Но сообщения (7), (15) и (20) написанные в резком обвинительном тоне не оставили выбора. Уж извините.
26. Yashazz 4707 05.01.14 01:41 Сейчас в теме
(25) Ладно, проехали. С праздниками всех, кстати. Просто у меня пунктик - очень не люблю баянить сам, иногда и других начинаю пинать, увлёкшись. Прошу пардону.
11. MrFlanker 219 26.12.13 19:11 Сейчас в теме
Гифики помедленей пожалуйста, ну непонятно что ж такое происходит.
12. tormozit 7133 26.12.13 22:59 Сейчас в теме
Кроссплатформенную замену VBScript.RegExp обещал Орефков, но что то тишина у него уже пол года. Видимо крепко засел над снегопатом для 8.3. Кстати в ИР уже давно есть поддержка его компоненты, но отключено внутри, т.к. она пока в некоторых случаях аварийно завершает приложение. Качественный багрепорт ему я еще весной отправил.
Vladimir Litvinenko; +1 Ответить
13. Vladimir Litvinenko 2865 27.12.13 02:16 Сейчас в теме
(12) Интересно, иметь такой инструмент было бы хорошо. Будем ждать.
А реализация планировалась средствами 1С или через какую-то библиотеку?
14. tormozit 7133 27.12.13 08:17 Сейчас в теме
22. МимохожийОднако 140 01.01.14 09:19 Сейчас в теме
23. help1Ckr 01.01.14 15:02 Сейчас в теме
Спасибо за статью, особенно за то что выложили здесь подробное описание алгоритма.
27. servs 65 08.01.14 13:43 Сейчас в теме
Обращаю внимание критиков: способность писать код на языке 1С, не прибегая при этом к dll - это критерий, по которому можно отличить новичков (или лентяев :-) ) от грамотных программистов 1С.

Не использование dll в конкретной задаче - это изюминка статьи,
+ алгоритм также полезен не менее.

Многим профессионалам есть чему поучиться, ящетаю)))

Спасибо за статью! Ставлю жирный плюс!

П.С.: Есть статьи на ИС, которые иногда вызывают у меня такую же реакцию как у критиков выше (например, обработка запуска амми из 1С). Эта статья заслуживает на похвалу. Нужно уметь понять ее ценность, что не каждому дано.
astrius; dr2c; +2 Ответить
28. Alex1Cnic 148 21.01.14 12:45 Сейчас в теме
А что, интересная статья. Люблю, когда все по-полочкам разложено...
29. Ivon 673 16.07.14 17:23 Сейчас в теме
Вообще молодец. Плюсанул.
30. CaSH_2004 372 21.09.16 21:29 Сейчас в теме
Спасибо, полезная штука, сам такой давно написал, но были огрехи и не хотелось вникать, а тут скопировал, вставил и все взлетело.
31. TerveRus 31.10.16 12:55 Сейчас в теме
Ну вот, думал скачать и сразу использовать, но как всегда пришлось допилить)

Автор, открытие конструктора в тонком клиенте возможно, начиная с версии платформы 8.3.5! А здесь проверка на толстый клиент и привет!
Во-вторых, пришлось переделывать на открытие конструктора через Показать() и оповещение, модальный вызов в тонком клиенте не работает.
Оставьте свое сообщение