Мелкие полезные функции

19.11.14

Разработка - Универсальные функции

На Инфостарте некоторое время назад существовали блоги. Я записывал заметки туда. Сейчас обнаружил, что блоги кончились. Решил перенести некоторые заметки из бога в отдельную публикацию.
Вот заметки:
1. Поиск объекта по идентификатору.
2. Разрешение пользолваателям редактировать отдельные реквизиты документа без перепроведения.

1. Получение объекта по идентификатору.

Синхронизация справочников и документов с сайтом я предпочитаю выполнять по уникальным идентификаторам. Поэтому часто необходимо получать ссылку по идентификатору. Написал для этого универсальную функцию.

// Возвращает ссылку на найденный справочник или документ или Неопределено, если объекта нет.
// Параметры
// ИД - строковое представления уникального идентификатора
// Тип - наименование вида справочника или документа. Благо их наименования не пересекаются.
Функция ПолучитьСсылкуПоИД(ИД, Тип = Неопределено)
	Если ИД = "" и Тип <> Неопределено Тогда
		// Тип известен, элемент явно пустой, значит нужно вернуть пустую ссылку
		спр = Метаданные.Справочники.Найти(Тип);
		Если спр <> Неопределено Тогда
			Возврат Справочники[Тип].ПустаяСсылка();
		КонецЕсли;
		
		док = Метаданные.Документы.Найти(Тип);
		Если док <> Неопределено Тогда
			Возврат Документы[Тип].ПустаяСсылка();
		КонецЕсли;
		Возврат Неопределено
	КонецЕсли;
	
	Попытка
		УИД = Новый УникальныйИдентификатор(ИД);
	Исключение
		Возврат Неопределено
	КонецПопытки;
	
	// Если тип известен, то ищем только в одной таблице
	Если Тип <> Неопределено Тогда
		спр = Метаданные.Справочники.Найти(Тип);
		Если спр <> Неопределено Тогда
			Ссылка = Справочники[Тип].ПолучитьСсылку(УИД);
			Если Не Ссылка.Пустая() и Ссылка.ПолучитьОбъект() <> Неопределено Тогда
				Возврат Ссылка
			КонецЕсли;
			Возврат Неопределено
		КонецЕсли;
		
		док = Метаданные.Документы.Найти(Тип);
		Если док <> Неопределено Тогда
			Ссылка = Документы[Тип].ПолучитьСсылку(УИД);
			Если Не Ссылка.Пустая() и Ссылка.ПолучитьОбъект() <> Неопределено Тогда
				Возврат Ссылка
			КонецЕсли;
		КонецЕсли;
		Возврат Неопределено
	КонецЕсли;
	
	// Если тип неизвестен, то перебираем все справочники и документы.
	// Это долго. Поэтому тип очень хочется получить.
	Для Каждого спр из Метаданные.Справочники Цикл
		Ссылка = Справочники[спр.Имя].ПолучитьСсылку(УИД);
		Если Ссылка.ПолучитьОбъект() <> Неопределено Тогда
			Возврат Ссылка
		КонецЕсли;
	КонецЦикла;
	
	Для Каждого док из Метаданные.Документы Цикл
		Ссылка = Документы[док.Имя].ПолучитьСсылку(УИД);
		Если Ссылка.ПолучитьОбъект() <> Неопределено Тогда
			Возврат Ссылка
		КонецЕсли;
	КонецЦикла;
	
	Возврат Неопределено
КонецФункции

 

2. Разрешение пользователям редактировать отдельные реквизиты документа без перепроведения или просто одни реквизиты разрешать, а другие запрещать.

Иногда необходимо разрешить редактирование некоторых реквизитов документа без перепроведения. Например: Комментарий, АдресКонтрагента, КонтактноеЛицо. Ещё бывает необходимым разрешить изменение отдельных реквизитов в закрытых документах. Например, поставить отметку о состоянии доставки и написать комментарий.

В модуле менеджера документа пишем функцию, которая определяет массив допустимых к редактированию реквизитов

