Настройки СКД, Хелп ми плиз !

1. sky.xn 06.03.15 08:38 Сейчас в теме
Всем привет ! Во внешней обработке [Не отчете !] создал программно отчет в СКД, вывел его в табличный документ на форме. Как можно сделать кнопку по которой бы открывались настройки отчета [Такие же как если создавать отчет в СКД стандартным образом, настройки группировки, сортировки и т.д.] ?
Вознаграждение за ответ
Показать полностью
Найденные решения
54. spacecraft 11.03.15 12:08 Сейчас в теме
(53) sky.xn, НастройкиДляКомпоновкиМакета.ПараметрыДанных.ДатаНачала = ДатаРучная ?
хотя скорее всего только для чтения. Тогда:
УстановитьЗначениеПараметра(<Параметр>, <Значение>)

НастройкиДляКомпоновкиМакета.ПараметрыДанных.УстановитьЗначениеПараметра("ДатаНачала", ДатаРучная);
Остальные ответы
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
2. sky.xn 06.03.15 08:48 Сейчас в теме
Конфигурация - Бухгалтерия 3.0
3. Swetlana 20 06.03.15 08:48 Сейчас в теме
есть уже типовой шаблон СКД с диска ИТС, там все уже есть

Естественно что его можно дорабатывать для своих нужд

Обычно так и делают
4. sky.xn 06.03.15 08:51 Сейчас в теме
(3) Swetlana, не знал, не подскажете как он точно называется ?
5. sky.xn 06.03.15 09:02 Сейчас в теме
Подскажет кто нибудь ???
6. Swetlana 20 06.03.15 09:03 Сейчас в теме
так и называется- типовой шаблон СКД, давно видела, правда под 8.2

