Методика упрощения поддержки конфигураций. Переопределение и вызов обработчиков событий для УФ 1С 8.2-8.3

25.03.14

Разработка - Универсальные функции

Каждый программист 1С хотя бы раз задумывался над тем, как уменьшить в разы трудозатраты на обновления переписанных конфигураций. Как не забыть добавить некий код, команду, кнопку в форму типовой конфигурации, изменить стандартный обработчик события формы – этот список можно продолжать до бесконечности. В этой статье изложен метод для управляемых форм, который позволяет реализовать эту возможность.

Скачать файлы

Наименование Файл Версия Размер
cf+epf
.7z 36,30Kb
117
.7z 36,30Kb 117 Скачать

Этот метод появился на свет благодаря публикации //infostart.ru/public/16980/ и внедрения конфигурации «Управление торговлей, редакция 11» в не российской торговой компании, из чего следует, что переписано и изменено было очень многое. С выходом каждого нового обновления, для внесения этих изменений, уходило все больше времени и на пике достигало уже до месяца и выливалось в огромные затраты. Так же при выявлении ошибок их нужно было исправлять оперативно и быстро, что со 100-150 одновременно работающими пользователями составляло огромную проблему. 


Предлагаемый метод состоит в том, чтобы в модуле формы в процедуре «ПриСозданииНаСервере» переопределить обработчики событий для этой формы, которые будут вызывать старые обработчики (если это нужно) и выполнить нужный код до и после этого вызова. Так же обеспечить возможность вносить изменения в поведения программы на лету – без отключения от базы пользователей и без использования динамического обновления конфигурации, то есть изменения уже будут готовы к использованию.

Что же для этого нужно? Рассматриваемый пример работает на конфигурации «Управление торговлей, редакция 11», для любой другой конфигурации адаптировать его не составит большого труда.

1. Нужно создать общий модуль МодульПереназначенияОбработчиков, вот такой он у меня: 

// Общая процедура перед переназначения обработчиков
//
// Параметры:
//  УправляемаяФорма – УправляемаяФорма – Управляемая форма.
//

Процедура ПереназначитьОбработчики(УправляемаяФорма) Экспорт
    Если
ТипЗнч(УправляемаяФорма) = Тип("УправляемаяФорма") Тогда
       
ОбщаяВнешняяОбработка = ПолучитьВнешнийОбъект("Библиотека внешних обработок");

       
ВнешняяОбработкаСерийныеНомера = ПолучитьВнешнийОбъект("Серийные номера");
       
ИмяВнешнейОбработкиСерийныеНомера = ПолучитьИмяВнешнегоОбъекта("Серийные номера");
       
ВнешняяОбработкаСерийныеНомера.ПодготовитьСерийныеНомераКРаботе(УправляемаяФорма, ОбщаяВнешняяОбработка, ИмяВнешнейОбработкиСерийныеНомера);

       
ОбщаяВнешняяОбработка.ПодменитьДействиеУправляемоеПриложение(УправляемаяФорма, "ПриЗакрытии", , "ВыполнитьОткатОбработчиков");

       
//Пример как можно изменить свойства управляемой формы
       
УправляемаяФорма.ПоведениеКлавишиEnter = ТипПоведенияКлавишиEnter.ПереходПоЭлементамФормы;
    КонецЕсли;
КонецПроцедуры


// Получаем внешнюю обработку или внешний отчет.
//
// Параметры:
//  ИмяВнешнегоОбъекта – Строка - имя внешнего объекта;
//  ЭтоОтчет – Булево – Ложь (Внешняя обработка), Истина (Внешний отчет).
//
// Возвращаемое значение:
//             – ВнешняяОбработка или ВнешнийОтчет
//

Функция ПолучитьВнешнийОбъект(ИмяВнешнегоОбъекта, ЭтоОтчет = Ложь) Экспорт
   
Ссылка          = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоНаименованию(ИмяВнешнегоОбъекта);
    Если
Ссылка = Неопределено Тогда
        ВызватьИсключение
"Внешний объект с именем не найден: " + ИмяВнешнегоОбъекта;
    КонецЕсли;
   
ДвоичныеДанные  = Ссылка.ХранилищеОбработки.Получить();
   
АдресХранилища  = ПоместитьВоВременноеХранилище(ДвоичныеДанные);
   