// Возвращает массив имён реквизитов, разрешённых для изменнения без перепроведения.
// Если получен параметр типа Массив, то имена реквизитов добавляются в него
Функция ПолучитьМассивРеквизитовИзменяемыхБезПерепроведения(МассивРеквизитовДопустимыхКИзменению =  Неопределено) Экспорт
	Если Не ТипЗнч(МассивРеквизитовДопустимыхКИзменению) = Тип("Массив") Тогда
		МассивРеквизитовДопустимыхКИзменению = Новый Массив;
	КонецЕсли;
	//Типовые реквизиты
	МассивРеквизитовДопустимыхКИзменению.Добавить("Грузополучатель");
	МассивРеквизитовДопустимыхКИзменению.Добавить("ДоверенностьНомер");
	МассивРеквизитовДопустимыхКИзменению.Добавить("ДоверенностьДата");
	МассивРеквизитовДопустимыхКИзменению.Добавить("ДоверенностьНомер");
	МассивРеквизитовДопустимыхКИзменению.Добавить("ДоверенностьВыдана");
	МассивРеквизитовДопустимыхКИзменению.Добавить("ДоверенностьЧерезКого");
	МассивРеквизитовДопустимыхКИзменению.Добавить("Комментарий");
	МассивРеквизитовДопустимыхКИзменению.Добавить("АдресДоставки");
	//Добавленные реквизиты
	
	Возврат МассивРеквизитовДопустимыхКИзменению;
КонецФункции

В модуле ОбщегоНазначения пишем функции общие для всех документов.

// сравниваем реквизиты документа из базы данных с записываемым объектом
// имена изменённых реквизитов запихываем в массив
Функция ПолучитьСписокИзменённыхРеквизитов(ДокОбъект) Экспорт
	СписокИзменённыхРеквизитов = Новый Массив;
	
	Ссылка = ДокОбъект.Ссылка;
	мдОбъекта = ДокОбъект.Метаданные();
	// сравниваем стандартные реквизиты
	Для Каждого Реквизит из мдОбъекта.СтандартныеРеквизиты Цикл
		Если ДокОбъект[Реквизит.Имя] <> Ссылка[Реквизит.Имя] Тогда
			СписокИзменённыхРеквизитов.Добавить(Реквизит.Имя);
		КонецЕсли;
	КонецЦикла;
	
	// сравниваем реквизиты шапки
	Для Каждого Реквизит из мдОбъекта.Реквизиты Цикл
		Если ДокОбъект[Реквизит.Имя] <> Ссылка[Реквизит.Имя] Тогда
			СписокИзменённыхРеквизитов.Добавить(Реквизит.Имя);
		КонецЕсли;
	КонецЦикла;
	
	// сравниваем табличные части
	Для Каждого тч из мдОбъекта.ТабличныеЧасти Цикл
		Если ДокОбъект[тч.Имя].Количество() = Ссылка[тч.Имя].Количество() Тогда // Не добавляли и не убирали строки в тч
			Для Каждого строкаОбъекта Из ДокОбъект[тч.Имя] Цикл
				СтрокаСсылки = Ссылка[тч.Имя].Получить(строкаОбъекта.НомерСтроки - 1);
				Для Каждого Реквизит из тч.Реквизиты Цикл
					Если СтрокаСсылки[Реквизит.Имя] <> строкаОбъекта[Реквизит.Имя] Тогда
						СписокИзменённыхРеквизитов.Добавить(тч.Имя + "." + Реквизит.Имя);
					КонецЕсли;
				КонецЦикла;
			КонецЦикла;
		Иначе
			СписокИзменённыхРеквизитов.Добавить(тч.Имя);
		КонецЕсли;
	КонецЦикла;
	
	Возврат СписокИзменённыхРеквизитов;
КонецФункции

