Быстрый ввод строковых значений в поля составного типа

09.10.15

Разработка - Работа с интерфейсом

Когда нужно дать пользователю возможность вводить с клавиатуры строковые значения в поле ввода составного типа

Пример: в документе "Встреча" нужно вводить как заведенные в справочнике "Площадки" значения, так и произвольные строки. Такая необходимость может возникнуть в том случае, когда замусоривание справочника случайными значениями нежелательно.

Типовое поведение полей ввода значений составного типа не позволяет простым набором текста и нажатием Enter ввести строковое значение:

- при позиционировании в таком поле нельзя сразу начать набор текста: сначала нужно нажать на "педальку" (или F4) и выбрать тип:

2) при ненайденном элементе справочника платформа показывает всплывающее окно с кнопкой создания элемента и гиперссылкой "Показать все", от которого (без применения мышки) можно "избавиться"* только через Esc, либо стерев введенный текст:

* под "избавиться" подразумевается ввод желаемого строкового значения с клавиатуры, а не выбор из предлагаемых элементов справочника или создание нового

Далее предлагается метод, который позволяет пользователю после набора текста сразу вводить значение в поле ввода по нажатию Enter (без показа диалогов и всплывающих окон). При этом:

- можно как выбирать любое значение из справочника:

- так и вводить произвольное строковое значение:

Для реализации такого поведения требуется выполнить следующие шаги:

1. В модуле формы в ПриСозданииНаСервере() выставить для поля ввода ограничение типа:

 

МассивТипов = Новый Массив;
МассивТипов.Добавить(Тип("Строка"));
Элементы.МестоПроведенияВстречи.ОграничениеТипа = Новый ОписаниеТипов(МассивТипов, Новый КвалификаторыСтроки(200));

2. В событии НачалоВыбора() поля ввода реализовать возможность выбора элементов справочника:

&НаКлиенте
Процедура МестоПроведенияВстречиНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;

	ПараметрыФормы = Новый Структура;
	Если ТипЗнч(Объект.МестоПроведенияВстречи) = Тип("СправочникСсылка.Площадки") И ЗначениеЗаполнено(Объект.МестоПроведенияВстречи) Тогда
		ПараметрыФормы.Вставить("ТекущаяСтрока", Объект.МестоПроведенияВстречи);
	КонецЕсли;

	ОткрытьФорму("Справочник.Площадки.ФормаВыбора", ПараметрыФормы, Элемент);
	
КонецПроцедуры

3. Наконец, реализовать возможность подбирать в поле ввода элементы из справочника простым набором текста, добавив обработчик события АвтоПодбор():

&НаКлиенте
Процедура МестоПроведенияВстречиАвтоПодбор(Элемент, Текст, ДанныеВыбора, Параметры, Ожидание, СтандартнаяОбработка)
	Если Ожидание <> 0 И НЕ ПустаяСтрока(Текст) Тогда
		
		СтандартнаяОбработка = Ложь;
		ДанныеВыбора = ПолучитьСписокВыбораПлощадок(Текст);
		
	КонецЕсли;
	
КонецПроцедуры

// Процедура заполняет данные выбора площадки.
//
// Параметры:
//  СтрокаПоиска - Строка	 - Набираемый текст
&НаСервереБезКонтекста
Функция ПолучитьСписокВыбораПлощадок(знач СтрокаПоиска)
	
	СписокВыбораПлощадки = Новый СписокЗначений;
	
	ПараметрыВыбора = Новый Структура;
	ПараметрыВыбора.Вставить("Отбор", Новый Структура("ПометкаУдаления", Ложь));
	ПараметрыВыбора.Вставить("СтрокаПоиска", СтрокаПоиска);
	ПараметрыВыбора.Вставить("ВыборГруппИЭлементов", ИспользованиеГруппИЭлементов.Элементы);
	
	ДанныеВыбораПлощадки = Справочники.Площадки.ПолучитьДанныеВыбора(ПараметрыВыбора);
	
	Для Каждого ЭлементСписка Из ДанныеВыбораПлощадки Цикл
		СписокВыбораПлощадки.Добавить(ЭлементСписка.Значение, Новый ФорматированнаяСтрока(ЭлементСписка.Представление, " (площадка)"));
	КонецЦикла;
	
	Возврат СписокВыбораПлощадки;
	
КонецФункции

После выполнения перечисленных шагов ваши пользователи смогут вводить в поле произвольные строковые значения, а при наличии подходящих элементов в справочнике - быстро (удобно) выбирать их.

поле ввода составной тип строка ввод с клавиатуры

См. также

Богатый редактор картинок, хранимых в базе, с возможностью РИСОВАНИЯ. Редактор внешних файлов картинок. Объект, расширяющий возможности работы с картинками из встроенного языка (Три в одном) + Обработка «Стандартизация картинок»