ИмяВнОбработки  = ?(ЭтоОтчет, ВнешниеОтчеты, ВнешниеОбработки).Подключить(АдресХранилища, , Ложь);
   
ОбработкаОбъект = ?(ЭтоОтчет, ВнешниеОтчеты, ВнешниеОбработки).Создать(ИмяВнОбработки);
    Возврат
ОбработкаОбъект;
КонецФункции


// Получаем имя внешней обработки или внешнего отчета.
//
// Параметры:
//  ИмяВнешнегоОбъекта – Строка - имя внешнего объекта;
//  ЭтоОтчет – Булево – Ложь (Внешняя обработка), Истина (Внешний отчет).
//
// Возвращаемое значение:
//             – Строка - Имя внешней обработки или отчета.
//

Функция ПолучитьИмяВнешнегоОбъекта(ИмяВнешнегоОбъекта, ЭтоОтчет = Ложь) Экспорт
   
Ссылка = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоНаименованию(ИмяВнешнегоОбъекта);
    Если
Ссылка = Неопределено Тогда
        ВызватьИсключение
"Внешний объект с именем не найден: " + ИмяВнешнегоОбъекта;
    КонецЕсли;
   
ДвоичныеДанные  = Ссылка.ХранилищеОбработки.Получить();
   
АдресХранилища  = ПоместитьВоВременноеХранилище(ДвоичныеДанные);
    Возврат ?(
ЭтоОтчет, ВнешниеОтчеты, ВнешниеОбработки).Подключить(АдресХранилища, , Ложь);
КонецФункции


// Получаем ссылку на элемент справочника ДополнительныеОтчетыИОбработки.
//
// Параметры:
//  ИмяВнешнегоОбъекта – Строка - имя внешнего объекта;
//
//
// Возвращаемое значение:
//             – СправочникСсылка.ДополнительныеОтчетыИОбработки - ссылка на элемент справочника ДополнительныеОтчетыИОбработки.
//

Функция ПолучитьСсылкуНаВнешнийОбъект(ИмяВнешнегоОбъекта) Экспорт
    Возврат
Справочники.ДополнительныеОтчетыИОбработки.НайтиПоНаименованию(ИмяВнешнегоОбъекта);
КонецФункции

 

2. Далее, нужно загрузить общую внешнюю обработку в режиме предприятия. Код обработки:

// Функция добавляет элемент в коллекцию элементов формы и возращает его.
//
// Параметры:
//  ЭлементыФормы – ВсеЭлементыФормы – Содержит коллекцию всех элементов управляемой формы;
//  Параметры – Структура – параметры добавляемого элемента;
//  Родитель – ГруппаФормы, ТаблицаФормы, УправляемаяФорма – родитель добавляемого элемента.
//
// Возвращаемое значение:
//             – ДекорацияФормы, ГруппаФормы, КнопкаФормы, ТаблицаФормы, ПолеФормы – элемент управляемой формы.
//

Функция ДобавитьЭлементВКоллекциюЭлементовФормы(ЭлементыФормы, Параметры, Родитель = Неопределено) Экспорт

    Перем
ИмяЭлемента, ТипЭлемента;

    Если НЕ
ТипЗнч(Параметры) = Тип("Структура") Тогда
        ВызватьИсключение
"Параметры элемента формы не заданы!";
    КонецЕсли;

    Если НЕ
Параметры.Свойство("Имя", ИмяЭлемента) Тогда
        ВызватьИсключение
"Имя элемента формы не задано!";
    КонецЕсли;

    Если НЕ
Параметры.Свойство("ТипЭлемента", ТипЭлемента) Тогда
        ВызватьИсключение
"Тип элемента формы не задан!";
    КонецЕсли;

    Если НЕ
Родитель = Неопределено Тогда
        Если
ТипЗнч(Родитель) <> Тип("ГруппаФормы")
         И  
ТипЗнч(Родитель) <> Тип("ТаблицаФормы")
         И  
ТипЗнч(Родитель) <> Тип("УправляемаяФорма") Тогда
            ВызватьИсключение
"Родитель должен иметь один из перечисленных типов: ГруппаФормы; ТаблицаФормы; УправляемаяФорма.";
        КонецЕсли;
    КонецЕсли;

   
ЭлементФормы = ЭлементыФормы.Добавить(ИмяЭлемента, ТипЭлемента, Родитель);
   