под 8.3 не пробовала ещё, может и под него есть.
7. Swetlana 20 06.03.15 09:05 Сейчас в теме
кстати- нашла на инфостарте http://infostart.ru/public/242708/ и как раз под управляемые формы
8. sky.xn 06.03.15 09:17 Сейчас в теме
(7) Swetlana, Посмотрел, это все не то. Мне бы хотя бы теоретически понять как можно открыть стандартную форму пользовательской настройки отчета на скд, который сформирован полностью программным способом
9. spacecraft 06.03.15 09:26 Сейчас в теме
Не указана конфигурация. Типовая на БСП?
Смотреть в сторону общих форм "ФормаНастроекОтчета".
10. sky.xn 06.03.15 09:28 Сейчас в теме
(9) spacecraft, указал во втором сообщении. Да, типовая Бух 3.0 на БСП ! Подскажите чуть подробнее про "ФормуНастроекОтчета", хотя бы на теоретическом уровне ?
11. sky.xn 06.03.15 09:30 Сейчас в теме
(9) spacecraft, Я так понял эта форма просто для отбора ((( А как вывести стандартную форму настроек отчета на СКД зашитую в платформу ?
12. besica 06.03.15 09:45 Сейчас в теме
Это "КомпановщикНастроекПользователскиеНастройки" имеется ввиду?
Он так и называется - в любом стандартном отчете в форме можно посмотреть как называется и на что ссылается
13. sky.xn 06.03.15 09:56 Сейчас в теме
(12) besica, как открыть стандартную форму где пользователь смог бы редактировать группировки, отборы и сортировку ? Вот в чем вопрос
14. spacecraft 06.03.15 10:39 Сейчас в теме
Если в отчете нет формы, то подключается общая форма "ФормаОтчета". и в ней настройки открывают общую форму "ФормаНастроекОтчета".
Там кода... мало не покажется.

А в СКД нужно внести выбранные поля и отбор, чтоб в настройках появилось.

Или делать свою форму и свои настройки рисовать.
15. sky.xn 06.03.15 10:43 Сейчас в теме
(14) spacecraft, я же говорю у меня не отчет, а внешняя обработка ...
16. besica 06.03.15 11:17 Сейчас в теме
На форме в обработке можно добавить реквизит с типом компоновщик настроек компоновки данных. И программно при создании прицеплять его к вашей компоновке.
17. Gossar 06.03.15 11:52 Сейчас в теме
просто добавить группу и определить настройки компоновки туда
18. sky.xn 06.03.15 12:13 Сейчас в теме
На форме в обработке можно добавить реквизит с типом компоновщик настроек компоновки данных. И программно при создании прицеплять его к вашей компоновке.


А поподробнее можно чуть ? Я создал реквизит, выбрал тип - КомпоновщикНастроекКомпоновкиДанных. Как теперь его на форму вывести ?

просто добавить группу и определить настройки компоновки туда


Мне бы чуть подробнее ((
19. sky.xn 08.03.15 16:24 Сейчас в теме
Хелп ми плиз ! Ну подскажите хоть кто нибудь ((
20. spacecraft 08.03.15 19:20 Сейчас в теме
Создаешь группу или страницу и туда выводишь Реквизит - Настройки
Только не забудь этот реквизит к своей СКД подключить.
Вот тут есть немного:
http://infostart.ru/public/255063/
21. sky.xn 11.03.15 06:53 Сейчас в теме
(20) spacecraft, Настройки на форму вывел. Подключить не получается, может кто нибудь скинуть примерный код ?
22. sky.xn 11.03.15 08:00 Сейчас в теме
Добавляю вознаграждение, помогите !
23. sky.xn 11.03.15 08:08 Сейчас в теме
Попробовал вот так:

Реквизит.ЗагрузитьНастройки(НастройкиКомпоновкиДанных);

В этом реквизите вышла только группировка и все, причем менять ее не получается, т.к. не видно полей выбора, отбор как делать не нашел ...
33. spacecraft 11.03.15 11:02 Сейчас в теме
(23) sky.xn, а выбранные поля и отбор в СКД настроен?
35. sky.xn 11.03.15 11:05 Сейчас в теме
(33) spacecraft, в макете настроены выбранные поля, условия отбора тоже есть, но эти параметры не появляются ...
37. spacecraft 11.03.15 11:09 Сейчас в теме
(35) sky.xn, на форму нужно вывести РеквизитКомпоновщикНастроек.Настройки.Отбор.
Это для отбора.
38. sky.xn 11.03.15 11:12 Сейчас в теме
(37) spacecraft, Вот смотри, у меня в запросе в макете указаны параметры отбора:

ГДЕ Документ.Дата >= ДатаНачала
И Документ.Дата <= ДатаОкончания

В "РеквизитКомпоновщикНастроек.Настройки.Отбор" они не появляются ...
39. spacecraft 11.03.15 11:14 Сейчас в теме
(38) sky.xn, вот пример из типовой по подключению компоновщика:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Если Параметры.Свойство("АвтоТест") Тогда // Возврат при получении формы для анализа.
		Возврат;
	КонецЕсли;
	
	ЗакрыватьПриЗакрытииВладельца = Истина;
	
	Заголовок = Параметры.Заголовок;
	
	Если Параметры.Свойство("АдресКомпоновщикаНастроек", АдресКомпоновщикаНастроек) Тогда
		// Хранилище приоритетнее
		Данные = ПолучитьИзВременногоХранилища(АдресКомпоновщикаНастроек);
 		АдресСхемыКомпоновки = ПоместитьВоВременноеХранилище(Данные.СхемаКомпоновки, УникальныйИдентификатор);;
		КомпоновщикНастроек = Новый КомпоновщикНастроекКомпоновкиДанных;
		КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемыКомпоновки));
		КомпоновщикНастроек.ЗагрузитьНастройки(Данные.Настройки);
	Иначе
		АдресСхемыКомпоновки = "";
		КомпоновщикНастроек = Параметры.КомпоновщикНастроек;
	КонецЕсли;
	
	Параметры.Свойство("ПериодДанных", ПериодДанных);
	
	Если Параметры.ВыборПериода Тогда
		ВыгружатьЗаПериод = Истина;
	Иначе
		ВыгружатьЗаПериод = Ложь;
		// Отключаем выбор периода совсем
		Элементы.ПериодДанных.Видимость = Ложь;
	КонецЕсли;
	
КонецПроцедуры
Показать
42. orfos 215 11.03.15 11:22 Сейчас в теме
(38) sky.xn, если не появляются значит дата у тебя параметр
40. sky.xn 11.03.15 11:14 Сейчас в теме
(37) spacecraft, Так, вру, кажется появляются, но на форме их вручную нужно вытягивать, т.е. щелкать правой кнопкой, нажимать "Добавить", выбирать параметр и только потом забивать ... Как сделать, чтобы они сразу выходили ?
41. spacecraft 11.03.15 11:19 Сейчас в теме
(40) sky.xn, включать в пользовательские настройки?
44. sky.xn 11.03.15 11:25 Сейчас в теме
(41) spacecraft, Вот я олух, точно, теперь появляются, но отчет почему то не формируется ... Вернее пустой получается, как будто настройки не влияют.
(42) orfos, Да, параметр, уже разобрался, осталось только понять как сделать чтоб эти параметры действовали
46. spacecraft 11.03.15 11:35 Сейчас в теме
(44) sky.xn, Вот что пишут 1С:
В управляемой форме источник доступных настроек для схемы компоновки данных на клиенте работать не может. Поэтому в управляемой форме нужно создавать источник доступных настроек для адреса схемы компоновки данных.

В качестве адреса схемы компоновки данных может выступать адрес во временном хранилище, в которое поместили схему компоновки данных, или адрес значения в записи базы данных.

Пример создания источника доступных настроек для схемы, помещенной во временное хранилище:

Копировать в буфер обмена
АдресСхемы = ПоместитьВоВременноеХранилище(Схема, УникальныйИдентификатор);
КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемы));
В данном примере во временное хранилище помещается схема компоновки данных, находящаяся в переменной Схема.

Пример создания источника доступных настроек для схемы, расположенной в базе данных:

Копировать в буфер обмена
АдресСхемы = ПолучитьНавигационнуюСсылку(Ссылка, "СхемаКомпоновкиДанных");
КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемы));
В данном примере схема будет получаться базы данных, из реквизита с именем СхемаКомпоновкиДанных объекта со ссылкой Ссылка.
Показать
43. orfos 215 11.03.15 11:24 Сейчас в теме
(40) sky.xn, они будут сразу выходить. там важно в разделе данные указать нужный тип данных. Для параметров вот такой: КомпоновщикНастроек.Настройки.ПараметрыДанных
24. bezplana 11.03.15 08:14 Сейчас в теме
Покажу пример как вывести настройки и отбор на ту же форму, где отображается результат, аналогично разделить это по разным формам не составит труда.
1)Добавляешь в обработку макет СКД
2)Создаешь у обработки реквизит Компоновщик типа КомпоновщикНастроекКомпоновкиДанных
3)В режиме редактирования формы выводишь КомпоновщикНастроекНастройкиОтбор и КомпоновщикНастроекНастройкиПараметрыДанных из реквизита Компоновщик (это его вложенные поля)


Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