Работа с интерфейсом Рабочее место Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Платные (руб)

Обработка предназначена для редактирования картинок в режиме «Предприятие», с возможностью РИСОВАТЬ на них. Поддерживается работа как в обычных формах (толстый клиент) так и на управляемых формах (тонкий клиент). Обработка позволяет редактировать как картинки, хранимые в базе, так и графические файлы с диска на файловой системе. Помимо базовых функций (изменение размеров, преобразование формата, обрезание картинки, повороты и т.п.) – редактор имеет богатый набор инструментов для рисования. Доступна функция вставки изображения из буфера обмена. Также обработка может быть использована из встроенного языка как объект для редактирования картинок. Объект может быть использован: на стороне клиента, на стороне сервера, из внешнего соединения. Данная обработка будет особенно полезна тем, кто вносит картинки в базу (изображения номенклатуры, фотографии физических лиц и т.п.). Функционал реализуется с использованием JavaScript и бесплатного ПО ImageMagick (без использования внешних компонент).

6000 руб.

16.01.2015    61797    43    59    

80

[Расширения] Динамическое управление видимостью и доступностью элементов форм (УФ) (8.3.6+)

Работа с интерфейсом Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Платные (руб)

Механизм «Динамическое управление доступом к элементам форм объектов 1С8» предназначен для обеспечения возможности оперативного управления видимостью и доступностью элементов форм документов и справочников продуктов фирмы «1С» «1С:Предприятие 8». Решение универсальное, встраивается в любую конфигурацию с минимальными доработками, что позволяет без проблем обновлять типовые решения.

5000 руб.

14.01.2016    54403    16    21    

42

Управление дашбордами

Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Обработка предназначена для создания и управления дашбордами.

2400 руб.

29.06.2020    16698    21    4    

35

Новогоднее оформление для 1С

Работа с интерфейсом Платформа 1С v8.3 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Зарплата и Управление Персоналом 3.x 1С:Управление нашей фирмой 3.0 Бесплатно (free)

Добавьте новогоднего настроения! Расширение создает декорацию в виде гирлянды на некоторых формах объектов.

27.12.2023    10738    750    elcoan    45    

106

Конструктор HTML, CSS и javascript

Инструментарий разработчика Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Подходит для создания web-страниц для замены управляемых форм 1С, красивых отчетов, интерфейса мобильного приложения на платформе 1С и для простых страниц веб-сайтов.

2 стартмани

10.04.2023    9615    151    acces969    31    

118

Модель состояния для MVC

Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

"MVC плохо применима в 1С" - познакомьтесь с моделью состояния и, возможно, ваше мнение поменяется! Представленное решение является эволюционным развитием идеи реализации MVC для 1С. В новой версии добавлены DSL для описания модели состояния, а также параметризация свойств параметров и элементов формы.

1 стартмани

05.07.2022    3665    kalyaka    2    

27

Табло очереди заказов на экран телевизора

WEB-интеграция Работа с интерфейсом Платформа 1С v8.3 1С:Розница 2 Платные (руб)

Связка из веб-приложения и расширения для 1С: Розница 2.3.

3600 руб.

29.04.2022    12080    1    5    

10
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. dj_serega 390 04.06.15 10:34 Сейчас в теме
Интересно. Нужно бы где-то не забыть применить :)
2. jobkostya1c_ERP 100 04.06.15 20:56 Сейчас в теме
Такая потребность для удобства работы операторов по вводу данных нужна (хоть и грузит ПК). Стоит проверить.
3. androgin 05.06.15 02:09 Сейчас в теме
у меня автоподбор без учета языка клавиатуры реализован, и с учетом составного типа )))) (рус и анг)
4. xsazar 5 05.06.15 17:08 Сейчас в теме
После выбора, объект всегда строка
5. Traas 78 05.06.15 23:01 Сейчас в теме
6. RustIG 1351 14.06.15 21:38 Сейчас в теме
(0) у вас какая конфа? нетиповая ? самописная?
в свое время использовал такой способ при разработке на платформе 8.1, 8.2 на обычных формах,
сейчас с непривычки на 8.3 управляемые формы теряюсь, хотя остался тот же метод - а именно переопределение процедур на события формы. в свое время об этом много читал на ИТС, а сейчас даже не уверен, что для управляемых форм статьи переписаны...
теперь по задаче: в чем заключается смысл реквизита, который имеет составной тип "Справочник + Строка"?
если при открытии формы тип переопределяется как "Справочный", нельзя ли этот вопрос решить на уровне конфигурирования формы = задать сразу нужный тип? заранее спасибо за подробности
7. Cyberhawk 135 14.06.15 22:06 Сейчас в теме
(6) Rustig, описанный в статье подход мною использован в самописной конфигурации на базе подсистемы БСП "Взаимодействия" (в документе "Событие").
Смысл составного реквизита в том, чтобы самые "деревянные" (непонятливые) пользователи не заводили лишние элементы справочника (когда не могут найти подходящий существующий), а смысл ограничения типа поля ввода при открытии формы в том, чтобы:
- они могли при вводе в поле несуществующего элемента этим и ограничиться (не создавать новый сылочный объект в базе, т.е. не замусоривать справочник)
- им не требовалось для ввода строкового типа нажимать кнопку выбора (в "Такси" это педалька, а ранее - кнопка выбора типа "Т") и не пользоваться мышкой (для пользователя это может быть слишком сложно и изматывающе)
8. RustIG 1351 14.06.15 23:24 Сейчас в теме
(7) если ограничение на тип задано = Строка, АвтоПодбор позволяет подставлять и сохранять в поле тип Справочник? если да, то это неочевидное поведение платформы.... поэтому интересно узнать об этом...
и еще вопрос: кто же в дальнейшем заводит в справочник места встреч? получается что единого справочника нет, если каждый может прописать место встречи как ему удобно...
чтобы самые "деревянные" (непонятливые) пользователи не заводили лишние элементы справочника (когда не могут найти подходящий существующий)