// Сравниваем массив изменённых реквизитов с массивом реквизитов, разрешённых к изменению
// возвращает пустую строку, если документ можно записывать или список изменённых реквизитов из-за которых документ нельзя записать
Функция МожноЗаписыватьБезПерепроведения(ДокОбъект, МассивРеквизитовДопустимыхКИзменению, СписокИзменённыхРеквизитов = Неопределено) Экспорт
	стр = "";
	Если СписокИзменённыхРеквизитов = Неопределено Тогда
		СписокИзменённыхРеквизитов = ПолучитьСписокИзменённыхРеквизитов(ДокОбъект);
	КонецЕсли;
	Для Каждого зн из СписокИзменённыхРеквизитов Цикл
		Если МассивРеквизитовДопустимыхКИзменению.Найти(зн) = Неопределено Тогда
			стр = стр + "
			|" + зн;
		КонецЕсли;
	КонецЦикла;
	Возврат стр;
КонецФункции

В модуле документа ПредЗаписью разрешаем запись без пререпроведения в случае, если были изменены только реквизиты, не вызывающие перепроведение.

РедактированиеЗаднимЧислом = Ложь;
МассивРеквизитовДопустимыхКИзменению = Документы.РеализацияТоваровУслуг.ПолучитьМассивРеквизитовИзменяемыхБезПерепроведения();
СписокИзменённыхРеквизитов = ОбщегоНазначения.ПолучитьСписокИзменённыхРеквизитов(ЭтотОбъект);
СписокИзменённыхРеквизитовВызывающихПерепроведение = ОбщегоНазначения.МожноЗаписыватьБезПерепроведения(ЭтотОбъект, МассивРеквизитовДопустимыхКИзменению, СписокИзменённыхРеквизитов);
Если СписокИзменённыхРеквизитовВызывающихПерепроведение = "" И Проведен И СписокИзменённыхРеквизитов.Количество() > 0 Тогда
	РежимЗаписи = РежимЗаписиДокумента.Запись;
ИначеЕсли НЕ РедактированиеЗаднимЧислом и Дата < НачалоДня(ТекущаяДата()) И Не РольДоступна("ПравоАдминистрирования") Тогда
	Сообщить("Недостаточно прав для проведения реализации " + Номер + " " + Строка(Дата) +
			" задним числом. Изменены реквизиты: " + СписокИзменённыхРеквизитовВызывающихПерепроведение);
	Отказ = Истина;
КонецЕсли;

В этой заметке не рассмотрена установка флага ТолькоПросмотр для реквизитов формы, которые нельзя редактить. Это делается сосем несложно.

Не знаю, может быть подобное решение уже есть в БСП. Не смотрел.

газета Суть Времени

полезняшки

См. также

Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024    2655    0    John_d    8    

53

GUID в 1С 8.3 - как с ними быть

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.

12.02.2024    4590    atdonya    22    

45

Переоткрытие внешних обработок

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    3950    ke.92@mail.ru    16    

61

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8799    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2069    21    progmaster    7    

3

Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    16139    133    sapervodichka    112    

129

Система контроля ведения учета [БСП]

Универсальные функции Механизмы типовых конфигураций БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данном материале рассмотрим типовой алгоритм подсистемы контроля учета БСП в конфигурациях на примерах.

18.07.2022    7241    quazare    8    

109
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Князь 77 19.11.14 13:45 Сейчас в теме
С выбором режима проведения в зависимости от того, какие реквизиты были изменены, получилось очень необычно. Возьму на карандаш/клавиатуру. Ещё можно додумать идею и в несколько строк дополнить сию процедуру регистрацией события изменения реквизита, для детального журнала, кто когда и что именно изменил в документе.
2. Трактор 1246 19.11.14 13:49 Сейчас в теме
(1) Обрати внимание, что режим записи не меняется, если нет изменений. Это надо на случай перепроведения. А то как-то раз стукнулся, об то, что перепроведение не выполняется.
Риник; +1 Ответить
3. xzorkiix 34 19.11.14 16:57 Сейчас в теме
Из статьи узнал, что блогов нет. Зря они это. не пользовался, но в целом ветка была уместной (статьи и публикации для основательного труда, блог для мелких пометок на полях для себя и заинтересованных)
4. xzorkiix 34 19.11.14 17:04 Сейчас в теме
Функция А()
Возврат Неопределено;
КонецФункции

Эффект этого равносилен