СхемаСКД = РеквизитФормыВЗначение("Объект").ПолучитьСхемуСКД();
АдресСхемы = ПоместитьВоВременноеХранилище(СхемаСКД,Новый УникальныйИдентификатор);
КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемы));
КомпоновщикНастроек.ЗагрузитьНастройки(СхемаСКД.НастройкиПоУмолчанию);	

КонецПроцедуры

&НаСервере
Процедура СформироватьСКД()
СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(АдресСхемы);
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновки   = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
	
	ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , , Истина);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	ТаблицаЗначений =  Новый ТаблицаЗначений;
	ПроцессорВывода.УстановитьОбъект(ТаблицаЗначений);
	ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	ТЗ.Загрузить(ТаблицаЗначений);
	
КонецПроцедуры

//Функция в модуле обработки
Функция ПолучитьСхемуСКД () Экспорт
	Схема = ПолучитьМакет("Макет");
	Возврат Схема;
КонецФункции // ()

Показать
25. Chameleon1980 11.03.15 08:29 Сейчас в теме
в книге по скд от Хрусталевой где-то в конце по этому вопросу есть.
Счас посмотрю.
26. Chameleon1980 11.03.15 08:34 Сейчас в теме
в последней главе посмотрите "Культура создания отчетов"
в инете эту книгу запросто найти
Разработка сложных отчетов....
27. sky.xn 11.03.15 08:38 Сейчас в теме
(26) Chameleon1980, А как книга точно называется ?

