Выбор варианта отчета СКД для обычных форм

03.10.12

Разработка - СКД

Выбор варианта отчета СКД для обычных форм

Всем добрый день!

Рассказать я хочу о том как мне пришлось бороться с выбором варианта отчета написанном при помощи СКД в НЕ управляемой форме. С управляемыми проблем нет. Там эта возможность включена по-умолчанию. Что касается обычных форм, то после безуспешного поиска в интернете стандартных решений, реализовал все сам вручную (кодом) через хранилище настроек. Может конечно я не умею искать, но думаю, что решение будет полезно и для других.

Вот ворма отчета:

Нижнее поле - результат, куда печ. форма выводится.

Чуть выше - стандартные настройки СКД Данные: "КомпоновщикНастроек.Настройки.ПараметрыДанных"

И верхнее - поле для выбора варианта, который нас и интересует.

Для выбора варианта отчета создал отдельную форму. На ней просто список вариантов.

Код из основной формы:

//////////////////////////////

Перем ИмяТекВар;

Процедура ЗаполнитьВарианты()
    Для каждого Вар из СхемаКомпоновкиДанных.ВариантыНастроек Цикл
        СЗВариантов.Добавить(Вар,Вар.Представление);
    КонецЦикла;    
КонецПроцедуры    

Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)
    СписокВар = ХранилищеВариантовОтчетов.ПолучитьСписок("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля");    
    Для каждого вар из СписокВар Цикл
        ТекВар = СхемаКомпоновкиДанных.ВариантыНастроек.Найти(вар.Значение);
        Если ТекВар = Неопределено Тогда
            СхемаКомпоновкиДанных.ВариантыНастроек.Добавить();
            ТекВар = СхемаКомпоновкиДанных.ВариантыНастроек[СхемаКомпоновкиДанных.ВариантыНастроек.Количество()-1];
            ТекВар.Имя = вар.Значение;
            ТекВар.Представление = вар.Представление;            
        КонецЕсли;    
    КонецЦикла;    
    
    ЗаполнитьВарианты();
    ИмяТекВар = СокрЛП(СЗВариантов[0].Значение.Имя);
    ВыбВариант = СЗВариантов[0].Значение.Представление;
    ТекН = ХранилищеВариантовОтчетов.Загрузить("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля",СокрЛП(СЗВариантов[0].Значение.Имя));
    Если ТекН = Неопределено Тогда
        КомпоновщикНастроек.ЗагрузитьНастройки(СЗВариантов[0].Значение.Настройки);    
    Иначе
        КомпоновщикНастроек.ЗагрузитьНастройки(ТекН);    
    КонецЕсли;    
КонецПроцедуры

Процедура ВыбВариантНачалоВыбора(Элемент, СтандартнаяОбработка)
    Он = Новый ОписаниеНастроек;
    Он.Представление =  СокрЛП(ВыбВариант);
    ХранилищеВариантовОтчетов.Сохранить("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля", СокрЛП(ИмяТекВар), КомпоновщикНастроек.Настройки, Он);
    Форм = ПолучитьФорму("Форма");
    Форм.Схема = СхемаКомпоновкиДанных;
    Форм.Компановщ = КомпоновщикНастроек;    
    Форм.Варианты =  СЗВариантов;
    ТекВар = Форм.ОткрытьМодально();
    Если НЕ(ТекВар = Неопределено) Тогда
        ВыбВариант = ТекВар.Представление;
        ИмяТекВар = СокрЛП(ТекВар.Имя);
    КонецЕсли;    
КонецПроцедуры

Процедура ПередЗакрытием(Отказ, СтандартнаяОбработка)
    Он = Новый ОписаниеНастроек;
    Он.Представление =  СокрЛП(ВыбВариант);    
    ХранилищеВариантовОтчетов.Сохранить("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля", СокрЛП(ИмяТекВар), КомпоновщикНастроек.Настройки, СокрЛП(ВыбВариант));
КонецПроцедуры
///////////////////////////////////////



Код в форме выбора:

////////////////////////

Перем Схема Экспорт;
Перем Компановщ Экспорт;