ЗаполнитьЗначенияСвойств(ЭлементФормы, Параметры);
    Возврат
ЭлементФормы;

КонецФункции


// Функция добавляет команду в коллекцию команд формы и возращает его.
//
// Параметры:
//  Команды – КомандыФормы – Содержит коллекцию всех элементов управляемой формы;
//  Параметры – Структура – параметры добавляемой команды.
//
// Возвращаемое значение:
//             – КомандаФормы – команда управляемой формы.
//

Функция ДобавитьКомандуВКоллекциюКомандФормы(Команды, Параметры) Экспорт

    Перем
ИмяЭлемента;

    Если НЕ
ТипЗнч(Параметры) = Тип("Структура") Тогда
        ВызватьИсключение
"Параметры команды не заданы!";
    КонецЕсли;

    Если НЕ
Параметры.Свойство("Имя", ИмяЭлемента) Тогда
        ВызватьИсключение
"Имя команды не задано!";
    КонецЕсли;

   
Команда = Команды.Добавить(ИмяЭлемента);
   
ЗаполнитьЗначенияСвойств(Команда, Параметры);
    Возврат
Команда;

КонецФункции

Процедура
ПереместитьЭлементВКоллекциюЭлементовФормы(ЭлементыФормы, ИмяЭлемента, ИмяРодителя, МестоРасположения) Экспорт
   
ЭлементыФормы.Переместить(ЭлементыФормы.Найти(ИмяЭлемента), ЭлементыФормы.Найти(ИмяРодителя), ЭлементыФормы.Найти(МестоРасположения));
КонецПроцедуры


// Переопределяет обработчик события формы.
// Сохраняет штатный обработчик события внутри формы и устанавливает новый.
//
// Параметры:
//  Форма – УправляемаяФорма – Управляемая форма;
//  ИмяСобытияФормы – Строка – имя события;
//  ПолноеИмяЭлементаФормы – Строка – полное имя элемента формы;
//  НовоеДействие - Строка - имя процедуры обработчика;
//  ОбработкаИсключений – Булево – сообщать о наличии старого обработчика.
//

Процедура ПодменитьДействиеУправляемоеПриложение(Форма, ИмяСобытияФормы = "", ПолноеИмяЭлементаФормы = "", НовоеДействие, ОбработкаИсключений = Ложь) Экспорт

   
Объект = Форма;
   
ИмяЭлементаФормы = "";
    Если НЕ
ПустаяСтрока(ПолноеИмяЭлементаФормы) Тогда

       
МассивФрагментов = РазобратьСтрокуВМассивПоРазделителю(ПолноеИмяЭлементаФормы);
       
ИмяЭлементаФормы = МассивФрагментов[0];
       
Объект = Форма.Элементы.Найти(ИмяЭлементаФормы);
        Если
Объект = Неопределено Тогда
            ВызватьИсключение
"Элемент формы: " + ИмяЭлементаФормы + " не найден!";
        КонецЕсли;

        Если
МассивФрагментов.Количество() > 1 Тогда
           
ИмяЭлементаФормы = ИмяЭлементаФормы + МассивФрагментов[1];
            Если
ТипЗнч(Объект) = Тип("ТаблицаФормы") Тогда
               
Объект = Объект.Колонки[МассивФрагментов[1]].ЭлементУправления;
            ИначеЕсли
ТипЗнч(Объект) = Тип("КоманднаяПанель") Тогда
               
Объект = Объект.Кнопки[МассивФрагментов[1]];
            Иначе
                ВызватьИсключение
"Ошибка на этапе получения элемента формы. Тип значения(" + ТипЗнч(Объект) + ")";
            КонецЕсли;
        КонецЕсли;
    КонецЕсли;

   
СтарыеОбработчики = "OldHandlers";
   
МассивРеквизитов = Форма.ПолучитьРеквизиты();
    Для Каждого
РеквизитФормы Из МассивРеквизитов Цикл
        Если
РеквизитФормы.Имя = СтарыеОбработчики Тогда
           
СтарыеОбработчики = Неопределено;
            Прервать;
        КонецЕсли;
    КонецЦикла;

    Если НЕ
СтарыеОбработчики = Неопределено Тогда
       
МассивНовыхРеквизитов = Новый Массив;
       
МассивНовыхРеквизитов.Добавить(Новый РеквизитФормы(СтарыеОбработчики, Новый ОписаниеТипов("СписокЗначений")));
       