(24) bezplana, Что за необъявленный реквизит ТЗ ? Можете скинуть какую нибудь уже рабочую обработку откуда можно выдернуть код ? Не увидел также в коде реквизита "Компоновщик", хотя вы его описали, а вопрос у меня именно с ним и связан.
28. Chameleon1980 11.03.15 09:09 Сейчас в теме
Е.Ю.Хрусталева
Разработка сложных отчетов в 1С:Предприятии 8
система компоновки данных

даже диск от книги в инете есть
29. sky.xn 11.03.15 09:26 Сейчас в теме
(28) Chameleon1980, Спасибо, сейчас скачаю, погляжу, может там что нибудь путное будет.
30. sky.xn 11.03.15 10:34 Сейчас в теме
Подскажет еще кто нибудь ?
31. orfos 215 11.03.15 10:42 Сейчас в теме
Добавь на форму "ТабличноеПоле" в качестве данных укажи тип "КомпоновщикНастроек.Настройки.ПараметрыДанных" или "КомпоновщикНастроек.Настройки.Отбор". Я так делал именно в обработке правда под 8.2. Мне кажется в 8.3 тоже самое можно сделать.
32. Chameleon1980 11.03.15 10:50 Сейчас в теме
(31) не совсем то автору нужно, как мне показалось
Ему в обработке (не в отчете) нужно открыть все настройки скд.
в книге не нашли?
34. sky.xn 11.03.15 11:04 Сейчас в теме
(32) Chameleon1980, ага в обработке нужно открыть настройки СКД для редактирования их пользователем. В книге не нашел, к сожалению (((31)

orfos, Пробовал так я, параметры остаются пустыми ... Хотя в макете СКД они есть. Если скинете готовую обработку посмотреть, буду благодарен.
36. sky.xn 11.03.15 11:06 Сейчас в теме
На форме имею ввиду не появляются
45. sky.xn 11.03.15 11:35 Сейчас в теме
Понял, у меня в процедуре ПриСозданииНаСервере -

СхемаСКД = РеквизитФормыВЗначение("Объект").ПолучитьСхемуСКД();
АдресСхемы = ПоместитьВоВременноеХранилище(СхемаСКД,Новый УникальныйИдентификатор);
КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемы));
КомпоновщикНастроек.ЗагрузитьНастройки(СхемаСКД.НастройкиПоУмолчанию);	


А в команде на формирование отчета следующее -

СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(АдресСхемы);
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки   = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, , ,);
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , , Истина);
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ТаблицаЗначений =  Новый ТаблицаЗначений;
ПроцессорВывода.УстановитьДокумент(ТабличныйДокумент);
ПроцессорВывода.Вывести(ПроцессорКомпоновки);	
Показать


Так вот в строке СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(АдресСхемы); "АдресСхемы" это реквизит формы с типом "Произвольный", на какой тип его поменять или как сделать иначе, ума не приложу ...
47. spacecraft 11.03.15 11:41 Сейчас в теме
48. sky.xn 11.03.15 11:43 Сейчас в теме
(47) spacecraft, ага, поставил тип "Строка", но не помогает, дело похоже не в этом. Если убрать параметры в макете СКД то все формируется, если поставить то ничего не формируется ...
52. spacecraft 11.03.15 11:56 Сейчас в теме
(45) sky.xn, вот так попробуй:
СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(АдресСхемы);
НастройкиДляКомпоновкиМакета = КомпоновщикНастроек.ПолучитьНастройки();
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки   = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиДляКомпоновкиМакета, , ,);
ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , , Истина);
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
ТаблицаЗначений =  Новый ТаблицаЗначений;
ПроцессорВывода.УстановитьДокумент(ТабличныйДокумент);
ПроцессорВывода.Вывести(ПроцессорКомпоновки); 
Показать
53. sky.xn 11.03.15 11:59 Сейчас в теме
(52) spacecraft, А как в твоем примере передать вручную параметр ДатаНачала и ДатаОкончания в скд ? НастройкиДляКомпоновкиМакета.ДатаНачала = ДатаРучная, как то так ?
54. spacecraft 11.03.15 12:08 Сейчас в теме
(53) sky.xn, НастройкиДляКомпоновкиМакета.ПараметрыДанных.ДатаНачала = ДатаРучная ?
хотя скорее всего только для чтения. Тогда:
УстановитьЗначениеПараметра(<Параметр>, <Значение>)