Процедура КоманднаяПанель1Добавить(Кнопка)
    имя = "";
    Если ВвестиСтроку(имя) Тогда
        Схема.ВариантыНастроек.Добавить();
        Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1].Представление = имя;
        Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1].Имя = СокрЛП(Схема.ВариантыНастроек.Количество()); 
        Варианты.Добавить(Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1],Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1].Представление);
        
        Он = Новый ОписаниеНастроек;
        Он.Представление =  СокрЛП(имя);
        
        ХранилищеВариантовОтчетов.Сохранить("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля", СокрЛП(Схема.ВариантыНастроек.Количество()), Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1].Настройки, Он);
    КонецЕсли;
КонецПроцедуры

Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)
    
КонецПроцедуры

Процедура ВариантыВыбор(Элемент, ВыбраннаяСтрока, Колонка, СтандартнаяОбработка)
    ТекН = ХранилищеВариантовОтчетов.Загрузить("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля",СокрЛП(Элемент.ТекущиеДанные.Значение.Имя));
    Если ТекН = Неопределено Тогда
        Компановщ.ЗагрузитьНастройки(Элемент.ТекущиеДанные.Значение.Настройки);    
    Иначе
        Компановщ.ЗагрузитьНастройки(ТекН);    
    КонецЕсли;    
    ЭтаФорма.Закрыть(Элемент.ТекущиеДанные.Значение);
КонецПроцедуры

Процедура КоманднаяПанель1Удалить(Кнопка)
    ТекДан = ЭлементыФормы.Варианты.ТекущиеДанные;
    Если НЕ (ТекДан = Неопределено) Тогда
        ХранилищеВариантовОтчетов.Удалить("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля",ТекДан.Значение.Имя,ПользователиИнформационнойБазы.ТекущийПользователь().Имя);
        Варианты.Удалить(Варианты.НайтиПоЗначению(ТекДан.Значение));
    КонецЕсли;    
КонецПроцедуры

Процедура ВариантыПередУдалением(Элемент, Отказ)
    ХранилищеВариантовОтчетов.Удалить("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля",Элемент.ТекущиеДанные.Значение.Имя,ПользователиИнформационнойБазы.ТекущийПользователь().Имя);
КонецПроцедуры

Процедура КоманднаяПанель1Копировать(Кнопка)
    Если НЕ(ЭлементыФормы.Варианты.ТекущиеДанные = Неопределено) Тогда
        имя = "";
        Если ВвестиСтроку(имя) Тогда
            Схема.ВариантыНастроек.Добавить();
            Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1].Представление = имя;
            Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1].Имя = СокрЛП(Схема.ВариантыНастроек.Количество()); 
            Варианты.Добавить(Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1],Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1].Представление);
            
            НастройкиСохранения = Схема.ВариантыНастроек[Схема.ВариантыНастроек.Количество()-1].Настройки;
            
            ТекН = ХранилищеВариантовОтчетов.Загрузить("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля",СокрЛП(ЭлементыФормы.Варианты.ТекущиеДанные.Значение.Имя));        
            Если НЕ(ТекН = Неопределено) Тогда
                НастройкиСохранения = ТекН;    
            КонецЕсли;    
            
            Он = Новый ОписаниеНастроек;
            Он.Представление =  СокрЛП(имя);
            
            ХранилищеВариантовОтчетов.Сохранить("ЭтотОтчетОтчетПоПроизведеннойНекондицииЛяляля", СокрЛП(Схема.ВариантыНастроек.Количество()),НастройкиСохранения , Он);
        КонецЕсли;
    КонецЕсли;
КонецПроцедуры

////////////////////

Вот как-то так.

Конечно, если кто-нибудь покажет, как сохранять и выбирать варианты СКД для обычных форм стандартными средствами, буду рад посмотреть :)

См. также

SALE! 20%

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

13000 10400 руб.

02.09.2020    122164    670    389    

714

Генератор схемы компоновки данных (СКД), написание кода схемы программно

Инструментарий разработчика СКД Платформа 1С v8.3 Конфигурации 1cv8 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

По выбранной схеме компоновки данных генерирует программный код, который генерирует СКД, аналогичную исходной схеме. Есть дополнительные инструменты для просмотра дерева схемы, сравнение исходной схемы и полученной по коду, а также сравнение изменений в сгенерированном коде для исходной схемы и для измененной.

3 стартмани

05.02.2024    4041    25    obmailok    17    

63

Набор-объект для СКД по тексту или запросу