Функция А()
КонецФункции
5. Трактор 1246 19.11.14 17:06 Сейчас в теме
(4) Читаемость кода тоже важна.
6. Armando 1399 19.11.14 21:58 Сейчас в теме
Буква ё не раскрашивается))
Ее кстати нельзя использовать в модулях.
7. Трактор 1246 19.11.14 23:32 Сейчас в теме
Ее кстати нельзя использовать в модулях.

(6) Armando, не знал. Использую. Работпет.
8. Armando 1399 20.11.14 00:00 Сейчас в теме
(7) нашел:

"4. В именах, синонимах и комментариях не допускается использовать букву "ё"."
http://its.1c.ru/db/v8std#content:2149184123:hdoc

"В текстах модулях не допускается использовать букву "ё"."
http://its.1c.ru/db/v8std#content:2149184105:hdoc
Трактор; +1 Ответить
10. Трактор 1246 20.11.14 10:39 Сейчас в теме
(8) Armando, проверил на типовой БП3. В ней есть функции ЗаменитьБуквуЁ ПодготовитьКПоискуПоФИОСБуквамиЕЁ, СтруктураПараметровДляРасчётаАпдекса. Так и называются. А в комментариях Ё встречается в полный рост. И это правильно. Незаслуженно букву обидели. 1С сама не придерживается своих рекомендаций. Но мы учтём.

(9) mtv:), хорошее решение. Замечание только одно. Объект.ОбменДанными.Загрузка = Истина возможно использовать не всегда. Если его не использовать то количество строк кода растёт.

Посмотрел на твою обработку. Редактирование с помощью функций ВвестиЧисло, ВвестиСтроку, ВвестиЗначение удобным никак никак не назовёшь. Это решение для очень редкого редактирования. Моё решение для случаев, когда вчерашние документы перепроводить нельзя, но вспомогательные данные вносить требуется.
11. ildarovich 7850 20.11.14 11:07 Сейчас в теме
(6)(10) А я вот как использовал букву ё, так и буду дальше использовать. Мне она нравится своей "нарядностью". Думаю, это ошибочная рекомендация.
dvsidelnikov; SeiOkami; chernyakai; FrLenok; wolfsoft; Puk2; Светлый ум; Патриот; shootnik; Трактор; +10 Ответить
15. Князь 77 24.11.14 05:10 Сейчас в теме
(11) ildarovich, поддерживаю. С детства всем прививали, что в русском языке 33 (тридцать три) буквы. А сейчас принуждают самих себя ограничивать и незаслуженно дискредитиировать бедную букву.
И вообще, мало кто значет, что бёквё ё с лёгкёстьё мёжёт зёмёнёть всё ёстёльнёё бёквё.
dvsidelnikov; albert.goncharov; BorisBelov; Светлый ум; Allexe8.1; Трактор; +6 Ответить
9. mtv:) 1027 20.11.14 08:44 Сейчас в теме
Хочу обратить Ваше внимание, что на Инфостарте есть еще одна публикация о редактировании реквизитов в закрытом периоде - "Есть ли жизнь в закрытом периоде? Или способ заставить работать "Обработку заполнения табличных частей" в закрытом периоде".
В этой публикации рассматриваются два способа:
1. С минимальными изменениями кофигурации (добавляется всего ОДНА строка!);
2. Без внесения изменений в конфигурацию.
rozer; endru; +2 Ответить
12. OdinAss 20.11.14 15:52 Сейчас в теме
Реализовывал вторую задачу внешней обработкой без изменения конфы (но новые значения реквизита пользователь выбирал в форме обработки, а не в документах) в БП 3.0. Не очень читабельно, но оставлю здесь ключевой кусок, может пригодиться кому =)

&НаСервере
Процедура УстановитьНаСервере()
	
	УстановитьПривилегированныйРежим(Истина);

// для отмены проверки даты запрета изменения можно использовать
// Док.ДополнительныеСвойства.Вставить("ПропуститьПроверкуЗапретаИзменения",
// Истина); 
// но т.к. вслед за РТУ/ПТУ перезаписываются связанные с/ф, для которых 
// доп. свойство не передать, то использовал следующее 
// (устанавливает параметр сеанса ПропуститьПроверкуЗапретаИзменения)

	ДатыЗапретаИзмененияСлужебный.ПропуститьПроверкуЗапретаИзменения(Истина);