НастройкиДляКомпоновкиМакета.ПараметрыДанных.УстановитьЗначениеПараметра("ДатаНачала", ДатаРучная);
55. sky.xn 11.03.15 13:45 Сейчас в теме
(54) spacecraft, Спасибо, сейчас попробую !
49. sky.xn 11.03.15 11:45 Сейчас в теме
А ннннеет, теперь и так и так не формируется ... ппц, дурацкий СКД
50. sky.xn 11.03.15 11:53 Сейчас в теме
Все таки это не СКД дурацкий, а я олень. Камрады, все получилось, спасибо всем огромное !!! Остался только один маленький вопрос, как можно параметры заполнить программно ? Вот текущий код:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	СхемаСКД = РеквизитФормыВЗначение("Объект").ПолучитьСхемуСКД();
	АдресСхемы = ПоместитьВоВременноеХранилище(СхемаСКД,Новый УникальныйИдентификатор);
	КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемы));
	КомпоновщикНастроек.ЗагрузитьНастройки(СхемаСКД.НастройкиПоУмолчанию);	
	
КонецПроцедуры
Показать


&НаСервере
Процедура ЭкспрессПроверкаНаСервере()
	    	
	СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(АдресСхемы);
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    МакетКомпоновки   = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, , ,);
    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , , Истина);
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ТаблицаЗначений =  Новый ТаблицаЗначений;
    ПроцессорВывода.УстановитьДокумент(ТабличныйДокумент);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);	
    //ТЗ.Загрузить(ТаблицаЗначений);
	
КонецПроцедуры
Показать


Помогите, плз !
51. sky.xn 11.03.15 11:53 Сейчас в теме
//Функция в модуле обработки
Функция ПолучитьСхемуСКД () Экспорт
    Схема = ПолучитьМакет("Макет1");
    Возврат Схема;
КонецФункции // ()
56. sky.xn 11.03.15 14:15 Сейчас в теме
Получилось вот так:
КомпоновщикНастроек.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("ДатаНачала", Объект.НачалоПериода);


В итоге, может кто наткнется, понадобится:
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	СхемаСКД = РеквизитФормыВЗначение("Объект").ПолучитьСхемуСКД();
	АдресСхемы = ПоместитьВоВременноеХранилище(СхемаСКД,Новый УникальныйИдентификатор);
	КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемы));
	КомпоновщикНастроек.ЗагрузитьНастройки(СхемаСКД.НастройкиПоУмолчанию);	
	
КонецПроцедуры
Показать


&НаСервере
Процедура ЭкспрессПроверкаНаСервере()
	КомпоновщикНастроек.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("ДатаНачала", Объект.НачалоПериода);
	КомпоновщикНастроек.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("ДатаОкончания", Объект.КонецПериода);  
	СхемаКомпоновкиДанных = ПолучитьИзВременногоХранилища(АдресСхемы);
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    МакетКомпоновки   = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, , ,);
    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(МакетКомпоновки, , , Истина);
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ТаблицаЗначений =  Новый ТаблицаЗначений;
    ПроцессорВывода.УстановитьДокумент(ТабличныйДокумент);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);	
    //ТЗ.Загрузить(ТаблицаЗначений);
	
КонецПроцедуры
Показать


//Функция в модуле обработки
Функция ПолучитьСхемуСКД () Экспорт
    Схема = ПолучитьМакет("Макет1");
    Возврат Схема;
КонецФункции // ()
FilatovRA; Alien_job; avto1c; +3 Ответить
57. sky.xn 11.03.15 14:17 Сейчас в теме
Камрады, всем большое спасибо ! К сожалению, на всех вознаграждение не разделишь, поэтому отдаю его самому активному участнику дискуссии :)
Оставьте свое сообщение
Вакансии
Руководитель направления 1С
Москва
зарплата от 350 000 руб.
Полный день

1С Программист
Москва
зарплата от 180 000 руб.
Полный день

Программист 1С
Москва
зарплата от 180 000 руб. до 220 000 руб.
Полный день

Аналитик 1С / Бизнес-аналитик
Нижний Новгород
зарплата от 100 000 руб. до 250 000 руб.
Временный (на проект)

Программист 1С
Москва
зарплата от 250 000 руб.
Полный день