Запросы СКД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    2000    2    Yashazz    0    

29

СКД на JavaScript в 1С

СКД WEB-интеграция Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Долгое время поддерживаю web-портал, в котором появилась необходимость создавать отчеты. Просмотрев различные фреймворки на js, я решил сделать свое решение, которое позволяло бы быстро разрабатывать и добавлять новые отчеты на web-портал.

2 стартмани

11.12.2023    8160    20    John_d    25    

123

Использование менеджера временных таблиц в СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Бесплатно (free)

Рассмотрим еще не получивший широкого распространения способ работы с внешними данным в СКД. В процессе обсуждения работы с СКД выяснилось, что многие не знакомы со способом помещения туда временной таблицы, полученной предварительно. Статья будет полезна разработчикам, знакомым с программным созданием СКД.

05.12.2023    4656    PROSTO-1C    13    

61

Модель СКД

Инструментарий разработчика СКД Платформа 1С v8.3 Система компоновки данных Абонемент ($m)

DSL для работы с СКД.

1 стартмани

15.11.2023    5806    15    kalyaka    5    

86

Пользовательские настройки отчетов 1С. Часть 1. Простые и расширенные настройки

СКД Инструкции пользователю Платформа 1С v8.3 Конфигурации 1cv8 1С:Бухгалтерия 3.0 Россия Бесплатно (free)

Простые приемы работы с отчетами на СКД. Что нужно знать пользователю про настройку отчетов, чтобы использовать их на полную катушку.

18.09.2023    6702    accounting_cons    5    

29

Разрыв страницы в СКД. Легко!

СКД Платформа 1С v8.3 Система компоновки данных Бесплатно (free)

Когда отчет надо разделить по страницам, это всегда проблема для разработчика. Поскольку в СКД нет стандартных вариантов, как это сделать. Нашел (на свой взгляд) самое простое и оптимальное решение.

01.09.2023    4520    KVIKS    15    

80
Вознаграждение за ответ
Показать полностью
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. samamoiloff 861 11.10.12 08:23 Сейчас в теме
В ЗУП интересные шаблоны типового отчета, когда варианты выбираются на спец.панели под верхним обрезом формы, их можно спрятать, а так же набор инструментов по созданию нового и выдаче прав по редактированию вариантов.
adhocprog; romankoav; cleaner_it; RustIG; +4 Ответить
2. Dimasik2007 430 11.10.12 08:25 Сейчас в теме
Когда давно скачал шаблон отчета на СКД с инфорстарта (авторство сейчас не помню), и добавил туда следующий блок

Процедура _СменаВариантаНастройки (Элемент)
Для каждого
Настройка Из СхемаКомпоновкиДанных.ВариантыНастроек Цикл
если
Элемент.Текст = Настройка.Представление тогда
КомпоновщикНастроек.ЗагрузитьНастройки(Настройка.Настройки);
//УстановитьВидимостьОтбора();
//ОбновитьЗаголовок();
//ОбновитьСтрокуПериода();
//ОбновитьКнопкиИстории();
//УстановитьВидимостьЗаголовка();
//УстановитьВидимостьПараметров();
прервать;
конецЕсли;
КонецЦикла;
КонецПроцедуры

Процедура
УстановитьВариантыНастроек()
КП = ЭлементыФормы.ДействияФормы;
НоваяКнопка = КП.Кнопки.Вставить(1,"_ВариантыОтчетов", ТипКнопкиКоманднойПанели.Подменю, "Варианты отчетов", );
НовоеДействие = Новый Действие("_СменаВариантаНастройки");
ч = 1;
Для каждого
Настройка Из СхемаКомпоновкиДанных.ВариантыНастроек Цикл
НоваяКнопка = КП.Кнопки._ВариантыОтчетов.Кнопки.Добавить("Вариант"+Строка(ч), ТипКнопкиКоманднойПанели.Действие,
Настройка.Представление,
НовоеДействие);

ч = ч + 1;
КонецЦикла;
КонецПроцедуры

Процедура
ПриОткрытии()
УстановитьВариантыНастроек();
...


получается вот такое простое меню:

Прикрепленные файлы:
tsatsur; irtk; DimaP; trest30; arisgeser; Alex_Iz; user726666; БоНН; BoBaH; adhocprog; ITMS; VladimirMelnychenko; it-volna.com; IvanPoh; it.k.bondarev; AnnaKalacheva; rava_aal; Cobranet123; elizarovs; Aero; freeek; mp40; VanechkaDiev; toltec; feel_deep; NamelessPony; BorisKoo; Dmitrii D; gemini76; gusda; Pavel_Vladivostok; simich; VovkaPutin; rise; rainspb; teyana; kvk98; 1Снег; Xephone; Yasen; ftm; artichoke; +42 Ответить
3. Just 2 11.10.12 08:29 Сейчас в теме
Не совсем понял, в чем смысл статьи. Ведь есть стандартный шаблон отчета для СКД, как был и есть УниверсальныйОтчет для обычных запросов. На стандартном шаблоне отчетов для СКД построены все отчету по зарплате и проблемм с сохранение/востановлением настроек пользователем нет или я что-то не догнал?
4. Dimasik2007 430 11.10.12 08:32 Сейчас в теме
(3) Не путайте настройки отчета, созданные пользователем, и варианты отчетов, зашитые в макет СКД.
5. Just 2 11.10.12 08:36 Сейчас в теме
(4) Dimasik2007, http://comol.livejournal.com/3867.html
это разве не то? что в этой статье есть такого, чего нет в типовом шаблоне???
6. Dimasik2007 430 11.10.12 08:44 Сейчас в теме
А что накинулись то на ТС, он только учится еще, заодно и выкладывает вещи... Потом будет рефакторинг и левел-ап...
По типовому отчету от 1С, который с вертикальным меню вариантов отчета - вот все! мои пользователи кричат, что это гггг, работать не удобно, не понятно и т.п. Для 99% минималистичного отчета вполне достаточно.
user970589; adhocprog; +2 Ответить
7. Just 2 11.10.12 08:53 Сейчас в теме
так никто и не накидывался, я только спроисл в чём фокус, может я чего на понял в статье, да и человек просил ему типовые решение подсказать.....
8. webester 26 11.10.12 09:09 Сейчас в теме
эммм если, это статья которая должна чему то научить, то почему, тут тупо копипаст кода? Где подробное комментирование и документирование? Где ход мысли? Вы сами не понимаете что тут написано или просто лень нормально оформить? Я уж молчу про раскраску кода.
9. anig99 2843 11.10.12 12:25 Сейчас в теме
Как-то всё запутано...

Процедура ЗаполнитьВариантыОтчетов()
    Для Каждого стрВариант из ОтчетОбъект.СхемаКомпоновкиДанных.ВариантыНастроек Цикл
        ЭтаФорма.ЭлементыФормы.ВариантОтчета.СписокВыбора.Добавить(стрВариант, стрВариант.Представление,, БиблиотекаКартинок.Отчет);
    КонецЦикла;
КонецПроцедуры

Процедура ПриОткрытии()
    СтруктураНастройки = Новый Структура;
    СтруктураНастройки.Вставить("Пользователь", глЗначениеПеременной("глТекущийПользователь"));
    СтруктураНастройки.Вставить("ИмяОбъекта", ЭтотОбъект.Метаданные().ПолноеИмя());
		
    Если УниверсальныеМеханизмы.ПолучитьНастройкуИспользоватьПриОткрытии(СтруктураНастройки) Тогда
        мТекущаяНастройкаИмя = СтруктураНастройки.НаименованиеНастройки;
        КомпоновщикНастроек.ЗагрузитьНастройки(СтруктураНастройки.СохраненнаяНастройка);
        УстановитьЗаголовокФормы();
    Иначе
        ВариантОтчета = ЭлементыФормы.ВариантОтчета.СписокВыбора[0].Значение;
        УстановитьЗаголовокФормы(" [Вариант: " + ВариантОтчета.Представление + "]");
    КонецЕсли;
КонецПроцедуры