//заполняю нужный реквизит в документах

	Для Каждого Строка Из Объект.СписокДокументов Цикл
		Если Строка.Статус <> Строка.НовСтатус 
			И Строка.НовСтатус <> Перечисления.СтатусыДокументов.ПустаяСсылка() Тогда
			Док = Строка.Документ.ПолучитьОбъект();
			Док.Статус = Строка.НовСтатус;
			Попытка
				Док.Записать(РежимЗаписиДокумента.Запись);
				Строка.Статус = Строка.НовСтатус;

// документ записан, но если период закрыт, то необходимо восстановить его 
// в последовательности проведения документов

				Если ДатыЗапретаИзмененияСлужебный.ИзменениеИлиЗагрузкаЗапрещена(Док,Док.Ссылка,Ложь) Тогда 
					ВернутьВПоследовательность(Док.Ссылка);
				КонецЕсли;

// тоже самое для счетов-фактур

				Если ТипЗнч(Док) <> Тип("ДокументОбъект.АктСверкиВзаиморасчетов") Тогда
					СчетФактура = УчетНДСПереопределяемый.НайтиПодчиненныйСчетФактуруВыданныйНаРеализацию(Док.Ссылка);
					Если СчетФактура <> Неопределено И Не СчетФактура.Пустая() Тогда
						Если ДатыЗапретаИзмененияСлужебный.ИзменениеИлиЗагрузкаЗапрещена(СчетФактура.ПолучитьОбъект(),СчетФактура,Ложь) Тогда
							ВернутьВПоследовательность(СчетФактура);
						КонецЕсли;
					КонецЕсли;
				КонецЕсли;				
			Исключение
				Сообщить("Не удалось изменить статус: " + Строка.Документ);
			КонецПопытки;
		КонецЕсли;
	КонецЦикла;

//возвращаем параметр сеанса

	ДатыЗапретаИзмененияСлужебный.ПропуститьПроверкуЗапретаИзменения(Ложь);
	УстановитьПривилегированныйРежим(Ложь);
	
КонецПроцедуры

&НаСервере
Процедура ВернутьВПоследовательность(ДокСсылка)

	НаборЗаписей = Последовательности.ДокументыОрганизаций.СоздатьНаборЗаписей();
		
	НаборЗаписей.Отбор.Регистратор.Значение = ДокСсылка;
	НаборЗаписей.Отбор.Регистратор.Использование = Истина;
	НаборЗаписей.Прочитать();
	НаборЗаписей.Очистить();
		
	Запись = НаборЗаписей.Добавить();
	//Запись.Период = Новый МоментВремени(ДокСсылка.Дата,ДокСсылка);
	Запись.Период = ДокСсылка.Дата;	
	Запись.Регистратор = ДокСсылка;
	Запись.Организация = ДокСсылка.Организация;
	Запись.СостояниеПроведения = Перечисления.СостоянияПроведенияВПоследовательности.ПроведенВПоследовательности;
	
	НаборЗаписей.Записать(Истина);
	
КонецПроцедуры
Показать
jobkostya1c_ERP; Трактор; +2 Ответить
13. Allexe8.1 21.11.14 17:39 Сейчас в теме
Проверку на наличие ссылки в базе, думаю, лучше запросом делать:
//1) объектный способ, получаются все реквизиты, все ТЧ объекта:
НетСсылки = СсылкаНаОбъект.ПолучитьОбъект() = Неопределено

//2) метод запроса, только проверка:
Запрос = Новый Запрос("ВЫБРАТЬ ПЕРВЫЕ 1 1 ИЗ " + ИмяКласса+ "." + ИмяВида + " ГДЕ Ссылка = &Ссылка");
Запрос.УстановитьПараметр("Ссылка", СсылкаНаОбъект);
РезультатЗапроса = Запрос.Выполнить();
НетСсылки = РезультатЗапроса.Пустой();
u_n_k_n_o_w_n; +1 Ответить
14. Трактор 1246 21.11.14 17:56 Сейчас в теме
(13) Allexe8.1,
1. СсылкаНаОбъект.ПолучитьОбъект() у меня используется. Это, кстати, довольно тяжёлый метод. Я всё думал как обойтись без него, но не придумал. Метод тяжёл так как при получении объекта происходит инициализация модуля объекта, а что там понаписал программист мы не знаем.