Форма.ИзменитьРеквизиты(МассивНовыхРеквизитов);
    КонецЕсли;

    Если
ТипЗнч(Объект) = Тип("КнопкаФормы") Тогда
       
СтароеДействие = Объект.ИмяКоманды;
    Иначе
       
СтароеДействие = Объект.ПолучитьДействие(ИмяСобытияФормы);
    КонецЕсли;

    Если
ОбработкаИсключений И НЕ СтароеДействие = Неопределено Тогда
        ВызватьИсключение
"Конфликт обработчиков события """ + ИмяСобытияФормы + """ объекта """ + Строка(Объект) + """";
    КонецЕсли;

    Если
ТипЗнч(Объект) = Тип("КнопкаФормы") Тогда
       
Объект.ИмяКоманды = НовоеДействие;
    Иначе
       
Объект.УстановитьДействие(ИмяСобытияФормы, НовоеДействие);
    КонецЕсли;

   
OldHandlers = Форма.OldHandlers;
    Если НЕ
СтароеДействие = Неопределено И НЕ ПустаяСтрока(СтароеДействие) Тогда
       
OldHandlers.Добавить(ИмяЭлементаФормы + "." + ИмяСобытияФормы, СтароеДействие);
    КонецЕсли;
КонецПроцедуры


// Возвращает старый обработчик события формы.
//
// Параметры:
//  Форма – УправляемаяФорма – Управляемая форма;
//  ИмяСобытияФормы – Строка – имя события;
//  ПолноеИмяЭлементаФормы – Строка – полное имя элемента формы;
//  СтароеДействие - Строка - имя процедуры обработчика.
//

Процедура ОткатитьДействиеУправляемоеПриложение(ФормаИмяСобытияФормы = "", ПолноеИмяЭлементаФормы = "", СтароеДействие) Экспорт

   
Объект = Форма;
   
ИмяЭлементаФормы = "";
    Если НЕ
ПустаяСтрока(ПолноеИмяЭлементаФормы) Тогда

       
МассивФрагментов = РазобратьСтрокуВМассивПоРазделителю(ПолноеИмяЭлементаФормы);
       
ИмяЭлементаФормы = МассивФрагментов[0];
       
Объект = Форма.Элементы.Найти(ИмяЭлементаФормы);
        Если
Объект = Неопределено Тогда
            ВызватьИсключение
"Элемент формы: " + ИмяЭлементаФормы + " не найден!";
        КонецЕсли;

        Если
МассивФрагментов.Количество() > 1 Тогда
           
ИмяЭлементаФормы = ИмяЭлементаФормы + МассивФрагментов[1];
            Если
ТипЗнч(Объект) = Тип("ТаблицаФормы") Тогда
               
Объект = Объект.Колонки[МассивФрагментов[1]].ЭлементУправления;
            ИначеЕсли
ТипЗнч(Объект) = Тип("КоманднаяПанель") Тогда
               
Объект = Объект.Кнопки[МассивФрагментов[1]];
            Иначе
                ВызватьИсключение
"Ошибка на этапе получения элемента формы. Тип значения(" + ТипЗнч(Объект) + ")";
            КонецЕсли;
        КонецЕсли;

    КонецЕсли;

    Если
ТипЗнч(Объект) = Тип("КнопкаФормы") Тогда
       
Объект.ИмяКоманды = СтароеДействие;
    Иначе
       
Объект.УстановитьДействие(ИмяСобытияФормы, СтароеДействие);
    КонецЕсли;
КонецПроцедуры


// Возвращает старые обработчики событий формы.
// Сохраняет штатный обработчик события внутри формы и устанавливает новый.
//
// Параметры:
//  Форма – УправляемаяФорма – Управляемая форма.
//

Процедура ВыполнитьОткатОбработчиков(Форма) Экспорт
    Для Каждого
Обработчик Из Форма.OldHandlers Цикл
       
Строка      = Обработчик.Значение;
       
ИндексТочки = Найти(Строка, ".");
       
ОткатитьДействиеУправляемоеПриложение(Форма, Прав(Строка, СтрДлина(Строка)-ИндексТочки), Лев(Строка, ИндексТочки-1), Обработчик.Представление);
    КонецЦикла;
КонецПроцедуры


// Функция разбивает строку разделителем.
//
// Параметры:
//  Строка - Строка - которую разбиваем;
//  Разделитель - Строка - символ-разделитель.
//
// Возвращаемое значение:
//             - Массив - содержащий фрагменты, на которые разбивает строку разделитель.
//

Функция РазобратьСтрокуВМассивПоРазделителю(Строка, Разделитель = ".") Экспорт
   
МассивСтрок = Новый Массив;
   
СтрокаЗамены = СтрЗаменить(Строка, Разделитель, Символы.ПС);
    Для
i=1 По СтрЧислоСтрок(СтрокаЗамены) Цикл МассивСтрок.Добавить(СтрПолучитьСтроку(СтрокаЗамены, i)); КонецЦикла;
    Возврат
МассивСтрок;
КонецФункции

 

На данном этапе, все уже готово для использования. Вот видео-пример использования механизма.

Статья в нашем блоге: www.avtomat.biz


UPDATE (24.03.2014): 
Изменена схема работы метода, проведена оптимизация и исправлены некоторые недочеты. Все это можно посмотреть в новом архиве к статье. Так же сама статья расширена.

 

ОТВЕТЫ НА ВОПРОСЫ:

  1. Для каких конфигураций подходит данный модуль?  механизм предназначен для работы с 1С Предприятие 8.2-8.3, основной режим запуска: "Управляемое приложение", так же конфигурация должна использовать "Библиотеку стандартных подсистем" (БСП), в противном случае нужно будет создать справочник "ДополнительныеОтчетыИОбработки" аналогичный как в БСП;
  2. Какие изменения нужно внести в конфигурацию?  нужно добавить в конфигурацию несколько общих модулей, а так же внести изменения в необходимую управляемую форму (УФ) в конце модуля и для подмены событий этой формы в обработчики ПриСозданииНаСервере() или ПриЧтенииНаСервере(). Реквизиты и табличные части документов можно добавлять, если вам нужно хранить учетные данные;
  3. Как влияет на "быстродействие" использование внешних обработок?  когда используется одна внешняя обработка ничего не заметно для конечного пользователя, когда парк обработок увеличивается скорость запуска формы увеличивается в среднем на ~0.3с с каждой новой обработкой. Не надо паниковать  проблема уже решена;
  4. Как можно вызвать старый обработчик события?  вызвать процедуру ВыполнитьДействиеПоУмолчанию() в которую передать имя события и массив параметров;
  5. Как методика упрощает обновление конфигурации?  после обновления достаточно перенести обработчики переопределения в обновленную конфигурацию и даже если появились новые штатные обработчики событий они будут работать верно в повальном количестве случаев. Управляемые формы не нужно изменять вручную - это все можно сделать с помощью этой методики програмно;
  6. Методика увеличивает время разработки?  да увеличивает время разработки. Если уже несколько форм переделано этим методом – тогда затраты времени ростут незначительно, а затраты на обновление конфигурации уменьшается очень существенно;
  7. Есть критическая ошибка, но пользователей нельзя отключать от базы, что делать? - достаточно внести измения во внешную обработку, изменить ее версию и подключить к базе. После этого, пользователи автоматически уже будут использовать исправленную версию обработки. А ночью обновить общий модуль, который связан с внешней обработкой для более комфортного использования конфигурации.

 

КЛЮЧЕВЫЕ ИЗМЕНЕНИЯ:

  1. У всех общих модулей снято свойство "Вызов сервера", теперь вызов из модуля формы выполняется вот так: &НаКлиенте -> &НаСервере -> ОбщийМодульСервер;
  2. Для сокращения запуска и вызова внешних обработчиков событий, код доработок дублируется в общих модулях. При запуске проверяется версия общего модуля с версией внешней обработки из справочника "ДополнительныеОтчетыИОбработки". Если версии совпадают УФ будет работать с контекстом общего модуля, если версии отличаются вызов процедур и функций будет осуществляется из внешнего объекта;
  3. Переработана работа с контекстом &НаКлиенте  код из форм внешнего объекта дублируется в общем клиентском модуле;
  4. Сам метод переопределения обработчиков событий оформлен так же как внешняя обработка, что добавляет некоторую дополнительную гибкость;
  5. Проверка на дополнительный вызов переназначения обработчиков. 

 

ТАК КАК ЖЕ ЭТО РАБОТАЕТ:

  1. Пользователь открывает документ происходит вызов ПриСозданииНаСервере() или ПриЧтенииНаСервере(). В одну или в обе процедуры мы добавляем наш вызов git_ПереопределениеОбработчиковСервер.ПереопределитьОбработчикиСобытий(ЭтаФорма). Как понять куда добавлять?  нужно посмотреть есть ли переопределение обработчиков в стандартной конфигурации (в УТ 11 оно есть), и добавить перед этим переопределением свой вызов;
  2. Далее идет переход в общий модуль "git_ПереопределениеОбработчиковСервер" в котором определяется первый ли это вызов (на случай, если добавили обработчики в ПриСозданииНаСервере() или ПриЧтенииНаСервере());
  3. Идет проверка версии модуля с версией внешней обработки, если версии одинаковые будет использоваться общий модуль git_ПереопределениеОбработчиковСервер, если версии различные будет использоваться внешняя обработка;
  4. Далее идет такая же проверка для каждой подключаемой внешней обработки (код можно посмотреть в файле .cf) и внутри каждой подключаемой обработки или общего модуля проверяется путь к механизму переопределения для вызова функций и процедур (общий модуль переопределения или модуль внешней обработки, служебные процедуры и функции обозначены комментарием // Только для внутреннего использования); 
  5. Ура! Форма пользовательского документа открылась, теперь так же необходимые функции запускаются из общего модуля (клиент, сервер) или из модуля\формы внешней обработки;
  6. Вызов обработчиков по умолчанию исполняеться с помощь вызова процедуры ВыполнитьДействиеПоУмолчанию();
  7. После закрытия формы все обработчики будут восстанавливаться для избежания проблем с кешированием форм.

Статья в нашем блоге (часть 2): www.avtomat.biz

См. также

Обновление для КА 1.1, ЗУП 2.5, БУХ 2.0: НДС, ЕФС-1, Расчет страховых взносов, Мобилизация, Статистика, Электронные трудовые книжки, 2-НДФЛ, Регламентированная отчетность, Кадровый учет, Прослеживаемость импортных товаров

Зарплата Регламентированный учет и отчетность Кадровый учет Обновление 1С Платформа 1С v8.3 Сложные периодические расчеты 1С:Комплексная автоматизация 1.х 1С:Бухгалтерия 2.0 1С:Зарплата и Управление Персоналом 2.5 Бухгалтерский учет Налоговый учет Управленческий учет Акцизы ЕНВД ЕСН Земельный налог ИП, ПБОЮЛ, КФХ Налог на имущество Налог на прибыль НДС НДФЛ ФОМС, ЕФС Транспортный налог УСН ПСН (патентная система налогообложения) Платные (руб)

Обновления для конфигураций: КА 1.1; ЗУП 2.5; БУХ 2.0; КА 1.1 Комплексная автоматизация торговли алкогольной продукцией; КА 1.1 Комплексный учет сельскохозяйственного предприятия

19900 руб.

01.04.2020    140647    678    352    

231

Автоматическое подтверждение легальности обновления базы или как обновить 100 типовых баз 1С за 5 часов

DevOps и автоматизация разработки Обновление 1С Платформа 1С v8.3 Конфигурации 1cv8 1С:Бухгалтерия 3.0 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Расширение для конфигураций 1С для автоматического подтверждения легальности обновления и выполнения обработчиков обновления при пакетном автоматическом обновлении большого числа баз 1С. А также сам модуль обработки по автоматическому обновлению баз.

2 стартмани

08.05.2019    24220    54    VPanin56    26    

26

Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024    2680    1    John_d    8    

55

Переоткрытие внешних обработок

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    3964    ke.92@mail.ru    16    

61

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8845    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2077    21    progmaster    7    

3

Обновил платформу на 8.3.22 или 8.3.23 = Поломалась почта

Обновление 1С Платформа 1С v8.3 Бесплатно (free)

Проверка настроек почтового ящика выдает ошибки. Официальный баг 1С и как его исправить.

04.07.2023    26550    VPanin56    59    

69
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Поручик 4670 10.02.13 15:43 Сейчас в теме
Пока не пробовал, но работа хорошая. Жалко, что в управляемых формах нет секции инициализации или операторов основной программы. Тогда не пришлось бы вторгаться в штатную процедуру ПриСозданииНаСервере.
RomanRomans; +1 Ответить
2. MarSeN 984 10.02.13 23:42 Сейчас в теме
Доброе время суток.
Спасибо автору за статью - обязательно скачаю и попробую. Интересный подход в котором надо разобраться.
Плюс в копилку.
Как вариант решения описанной задачи 2 статьи:
http://infostart.ru/public/171514/?fruser=yes#users_raters
http://infostart.ru/public/170935/
Судя по описанию Ваш подход к переопределению обработчиков не требует вставки кода в модуль формы, надо посмотреть как реализовано. Я считал что процедура обработки должна находиться в контексте формы.
Буду признателен, если Вы в 2-х словах опишите механизм
3. pbazeliuk 1955 10.02.13 23:51 Сейчас в теме
(2) MarSeN, Добрый вечер, модуль формы требует изменения в процедуре "ПриСозданииНаСервере" и вставки ваших функций в конец модуля формы. Когда появиться возможность подписки на события формы, этих действий уже не потребуется.

Основной упор делается на то, что изменения в свои обработчики можно вносить без обновления конфигурации - просто обновляя внешнюю обработку, а так же сходство с подходом для 8.1, который описал в свое время tormozit. В видео это продемонстрировано.
4. MarSeN 984 10.02.13 23:55 Сейчас в теме
(3) Baza
Спасибо, получается что в принципе подходы у нас одинаковые ). Хранение кода в разных местах. Потребность диктует решения.
6. plevakin 11.02.13 15:01 Сейчас в теме
(3) Когда появиться возможность подписки на события формы

А когда эта возможность появится?
8. pbazeliuk 1955 11.02.13 16:02 Сейчас в теме
5. alekseies 11.02.13 10:06 Сейчас в теме
Также жалко, что в управляемых формах нет секции инициализации или операторов основной программы. Тогда не пришлось бы вторгаться в штатную процедуру ПриСозданииНаСервере. Так же считаю что процедура обработки должна находиться в контексте формы, легче отслеживать изменения конфигурации ......
RomanRomans; +1 Ответить
7. akomar 454 11.02.13 15:06 Сейчас в теме
(5) Зато очень легко вносить изменения в обоработку, на лету, без отключения пользователей от базы, что критично при большом количестве пользователей.
9. tormozit 7138 12.02.13 10:35 Сейчас в теме
Было бы неплохо указать ссылку и на основу, опубликованную на инфостарте http://infostart.ru/public/16980/ .
10. pbazeliuk 1955 12.02.13 22:38 Сейчас в теме
15. TODD22 18 18.02.13 09:17 Сейчас в теме
(9) Не открывается. Пишет что публикация не активна.
11. Азбука Морзе 104 13.02.13 13:22 Сейчас в теме
Отличная работа. Обязательно приму на вооружение.

п.с. В прошлой жизни так припекло с обновлением переделанной УТ11, что пришлось застрелится:)
12. fr.myha 14.02.13 17:16 Сейчас в теме
13. alekseies 15.02.13 10:54 Сейчас в теме
изменения можно вносить и в модуль формы, и также без отключения пользователей от базы, динамическое обновление, только изменения вносить программно .....
14. pbazeliuk 1955 15.02.13 13:12 Сейчас в теме
(13) alekseies, динамическое обновление в высоконагруженной базе в часто приводит к крашу базы, сама 1С не рекомендует его применять и еще что бы пользователь мог использовать обновления ему нужно перезапустить базу (для каждого сеанса конфигурация кешируеться). В данном методе все безопасно и перезагружать пользователю базу не нужно.
16. ivanov660 4332 16.03.13 09:33 Сейчас в теме
Статья заинтересовала. Буду смотреть, надеюсь это поможет в нашей ситуации.
17. ivanov660 4332 07.05.13 15:56 Сейчас в теме
Посмотрел, кое что понравилось и буду использовать что-то.
Вопрос: А как влияет на "быстродействие" использование внешних обработок? Я бы, к примеру, создал "Библиотека внешних обработок" как внутреннюю обработку.
18. pbazeliuk 1955 10.05.13 09:38 Сейчас в теме
(17) ivanov660, на быстродействие никак особо не влияет.
19. pbazeliuk 1955 19.03.14 15:14 Сейчас в теме
(17) ivanov660, с ростом числа подключенных обработок начало влиять. К понедельнику выкачу новую статью с оптимизацией данного метода.
22. pbazeliuk 1955 23.03.14 03:13 Сейчас в теме
(17) ivanov660, (20) zakov, вот часть 2 - avtomat.biz
zakov; teflon; +2 Ответить
20. zakov 20.03.14 13:27 Сейчас в теме
Спасибо за статью, метод классный. Не пойму только как можно вызвать старый обработчик?
21. pbazeliuk 1955 20.03.14 23:04 Сейчас в теме
(20) zakov, к понедельнику в продолжении статьи все опишу.
23. Andry.Boris 59 25.03.14 00:19 Сейчас в теме
Спасибо за статью,
очень интересная реализация...
24. amon_ra 54 25.03.14 14:25 Сейчас в теме
Отлично. Пожалуй возьму себе на заметку. Огромное спасибо!
25. higs 26.03.14 21:28 Сейчас в теме
Присоединяюсь, интересный подход. И достаточно универсален. Спасибо!!
26. Alex_Japanese_Student 454 30.03.14 07:11 Сейчас в теме
Плюсую, сильная разработка, очень поможет
27. 0vrcr 57 03.03.15 14:37 Сейчас в теме
А не появилось варианта назначения нового обработчика на динамически созданный элемент? И чтобы сам обработчик был в глобальном модуле?

Например, создаем РегистрСведенийНаборЗаписей динамически на форме. Подключаем обработчик ПриИзменении. И чтобы этот обработчик хранился в общем модуле?
28. pbazeliuk 1955 03.03.15 17:45 Сейчас в теме
(27) 0vrcr, появилось что-то похожее, но все равно нужно добавить в форму процедуру\функцию перенаправления на общие модуля\внешние модуля
29. 0vrcr 57 05.03.15 17:49 Сейчас в теме
Ясно. Ну этот метод я знаю, сам использую. Жаль, спасибо! :)
30. CheBurator 3119 05.03.15 19:20 Сейчас в теме
Было бы интересно почитать весьма про "внедрения конфигурации «Управление торговлей, редакция 11» в не российской торговой компании, из чего следует, что переписано и изменено было очень многое." - такие проекты не частые гости...
31. pbazeliuk 1955 06.03.15 03:59 Сейчас в теме
(30) CheBurator, возможно, когда-то. На самом деле реализовано много, что-то более 7000 задач только на разработку, 3000 обращений на поддержку каждый месяц. А конца так и не видно...
32. pbazeliuk 1955 06.03.15 04:04 Сейчас в теме
(30) CheBurator, самое, наверное, интересное - партионная себестоимость, которая полностью за месяц пересчитывается за 1-3 минуты, без перепроведения документов и использования последовательностей.
33. mikhailv 19 02.04.15 14:32 Сейчас в теме
Видео из статьи не воспроизводится: ролик не найден. Почините, пожалуйста.
34. pbazeliuk 1955 03.04.15 09:43 Сейчас в теме
(33) mikhailv, добрый день, к сожалению, видео безвозвратно утеряно. Постараюсь на выходных обновить статью и снять новое видео.
35. Cyberhawk 135 30.05.16 18:23 Сейчас в теме
Я правильно понимаю, что нет возможности размещать ЭУ (элементы управления - например, поле формы) в произвольном месте родителя (группы формы)?
Т.е. программно добавляемые ЭУ всегда размещаются в конце (справа или снизу).

//
Отбой, нашел метод Вставить() вместо Добавить()
36. pbazeliuk 1955 31.05.16 09:46 Сейчас в теме
(35) Cyberhawk, используйте процедуру ПереместитьЭлементВКоллекциюЭлементовФорм, если нужно изменить место расположения.
37. UNIT68RUS 08.05.19 09:29 Сейчас в теме
Коллеги не пойму по поводу обработки? Можно скрин обработки?
38. pbazeliuk 1955 08.05.19 11:52 Сейчас в теме
(37) Статья довольно старая, у вас уже есть возможность использовать "Расширения конфигураций". Мы уже понемногу отказываемся от указанного метода и переносим код в расширения, но в 2012 году без него было очень сложно.
39. tormozit 7138 08.05.19 11:57 Сейчас в теме
40. pbazeliuk 1955 08.05.19 12:02 Сейчас в теме
(39) Согласен. Обычные формы еще лет 10 проживут; смотрю на то как мы все переносим в расширения - этот процес займет еще лет 5 (не приоритет, бизнес на этом денег больше не заработает).
Оставьте свое сообщение