Процедура ВариантОтчетаПриИзменении(Элемент)
    //Если НЕ ЗначениеЗаполнено(ЭтаФорма.ВариантОтчета) Тогда Возврат КонецЕсли;
    Если Вопрос("Заменить текущие настройки на стандартные настройки варианта?", РежимДиалогаВопрос.ДаНет,, КодВозвратаДиалога.Нет) = КодВозвратаДиалога.Нет Тогда 
        ЭтаФорма.ВариантОтчета = Неопределено;
        Возврат;
    КонецЕсли;
    ОтчетОбъект.КомпоновщикНастроек.ЗагрузитьНастройки(ЭтаФорма.ВариантОтчета.Настройки);
    мТекущаяНастройкаИмя = "";
    УстановитьЗаголовокФормы(" [Вариант: " + ЭтаФорма.ВариантОтчета.Представление + "]");
КонецПроцедуры
Показать
pashamak; adhocprog; Najly; +3 Ответить
18. Najly 61 03.10.16 09:08 Сейчас в теме
(9) anig99, спасибо, то что надо!
10. y22-k 250 11.10.12 17:15 Сейчас в теме
Я делал немного по другому
При открытии на форме заполнял панель кнопками вариантов
Процедура ПриОткрытии()
    ЭлементыФормы.КоманднаяПанель1.Кнопки.Очистить();
    пВарианты = СхемаКомпоновкиДанных.ВариантыНастроек;
    Для Каждого пЭл ИЗ пВарианты Цикл
        СтруктураВариантов.Вставить(пЭл.Имя,пЭл.Настройки);
        ЭлементыФормы.КоманднаяПанель1.Кнопки.Добавить(пЭл.Имя,ТипКнопкиКоманднойПанели.Действие,пЭл.Представление,Новый Действие("НажатиеНаКнопкуВарианта"));
        ЭлементыФормы.КоманднаяПанель1.Кнопки.Добавить("",ТипКнопкиКоманднойПанели.Разделитель);
    КонецЦикла;
    ЭлементыФормы.КоманднаяПанель1.Кнопки.Добавить("",ТипКнопкиКоманднойПанели.Разделитель);
КонецПроцедуры
Показать

При нажатии на кнопку варианта вызывалось
Процедура Нажатие(Кнопка)
     пНастройки = СтруктураВариантов[Кнопка.Имя];
     Для Каждого Кнопка_ из ЭлементыФормы.КоманднаяПанель1.Кнопки цикл
         Кнопка_.Пометка = Ложь;
     КонецЦикла;
     Кнопка.Пометка = Истина;
	 
     СтарыйОтбор = КомпоновщикНастроек.Настройки.Отбор.Элементы; 
     КомпоновщикНастроек.ЗагрузитьНастройки(пНастройки);
     КомпоновщикНастроек.Настройки.Отбор.Элементы.Очистить();
	 
     НачПериодаПриИзменении(ЭлементыФормы.НачПериода);
     КонПериодаПриИзменении(ЭлементыФормы.КонПериода);
	 
     Для Каждого Строка из СтарыйОтбор Цикл
         СтрокаОтбора = КомпоновщикНастроек.Настройки.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
		 ЗаполнитьЗначенияСвойств(СтрокаОтбора,Строка);
     КонецЦикла;
     ДействияФормыСформировать(Неопределено);
КонецПроцедуры
Показать
Irwin; adhocprog; Chaotic; +3 Ответить
11. klel 11.10.12 20:42 Сейчас в теме
Большой + за старания =)
12. Гость 11.10.12 22:36
Так проще :)
Процедура ПриОткрытии()
	СписокВыбора = Новый СписокЗначений;
	Для Каждого Вариант Из ОтчетОбъект.СхемаКомпоновкиДанных.ВариантыНастроек Цикл
		СписокВыбора.Добавить(Вариант, Вариант.Представление);
	КонецЦикла;
	ЭлементыФормы.Вариант.СписокВыбора = СписокВыбора;
КонецПроцедуры

Процедура ВариантПриИзменении(Элемент)
	ОтчетОбъект.КомпоновщикНастроек.ЗагрузитьНастройки(ЭлементыФормы.Вариант.Значение.Настройки);
КонецПроцедуры
Показать

Только пользовательские настройки сбрасывает.
Irwin; Alex_Iz; abrafaks; Aero; Pavel_Vladivostok; purgin; NittenRenegade; svilsa; ixijixi; Jazz2; cheburashka; +11 Ответить
13. cheburashka 41 12.10.12 14:00 Сейчас в теме
15. Serge_ASB 06.11.14 15:39 Сейчас в теме
(12) Гость,
как сделать тип значения Произвольный?
УТ 10.3 - СКД
14. Pechenuych_ka 19.02.13 16:16 Сейчас в теме
Подскажите, пожалуйста, как в таком отчете сделать так,что выводило параметры?
Делаю в первые отчет при помощи СКД в НЕ управляемой форме и никак не могу настроить что бы выводило параметры отчета
16. vashkostya 36 04.01.16 10:18 Сейчас в теме
Вот проще:

Процедура _СменаВариантаНастройки (Элемент)
    Для Каждого Настройка Из СхемаКомпоновкиДанных.ВариантыНастроек Цикл
        Если Элемент.Текст = Настройка.Представление Тогда
            КомпоновщикНастроек.ЗагрузитьНастройки(Настройка.Настройки);
            Прервать;
        КонецЕсли;
    КонецЦикла;
КонецПроцедуры

Процедура УстановитьВариантыНастроек()
    КП = ЭлементыФормы.ДействияФормы; 
    НоваяКнопка = КП.Кнопки.Вставить(1,"_ВариантыОтчетов", ТипКнопкиКоманднойПанели.Подменю, "Варианты отчетов", );
    НовоеДействие = Новый Действие("_СменаВариантаНастройки");
    ч = 1;
    Для Каждого Настройка Из СхемаКомпоновкиДанных.ВариантыНастроек Цикл
        НоваяКнопка = КП.Кнопки._ВариантыОтчетов.Кнопки.Добавить("Вариант"+Строка(ч), ТипКнопкиКоманднойПанели.Действие, Настройка.Представление, НовоеДействие); 
        ч = ч + 1;
    КонецЦикла;
КонецПроцедуры

Процедура ПриОткрытии()
    УстановитьВариантыНастроек();
    ...
Показать
Прикрепленные файлы:
Maito; user1169791; pashamak; Aero; _p_; SamS; alexhline; +7 Ответить
17. victor_k 95 12.08.16 04:46 Сейчас в теме
Все представленные здесь варианты примеров загружают настройки из "КомпоновщикНастроек", которые создаются в режиме конфигуратора. Эти примеры не позволяют сохранять пользовательские изменения во ВСЕХ вариантов настроек. Что то более подходящее нашёл здесь http://infostart.ru/public/264758/.
19. ivs2000 31.08.18 14:36 Сейчас в теме
с сохранением заполненных настроек пример интересен.
а вот мой краткий без сохранения

ВариантыОтчетаСписок - поле выбора (элемент формы)

Процедура УстановитьНастройки()
	
	ВариантОтчета = ЭлементыФормы.ВариантыОтчетаСписок.Значение;
	КомпоновщикНастроек.ЗагрузитьНастройки(СхемаКомпоновкиДанных.ВариантыНастроек[ВариантОтчета].Настройки);
	
Конецпроцедуры	
//
Процедура ПриОткрытии()
	
	счетчикцикла = 0;
	
	Для каждого Настройка Из СхемаКомпоновкиДанных.ВариантыНастроек Цикл
		
		ЭлементыФормы.ВариантыОтчетаСписок.СписокВыбора.Добавить(счетчикцикла, Настройка.Представление);
		СчетчикЦикла = СчетчикЦикла + 1;
		
	КонецЦикла;
	
	попытка
		ЭлементыФормы.ВариантыОтчетаСписок.Значение = ВосстановитьЗначение("ВариантОтчета12345");
	исключение
	КонецПопытки;
	
	если ЭлементыФормы.ВариантыОтчетаСписок.Значение = Неопределено тогда
		ЭлементыФормы.ВариантыОтчетаСписок.Значение = 0;
	КонецЕсли;
	
	УстановитьНастройки();
	
КонецПроцедуры
//
Процедура ВариантОтчетаПриИзменении(Элемент)
	
	ВариантОтчета = ЭлементыФормы.ВариантыОтчетаСписок.Значение;
	КомпоновщикНастроек.ЗагрузитьНастройки(СхемаКомпоновкиДанных.ВариантыНастроек[ВариантОтчета].Настройки);
	
КонецПроцедуры
//
Процедура ПриЗакрытии()
	
	СохранитьЗначение("ВариантОтчета12345", ЭлементыФормы.ВариантыОтчетаСписок.Значение);
	
КонецПроцедуры
Показать
Оставьте свое сообщение