эта задача все же не решена, кто-то же должен заводить новые элементы (при чем унифицировано), чтобы ими пользоваться.
хотя ваш способ минимизирует дублирующие элементы на начальном этапе заполнения базы, не ясна перспектива использования справочника в дальнейшем - наполняемость, дальнейший поиск и отбор

для какой отрасли конфигурируется база? у меня был опыт знакомства с подобной проблемой у грузоперевозок: были справочники место загрузки и место выгрузки... в итоге все свелось к тому, что менеджеры указывают из справочника только город загрузки и город выгрузки (при этом не пришлось ограничивать тип реквизита строкой - перепутать города сложно), а подробный адрес загрузки и выгрузки указывают в дополнительных строковых полях, используя или нет КЛАДР (кому как удобно).
9. Cyberhawk 135 15.06.15 12:33 Сейчас в теме
(8) Rustig,
если ограничение на тип задано = Строка, АвтоПодбор позволяет подставлять и сохранять в поле тип Справочник? если да, то это неочевидное поведение платформы.... поэтому интересно узнать об этом...
Ограничение задается на тип значения, отображаемого в поле ввода, а не на хранимый в базе реквизит, поэтому "сохранять в поле" кажется не очень подходящим описанием происходящего. "Подставлять в поле" - это делает платформа, когда в обработчике ОбработкаВыбора() выполняется примерно такой код (он в статье не приведен):
&НаКлиенте
Процедура МестоПроведенияВстречиОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	Модифицированность = Истина;
	
	Если ЗначениеЗаполнено(ВыбранноеЗначение) Тогда
		Объект.МестоПроведенияВстречи = ВыбранноеЗначение;
	КонецЕсли;
	
КонецПроцедуры
Показать
Как видно, после присвоения значения реквизиту объекта поле ввода будет отображать значение в соответствии с наложенным на него ограничением типа, т.е. простую строку - представление объекта (о чем пишут (4) и (5)). Для меня такое поведение платформы кажется очевидным.
и еще вопрос: кто же в дальнейшем заводит в справочник места встреч? получается что единого справочника нет, если каждый может прописать место встречи как ему удобно...
Я просто не описал это в статье: данный справочник заполняется пользователями "более высокого" уровня (более продвинутыми) и содержит ограниченный перечень площадок, принадлежащих фирме заказчика. Обычно на начало работы всех пользователей в базе этот справочник уже заполнен. Когда же рядовые пользователи создают в базе встречу, они могут как выбрать уже заведенную там площадку, так и указать произвольное место встречи (если, например, встреча происходит не на территории заказчика). Думаю, значительная часть вопросов отпала после прояснения этого момента.
не ясна перспектива использования справочника в дальнейшем - наполняемость, дальнейший поиск и отбор
Полный перечень мест назначения встреч никому не интересен, поэтому справочник и не наполяется в этом сценарии. Скорее справочник призван помочь пользователям быстро находить и вводить площадку (не особо важно, строкой или ссылкой на уже заведенную площадку).
для какой отрасли конфигурируется база?
Для любой, т.к. это часть CRM для "обзванивальщиков".
10. RustIG 1351 17.06.15 00:09 Сейчас в теме
(9) на мой взгляд, проблема шире, чем вы описали, а значит и решение должно быть шире: то, что "обзванивальщик" заполнит в документе реквизит "Место встречи" = "16 км от МКАД" - должно быть понятно не только данному "обзванивальщику", но и другим коллегам по цеху, агентам, менеджерам, руководителям... придется писать или подробно, или все-таки вытаскивать из унифицированного справочника (хоть бы даже из того же КЛАДРа). И тогда задача формулируется иначе: как разработать удобный и понятный интерфейс, чтобы "обзванивальщики" понятно, быстро и подробно фиксировали место встречи. Если так, то решение я вижу таким, при нажатии на "три точки" должно выходить окно типа "КЛАДР" или подобное, в котором есть поля, с помощью которых можно сузить поиск уже введеного элемента справочника или задать унифицированный элемент, например такие поля как если речь идет о Москве: поле1 = Москва/Подмосковье, поле2=шоссе для Подмосковья, поле3=округ для Москвы, поле4 = станция метро (и сразу название ветки), поле5 = улица, поле6 = дом, поле7= комментарий для нюансов вроде = "рядом с памятником"
11. Cyberhawk 135 17.06.15 10:18 Сейчас в теме
(10) Там, где это было применено, место встречи нужно было исключительно для того, кто на нее поедет. И, повторюсь, хранить всю эту несистематизированную информацию или тем более систематизировать ее никому там было не надо.
А ваш вариант, скорее всего, потребует от пользователя делать движения мышкой, либо, по крайней мере, потребует знание того, что "педалька" / "три точки" - это F4. А это отвлекает при частом вводе документов, где работают только клавиша Enter и непосредственный набор текста.
P.S. Я не спорю - там, где адреса должны храниться систематизированно и нужны удобства по их заполнению, нужно продумывать интерфейс или повышать требования к грамотности пользователя (чтобы пользоваться типовой формой ввода адреса). Только статья совсем не об этом.
12. RustIG 1351 18.06.15 10:04 Сейчас в теме
(11)
Там, где это было применено, место встречи нужно было исключительно для того, кто на нее поедет.