2. Читать запросом реквизиты ссылки, конечно прикольно, но в этом случае число запросов будет на один больше числа табличных частей объекта. А если читать реквизиты как Ссылка (точка) Имя реквизита, то значения реквизитов кэшируются и/или подтягиваются при чтении, точно не помню. Важно что число запросов к базе примерно такое же как и при чтении запросом. Только эти запросы выполняются в фоне. По сути разницы нет как читать реквизиты ссылки.
16. пользователь 24.11.14 10:15
Сообщение было скрыто модератором.
...
17. fishca 1254 24.11.14 15:59 Сейчас в теме
1. Тексты модулей должны быть написаны на русском языке. В текстах модулях не допускается использовать букву "ё".

Они вообще сами-то с русским языком дружат !!!???
18. DarLord 8 26.11.14 11:18 Сейчас в теме
(17) А какой оператор ты хочешь с буквой Ё написать???
19. DAnry 8 26.11.14 14:30 Сейчас в теме
Всё понимаю, вот только зачем мертвеца реанимировать (имею ввиду илюстрацию к статье)!?
22. Трактор 1246 26.11.14 15:33 Сейчас в теме
вот только зачем мертвеца реанимировать

(19) DAnry, капитализм принёс уже две мировые войны. Боюсь, что сейчас мы живём в начальный период третьей мировой войны. Капитализм смог развалить СССР. Но СССР жив пока жив, например, я и другие, разделяющие мои убеждения. Я надеюсь возродить СССР, исправив ошибки.

враньё. можно запросто создать документ и справочник с одинаковыми названиями.

(21) МихаилМ, это кусок кода и комментарий из работающей конфы. В ней имена справочников и документов не пересекаются.
Как-нибудь поправлю, уберу это замечание или напишу, что нежелательно пересекать названия.
dvsidelnikov; +1 Ответить
20. DAnry 8 26.11.14 14:51 Сейчас в теме
Насчёт буквы ё. Конечно нельзя ёё так "опускать". Это изюминка русского языка, не дайте ей исчезнуть. Сам я не русский, но думаю имею право высказать своё мнение, потому что у нас, украинцев, тоже есть похожая ситуация, даже две - "ї" и "ґ". Берегите родной язык.
BorisBelov; Allexe8.1; Трактор; +3 Ответить
21. МихаилМ 26.11.14 14:52 Сейчас в теме
"// Тип - наименование вида справочника или документа. Благо их наименования не пересекаются."

враньё. можно запросто создать документ и справочник с одинаковыми названиями.
те будут "пересекаться"
так что код условно рабочий.
Прикрепленные файлы:
23. jobkostya1c_ERP 100 26.11.14 18:57 Сейчас в теме
Про доступ к сайту по ГУИД не понял. Наверное Вы говорили про доступ к базе 1С 8?
Про "перепроведение" тоже приемы могут пригодиться. Жаль что не всегда.
Вопрос как быть если конфигурация в желтых кубах "за замке" и трогать ее нельзя. Пишите что и нижеприведенный прием не помогает.

ДокОбъект.ОбменДанными.Записать = Истина;
ДокОбъект.Записать(РежимЗаписиДокумента.Запись);

Я спросил про задачи, когда нужно программно перезаполнить документы в прошлом закрытом периоде или установить значение нового реквизита.
Не всегда ведь даже признак в свойствах у документа может быть "записывать модифицированные при проведении" и прочие свойства формы документа "при записи перепроводить".
Когда все закрыто тут как быть то?
Прикрепленные файлы:
24. Трактор 1246 26.11.14 22:51 Сейчас в теме
Вопрос как быть если конфигурация в желтых кубах "за замке" и трогать ее нельзя

(23) kostyaomsk, тогда остаются только внешние обработки. О них написано выше. Можно хоть печатную форму, обработку заполнения табличной части использовать для этого. Открывать свою форму и из неё редактить что угодно.