для таких целей есть дополнительные поля "Комментарий", "Дополнительное описание" и подобное...
Только статья совсем не об этом.

многие прочитают статью, и возьмут за правило ваш подход к решению проблемы,
а если смотреть в корень, то так сложно решать задачу и не надо...
13. nl8 182 30.06.15 06:38 Сейчас в теме
Решение понравилось. Для несложных мест встречи самое то. Поле выступает и расширенным элементом (справочником) для сложного, частоповторяющегося места встречи с доп. реквизитами и простым комментарием когда место понятно обоим.
14. пользователь 30.06.15 06:39
Сообщение было скрыто модератором.
...
15. Chancellor 13.02.17 17:08 Сейчас в теме
Спасибо! Отличное решение, но немного не доработанное. Как писали выше после проведения подобных манипуляций возвращается только значение "Строка", что не очень удобно. НО это можно исправить, если в обработке выбора написать этот код:
&НаКлиенте
Процедура МестоПроведенияВстречиОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
	Если ТипЗнч(ВыбранноеЗначение) = Тип("СправочникСсылка.Площадки") Тогда 
		МассивТипов = Новый Массив;
		МассивТипов.Добавить(Тип("СправочникСписок.Площадки"));
		Элементы.МестоПроведенияВстречи.ОграничениеТипа = Новый ОписаниеТипов(МассивТипов, Новый КвалификаторыСтроки(200));		
	КонецЕсли;	           
КонецПроцедуры
Cyberhawk; +1 Ответить
18. Merkalov 8 23.12.21 07:35 Сейчас в теме
(15)
Вы...1 раз присваиваете колонке ограничение типа при создании на сервере, тем самым отключая срабатывание "НачалоВыбора" при входе в редактирование пустой ячейки, но в обработке выбора вы каждый раз для одной и тоже колонки изменяете ограничение типа, добавляя туда ссылочный тип, это же просто бессмысленно...после такой манипуляции снова начнет срабатывать "НачалоВыбора" в любой пустой ячейки данной колонки.
16. Puhov2112 13.11.19 10:00 Сейчас в теме
Идея хороша.
Но так как написано не получилось. Может что-то не так сделал.
Не завершался ввод в поле когда вводишь строкой (обработка выбора тоже не срабатывала).

В моем случае решил так. В функции "ПолучитьСписокВыбораПлощадок" перед возвратом списка значений дописал следующий текст:
...
Если Не СписокВыбораПлощадки.Количество() Тогда
	СписокВыбораПлощадки.Добавить(СтрокаПоиска, Новый ФорматированнаяСтрока(СтрокаПоиска, " (не найдена)"));
КонецЕсли; 

Возврат СписокВыбораПлощадки;
17. jaroslav.h 180 15.07.20 18:58 Сейчас в теме
Спасибо за идею, работает. Как раз такой случай, что пользователь при вводе первых символов должен получать выпадающий список из совпадающих результатов, для реквизита формы составного типа.
Оставьте свое сообщение