Я не говорил, что нельзя использовать конструкцию
ОбменДанными.Записать = Истина; 

Можно. Но надо помнить о последствиях. Для распределённой базы, для логики, связанной с изменяемыми реквизитами. Короче говоря если осторожно, то можно всё.
jobkostya1c_ERP; +1 Ответить
25. jobkostya1c_ERP 100 28.11.14 07:21 Сейчас в теме
(24) спасибо, видел что можно внешними обработками реализовать такие функции записи без проведения. Возможно, в отраслевых конфигурациях опять что-то попалось из обработчиков. Проверю на типовых.
26. sas95 09.12.14 14:20 Сейчас в теме
27. rbsoft 208 15.10.23 08:41 Сейчас в теме
Полезные функции. Спасибо.
Можно оптимизировать скорость.
// Если тип неизвестен, то перебираем все справочники и документы.
// Это долго. Поэтому тип очень хочется получить.
    Для Каждого спр из Метаданные.Справочники Цикл
        Ссылка = Справочники[спр.Имя].ПолучитьСсылку(УИД);
        Если Ссылка.ПолучитьОбъект() <> Неопределено Тогда
            Возврат Ссылка
        КонецЕсли;
    КонецЦикла;
    
    Для Каждого док из Метаданные.Документы Цикл
        Ссылка = Документы[док.Имя].ПолучитьСсылку(УИД);
        Если Ссылка.ПолучитьОбъект() <> Неопределено Тогда
            Возврат Ссылка
        КонецЕсли;
    КонецЦикла;
Показать


Ссылка.ПолучитьОбъект() - очень затратная операция. Читается весь из базы объект в память. А нам надо просто убедиться что ссылка есть в базе.
Если заменить на поиск в таблице по ссылке, то скорость значительно увеличится.

Например:
Добавить функцию для поиска по любой таблице по любому полю:

Функция НайтиСсылкуПоПолю(ТипТаблицы,ИмяПоляПоиска,ЗначениеПоиска) экспорт
	 Запрос = Новый Запрос;
	 Запрос.Текст = "ВЫБРАТЬ ПЕРВЫЕ 1
	 |	Таблица.Ссылка КАК Ссылка
	 |ИЗ
	 |	"+ТипТаблицы+" КАК Таблица
	 |ГДЕ
	 |	Таблица."+ИмяПоляПоиска+" = &ЗначениеПоиска";
	 
	 Запрос.УстановитьПараметр("ЗначениеПоиска", ЗначениеПоиска);
	 
	 Результат = Запрос.Выполнить();
	 Выборка = Результат.Выбрать();
	 
	 Если Выборка.Следующий() Тогда
	     возврат Выборка.Ссылка;
	 КонецЕсли;
	 возврат Неопределено;
 КонецФункции
Показать


Переписать кусок кода так:

// Если тип неизвестен, то перебираем все справочники и документы.
    // Это долго. Поэтому тип очень хочется получить.
    Для Каждого спр из Метаданные.Справочники Цикл
                Ссылка = Справочники[спр.Имя].ПолучитьСсылку(УИД);
		//Если Ссылка.ПолучитьОбъект() <> Неопределено Тогда
		//    Возврат Ссылка
		//КонецЕсли; 
		
		Если НайтиСсылкуПоПолю(спр.ПолноеИмя(),"Ссылка",Ссылка)<>Неопределено Тогда
			возврат Ссылка;
		КонецЕсли;	
		
    КонецЦикла;
    
    Для Каждого док из Метаданные.Документы Цикл
                Ссылка = Документы[док.Имя].ПолучитьСсылку(УИД);
		//Если Ссылка.ПолучитьОбъект() <> Неопределено Тогда
		//    Возврат Ссылка
		//КонецЕсли;
		Если НайтиСсылкуПоПолю(док.ПолноеИмя(),"Ссылка",Ссылка)<>Неопределено Тогда
			возврат Ссылка;
		КонецЕсли;	
    КонецЦикла;

Показать
Трактор; +1 Ответить
Оставьте свое сообщение